home *** CD-ROM | disk | FTP | other *** search
/ Chip 2001 May / W2KPRK.iso / ras.cab / logmeminfo.vbs < prev    next >
Text File  |  1999-11-04  |  24KB  |  696 lines
  1. '********************************************************************
  2. '*
  3. '* File:           LogMemInfo.Vbs
  4. '* Created:        March 1999
  5. '* Version:        1.0
  6. '*
  7. '*  Main Function:  Obtains the logical memory configuration of a machine.
  8. '*
  9. '*  LogMemInfo.vbs      [/S <server>] [/U <username>] [/W <password>] 
  10. '*                      [/O <outputfile>]
  11. '*
  12. '* Copyright (C) 1999 Microsoft Corporation
  13. '*
  14. '********************************************************************
  15.  
  16. OPTION EXPLICIT
  17.  
  18.     'Define constants
  19.     CONST CONST_ERROR                   = 0
  20.     CONST CONST_WSCRIPT                 = 1
  21.     CONST CONST_CSCRIPT                 = 2
  22.     CONST CONST_SHOW_USAGE              = 3
  23.     CONST CONST_PROCEED                 = 4
  24.  
  25.     'Declare variables
  26.     Dim intOpMode, i
  27.     Dim strServer, strUserName, strPassword, strOutputFile
  28.  
  29.     'Make sure the host is csript, if not then abort
  30.     VerifyHostIsCscript()
  31.  
  32.     'Parse the command line
  33.     intOpMode = intParseCmdLine(strServer     ,  _
  34.                                 strUserName   ,  _
  35.                                 strPassword   ,  _
  36.                                 strOutputFile    )
  37.  
  38.  
  39.     Select Case intOpMode
  40.  
  41.         Case CONST_SHOW_USAGE
  42.             Call ShowUsage()
  43.  
  44.         Case CONST_PROCEED                 
  45.             Call LogMemInfo(strServer     , _
  46.                             strOutputFile , _
  47.                             strUserName   , _
  48.                             strPassword     )
  49.  
  50.         Case CONST_ERROR
  51.             'Do Nothing
  52.  
  53.         Case Else                    'Default -- should never happen
  54.             Call Wscript.Echo("Error occurred in passing parameters.")
  55.  
  56.     End Select
  57.  
  58. '********************************************************************
  59. '* End of Script
  60. '********************************************************************
  61.  
  62. '********************************************************************
  63. '*
  64. '* Sub LogMemInfo()
  65. '*
  66. '* Purpose: Obtains the logical memory configuration of a machine.
  67. '*
  68. '* Input:   strServer           a machine name
  69. '*          strOutputFile       an output file name
  70. '*          strUserName         the current user's name
  71. '*          strPassword         the current user's password
  72. '*
  73. '* Output:  Results are either printed on screen or saved in strOutputFile.
  74. '*
  75. '********************************************************************
  76. Private Sub LogMemInfo(strServer, strOutputFile, strUserName, strPassword)
  77.  
  78.  
  79.  
  80.     ON ERROR RESUME NEXT
  81.  
  82.     Dim objFileSystem, objOutputFile, objService, objMem, objWshNet
  83.     Dim strQuery, strMessage, strCat
  84.  
  85.     'Open a text file for output if the file is requested
  86.     If Not IsEmpty(strOutputFile) Then
  87.         If (NOT blnOpenFile(strOutputFile, objOutputFile)) Then
  88.             Call Wscript.Echo ("Could not open an output file.")
  89.             Exit Sub
  90.         End If
  91.     End If
  92.  
  93.     'Establish a connection with the server.
  94.     If blnConnect("root\cimv2" , _
  95.                    strUserName , _
  96.                    strPassword , _
  97.                    strServer   , _
  98.                    objService  ) Then
  99.         Call Wscript.Echo("")
  100.         Call Wscript.Echo("Please check the server name, " _
  101.                         & "credentials and WBEM Core.")
  102.         Exit Sub
  103.     End If
  104.  
  105.     'Get the logical memory configuration
  106.     Set objMem = objService.Get("Win32_LogicalMemoryConfiguration=""" _
  107.                  & "LogicalMemoryConfiguration""")
  108.     If Err.Number Then
  109.       Wscript.Echo "Error 0x" & CStr(Hex(Err.Number)) & _
  110.                    " occurred getting the memory configuration."
  111.       If Err.Description <> "" Then
  112.           Wscript.Echo "Error description: " & Err.Description & "."
  113.       End If
  114.       Err.Clear
  115.       Exit Sub
  116.     End If
  117.  
  118.     Call WriteLine("Memory Configuration (Kb)", objOutputFile)
  119.  
  120.     strCat = "Machine"
  121.     strCat = strPackString(strCat, 20, 1, 1)
  122.     strMessage = strMessage + strCat
  123.  
  124.     strCat = "Tot Physical"
  125.     strCat = strPackString(strCat, 15, 1, 1)
  126.     strMessage = strMessage + strCat
  127.  
  128.     strCat = "Tot Virtual"
  129.     strCat = strPackString(strCat, 15, 1, 1)
  130.     strMessage = strMessage + strCat
  131.  
  132.     strCat = "Pagefile Space"
  133.     strCat = strPackString(strCat, 15, 1, 1)
  134.     strMessage = strMessage + strCat
  135.  
  136.     strCat = "Avail Virt"
  137.     strCat = strPackString(strCat, 15, 1, 1)
  138.     strMessage = strMessage + strCat
  139.     Call WriteLine(strMessage, objOutputFile)
  140.  
  141.     strMessage = Empty
  142.  
  143.     If IsEmpty(strServer) Then
  144.         Set objWshNet = CreateObject("Wscript.Network")
  145.         strServer = objWshNet.ComputerName
  146.     End If
  147.  
  148.     strMessage = strMessage + strPackString _
  149.                  (strServer, 20, 1, 1)
  150.  
  151.     strMessage = strMessage + strPackString _
  152.                  (strInsertCommas(objMem.TotalPhysicalMemory), 15, 1, 1)
  153.  
  154.     strMessage = strMessage + strPackString _
  155.                  (strInsertCommas(objMem.TotalVirtualMemory), 15, 1, 1)
  156.  
  157.     strMessage = strMessage + strPackString _
  158.                  (strInsertCommas(objMem.TotalPagefileSpace), 15, 1, 1)
  159.  
  160.     strMessage = strMessage + strPackString _
  161.                  (strInsertCommas(objMem.AvailableVirtualMemory), 15, 1, 1)
  162.  
  163.     Call WriteLine(strMessage, objOutputFile)
  164.  
  165.     If IsObject(objOutputFile) Then
  166.         objOutputFile.Close
  167.         Call Wscript.Echo ("Results are saved in file " & strOutputFile & ".")
  168.     End If
  169. End Sub
  170.  
  171. '********************************************************************
  172. '*
  173. '* Function intParseCmdLine()
  174. '*
  175. '* Purpose: Parses the command line.
  176. '* Input:   
  177. '*
  178. '* Output:  strServer         a remote server ("" = local server")
  179. '*          strUserName       the current user's name
  180. '*          strPassword       the current user's password
  181. '*          strOutputFile     an output file name
  182. '*
  183. '********************************************************************
  184. Private Function intParseCmdLine( ByRef strServer,        _
  185.                                   ByRef strUserName,      _
  186.                                   ByRef strPassword,      _
  187.                                   ByRef strOutputFile     )
  188.  
  189.  
  190.     ON ERROR RESUME NEXT
  191.  
  192.     Dim strFlag
  193.     Dim intState, intArgIter
  194.     Dim objFileSystem
  195.  
  196.     If Wscript.Arguments.Count > 0 Then
  197.         strFlag = Wscript.arguments.Item(0)
  198.     End If
  199.  
  200.     If IsEmpty(strFlag) Then                'No arguments have been received
  201.         intParseCmdLine = CONST_PROCEED
  202.         Exit Function
  203.     End If
  204.  
  205.     'Check if the user is asking for help or is just confused
  206.     If (strFlag="help") OR (strFlag="/h") OR (strFlag="\h") OR (strFlag="-h") _
  207.         OR (strFlag = "\?") OR (strFlag = "/?") OR (strFlag = "?") _ 
  208.         OR (strFlag="h") Then
  209.         intParseCmdLine = CONST_SHOW_USAGE
  210.         Exit Function
  211.     End If
  212.  
  213.     'Retrieve the command line and set appropriate variables
  214.      intArgIter = 0
  215.     Do While intArgIter <= Wscript.arguments.Count - 1
  216.         Select Case Left(LCase(Wscript.arguments.Item(intArgIter)),2)
  217.   
  218.             Case "/s"
  219.                 If Not blnGetArg("Server", strServer, intArgIter) Then
  220.                     intParseCmdLine = CONST_ERROR
  221.                     Exit Function
  222.                 End If
  223.                 intArgIter = intArgIter + 1
  224.  
  225.             Case "/o"
  226.                 If Not blnGetArg("Output File", strOutputFile, intArgIter) Then
  227.                     intParseCmdLine = CONST_ERROR
  228.                     Exit Function
  229.                 End If
  230.                 intArgIter = intArgIter + 1
  231.  
  232.             Case "/u"
  233.                 If Not blnGetArg("User Name", strUserName, intArgIter) Then
  234.                     intParseCmdLine = CONST_ERROR
  235.                     Exit Function
  236.                 End If
  237.                 intArgIter = intArgIter + 1
  238.  
  239.             Case "/w"
  240.                 If Not blnGetArg("User Password", strPassword, intArgIter) Then
  241.                     intParseCmdLine = CONST_ERROR
  242.                     Exit Function
  243.                 End If
  244.                 intArgIter = intArgIter + 1
  245.  
  246.             Case Else 'We shouldn't get here
  247.                 Call Wscript.Echo("Invalid or misplaced parameter: " _
  248.                    & Wscript.arguments.Item(intArgIter) & vbCRLF _
  249.                    & "Please check the input and try again," & vbCRLF _
  250.                    & "or invoke with '/?' for help with the syntax.")
  251.                 Wscript.Quit
  252.  
  253.         End Select
  254.  
  255.     Loop '** intArgIter <= Wscript.arguments.Count - 1
  256.  
  257.     If IsEmpty(intParseCmdLine) Then _
  258.         intParseCmdLine = CONST_PROCEED
  259.  
  260. End Function
  261.  
  262. '********************************************************************
  263. '*
  264. '* Sub ShowUsage()
  265. '*
  266. '* Purpose: Shows the correct usage to the user.
  267. '*
  268. '* Input:   None
  269. '*
  270. '* Output:  Help messages are displayed on screen.
  271. '*
  272. '********************************************************************
  273. Private Sub ShowUsage()
  274.  
  275.     Wscript.Echo ""
  276.     Wscript.Echo "Obtains the logical memory configuration of a machine."
  277.     Wscript.Echo ""
  278.     Wscript.Echo "SYNTAX:"
  279.     Wscript.Echo "  LogMemInfo.vbs [/S <server>] [/U <username>]" _
  280.                     & " [/W <password>]"
  281.     Wscript.Echo "              [/O <outputfile>]"
  282.     Wscript.Echo ""
  283.     Wscript.Echo "PARAMETER SPECIFIERS:"
  284.     Wscript.Echo "   server        A machine name."
  285.     Wscript.Echo "   username      The current user's name."
  286.     Wscript.Echo "   password      Password of the current user."
  287.     Wscript.Echo "   outputfile    The output file name."
  288.     Wscript.Echo ""
  289.     Wscript.Echo "EXAMPLE:"
  290.     Wscript.Echo "1. cscript LogMemInfo.vbs"
  291.     Wscript.Echo "   Obtains the logical memory configuration for " _
  292.                & "the current machine."
  293.     Wscript.Echo "2. cscript LogMemInfo.vbs /S MyMachine2"
  294.     Wscript.Echo "   Obtains the logical memory configuration for " _
  295.                & "the machine MyMachine2."
  296.  
  297. End Sub
  298.  
  299. '********************************************************************
  300. '* General Routines
  301. '********************************************************************
  302.  
  303. '********************************************************************
  304. '*
  305. '* Function strInsertCommas()
  306. '*
  307. '* Purpose: Puts commas into an interger to make it more readable.
  308. '*
  309. '* Input:   intValue    an integer
  310. '*
  311. '* Output:  strInsertCommas  A String
  312. '*
  313. '********************************************************************
  314. Function strInsertCommas(intValue)
  315.  
  316.     Dim IntPlace
  317.  
  318.     strInsertCommas = ""
  319.     intPlace = 0 
  320.     For I = len(intValue) to 1 Step - 1
  321.         strInsertCommas = Mid(intValue,I,1) & strInsertCommas
  322.         intPlace = intPlace + 1
  323.         If intPlace = 3 then
  324.             strInsertCommas = "," & strInsertCommas
  325.             intPlace = 0
  326.         End If
  327.     Next
  328.     If Left(strInsertCommas,1) = "," then
  329.         strInsertCommas = Right(strInsertCommas, len(strInsertCommas) -1)
  330.     End If
  331.  
  332. End Function
  333.  
  334. '********************************************************************
  335. '*
  336. '* Function strPackString()
  337. '*
  338. '* Purpose: Attaches spaces to a string to increase the length to intWidth.
  339. '*
  340. '* Input:   strString   a string
  341. '*          intWidth    the intended length of the string
  342. '*          blnAfter    Should spaces be added after the string?
  343. '*          blnTruncate specifies whether to truncate the string or not if
  344. '*                      the string length is longer than intWidth
  345. '*
  346. '* Output:  strPackString is returned as the packed string.
  347. '*
  348. '********************************************************************
  349. Private Function strPackString( ByVal strString, _
  350.                                 ByVal intWidth,  _
  351.                                 ByVal blnAfter,  _
  352.                                 ByVal blnTruncate)
  353.  
  354.     ON ERROR RESUME NEXT
  355.  
  356.     intWidth      = CInt(intWidth)
  357.     blnAfter      = CBool(blnAfter)
  358.     blnTruncate   = CBool(blnTruncate)
  359.  
  360.     If Err.Number Then
  361.         Call Wscript.Echo ("Argument type is incorrect!")
  362.         Err.Clear
  363.         Wscript.Quit
  364.     End If
  365.  
  366.     If IsNull(strString) Then
  367.         strPackString = "null" & Space(intWidth-4)
  368.         Exit Function
  369.     End If
  370.  
  371.     strString = CStr(strString)
  372.     If Err.Number Then
  373.         Call Wscript.Echo ("Argument type is incorrect!")
  374.         Err.Clear
  375.         Wscript.Quit
  376.     End If
  377.  
  378.     If intWidth > Len(strString) Then
  379.         If blnAfter Then
  380.             strPackString = strString & Space(intWidth-Len(strString))
  381.         Else
  382.             strPackString = Space(intWidth-Len(strString)) & strString & " "
  383.         End If
  384.     Else
  385.         If blnTruncate Then
  386.             strPackString = Left(strString, intWidth-1) & " "
  387.         Else
  388.             strPackString = strString & " "
  389.         End If
  390.     End If
  391.  
  392. End Function
  393.  
  394. '********************************************************************
  395. '* 
  396. '*  Function blnGetArg()
  397. '*
  398. '*  Purpose: Helper to intParseCmdLine()
  399. '* 
  400. '*  Usage:
  401. '*
  402. '*     Case "/s" 
  403. '*       blnGetArg ("server name", strServer, intArgIter)
  404. '*
  405. '********************************************************************
  406. Private Function blnGetArg ( ByVal StrVarName,   _
  407.                              ByRef strVar,       _
  408.                              ByRef intArgIter) 
  409.  
  410.     blnGetArg = False 'failure, changed to True upon successful completion
  411.  
  412.     If Len(Wscript.Arguments(intArgIter)) > 2 then
  413.         If Mid(Wscript.Arguments(intArgIter),3,1) = ":" then
  414.             If Len(Wscript.Arguments(intArgIter)) > 3 then
  415.                 strVar = Right(Wscript.Arguments(intArgIter), _
  416.                          Len(Wscript.Arguments(intArgIter)) - 3)
  417.                 blnGetArg = True
  418.                 Exit Function
  419.             Else
  420.                 intArgIter = intArgIter + 1
  421.                 If intArgIter > (Wscript.Arguments.Count - 1) Then
  422.                     Call Wscript.Echo( "Invalid " & StrVarName & ".")
  423.                     Call Wscript.Echo( "Please check the input and try again.")
  424.                     Exit Function
  425.                 End If
  426.  
  427.                 strVar = Wscript.Arguments.Item(intArgIter)
  428.                 If Err.Number Then
  429.                     Call Wscript.Echo( "Invalid " & StrVarName & ".")
  430.                     Call Wscript.Echo( "Please check the input and try again.")
  431.                     Exit Function
  432.                 End If
  433.  
  434.                 If InStr(strVar, "/") Then
  435.                     Call Wscript.Echo( "Invalid " & StrVarName)
  436.                     Call Wscript.Echo( "Please check the input and try again.")
  437.                     Exit Function
  438.                 End If
  439.  
  440.                 blnGetArg = True 'success
  441.             End If
  442.         Else
  443.             strVar = Right(Wscript.Arguments(intArgIter), _
  444.                      Len(Wscript.Arguments(intArgIter)) - 2)
  445.             blnGetArg = True 'success
  446.             Exit Function
  447.         End If
  448.     Else
  449.         intArgIter = intArgIter + 1
  450.         If intArgIter > (Wscript.Arguments.Count - 1) Then
  451.             Call Wscript.Echo( "Invalid " & StrVarName & ".")
  452.             Call Wscript.Echo( "Please check the input and try again.")
  453.             Exit Function
  454.         End If
  455.  
  456.         strVar = Wscript.Arguments.Item(intArgIter)
  457.         If Err.Number Then
  458.             Call Wscript.Echo( "Invalid " & StrVarName & ".")
  459.             Call Wscript.Echo( "Please check the input and try again.")
  460.             Exit Function
  461.         End If
  462.  
  463.         If InStr(strVar, "/") Then
  464.             Call Wscript.Echo( "Invalid " & StrVarName)
  465.             Call Wscript.Echo( "Please check the input and try again.")
  466.             Exit Function
  467.         End If
  468.         blnGetArg = True 'success
  469.     End If
  470. End Function
  471.  
  472. '********************************************************************
  473. '*
  474. '* Function blnConnect()
  475. '*
  476. '* Purpose: Connects to machine strServer.
  477. '*
  478. '* Input:   strServer       a machine name
  479. '*          strNameSpace    a namespace
  480. '*          strUserName     name of the current user
  481. '*          strPassword     password of the current user
  482. '*
  483. '* Output:  objService is returned  as a service object.
  484. '*          strServer is set to local host if left unspecified
  485. '*
  486. '********************************************************************
  487. Private Function blnConnect(ByVal strNameSpace, _
  488.                             ByVal strUserName,  _
  489.                             ByVal strPassword,  _
  490.                             ByRef strServer,    _
  491.                             ByRef objService)
  492.  
  493.     ON ERROR RESUME NEXT
  494.  
  495.     Dim objLocator, objWshNet
  496.  
  497.     blnConnect = False     'There is no error.
  498.  
  499.     'Create Locator object to connect to remote CIM object manager
  500.     Set objLocator = CreateObject("WbemScripting.SWbemLocator")
  501.     If Err.Number then
  502.         Call Wscript.Echo( "Error 0x" & CStr(Hex(Err.Number)) & _
  503.                            " occurred in creating a locator object." )
  504.         If Err.Description <> "" Then
  505.             Call Wscript.Echo( "Error description: " & Err.Description & "." )
  506.         End If
  507.         Err.Clear
  508.         blnConnect = True     'An error occurred
  509.         Exit Function
  510.     End If
  511.  
  512.     'Connect to the namespace which is either local or remote
  513.     Set objService = objLocator.ConnectServer (strServer, strNameSpace, _
  514.        strUserName, strPassword)
  515.     ObjService.Security_.impersonationlevel = 3
  516.     If Err.Number then
  517.         Call Wscript.Echo( "Error 0x" & CStr(Hex(Err.Number)) & _
  518.                            " occurred in connecting to server " _
  519.            & strServer & ".")
  520.         If Err.Description <> "" Then
  521.             Call Wscript.Echo( "Error description: " & Err.Description & "." )
  522.         End If
  523.         Err.Clear
  524.         blnConnect = True     'An error occurred
  525.     End If
  526.  
  527.     'Get the current server's name if left unspecified
  528.     If IsEmpty(strServer) Then
  529.         Set objWshNet = CreateObject("Wscript.Network")
  530.     strServer     = objWshNet.ComputerName
  531.     End If
  532.  
  533. End Function
  534.  
  535. '********************************************************************
  536. '*
  537. '* Sub      VerifyHostIsCscript()
  538. '*
  539. '* Purpose: Determines which program is used to run this script.
  540. '*
  541. '* Input:   None
  542. '*
  543. '* Output:  If host is not cscript, then an error message is printed 
  544. '*          and the script is aborted.
  545. '*
  546. '********************************************************************
  547. Sub VerifyHostIsCscript()
  548.  
  549.     ON ERROR RESUME NEXT
  550.  
  551.     Dim strFullName, strCommand, i, j, intStatus
  552.  
  553.     strFullName = WScript.FullName
  554.  
  555.     If Err.Number then
  556.         Call Wscript.Echo( "Error 0x" & CStr(Hex(Err.Number)) & " occurred." )
  557.         If Err.Description <> "" Then
  558.             Call Wscript.Echo( "Error description: " & Err.Description & "." )
  559.         End If
  560.         intStatus =  CONST_ERROR
  561.     End If
  562.  
  563.     i = InStr(1, strFullName, ".exe", 1)
  564.     If i = 0 Then
  565.         intStatus =  CONST_ERROR
  566.     Else
  567.         j = InStrRev(strFullName, "\", i, 1)
  568.         If j = 0 Then
  569.             intStatus =  CONST_ERROR
  570.         Else
  571.             strCommand = Mid(strFullName, j+1, i-j-1)
  572.             Select Case LCase(strCommand)
  573.                 Case "cscript"
  574.                     intStatus = CONST_CSCRIPT
  575.                 Case "wscript"
  576.                     intStatus = CONST_WSCRIPT
  577.                 Case Else       'should never happen
  578.                     Call Wscript.Echo( "An unexpected program was used to " _
  579.                                        & "run this script." )
  580.                     Call Wscript.Echo( "Only CScript.Exe or WScript.Exe can " _
  581.                                        & "be used to run this script." )
  582.                     intStatus = CONST_ERROR
  583.                 End Select
  584.         End If
  585.     End If
  586.  
  587.     If intStatus <> CONST_CSCRIPT Then
  588.         Call WScript.Echo( "Please run this script using CScript." & vbCRLF & _
  589.              "This can be achieved by" & vbCRLF & _
  590.              "1. Using ""CScript LogMemInfo.vbs arguments"" for Windows 95/98 or" _
  591.              & vbCRLF & "2. Changing the default Windows Scripting Host " _
  592.              & "setting to CScript" & vbCRLF & "    using ""CScript " _
  593.              & "//H:CScript //S"" and running the script using" & vbCRLF & _
  594.              "    ""LogMemInfo.vbs arguments"" for Windows NT/2000." )
  595.         WScript.Quit
  596.     End If
  597.  
  598. End Sub
  599.  
  600. '********************************************************************
  601. '*
  602. '* Sub WriteLine()
  603. '* Purpose: Writes a text line either to a file or on screen.
  604. '* Input:   strMessage  the string to print
  605. '*          objFile     an output file object
  606. '* Output:  strMessage is either displayed on screen or written to a file.
  607. '*
  608. '********************************************************************
  609. Sub WriteLine(ByVal strMessage, ByVal objFile)
  610.  
  611.     On Error Resume Next
  612.     If IsObject(objFile) then        'objFile should be a file object
  613.         objFile.WriteLine strMessage
  614.     Else
  615.         Call Wscript.Echo( strMessage )
  616.     End If
  617.  
  618. End Sub
  619.  
  620. '********************************************************************
  621. '* 
  622. '* Function blnErrorOccurred()
  623. '*
  624. '* Purpose: Reports error with a string saying what the error occurred in.
  625. '*
  626. '* Input:   strIn        string saying what the error occurred in.
  627. '*
  628. '* Output:  displayed on screen 
  629. '* 
  630. '********************************************************************
  631. Private Function blnErrorOccurred (ByVal strIn)
  632.  
  633.     If Err.Number Then
  634.         Call Wscript.Echo( "Error 0x" & CStr(Hex(Err.Number)) & ": " & strIn)
  635.         If Err.Description <> "" Then
  636.             Call Wscript.Echo( "Error description: " & Err.Description)
  637.         End If
  638.         Err.Clear
  639.         blnErrorOccurred = True
  640.     Else
  641.         blnErrorOccurred = False
  642.     End If
  643.  
  644. End Function
  645.  
  646. '********************************************************************
  647. '* 
  648. '* Function blnOpenFile
  649. '*
  650. '* Purpose: Opens a file.
  651. '*
  652. '* Input:   strFileName        A string with the name of the file.
  653. '*
  654. '* Output:  Sets objOpenFile to a FileSystemObject and setis it to 
  655. '*            Nothing upon Failure.
  656. '* 
  657. '********************************************************************
  658. Private Function blnOpenFile(ByVal strFileName, ByRef objOpenFile)
  659.  
  660.     ON ERROR RESUME NEXT
  661.  
  662.     Dim objFileSystem
  663.  
  664.     Set objFileSystem = Nothing
  665.  
  666.     If IsEmpty(strFileName) OR strFileName = "" Then
  667.         blnOpenFile = False
  668.         Set objOpenFile = Nothing
  669.         Exit Function
  670.     End If
  671.  
  672.     'Create a file object
  673.     Set objFileSystem = CreateObject("Scripting.FileSystemObject")
  674.     If blnErrorOccurred("Could not create filesystem object.") Then
  675.         blnOpenFile = False
  676.         Set objOpenFile = Nothing
  677.         Exit Function
  678.     End If
  679.  
  680.     'Open the file for output
  681.     Set objOpenFile = objFileSystem.OpenTextFile(strFileName, 8, True)
  682.     If blnErrorOccurred("Could not open") Then
  683.         blnOpenFile = False
  684.         Set objOpenFile = Nothing
  685.         Exit Function
  686.     End If
  687.     blnOpenFile = True
  688.  
  689. End Function
  690.  
  691. '********************************************************************
  692. '*                                                                  *
  693. '*                           End of File                            *
  694. '*                                                                  *
  695. '********************************************************************
  696.