home *** CD-ROM | disk | FTP | other *** search
/ PC World Komputer 1998 May / Pcwk5b98.iso / Borland / Cplus45 / BC45 / START16.PAK / C0W.ASM < prev    next >
Assembly Source File  |  1995-08-29  |  12KB  |  449 lines
  1. ;[]------------------------------------------------------------[]
  2. ;|      C0W.ASM -- Start Up Code For Windows                    |
  3. ;[]------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 6.5
  7. ; 
  8. ;       Copyright (c) 1991, 1994 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.         locals
  13.  
  14.         __C0__ = 1
  15. include         RULES.ASI
  16.  
  17.         ASSUME CS:_TEXT, DS:DGROUP
  18.  
  19.         public  __acrtused              ;satisfy MS for now
  20. __acrtused      equ     0
  21. IFNDEF __DPMI16__
  22.         public  __WINMAINCALL           ; used internally
  23. ENDIF
  24.         public  __INITAPPCALLED         ; used internally
  25.  
  26. IFNDEF __DPMI16__
  27. extrn           WINMAIN:DIST
  28. ENDIF
  29.  
  30. extrn           INITAPP:far
  31. extrn           INITTASK:far
  32. extrn           FATALEXIT:far
  33. extrn           WAITEVENT:far
  34. extrn           LOCKSEGMENT:far
  35. extrn           UNLOCKSEGMENT:far
  36. extrn           GETWINFLAGS:far
  37. IFDEF __DPMI16__
  38.   extrn         _main:DIST
  39.   extrn         _OkToInitWindowsRTL:DIST
  40.   extrn         __abort:DIST
  41. ENDIF
  42. extrn           _exit:DIST
  43. extrn           __exit:DIST
  44. extrn           __exitbuf:DIST
  45. extrn           __exitfopen:DIST
  46. extrn           __exitopen:DIST
  47. extrn           __setupio:near                  ;required!
  48. extrn           __ExceptInit:DIST
  49.  
  50.         public __DestructorCount        ;Offset to global destructor count
  51. __DestructorCount EQU  10H
  52.         public __Exception_list         ;Offset to global exception list
  53. __Exception_list  EQU  14H
  54. NULL            segment
  55.         db      16 dup (0)              ;Windows
  56.         db       4 dup (0)              ;destructor count
  57.         db       2 dup (0)              ;exception list
  58.         db       4 dup (0)              ;exception vptr
  59.         db       6 dup (0)              ;reserved
  60.         db       2 dup (0)              ;VBX control jump vector
  61.                         ;MUST be at SS:20h
  62.         db       2 dup (0)              ;reserved
  63.         ends
  64.  
  65. _CVTSEG         segment
  66.         public __RealCvtVector
  67. __RealCvtVector label word
  68.         ends
  69.  
  70. _SCNSEG         segment
  71.         public __ScanTodVector
  72. __ScanTodVector label word
  73.         ends
  74.  
  75. _FPSEG          segment
  76.         public __FPVector
  77. __FPVector      dd      0
  78.         ends
  79.  
  80. _DATA           segment
  81.         public _errno
  82. _errno          dw      0
  83.         public __protected
  84. __protected     dw      0
  85.         public __8086
  86. __8086          dw      0
  87.         public __8087
  88. __8087          dw      0
  89.         public __psp
  90. __psp           dw      0
  91.         public __hInstance
  92. __hInstance     dw      0
  93.         public __hPrev
  94. __hPrev         dw      0
  95.         public __pszCmdline
  96. __pszCmdline    dw      0
  97.         public __cmdShow
  98. __cmdShow       dw      0
  99.         public __version
  100. __version       label word
  101.         public __osversion
  102. __osversion     label word
  103.         public __osmajor
  104. __osmajor       db      0
  105.         public __osminor
  106. __osminor       db      0
  107.         public __osmode         ;Used for OS/2 protected mode by MS,
  108. __osmode        db      0               ;  currently set to 0 under Windows
  109.         public __WinAllocFlag   ;Used by malloc to get additional flags
  110. __WinAllocFlag  dw      0               ;  to pass to GlobalAlloc (for DLL use)
  111.         public __LockWIN87EM    ;Used do lock down WIN87EM to avoid
  112. __LockWIN87EM   dw      1               ;  DLL unload ordering problem
  113.         public  __abend
  114. __abend         dw      0               ;Signals abnormal end, don't run destructors etc.
  115.  
  116. IFDEF __DPMI16__
  117.   extrn         __C0environ:dword
  118.   extrn         __C0argv:dword
  119.   extrn         __C0argc:word
  120. ENDIF
  121.  
  122. CopyRight       db      'Borland C++ - Copyright 1994 Borland Intl.',0
  123. IFDEF __DPMI16__
  124. DPMI16Error_s   db      'This DPMI16 application was linked incorrectly and'
  125.         db      ' will fail.',10,13,'$'
  126. ENDIF
  127.         ends
  128.  
  129. _TEXT           segment
  130.  
  131. Main            proc near
  132.  
  133. ;Windows initialization.  Sets up registers and stack.
  134.  
  135. IFDEF   __DPMI16__
  136.         mov     ax, seg DGROUP
  137.         mov     ds, ax
  138. ENDIF
  139.  
  140.         push    bx cx es
  141.         xor     ax,ax
  142.         push    ax
  143.         call    __ExceptInit
  144.         pop     ax
  145.         pop     es cx bx
  146.  
  147.         ;INITTASK returns:
  148.         ;  'Failure:
  149.         ;    AX = zero if it failed
  150.         ;  Success:
  151.         ;    AX = 1
  152.         ;    CX = stack limit
  153.         ;    DX = cmdShow parameter to CreateWindow
  154.         ;    ES:BX = -> DOS format command line (ES = PSP address)
  155.         ;    SI = hPrevinstance
  156.         ;    DI = hinstance
  157.         call    INITTASK
  158.         or      ax,ax
  159.         jnz     @@OK
  160.         jmp     @@Fail
  161. @@OK:           mov     word ptr ss:[__Exception_list], -1
  162.         mov     __psp,es
  163.         mov     word ptr __pszCmdline,bx
  164.         mov     __hPrev,si
  165.         mov     __hInstance,di
  166.         mov     __cmdShow,dx
  167.  
  168. IF LDATA EQ false
  169.         mov     ax,-1
  170.         push    ax
  171.         call    LOCKSEGMENT
  172. ENDIF
  173.  
  174. ;Clear _BSS, uninitialized data area
  175.  
  176. IFNDEF  __HUGE__
  177.         xor     ax, ax
  178.         push    ds
  179.         pop     es
  180.         mov     di,offset DGROUP:BeginBSS
  181.         mov     cx,offset DGROUP:EndBSS
  182.         sub     cx,di
  183.         cld
  184.         rep
  185.         stosb
  186. ENDIF
  187.  
  188. ;Init the Windows App
  189.  
  190.         xor     ax,ax
  191.         push    ax
  192.         call    WAITEVENT
  193.         push    __hInstance
  194.         call    INITAPP
  195. __INITAPPCALLED:or      ax,ax
  196.         jnz     @@InitOK
  197.         jmp     @@Fail
  198. @@InitOK:
  199.  
  200. ;Determine DOS version
  201.  
  202.         mov     ah, 30h
  203.         int     21h
  204.         mov     __version, ax   ; save minor and major revision
  205.  
  206. ;Determine whether we are in protected mode
  207.  
  208.         call    GETWINFLAGS
  209.         test    ax,1            ; WF_PMODE = 1
  210.         jz      @@realmode      ; Note:  GETWINFLAGS returns a long,
  211.                     ; so if WF_PMODE changed it could be
  212.                     ; in the high word.
  213.         mov     __protected, 8  ; Eight is for convenience.
  214. @@realmode:
  215.  
  216. ;Test for 8086/8087 presence
  217.  
  218.         test    ax,0400h        ; WF_8087 = 0x0400
  219.         jz      @@no8087
  220.         mov     __8087, 1
  221. @@no8087:
  222.         and     ax,08h+04h+02h  ; WF_CPU486|WF_CPU386|WF_CPU286
  223.         shr     ax,1            ; Convert to 4 or 2 or 1 or 0
  224.         test    ax,0004h        ; Have 4, 486 done
  225.         jnz     @@NoAdjust
  226.         or      ax,ax           ; Have 0, 8086 done
  227.         jz      @@NoAdjust
  228.         inc     ax              ; Have 2 or 1, need 3 or 2
  229. @@NoAdjust:
  230.         mov     __8086,ax       ; Set CPU Type
  231.  
  232.  
  233. IFDEF  __DPMI16__
  234. ;
  235. ; Here we attempt to prevent an early death caused by linking
  236. ; the libs in the wrong order
  237. ;
  238.         call    _OkToInitWindowsRTL
  239.         or      ax, ax
  240.         jnz     DPMI16Error
  241. ENDIF
  242.  
  243. ;Call our initialization functions, including C++ static constructors.
  244.  
  245.         mov     ax,ds
  246.         mov     es,ax
  247.         mov     si,offset DGROUP:InitStart      ;si = start of table
  248.         mov     di,offset DGROUP:InitEnd        ;di = end of table
  249.         call    Initialize
  250.  
  251. IFDEF __DPMI16__
  252. ;Set up and call _main for DPMI16 application
  253.  
  254.         push    word ptr [__C0environ+2]
  255.         push    word ptr [__C0environ]
  256.         push    word ptr [__C0argv+2]
  257.         push    word ptr [__C0argv]
  258.         push    [__C0argc]
  259.         call    _main
  260. ELSE
  261. ;Set up and call WinMain for Windows application
  262.         push    __hInstance
  263.         push    __hPrev
  264.         push    __psp
  265.         push    word ptr __pszCmdline
  266.         push    __cmdShow
  267. __WINMAINCALL:  call    WINMAIN
  268. ENDIF
  269.         push    ax      ; Push return value
  270.  
  271.         cmp     __abend, 0
  272.         jne     @@abnormalexit
  273.         call    _exit   ; Normal exit
  274. @@abnormalexit: call    __exit  ; Abnormal exit, don't call destructors etc.
  275.  
  276. IFDEF  __DPMI16__
  277. DPMI16Error:
  278.         mov     ah, 9
  279.         mov     dx, offset DPMI16Error_s
  280.         int     21h
  281.         call    __abort
  282. ENDIF
  283. ;---------------------------------------------------------------------------
  284. ;       _cleanup()      call all #pragma exit cleanup routines.
  285. ;       _checknull()    check for null pointer zapping copyright message
  286. ;       _terminate(int) exit program with error code
  287. ;       _restorezero()  restore interrupt vectors
  288. ;
  289. ;       These functions are called by exit(), _exit(), _cexit(),
  290. ;       and _c_exit().
  291. ;---------------------------------------------------------------------------
  292.  
  293. ;       Call cleanup routines
  294.  
  295. __cleanup       PROC    DIST
  296.         PUBLIC  __cleanup
  297.  
  298.         mov     ax,ds
  299.         mov     es,ax
  300.         push    si
  301.         push    di
  302.         mov     si,offset DGROUP:ExitStart
  303.         mov     di,offset DGROUP:ExitEnd
  304.         call    Cleanup
  305.         pop     di
  306.         pop     si
  307.         ret
  308. __cleanup       ENDP
  309.  
  310. ;       Check for null pointers before exit.  NO-OP on Windows.
  311.  
  312. __checknull     PROC    DIST
  313.         PUBLIC  __checknull
  314.         ret
  315. __checknull     ENDP
  316.  
  317. ;       Restore grabbed interrupt vectors.  NO-OP on Windows.
  318.  
  319. __restorezero     PROC    DIST
  320.         PUBLIC  __restorezero
  321.         ret
  322. __restorezero     ENDP
  323.  
  324. ;       Exit to DOS
  325.  
  326. __terminate     PROC    DIST
  327.         PUBLIC  __terminate
  328.  
  329. IF LDATA EQ false
  330.         mov     ax,-1
  331.         push    ax
  332.         call    UNLOCKSEGMENT
  333. ENDIF
  334.         mov     bp,sp
  335.         mov     al,[bp+cPtrSize]
  336.         mov     ah,4ch                  ;exit
  337.         int     21h
  338. __terminate     ENDP
  339.  
  340. @@Fail:         mov     al,0ffh
  341.         push    ax
  342.         call    _exit
  343.  
  344.         mov     ah,4ch                  ;exit
  345.         int     21h
  346.         endp
  347.  
  348. ;       Return default data segment in AX
  349.  
  350. __GetDGROUP     PROC    FAR
  351.         PUBLIC  __GetDGROUP
  352.         mov     ax, ss
  353.         ret
  354.         endp
  355.  
  356. ;------------------------------------------------------------------
  357. ;  Loop through a startup/exit (SE) table,
  358. ;  calling functions in order of priority.
  359. ;  ES:SI is assumed to point to the beginning of the SE table
  360. ;  ES:DI is assumed to point to the end of the SE table
  361. ;  First 64 priorities are reserved by Borland
  362. ;------------------------------------------------------------------
  363. PNEAR           EQU     0
  364. PFAR            EQU     1
  365. NOTUSED         EQU     0ffh
  366.  
  367. SE              STRUC
  368. calltype        db      ?                       ; 0=near,1=far,ff=not used
  369. priority        db      ?                       ; 0=highest,ff=lowest
  370. addrlow         dw      ?
  371. addrhigh        dw      ?
  372. SE              ENDS
  373.  
  374. Initialize      proc near
  375. @@Start:        mov     ax,100h                 ;start with lowest priority
  376.         mov     dx,di                   ;set sentinel to end of table
  377.         mov     bx,si                   ;bx = start of table
  378.  
  379. @@TopOfTable:   cmp     bx,di                   ;and the end of the table?
  380.         je      @@EndOfTable            ;yes, exit the loop
  381.         cmp     es:[bx.calltype],NOTUSED;check the call type
  382.         je      @@Next
  383.         mov     cl, es:[bx.priority]    ;move priority to CX
  384.         xor     ch, ch
  385.         cmp     cx,ax                   ;check the priority
  386.         jae     @@Next                  ;too high?  skip
  387.         mov     ax,cx                   ;keep priority
  388.         mov     dx,bx                   ;keep index in dx
  389. @@Next:         add     bx,SIZE SE              ;bx = next item in table
  390.         jmp     @@TopOfTable
  391.  
  392. @@EndOfTable:   cmp     dx,di                   ;did we exhaust the table?
  393.         je      @@Done                  ;yes, quit
  394.         mov     bx,dx                   ;bx = highest priority item
  395.         cmp     es:[bx.calltype],PNEAR  ;is it near or far?
  396.         mov     es:[bx.calltype],NOTUSED;wipe the call type
  397.         push    es                      ;save es
  398.         je      @@NearCall
  399.  
  400. @@FarCall:      call    DWORD PTR es:[bx.addrlow]
  401.         pop     es                      ;restore es
  402.         jmp     short @@Start
  403.  
  404. @@NearCall:     call    WORD PTR es:[bx.addrlow]
  405.         pop     es                      ;restore es
  406.         jmp     short @@Start
  407.  
  408. @@Done:         ret
  409.         endp
  410.  
  411. Cleanup         proc near
  412. @@Start:        mov     ah,0                    ;start with highest priority
  413.         mov     dx,di                   ;set sentinel to end of table
  414.         mov     bx,si                   ;bx = start of table
  415.  
  416. @@TopOfTable:   cmp     bx,di                   ;and the end of the table?
  417.         je      @@EndOfTable            ;yes, exit the loop
  418.         cmp     es:[bx.calltype],NOTUSED;check the call type
  419.         je      @@Next
  420.         cmp     es:[bx.priority],ah     ;check the priority
  421.         jb      @@Next                  ;too low?  skip
  422.         mov     ah,es:[bx.priority]     ;keep priority
  423.         mov     dx,bx                   ;keep index in dx
  424. @@Next:         add     bx,SIZE SE              ;bx = next item in table
  425.         jmp     @@TopOfTable
  426.  
  427. @@EndOfTable:   cmp     dx,di                   ;did we exhaust the table?
  428.         je      @@Done                  ;yes, quit
  429.         mov     bx,dx                   ;bx = highest priority item
  430.         cmp     es:[bx.calltype],PNEAR  ;is it near or far?
  431.         mov     es:[bx.calltype],NOTUSED;wipe the call type
  432.         push    es                      ;save es
  433.         je      @@NearCall
  434.  
  435. @@FarCall:      call    DWORD PTR es:[bx.addrlow]
  436.         pop     es                      ;restore es
  437.         jmp     short @@Start
  438.  
  439. @@NearCall:     call    WORD PTR es:[bx.addrlow]
  440.         pop     es                      ;restore es
  441.         jmp     short @@Start
  442.  
  443. @@Done:         ret
  444.         endp
  445.  
  446.         ends
  447.  
  448.         end Main
  449.