PC World Komputer 1998 April A/Pcwk4a98.iso/Wtestowe/OnNet16/TNTCH16.XXX

Text File | 1996-12-15 | 36KB | 1,174 lines

Const APPNAME = "TNVTPlus Script Wizard:"
Const RECORDNAME = "TNVTPlus Script Utility:"
Const WAITFORINPUT = "Waiting for input..."

Const GL_CANCEL = 0
Const GL_DATA = 1
Const GL_TIMOUT = 2
Const QUOTE = 34

' these constants must be the same in tnteach.tos
Const GR_CANCEL = 0
Const GR_NORMAL = 1
Const GR_IGNORE = 2
Const GR_DONE = 4
Const GR_PASSWORD = 5
Const GR_LOGIN = 6
Const GR_ENTER = 7
Const GR_DONE_TELNET = 8

Const CCR = 13
Const CLF = 10
Const CSP = 32

' Windows API calls for Help

Declare Function WinHelp Lib "user.dll" Alias "WinHelp" _
   (ByVal hWnd&, ByVal helpfn$, ByVal hflags%, ByVal hkey&) As Integer
Declare Function GetActiveWindow Lib "user.dll" () As Long

Declare Function Welcome%(id$, act%, spv&)
Declare Function SetTimer%(id$, act%, spv&)
Declare Function SetLogin%(id$, act%, spv&)
Declare Function WaitData%(id$, act%, spv&)
Declare Function GetOptions%(id$, act%, spv&)
Declare Function SetSaveas%(id$, act%, spv&)

Option Compare Binary   'TODO check this out!!!

Dim WelcomeRc as String
Dim HostReturn as String
Dim TimerReturn as String
Dim LoginRc as String
Dim SaveAsRc as String

Dim cchoices as String
Dim ComboBox1 as String
Dim myarray$(5)
Dim DefaultSecs
Dim waittime as String
Dim hostpromptchar as String
Dim Username as String, Password as String
Dim PasswordPrompt As String, LoginPrompt As String, PasswordPromt2 As String
Dim SavePassword As Integer
Dim ReadCount as Integer, custominit as Integer
Dim hostname as string
Dim port as string
Dim wVisible as Integer
Dim closeTelnet As Integer
Dim wCreateSte as Integer
Dim wPlaybackVis as Integer
Dim OutFilename as String
Dim SteFilename as String

Dim Telnet as object
Dim Session as object

' Prompt and Response builtins

Dim tn_prompt(20) As String
Dim tn_numprompts As Integer

Dim tn_suggest(20) As Integer

Dim tn_target() As String
Dim tn_numtargets As Integer
Dim tn_responsetype() As Integer
Dim tn_response() As String

' GetLine dialog box definitions and global vars

Const MAXBUFLEN = 4000
Const MAXLEN = MAXBUFLEN*2 + 1
Dim gl_bfr As String       ' Global input buffer
Dim gl_linbuf As String    ' Line buffer - parsed from input stream
Dim gl_lastline As String  ' Last line of text from host
Dim gl_lastatom As String  ' Last line of text from host
Dim gl_timeout As Integer  ' Dialog timeout value
Dim response As String
Dim glres As Integer, grres As Integer



Function Welcome%(id$, act%, spv&)


     Select Case act
      Case 2
         If DlgControlID(id) = DlgControlID("cancel1") Then
             WelcomeRc = "cancel"
         End If

         If DlgControlID(id) = DlgControlID("cancel1") Then
             WelcomeRc = "cancel"
         End If

         If DlgControlID(id) = DlgControlID("next1") Then
             WelcomeRc = "next"
         End If
     End Select

End Function

Function SetTimer%(id$, act%, spv&)

     Select Case act
      Case 1
          DlgText 5, waittime
          DlgFocus 5
          DlgValue 7, wVisible

      Case 2
         If DlgControlID(id) = DlgControlID("back2") Then
             TimerReturn = "back"
         End If

         If DlgControlID(id) = DlgControlID("cancel2") Then
             TimerReturn = "cancel"
         End If

         If DlgControlID(id) = DlgControlID("next2") Then
            waittime = DlgText(5)
            If VAL(waittime) < 1 Or VAL(waittime) > 300 Then
                 waittime = "30"
            End If
            TimerReturn = "next"

            If DlgValue(7) = 1 Then
                wVisible = 1
            Else
                wVisible = 0
            End If


         End If
     End Select

End Function

Function SetPrompt%(id$, act%, spv&)

     Select Case act
      Case 1
          DlgText 7, port
          DlgText 9, hostpromptchar
          DlgText 5, hostname
          DlgFocus 5

      Case 2
         If DlgControlID(id) = DlgControlID("back4") Then
             HostReturn = "back"
         End If

         If DlgControlID(id) = DlgControlID("cancel4") Then
             HostReturn = "cancel"
         End If

         If DlgControlID(id) = DlgControlID("next4") Then
             hostpromptchar = DlgText(9)
             port = DlgText(7)
             hostname = DlgText(5)

            If hostname = "" Then
                i = MsgBox("You must specify a hostname to continue! ",0,"Create Wizard Script: specify hostname")
                DlgFocus 5
                SetPrompt = 1
            Else
                HostReturn = "next"
            End If
         End If
     End Select

End Function


Function SetLogin%(id$, act%, spv&)
Dim i as Integer

     Select Case act
      Case 1
         DlgText 8, LoginPrompt                    ' set up LoginPrompt text in edit box
         DlgText 9, PasswordPrompt                 ' set up PasswordPrompt text in edit box
         DlgValue 10, SavePassword                 ' Checkbox SavePassword on or off
         DlgValue 11, wCreateSte                   ' Checkbox to create a .ste file on or off
         DlgEnable 9, wCreateSte AND SavePassword  ' Grey out PasswordPrompt edit box if can't create Password or .ste file
         DlgEnable 10, wCreateSte                  ' Grey out save password checkbox if can't create .ste file
         DlgFocus DlgControlID("TextBox1")         ' Focus on Username edit box
         DlgText 7, Username


      Case 2
         If DlgControlID(id) = DlgControlID("back3") Then
             LoginRc = "back"
         End If

         If DlgControlID(id) = DlgControlID("CheckBox1") Then
             DlgFocus DlgControlID("TextBox1")
         End If

         ' If Save Password unchecked, then grey out PasswordPrompt edit box.
         If DlgControlID(id) = DlgControlID("CheckBox1") Then
             SavePassword = DlgValue(10)
             DlgEnable 9, SavePassword
         End If

         ' If Save .ste file is unchecked, then grey out PasswordPrompt edit box and Save Password check box.
         If DlgControlID(id) = DlgControlID("CheckBox2") Then
             i = DlgValue(11)
             If i = 0 Then
                 wCreateSte = 0
                 DlgEnable 9, 0
                 DlgEnable 10, 0
             Else
                 wCreateSte = 1
                 DlgEnable 9, SavePassword
                 DlgEnable 10, 1
             End If
         DlgFocus DlgControlID("TextBox1")
         End If

         If DlgControlID(id) = DlgControlID("cancel3") Then
             LoginRc = "cancel"
         End If

         If DlgControlID(id) = DlgControlID("next3") Then
            Username = DlgText(7)
            LoginPrompt = DlgText(8)
            PasswordPrompt = DlgText(9)

            If Username = "" Then
                i = MsgBox("You must specify a Username to continue! ", 0, "Create Wizard Script: specify username")
                DlgFocus DlgControlID("TextBox1")
                SetLogin = 1
            Else
                LoginRc = "next"
            End If
         End If
     End Select

End Function

Function GetOptions%(id$, act%, spv&)
static tmptime As String, tmpchar As String


     Select Case act
      Case 1
          DlgText 4, waittime
          DlgText 1, hostpromptchar
          DlgValue 0, wVisible

      Case 2
         If DlgControlID(id) = DlgControlID("cancel") Then
             Exit Function
         End If

         If DlgControlID(id) = DlgControlID("ok") Then
             If DlgValue(0) = 1 Then
                 wVisible = 1
                 Telnet.Visible = TRUE
             Else
                 wVisible = 0
                 Telnet.Visible = FALSE
             End If

             waittime = DlgText(4)
             If VAL(waittime) < 1 Or VAL(waittime) > 300 Then
                 waittime = "30"
             End If

             hostpromptchar = DlgText(1)
             Exit Function
         End If


     End Select

End Function

Function SetSaveas%(id$, act%, spv&)

     Select Case act
      Case 1
         DlgValue 6, wPlaybackVis
         DlgFocus 3
         OutFilename = ""
         SaveAsRc = ""

      Case 2
         If DlgControlID(id) = DlgControlID("ok1") Then
             OutFilename = DlgText(3)
         End If

         If DlgControlID(id) = DlgControlID("cancel1") Then
             SaveAsRc = "cancel1"
         End If

         If DlgValue(6)  Then
             wPlaybackVis = 1
         Else
             wPlaybackVis = 0
         End If

      End Select

End Function

Sub InitVars()

  ' Setup built-in prompts and suggested responses

   tn_prompt(1) = "ogin:"
   tn_prompt(2) = "username:"
   tn_prompt(3) = "userid:"
   tn_prompt(4) = "id:"
   tn_prompt(5) = "password:"
   tn_prompt(6) = "who:"
   tn_prompt(7) = "id:"
   tn_prompt(8) = "user:"
   tn_prompt(9) = "login:"
   tn_prompt(10) = "name:"
   tn_prompt(11) = "secret"
   tn_prompt(12) = "security"
   tn_prompt(13) = "key"
   tn_prompt(14) = "Login:"
   tn_prompt(15) = "Password:"

   tn_numprompts = 16

   For k = 0 To 15
      tn_suggest(k) = 0
   Next k

   tn_suggest(5) = 1
   tn_suggest(11) = 1
   tn_suggest(12) = 1
   tn_suggest(13) = 1
   tn_suggest(15) = 1

   If hostpromptchar <> "" Then
       tn_prompt(0) = hostpromptchar
       tn_suggest(0) = 3      ' custom text if prompt not found!
   Else
       tn_prompt(0) = "login:"
   End If

End Sub

Sub SetOptions()

ctext1$ = ">"+CHR$(9)+"$"+chr$(9)+"#"+chr$(9)+"yourtext>"
ctext2$ = "30"+chr$(9)+"60"+chr$(9)+"90"+chr$(9)+"120"

Begin Dialog optionsdlg 281, 159, "TNVTPlus Script Utility:  Change Options", .GetOptions
   CheckBox  10, 66, 117, 11, "&Display TNVTPlus window", .CheckBox1
   DropComboBox  131, 10, 107, 70, ctext1, .DropComboBox1
   Text  9, 12, 117, 10, "Additional host prompt strings:", .Text1
   Text  9, 39, 117, 11, "Change host timeout:"
   DropComboBox  131, 34, 107, 70, ctext2, .DropComboBox2
   OkButton  137, 92, 50, 14, .ok
   CancelButton  189, 92, 50, 14, .cancel
End Dialog

   Dim optdlg as optionsdlg

   res = Dialog(optdlg)

End Sub


' Add target and response to playback tables

Sub AddResponse(target As String, resp As String, rtype As Integer)
   ReDim Preserve tn_target(tn_numtargets)
   ReDim Preserve tn_response(tn_numtargets)
   ReDim Preserve tn_responsetype(tn_numtargets)

   tn_target(tn_numtargets) = target
   tn_response(tn_numtargets) = resp
   tn_responsetype(tn_numtargets) = rtype

   tn_numtargets = tn_numtargets + 1
End Sub

' Output script opens a NewSession File
Sub WriteNewSession( fnum as Integer )

      Print #fnum, Tab(4) "set Session = Telnet.NewSessionFile"
      ResStr = "Session.Hostname =" & """" & hostname & """"
      Print #fnum, Tab(4) ResStr

      ResStr = "Session.Port =" & """" & port & """"
      Print #fnum, Tab(4) ResStr

      ResStr = "Session.Username =" & """" & Username & """"
      Print #fnum, Tab(4) ResStr

      Print #fnum, Tab(4) "Session.Connect"
End Sub

' Output script opens a saved .ste File and connects
Sub WriteOpenSession( fnum as Integer )

     Session.Username = Username
     If SavePassword = 1 Then
         Session.Password = Password
         Session.PasswordPrompt = PasswordPrompt
         Session.SavePassword = SavePassword
     End If

     Session.UsernamePrompt = LoginPrompt

     Telnet.SaveSessionFileAs(SteFilename)
     Print #fnum, Tab(4) "set Session = Telnet.OpenSessionFile(" & """" & SteFilename & """" & ")"

End Sub

Function askcancel As Integer
Dim answer as Integer

     answer = MsgBox("Are you sure you want to cancel and end the script without saving?",4,"Create Wizard Script: Cancel")
     askcancel = answer

End Function

Function LookupStringTable(tbl() As String, tmax As Integer, bfr As String) As Integer

   Dim k As Integer

   For k = 0 To tmax - 1
      If InStr(bfr, tbl(k)) > 0 Then
         LookupStringTable = k
         Exit Function
      End If
   Next k
   LookupStringTable = -1
End Function

Sub WriteScript( fnum as Integer )
    Dim ResStr as String, indx as Integer
    Dim InitVars As String
    Dim j as Integer

    ' write out the targets and responses that the user chose
    ResStr = "tn_numtargets =" & tn_numtargets
    For indx = 0 to tn_numtargets-1
       ResStr = "AddResponse " & """" & tn_target(indx) & """" & "," & """" & tn_response(indx) & """" & "," & tn_responsetype(indx)
       Print #fnum, Tab(4) ResStr
    Next indx

       Print #fnum,           ' Add a blank line

    '  Set up the telnet object and session; then connect

       Print #fnum, Tab(4) "set Telnet = CreateObject(""FTPSTNVTPlus.Application"")"


       If wCreateSte = 0 Then
          WriteNewSession( fnum )
       Else
          WriteOpenSession( fnum )
       End If

       ResStr = "Telnet.Visible = " & wPlaybackVis
       Print #fnum, Tab(4) ResStr

       ResStr = "wCreateSte = " & wCreateSte
       Print #fnum, Tab(4) ResStr

       ResStr = "waittime = " & """" & waittime & """"
       Print #fnum, Tab(4) ResStr

       Print #fnum, Tab(4) "If (tn_numtargets <> 0) Then res = ProcessTargets()"

       If closeTelnet <> 0 Then
           Print #fnum, Tab(4) "If NOT Telnet Is Nothing Then Telnet.VISIBLE = FALSE"
       End If

       Print #fnum, "End Sub"

End Sub

' All done recording, now do something about it

Function WrapItUp As Integer

Begin Dialog saveasdlg 281, 159, "TNVTPlus Script Utility:  Save As", .Setsaveas
   PushButton  152, 101, 40, 14, "OK", .ok1
   CancelButton  193, 101, 40, 14, .cancel1
   Text  1, 53, 73, 12, "Save File As :"
   TextBox  53, 51, 175, 17, .TextBox1
   GroupBox  1, 7, 229, 31, "Tip:"
   Text  11, 20, 204, 12, "Use extension .ote in order to automatically run this script."
   CheckBox  1, 79, 9, 12, "CheckBox", .CheckBox2
   Text  17, 82, 199, 15, "Disply TNVTPlus window when script runs"
End Dialog

    Dim res as Integer, attrib as Integer
    Dim savedlg as saveasdlg
    Dim fout as Integer
    Dim defaultDir as String,msgtext as String
    Dim position as Integer
    Dim pattern as String
    pattern = "/*?<>|"

saveas:
    res = Dialog(savedlg)


    ' cancel was chosen - ask user if sure
    if SaveAsRc = "cancel1" OR OutFilename = "" Then
        if (askcancel = 6) Then
            WrapItUp = -1
            Exit Function
        Else
            GoTo saveas
        End If
    End If

    lPattern = Len(pattern)
    For i = 1 TO lPattern
        position = InStr(OutFilename , Mid(pattern,i,1))
        If ( position <> 0 ) Then
            GoTo saveas
        End If
    Next i

    ' add .ste extension to create the STE filename
    OutFilename = Trim$(OutFilename)
    SteFilename = OutFilename

    ' If ".ote" extension not found, add .ste, else replace .ote with .ste extension
    position=InStr(SteFilename,".ote")
    If position = 0 Then
        SteFilename = SteFilename & ".ste"
    Else
        SteFilename = Left$(SteFilename,position-1) & ".ste"
    End If

    ' If ".ote" not found, add it to the end of the filename
    position=InStr(OutFilename,".ote")
    If position = 0 Then
        OutFilename = OutFilename & ".ote"
    End If

    ' If a filename is not fully qualified, then save it in the default sessions directory
    If InStr(OutFilename,"\") = 0 AND InStr(OutFilename,":") = 0 AND InStr(OutFilename,CHR$(QUOTE)) = 0 Then
       defaultDir = Telnet.DefaultDirectory
       OutFilename = Telnet.DefaultDirectory & "\" & OutFilename
       SteFilename = Telnet.DefaultDirectory & "\" & SteFilename
    End If

   ' test if file already exists!
   fout=FreeFile

   res = 0
   On Error Resume Next
   Err = 0
   attrib = GetAttr(OutFilename)

   ' check if file already exists

   If Err = 53 Then GoTo erroff
   If  Err <> 0 Then
       msgtext="File I/O error: Error number " & Err & " occurred at line: " & Erl
       i = MsgBox (msgtext, 0, "Create Wizard Script: File I/O error")
       GoTo saveas

   Else
   'check if file is write only
       if attrib <> 0 AND attrib <> 32 Then
           msgtext = " File i/o error: write permission denied - " & attrib
           i = MsgBox(msgtext ,0, "Create Wizard Script: File error")
           GoTo saveas
       Else
           ' if the file already exists - ask the user to overwrite it.
           msgtext = OutFilename & " already exists. Overwrite it anyway?"
           res = MsgBox (msgtext,4,"Create Wizard Script: File exists")
           Close #fout
           if res = 7 Then
               GoTo saveas
           End If
       End If
   End If

erroff:
   Close #fout

    ' copy the teach mode template to the output file
    On Error Resume Next
    Err = 0
    FileCopy "tnteach.tos", OutFilename
    If Err <> 0 then
       msgtext="File I/O error: Error number " & Err & " occurred at line: " & Erl
       i = MsgBox (msgtext, 0, "Create Wizard Script: File I/O error")
       GoTo saveas
    End If

    fout=FreeFile

    Open OutFilename For Append as fout
       if Err <> 0 Then
        WrapItUp = -1
        Exit Function
    End If

    On Error GoTo 0

    WriteScript(fout)

    Close #fout
    WrapItUp = fout
    Exit Function

End Function


' Return last atom at the end of a data buffer

Function GetLastAtom(bfr As String, spos As Integer) As String
   Dim ix As Integer, ll As Integer

   ' Scan left from spos for first space

   For ix = spos To 1 Step -1
      if Mid$(bfr, ix, 1) = Chr$(CSP) Then Exit For
   Next ix

   ' Return last (space delimited) atom at end-of-line

   GetLastAtom = Mid$(bfr, ix + 1, spos - ix)
End Function

' get last line of data for user prompt dialog box
Sub GetLastLine(bfr As String, spos As Integer)
   Dim ix As Integer, ll As Integer
   Dim temp As String, x As String

   ' Scan left from spos for first space

   For ix = spos To 1 Step -1
      x = Mid$(bfr, ix, 1)
      if x = CHR$(10) OR x = CHR$(CCR) OR x = CHR$(CLF) OR x = CHR$(0) Then Exit For
   Next ix

   ' Return last line of text (delimited by CR or LF)
   temp$ = Mid$(bfr, ix + 1, spos - ix)
   gl_lastline = temp
End Sub

Sub ReplaceChar(bfr As String, char as String)
   Dim ix As Integer

   ix = InStr(1, bfr, char)
   Do While ix > 0
      mid(bfr, ix, 1) = Chr$(CSP)
      ix = InStr(ix + 1, bfr, char)
   Loop
End Sub



' Dialog function
' Reads data until data is received or timeout (gl_timeout) occurs

Function WaitData%(id$, act%, spv&)
   Static timeoutStart as Long
   Static sectime as Long
   Static cc as Integer

   Dim thisSecs as Long
   Dim pos as Integer, sts As Integer

   Select Case act
      Case 1                  ' Dialog init
         'ReadCount = 0
         cc = 0
         timeoutStart = timer
         sectime = timer
         gl_bfr = ""
         AppActivate RECORDNAME

      Case 2
         If DlgControlID(id) = DlgControlID("cancel") Then
            DlgEnd GL_CANCEL
         End If

      Case 5                  ' Dialog idle callback

         ' Check for more input data every 2 seconds
         If timer > sectime + 2 Then
             gl_bfr = Session.GetEmulatorData(MAXBUFLEN)  ' read emulator data from TNVTPlus.
             cc = Session.LastReadCount                   ' how many bytes we just read.
             sectime = timer

             If cc > 0 Then
                 gl_linbuf = gl_linbuf + Left$(gl_bfr, cc) ' append data just read to gl_linbuf
                 ReadCount = ReadCount + cc
                 timeoutStart = timer                   ' reset the timeout timer every time we get more data
                 If ReadCount > MAXLEN Then
                     gl_linbuf = Left$(gl_bfr, MAXBUFLEN)
                     ReadCount = MAXBUFLEN
                 End If
             End If
         Else
             ' Kept reading data until there was no more (cc=0).
             If ReadCount > 0  AND cc = 0 Then
                 DlgEnd GL_DATA
             End If
         End If

         ' Check for timeout : gl_timeout is the maximum amt. of seconds to not see any data from TNVTPlus.
         thisSecs = timer
         If thisSecs < timeoutStart Then thisSecs = thisSecs + 24*3600
         thisSecs = gl_timeout - (thisSecs - timeoutStart)
         If thisSecs < 0 Then
             DlgEnd GL_TIMOUT   ' Timeout
         End If

         WaitData = 1      ' Keep idle loop going going
   End Select
End Function

Function GetLine(timeout As Integer) As Integer
   Begin Dialog waitdlg 129, 47, RECORDNAME, .WaitData
      CancelButton  39, 28, 50, 14, .cancel
      Text  7, 9, 115, 15, WAITFORINPUT, .waittext
   End Dialog

   Dim getdatawdlg as waitdlg
   Dim gl_text as String
   Dim res As Integer

   gl_bfr = ""
   ReadCount = 0
   gl_timeout = timeout
   res = Dialog(getdatawdlg)

   ' Keep receiving data until there is no more or until we've maxed out:
   If res = GL_DATA Or res = GL_CANCEL Then
       GetLastLine gl_linbuf, ReadCount
       gl_lastline = Trim$(gl_lastline)
       gl_lastatom = GetLastAtom(gl_lastline, Len(gl_lastline$))

   End If


   GetLine = res

End Function

Function rspdlgfunc%(id$, act%, spv&)

   Select Case act
      Case 1
         DlgEnable DlgControlID("customtext"), custominit
         If custominit = 1 Then
             DlgFocus DlgControlID("customtext")
         Else
             DlgFocus DlgControlID("ok")
         End If
         AppActivate RECORDNAME


      Case 2

         ' Help was selected
         If DlgControlID(id) = DlgControlID("help") Then
             Call WinHelp(GetActiveWindow(), "tnteach.hlp", 1, 990)
             rspdlgfunc = 1
         Else
             ' Options was selected
             If DlgControlID(id) = DlgControlID("options") Then
                 SetOptions
                 rspdlgfunc = 1
             Else
                 ' Enable custom text box if selected
                 If DlgControlID(id) = DlgControlID("selectcustom") Then
                     DlgEnable DlgControlID("customtext"), 1
                     DlgFocus DlgControlID("customtext")
                 Else
                     DlgEnable DlgControlID("customtext"), 0
                 End If
             End If
         End If

         If DlgControlID(id) = DlgControlID("ok") Then Exit Function
   End Select
End Function

' Converts character pairs ^<char> to special controls

Function CCString(inpstr As String) As String
   CCString = inpstr
End Function

Function GetResponse(inline As String, suggest As Integer, resp As String) As Integer

   Begin Dialog responsedlg 281, 159, RECORDNAME, .rspdlgfunc
   OkButton  210, 68, 46, 15, .ok
   CancelButton  210, 89, 46, 15
   PushButton  210, 107, 46, 15, "&Help", .help
   TextBox  54, 119, 102, 12, .customtext
   Text  5, 12, 200, 10, "How do you respond to:"
   TextBox  5, 26, 185, 12, .inline
   GroupBox  5, 49, 167, 88, "Respond with "
   OptionGroup .response
      OptionButton  13, 65, 50, 10, "&Username", .selectusername
      OptionButton  13, 83, 50, 10, "&Password", .selectpassword
      OptionButton  13, 101, 50, 10, "<&Enter> key", .selectCR
      OptionButton  13, 119, 40, 10, "&Custom:", .selectcustom
      OptionButton  78, 65, 61, 10, "&Ignore", .selectignore
      OptionButton  78, 83, 60, 10, "E&nd Script", .selectdone
      OptionButton  78, 101, 88, 10, "En&d Script and Telnet", .OptionButton1
   PushButton  210, 49, 46, 15, "&Options...", .options
End Dialog

   Dim getuser As responsedlg
   Dim res As Integer

   getuser.inline = inline             ' Seed dialog
   getuser.response = suggest

   If suggest = 3 Then
       custominit = 1
   Else
       custominit = 0
   End If


   res = Dialog(getuser)
   If res = 0 Then
      GetResponse = GR_CANCEL         ' Cancel
      Exit Function
   End If

   GetResponse = GR_NORMAL            ' Assume normal return

   Select Case getuser.response
      Case 0                  ' Username
         resp = Username + "<Enter>"
         GetResponse = GR_LOGIN
      Case 1                  ' Password
         If SavePassword = 0 OR Password = "" Then
             Password=PasswordBox("Enter your login password","Create Startup Script Wizard: Password ")
         End If
         resp = Password + "<Enter>"
         GetResponse = GR_PASSWORD
      Case 2
         resp = "<Enter>"     ' CR
         GetResponse = GR_ENTER
      Case 3                  ' Custom entry
         resp = CCString(getuser.customtext) + "<Enter>"
      Case 4                  ' Ignore input -- continue
         GetResponse = GR_IGNORE
      Case 5                  ' All done with input
         GetResponse = GR_DONE
      Case 6                  ' All done with input and close telnet session
         GetResponse = GR_DONE_TELNET
   End Select

End Function

Sub Main()
Begin Dialog weldlg 281, 159, "TNVTPlus Script Wizard:  Welcome", .Welcome
   PushButton  167, 129, 40, 14, "&Next >", .next1
   CancelButton  214, 129, 40, 14, .cancel1
   Text  7, 3, 256, 45, "This wizard helps you create a TNVTPlus script. For example, a script can connect to a network host automatically and do work on that host."
   Text  7, 27, 256, 45, "The wizard prompts you for information about automatic login and the commands you want to execute on the network host."
   Text  7, 51, 256, 45, "When you finish creating the TNVTPlus script, a file is created in your default sessions directory with an .ote extension. Double click on the .ote file to run it."
   Text  7, 90, 180, 25, "Click Next to continue."
End Dialog

cchoices = "30"+chr$(9)+"60"+chr$(9)+"90"+chr$(9)+"120"
ccombo = ">"+CHR$(9)+"$"+chr$(9)+"#"+chr$(9)+"yourtext>"

Begin Dialog timerdlg 281, 159, "TNVTPlus Script Wizard:  Set the Time Between Prompts", .SetTimer
   PushButton  167, 129, 40, 14, "&Next >", .next2
   Text  10, 38, 226, 44, "Type the maximum amount of time in seconds you want the TNVTPlus script to wait for a response from the network host. TIP: The maximum timeout value is 300 seconds."
   PushButton  125, 129, 40, 14, "< &Back", .back2
   CancelButton  214, 129, 40, 14, .cancel2
   Text  10, 10, 230, 25, "The TNVTPlus script sends messages to the network host and waits for a response.  The amount of time that the program waits is called a Timeout."
   DropComboBox  83, 76, 44, 70, cchoices, .ComboBox1
   Text  10, 76, 70, 11, "&Timeout (seconds):"
   CheckBox  10, 111, 159, 8, "&Display TNVTPlus window", .CheckBox1
End Dialog

Begin Dialog hostpromptdlg 281, 159, "TNVTPlus Script Wizard:  Set hostname and host prompt", .SetPrompt
   PushButton  167, 129, 40, 14, "&Next >", .next4
   PushButton  125, 129, 40, 14, "< &Back", .back4
   CancelButton  214, 129, 40, 14, .cancel4
   Text  5, 5, 269, 31, "Each network host has a name and an Internet Protocol (IP) address. The name is often called a host or hostname. The Host prompt chararacter(s)  helps the wizard identify when the network host is waiting for user input. "
   Text  5, 49, 89, 8, "Hostname:"
   TextBox  117, 49, 94, 13, .TextBox2
   Text  5, 73, 83, 25, "Port name or number:"
   TextBox  117, 72, 94, 14, .TextBox3
   Text  5, 95, 90, 15, "&Host prompt character(s):"
   DropComboBox  117, 95, 94, 70, ccombo, .DropComboBox1
End Dialog

Begin Dialog logindlg 281, 159, "TNVTPlus Script Wizard:  Automatic login", .SetLogin
   PushButton  167, 129, 40, 14, "&Next >", .next3
   PushButton  125, 129, 40, 14, "< &Back", .back3
   CancelButton  214, 129, 40, 14, .cancel3
   GroupBox  6, 6, 250, 81, "Automatic login:"
   Text  18, 23, 79, 14, "Username:"
   Text  18, 42, 79, 13, "Username prompt:"
   Text  18, 62, 79, 13, "Password prompt:"
   TextBox  91, 23, 125, 14, .TextBox1
   TextBox  91, 41, 125, 14, .TextBox2
   TextBox  91, 61, 125, 14, .TextBox4
   CheckBox  6, 114, 229, 14, "Save password in session file", .CheckBox1
   CheckBox  6, 94, 229, 14, "Automatically create session file (.ste) with TNVTPlus script (.ote)", .CheckBox2
End Dialog



Begin Dialog finishdlg 281, 159, "TNVTPlus Script Wizard:  Finish"
   PushButton  167, 129, 40, 14, "&Finish >", .next3
   PushButton  125, 129, 40, 14, "< &Back", .back3
   CancelButton  214, 129, 40, 14, .cancel3
   Text  7, 6, 247, 45, "The wizard has enough information to begin a TNVTPlus session. You will be prompted to respond to the program running on the network host."
   Text  7, 26, 247, 45, "Your responses are recorded in the .ote file. You can run the .ote file later to repeat the same commands."
   Text  7, 90, 180, 25, "Click Finish to begin the TNVTPlus session."
End Dialog

Dim hidlg as weldlg
Dim timedlg as timerdlg
Dim hostdlg as hostpromptdlg
Dim finaldlg as finishdlg
Dim logdlg as logindlg
Dim idx as Integer, createobj As Integer
Dim RetStatus As Integer
Dim cansave As Integer

Dim filenum As Integer
Dim res as Integer

'Initialize
   createobj = FALSE

' Set up hostname and port
   port = "Telnet"

' initialize variables
   waittime = "30"
   hostpromptchar = ">"
   hostname = ""
   Username = ""
   Password = ""
   SavePassword = 1
   LoginPrompt = "login:"
   PasswordPrompt = "password:"
   wVisible = 1
   tn_numtargets = 0
   wCreateSte = 1
   wPlaybackVis = 1

   ' create the tnvt object so that the GetUserName function can be accessed during the wizard
   If createobj = FALSE Then
       set Telnet = CreateObject("FTPSTNVTPlus.Application")
       createobj = TRUE
   End If

' invoke the startup screen
Hello:
   WelcomeRc = ""
   res = Dialog(hidlg)

   Select Case WelcomeRc
      Case "cancel"
         GoTo CancelTeach
   End Select

 ' Next> was chosen. Continue with the timer dialog.
Timeit:
   TimerReturn = ""
   res = Dialog(timedlg)
   Select Case TimerReturn
      Case "cancel"
          GoTo CancelTeach
      Case "back"
          GoTo Hello
   End Select


 ' Ask user for the typical host prompt to look for: '
hostprompt:
   HostReturn = ""
   res = Dialog(hostdlg)
   Select Case HostReturn
       Case "cancel"
          GoTo CancelTeach
        Case "back"
           GoTo Timeit
   End Select

   If Len(hostpromptchar) <> 0 Then
       tn_prompt(tn_numprompts) = hostpromptchar
       tn_suggest(tn_numprompts) = 3
       tn_numprompts = tn_numprompts + 1
   End If

Logit:
   LoginRc = ""
   Password = ""
   ' create a telnet object and obtain the username if possible

   Username = Telnet.GetUserName

   res = Dialog(logdlg)
   Select Case LoginRc
      Case "cancel"
         GoTo CancelTeach
      Case "back"
          GoTo hostprompt
   End Select



   ' if the user is not creating an .ste file OR not saving the password, then let the remote host request the password!
   If SavePassword <> 0 AND wCreateSte <> 0 Then
       Password=PasswordBox("Enter your login password","TNVTPlus Script Wizard: Password ")
       If Password = "" Then
           GoTo Logit
       End If

   End If


EndWizard:
   WRc = ""
   res = Dialog(finaldlg)
   Select Case res
      Case 0
         GoTo CancelTeach
      Case 2
          Goto Logit
   End Select

   ' create a session and login:

   set Session = Telnet.NewSessionFile
   Session.Hostname = hostname
   Session.Port = port
   Session.Username = Username

   Session.UsernamePrompt = LoginPrompt

   ' make sure the user is allowed to save the password in the session file
   Session.SavePassword = 1
   cansave = Session.SavePassword

   If cansave <> 0 Then
       Session.Password = Password
   End If

   if Password <> "" OR wCreateSte = 1 Then
       Session.PasswordPrompt = PasswordPrompt
   End If


   res = Session.Connect
   If res > 10000 Then
       res = MsgBox ("Telnet Connection failed. Would you like to try another host?", 4, "Create Wizard Script: cannot connect")
       if res = 6 Then
           GoTo hostprompt
       Else
           GoTo CancelTeach
       End If
   End If
   Telnet.Visible = wVisible
   InitVars


read_next:
    gl_linbuf = ""
    glres = GetLine(VAL(waittime))

    Select Case glres
       Case GL_CANCEL
         GoTo retry

       Case GL_TIMOUT
          res = MsgBox("Timeout and no data returned",5,"Create Wizard Script: Timeout")
          If res = 4 Then
              GoTo retry
          End If

         if (askcancel = 6) Then
             GoTo CancelTeach
         Else

             GoTo retry
         End If

    End Select

    idx = LookupStringTable(tn_prompt, tn_numprompts, gl_linbuf)
    if idx < 0 Then
        if glres = GL_TIMOUT Then
            grres = GetResponse(gl_lastline, 4, response)
            GoTo resp
        End If
    idx = 0
    End If

retry:
    grres = GetResponse(gl_lastline, tn_suggest(idx), response)

' First check for CANCEL
resp:
   Select Case grres
      Case GR_NORMAL
         If gl_lastatom <> "" Then
             Session.SendKeys(response)
             AddResponse gl_lastatom, response, GR_NORMAL
         End If
      Case GR_PASSWORD
         Session.SendKeys(response)
         PasswordPrompt2 = gl_lastatom
         AddResponse gl_lastatom, "GR_PASSWORD", GR_PASSWORD
      Case GR_LOGIN
         Session.SendKeys(response)
         AddResponse gl_lastatom, response, GR_LOGIN
      Case GR_CANCEL
         if (askcancel = 6) Then
             GoTo CancelTeach
         End If
     Case GR_ENTER
          Session.SendKeys(response)
          AddResponse gl_lastatom, response, GR_ENTER
      Case GR_IGNORE
         GoTo read_next
      Case GR_DONE
         closeTelnet = FALSE
         RetStatus = WrapItUp()
         GoTo ExitTeach
      Case GR_DONE_TELNET
         If gl_lastatom <> "" Then
              response = ""
              AddResponse gl_lastatom, response, GR_NORMAL
         End If
         closeTelnet = TRUE
         RetStatus = WrapItUp()
         GoTo CancelTeach
   End Select

   GoTo read_next

ExitTeach:
    If wPlaybackVis = 1 Then
        Telnet.Visible = TRUE
    End If
    Exit Sub

CancelTeach:
    If createobj = TRUE Then
        Telnet.Quit
    End If
    Exit Sub

End Sub