PC World Komputer 1996 May/PCW596.iso/polskie/eduk/genfast/genfast.lzh/DEMO_08.PAK/KULKA21.DA_

Text File | 1996-02-08 | 3KB | 154 lines

; Animowana kulka - aplikacja przykladowa
; Wykonanie: Piotr W.-Rakowski, 1996
; Wersja 1.1

; Obszerniejsze komentarze znajdziesz w pliku:
; KULKA2.DA_

[1!]
@ClrScr;
@Reset;
@ShowScreen;
@DisableStatusBar;
; Miejsce, od którego bædzie wy₧wietlana kulka
@A:=50
@B:=50
; Zdefiniowanie kierunku ruchu kulki
@K:=2
; Zdefiniowanie przesuniæcia kulki
@L:=2
; Zdefiniowanie szybko₧ci wy₧wietlania (dokÆadnie jest to
; zdefiniowanie pauzy pomiædzy dwoma kolejnymi wy₧wietleniami kulki
@D:=50
@E:=11
@DefIdleProc(6)
@UpArea(20,20,620,410,4);
@DownArea(29,29,611,401,7);
@DownArea(80,420,260,470,7);
@SetPosition(90,430);
@FastWrite('ANIMACJA-PrzykÆad 2');
@SetPosition(90,450);
@FastWrite('GENFAST wersja 2.0');
@DrawButton(20,420,70,470,7,200,'koniec.rbm','');
; Klawisz zmiany kulki
@DrawButton(270,420,300,470,7,40,'kulka.rbm','');
; Zdefiniowanie klawiszy zwiækszania i zmniejszania prædko₧ci kulki
@DrawButton(302,420,343,470,7,31,'lewo.rbm','');
@DrawButton(346,420,386,470,7,30,'prawo.rbm','');
; Klawisze zmiany kierunku kulki
@DrawButton(390,420,440,470,7,20,'kulka1.rbm','');
@DrawButton(450,420,500,470,7,21,'kulka2.rbm','');
@DrawButton(510,420,560,470,7,22,'kulka3.rbm','');
@DrawButton(570,420,620,470,7,23,'kulka4.rbm','');

[100]
@CheckEvents;

[2]
@A:=%A+%L
@B:=%B+%L
@IF (%B >= 370) Then GoSub:7
@IF (%A >= 580) Then GoSub:9
@Goto:100

[3]
@A:=%A+%L
@B:=%B-%L
@IF (%A >= 580) Then GoSub:8
@IF (%B <= 30) Then GoSub:10
@Goto:100

[4]
@A:=%A-%L
@B:=%B-%L
@IF (%B <= 30) Then GoSub:9
@IF (%A <= 30) Then GoSub:7
@Goto:100

[5]
@A:=%A-%L
@B:=%B+%L
@IF (%A <= 30) Then GoSub:10
@IF (%B >= 370) Then GoSub:8
@Goto:100

[6]
@SetPosition(%A,%B);
@IF (%E = 6) Then Begin
;Pierwotnie w tym miejscu byla nastepujaca linia:
@Picture('Kulka.pcx');
@Delay(%D);
@End;
;Kulka zostala zamieniona na postaì wektorowå '.CGV'
;@Picture('Kulka.cgv');
@IF (%E = 11) Then Begin
@Picture('Kulka2.pcx');
@Delay(%D);
;@Clear(%A,%B,%A+30,%B+30);
@End;
@Goto:%K

[7]
@K:=3
@Sound(100,%D);
@Return;

[8]
@K:=4
@Sound(100,%D);
@Return;

[9]
@K:=5
@Sound(100,%D);
@Return;

[10]
@K:=2
@Sound(100,%D);
@Return;

[20]
@GoSub:10
@GoTo:6

[21]
@GoSub:7
@GoTo:6

[22]
@GoSub:8
@GoTo:6

[23]
@GoSub:9
@GoTo:6

[30]
@D:=%D-5
@IF (%D < 0) Then Begin
@D:=0
@End;
@GoTo:100

[31]
@D:=%D+5
@IF (%D > 100) Then Begin
@D:=100
@End;
@GoTo:100

[40]
; Procedura typu 'przeÆåcznik'
@IF (%E = 6) Then Begin
@E:=11
@GoTo:100
@End;
@IF (%E = 11) Then Begin
@E:=6
@GoTo:100
@End;

[200]
@ReplaceProgram('shell.dat',1);