home *** CD-ROM | disk | FTP | other *** search
/ PC World Komputer 1999 mARCH / PCWK3A99.iso / Linux / DDD331 / DDD-3_1_.000 / DDD-3_1_ / ddd-3.1.1 / ddd / tips2m4.awk < prev    next >
Text File  |  1998-09-23  |  2KB  |  77 lines
  1. # $Id: tips2m4.awk,v 1.6 1998/09/23 09:21:04 zeller Exp $ -*- awk -*-
  2. # Convert tips of the day to app-resource format
  3.  
  4. # Copyright (C) 1998 Technische Universitaet Braunschweig, Germany.
  5. # Written by Andreas Zeller <zeller@ips.cs.tu-bs.de>.
  6. # 
  7. # This file is part of DDD.
  8. # 
  9. # DDD is free software; you can redistribute it and/or
  10. # modify it under the terms of the GNU General Public
  11. # License as published by the Free Software Foundation; either
  12. # version 2 of the License, or (at your option) any later version.
  13. # 
  14. # DDD is distributed in the hope that it will be useful,
  15. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  17. # See the GNU General Public License for more details.
  18. # 
  19. # You should have received a copy of the GNU General Public
  20. # License along with DDD -- see the file COPYING.
  21. # If not, write to the Free Software Foundation, Inc.,
  22. # 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23. # 
  24. # DDD is the data display debugger.
  25. # For details, see the DDD World-Wide-Web page, 
  26. # `http://www.cs.tu-bs.de/softech/ddd/',
  27. # or send a mail to the DDD developers <ddd@ips.cs.tu-bs.de>.
  28.  
  29. # This file requires GNU awk (gawk) or any other AWK according to the
  30. # Posix 1003.2(draft 11.3) definition of the AWK language - that is,
  31. # AWK as defined in Aho, Kernighan and Weinberger, The AWK Programming
  32. # Language, Addison-Wesley Publishing, 1988, (`the AWK book').
  33.  
  34. # Initialize variables.
  35.  
  36. BEGIN { 
  37.     tips  = 0;            # Next tip number
  38.     intip = 0;            # Whether we're in a tip text or not
  39.     seen  = 0;            # Whether we've seen a non-comment yet
  40.     printf("! Generated automatically from TIPS by tips2m4 -- DO NOT EDIT\n");
  41.     }
  42.  
  43. # Handle comments
  44. /^\#.*/  { next }
  45. /^!.*/   { print; seen = 1; next }
  46.  
  47. # Pass `include' unchanged, for M4
  48. /^include[(].*/ { print; next }
  49.  
  50. # Copy blank lines only when we've first seen something.
  51. !seen && !intip && $0 ~ "^$" { next }
  52. seen && !intip && $0 ~ "^$" { print; next }
  53.  
  54. # Start a tip
  55. !intip && !($0 ~ "^$") {
  56.     printf "Ddd*tip%d: \\\n@rm %s", tips, $0;
  57.     tips++;
  58.     intip = 1; seen = 1;
  59.     next }
  60.  
  61. # Continue a tip
  62. intip && !($0 ~ "^$") {
  63.     printf "\\n\\\n%s", $0;
  64.     next }
  65.  
  66. # End a tip
  67. intip && $0 ~ "^$" {
  68.     printf "\n\n";
  69.     intip = 0;
  70.     next }
  71.  
  72. # Ignore everything else (is there anything else?)
  73. /./ { next }
  74.  
  75. # Terminate with a final newline
  76. END { print ""; }
  77.