home *** CD-ROM | disk | FTP | other *** search
/ Chip 2001 May / W2KPRK.iso / ras.cab / eventlogmon.vbs < prev    next >
Text File  |  1999-11-04  |  22KB  |  649 lines
  1. '********************************************************************
  2. '*
  3. '* File:           EventLogMon.vbs 
  4. '* Created:        March 1999
  5. '* Version:        1.0
  6. '*
  7. '*  Main Function:  Outputs Information on CDRomDrives.
  8. '*
  9. '*  EventLogMon.vbs  [/S <server>] [/U <username>] [/W <password>] 
  10. '*                   [/O <outputfile>]
  11. '*
  12. '* Copyright (C) 1999 Microsoft Corporation
  13. '*
  14. '********************************************************************
  15.  
  16. OPTION EXPLICIT
  17.  
  18.     'Define constants
  19.     CONST CONST_ERROR                   = 0
  20.     CONST CONST_WSCRIPT                 = 1
  21.     CONST CONST_CSCRIPT                 = 2
  22.     CONST CONST_SHOW_USAGE              = 3
  23.     CONST CONST_PROCEED                 = 4
  24.  
  25.     'Declare variables
  26.     Dim intOpMode, i
  27.     Dim strServer, strUserName, strPassword, strOutputFile
  28.  
  29.     'Make sure the host is csript, if not then abort
  30.     VerifyHostIsCscript()
  31.  
  32.     'Parse the command line
  33.     intOpMode = intParseCmdLine(strServer     ,  _
  34.                                 strUserName   ,  _
  35.                                 strPassword   ,  _
  36.                                 strOutputFile    )
  37.  
  38.  
  39.     Select Case intOpMode
  40.  
  41.         Case CONST_SHOW_USAGE
  42.             Call ShowUsage()
  43.  
  44.         Case CONST_PROCEED                 
  45.             Call EventLogMon(strServer    , _
  46.                             strOutputFile , _
  47.                             strUserName   , _
  48.                             strPassword     )
  49.  
  50.         Case CONST_ERROR
  51.             'Do Nothing
  52.  
  53.         Case Else                    'Default -- should never happen
  54.             Call Wscript.Echo("Error occurred in passing parameters.")
  55.  
  56.     End Select
  57.  
  58. '********************************************************************
  59. '* End of Script
  60. '********************************************************************
  61.  
  62. '********************************************************************
  63. '*
  64. '* Sub EventLogMon()
  65. '* Purpose: Lists the size of RAM on a machine.
  66. '* Input:   strServer is the name of the machine to be checked
  67. '*          strOutputFile       an output file name
  68. '*          strUserName        the current user's name
  69. '*          strPassword        the current user's password
  70. '* Output:  The size of RAM is  printed on screen.
  71. '*
  72. '********************************************************************
  73.  
  74. Private Sub EventLogMon(strServer     , _
  75.                         strOutputFile , _
  76.                         strUserName   , _
  77.                         strPassword     )
  78.  
  79.     ON ERROR RESUME NEXT
  80.  
  81.     Dim objFileSystem, objOutputFile, objService, objEnumerator, objInstance
  82.     Dim strQuery, strTemp, strMessage
  83.     Dim i
  84.  
  85.  
  86.     'Open a text file for output if the file is requested
  87.     If Not IsEmpty(strOutputFile) Then
  88.         If (NOT blnOpenFile(strOutputFile, objOutputFile)) Then
  89.             Call Wscript.Echo ("Could not open an output file.")
  90.             Exit Sub
  91.         End If
  92.     End If
  93.  
  94.     'Establish a connection with the server.
  95.     If blnConnect("root\cimv2" , _
  96.                    strUserName , _
  97.                    strPassword , _
  98.                    strServer   , _
  99.                    objService  ) Then
  100.         Call Wscript.Echo("")
  101.         Call Wscript.Echo("Please check the server name, " _
  102.                         & "credentials and WBEM Core.")
  103.         Exit Sub
  104.     End If
  105.  
  106.     strQuery = "Select * from __InstancecreationEvent where " _
  107.         & "TargetInstance isa" & """Win32_NtLogEvent"""
  108.     'Now execute the query.
  109.     ReDim strProperties(4)
  110.  
  111.     strProperties(0) = "RecordNumber"
  112.     strProperties(1) = "LogFile"
  113.     strProperties(2) = "SourceName"
  114.     strProperties(3) = "TimeGenerated"
  115.     strProperties(4) = "Message"
  116.  
  117.     Set objEnumerator = objService.ExecNotificationQuery(strQuery)
  118.     If Err.Number Then
  119.         Print "Error 0x" & CStr(Hex(Err.Number)) & " occurred during the query."
  120.         If Err.Description <> "" Then
  121.             Print "Error description: " & Err.Description & "."
  122.         End If
  123.         Err.Clear
  124.         Exit Sub
  125.     End If
  126.  
  127.     'Print a header
  128.     strMessage = ""
  129.     For i = 0 To UBound(strProperties)
  130.         strMessage = strMessage & strPackString(strProperties(i), 15, 1, 0)
  131.     Next
  132.     WriteLine strMessage, objOutputFile
  133.  
  134.     i = 0
  135.     Do
  136.         Set objINstance = objEnumerator.NextEvent
  137.         If Err.Number Then
  138.             Err.Clear
  139.         Else
  140.             strMessage = ""
  141.             For i = 0 To UBound(strProperties)
  142.                 strTemp = _
  143.                  objInstance.TargetInstance.Properties_(strProperties(i))
  144.                 strMessage = strMessage & strPackString(strTemp, 15, 1, 0)
  145.             Next
  146.             WriteLine strMessage, objOutputFile
  147.         End If
  148.         i = i + 1
  149.     Loop Until i > 100
  150.  
  151.     If IsObject(objOutputFile) Then
  152.         objOutputFile.Close
  153.         Call Wscript.Echo ("Results are saved in file " & strOutputFile & ".")
  154.     End If
  155.  
  156. End Sub
  157.  
  158. '********************************************************************
  159. '*
  160. '* Function intParseCmdLine()
  161. '*
  162. '* Purpose: Parses the command line.
  163. '* Input:   
  164. '*
  165. '* Output:  strServer         a remote server ("" = local server")
  166. '*          strUserName       the current user's name
  167. '*          strPassword       the current user's password
  168. '*          strOutputFile     an output file name
  169. '*
  170. '********************************************************************
  171. Private Function intParseCmdLine( ByRef strServer,        _
  172.                                   ByRef strUserName,      _
  173.                                   ByRef strPassword,      _
  174.                                   ByRef strOutputFile     )
  175.  
  176.  
  177.     ON ERROR RESUME NEXT
  178.  
  179.     Dim strFlag
  180.     Dim intState, intArgIter
  181.     Dim objFileSystem
  182.  
  183.     If Wscript.Arguments.Count > 0 Then
  184.         strFlag = Wscript.arguments.Item(0)
  185.     End If
  186.  
  187.     If IsEmpty(strFlag) Then                'No arguments have been received
  188.         intParseCmdLine = CONST_PROCEED
  189.         Exit Function
  190.     End If
  191.  
  192.     'Check if the user is asking for help or is just confused
  193.     If (strFlag="help") OR (strFlag="/h") OR (strFlag="\h") OR (strFlag="-h") _
  194.         OR (strFlag = "\?") OR (strFlag = "/?") OR (strFlag = "?") _ 
  195.         OR (strFlag="h") Then
  196.         intParseCmdLine = CONST_SHOW_USAGE
  197.         Exit Function
  198.     End If
  199.  
  200.     'Retrieve the command line and set appropriate variables
  201.      intArgIter = 0
  202.     Do While intArgIter <= Wscript.arguments.Count - 1
  203.         Select Case Left(LCase(Wscript.arguments.Item(intArgIter)),2)
  204.   
  205.             Case "/s"
  206.                 If Not blnGetArg("Server", strServer, intArgIter) Then
  207.                     intParseCmdLine = CONST_ERROR
  208.                     Exit Function
  209.                 End If
  210.                 intArgIter = intArgIter + 1
  211.  
  212.             Case "/o"
  213.                 If Not blnGetArg("Output File", strOutputFile, intArgIter) Then
  214.                     intParseCmdLine = CONST_ERROR
  215.                     Exit Function
  216.                 End If
  217.                 intArgIter = intArgIter + 1
  218.  
  219.             Case "/u"
  220.                 If Not blnGetArg("User Name", strUserName, intArgIter) Then
  221.                     intParseCmdLine = CONST_ERROR
  222.                     Exit Function
  223.                 End If
  224.                 intArgIter = intArgIter + 1
  225.  
  226.             Case "/w"
  227.                 If Not blnGetArg("User Password", strPassword, intArgIter) Then
  228.                     intParseCmdLine = CONST_ERROR
  229.                     Exit Function
  230.                 End If
  231.                 intArgIter = intArgIter + 1
  232.  
  233.             Case Else 'We shouldn't get here
  234.                 Call Wscript.Echo("Invalid or misplaced parameter: " _
  235.                    & Wscript.arguments.Item(intArgIter) & vbCRLF _
  236.                    & "Please check the input and try again," & vbCRLF _
  237.                    & "or invoke with '/?' for help with the syntax.")
  238.                 Wscript.Quit
  239.  
  240.         End Select
  241.  
  242.     Loop '** intArgIter <= Wscript.arguments.Count - 1
  243.  
  244.     If IsEmpty(intParseCmdLine) Then _
  245.         intParseCmdLine = CONST_PROCEED
  246.  
  247. End Function
  248.  
  249. '********************************************************************
  250. '*
  251. '* Sub ShowUsage()
  252. '*
  253. '* Purpose: Shows the correct usage to the user.
  254. '*
  255. '* Input:   None
  256. '*
  257. '* Output:  Help messages are displayed on screen.
  258. '*
  259. '********************************************************************
  260. Private Sub ShowUsage()
  261.  
  262.     Wscript.Echo ""
  263.     Wscript.Echo "Monitors event log events."
  264.     Wscript.Echo ""
  265.     Wscript.Echo "SYNTAX:"
  266.     Wscript.Echo "  EventLogMon.vbs [/S <server>] [/U <username>]" _
  267.                 &" [/W <password>]"
  268.     Wscript.Echo "  [/O <outputfile>]"
  269.     Wscript.Echo ""
  270.     Wscript.Echo "PARAMETER SPECIFIERS:"
  271.     Wscript.Echo "   server        A machine name."
  272.     Wscript.Echo "   username      The current user's name."
  273.     Wscript.Echo "   password      Password of the current user."
  274.     Wscript.Echo "   outputfile    The output file name."
  275.     Wscript.Echo ""
  276.     Wscript.Echo "EXAMPLE:"
  277.     Wscript.Echo "1. cscript EventLogMon.vbs"
  278.     Wscript.Echo "   Monitors event log activity for the current machine."
  279.     Wscript.Echo "2. cscript EventLogMon.vbs /S MyMachine2"
  280.     Wscript.Echo "   Monitors event log activity for the machine MyMachine2."
  281.  
  282. End Sub
  283.  
  284. '********************************************************************
  285. '* General Routines
  286. '********************************************************************
  287.  
  288. '********************************************************************
  289. '*
  290. '* Function strPackString()
  291. '*
  292. '* Purpose: Attaches spaces to a string to increase the length to intWidth.
  293. '*
  294. '* Input:   strString   a string
  295. '*          intWidth    the intended length of the string
  296. '*          blnAfter    Should spaces be added after the string?
  297. '*          blnTruncate specifies whether to truncate the string or not if
  298. '*                      the string length is longer than intWidth
  299. '*
  300. '* Output:  strPackString is returned as the packed string.
  301. '*
  302. '********************************************************************
  303. Private Function strPackString( ByVal strString, _
  304.                                 ByVal intWidth,  _
  305.                                 ByVal blnAfter,  _
  306.                                 ByVal blnTruncate)
  307.  
  308.     ON ERROR RESUME NEXT
  309.  
  310.     intWidth      = CInt(intWidth)
  311.     blnAfter      = CBool(blnAfter)
  312.     blnTruncate   = CBool(blnTruncate)
  313.  
  314.     If Err.Number Then
  315.         Call Wscript.Echo ("Argument type is incorrect!")
  316.         Err.Clear
  317.         Wscript.Quit
  318.     End If
  319.  
  320.     If IsNull(strString) Then
  321.         strPackString = "null" & Space(intWidth-4)
  322.         Exit Function
  323.     End If
  324.  
  325.     strString = CStr(strString)
  326.     If Err.Number Then
  327.         Call Wscript.Echo ("Argument type is incorrect!")
  328.         Err.Clear
  329.         Wscript.Quit
  330.     End If
  331.  
  332.     If intWidth > Len(strString) Then
  333.         If blnAfter Then
  334.             strPackString = strString & Space(intWidth-Len(strString))
  335.         Else
  336.             strPackString = Space(intWidth-Len(strString)) & strString & " "
  337.         End If
  338.     Else
  339.         If blnTruncate Then
  340.             strPackString = Left(strString, intWidth-1) & " "
  341.         Else
  342.             strPackString = strString & " "
  343.         End If
  344.     End If
  345.  
  346. End Function
  347.  
  348. '********************************************************************
  349. '* 
  350. '*  Function blnGetArg()
  351. '*
  352. '*  Purpose: Helper to intParseCmdLine()
  353. '* 
  354. '*  Usage:
  355. '*
  356. '*     Case "/s" 
  357. '*       blnGetArg ("server name", strServer, intArgIter)
  358. '*
  359. '********************************************************************
  360. Private Function blnGetArg ( ByVal StrVarName,   _
  361.                              ByRef strVar,       _
  362.                              ByRef intArgIter) 
  363.  
  364.     blnGetArg = False 'failure, changed to True upon successful completion
  365.  
  366.     If Len(Wscript.Arguments(intArgIter)) > 2 then
  367.         If Mid(Wscript.Arguments(intArgIter),3,1) = ":" then
  368.             If Len(Wscript.Arguments(intArgIter)) > 3 then
  369.                 strVar = Right(Wscript.Arguments(intArgIter), _
  370.                          Len(Wscript.Arguments(intArgIter)) - 3)
  371.                 blnGetArg = True
  372.                 Exit Function
  373.             Else
  374.                 intArgIter = intArgIter + 1
  375.                 If intArgIter > (Wscript.Arguments.Count - 1) Then
  376.                     Call Wscript.Echo( "Invalid " & StrVarName & ".")
  377.                     Call Wscript.Echo( "Please check the input and try again.")
  378.                     Exit Function
  379.                 End If
  380.  
  381.                 strVar = Wscript.Arguments.Item(intArgIter)
  382.                 If Err.Number Then
  383.                     Call Wscript.Echo( "Invalid " & StrVarName & ".")
  384.                     Call Wscript.Echo( "Please check the input and try again.")
  385.                     Exit Function
  386.                 End If
  387.  
  388.                 If InStr(strVar, "/") Then
  389.                     Call Wscript.Echo( "Invalid " & StrVarName)
  390.                     Call Wscript.Echo( "Please check the input and try again.")
  391.                     Exit Function
  392.                 End If
  393.  
  394.                 blnGetArg = True 'success
  395.             End If
  396.         Else
  397.             strVar = Right(Wscript.Arguments(intArgIter), _
  398.                      Len(Wscript.Arguments(intArgIter)) - 2)
  399.             blnGetArg = True 'success
  400.             Exit Function
  401.         End If
  402.     Else
  403.         intArgIter = intArgIter + 1
  404.         If intArgIter > (Wscript.Arguments.Count - 1) Then
  405.             Call Wscript.Echo( "Invalid " & StrVarName & ".")
  406.             Call Wscript.Echo( "Please check the input and try again.")
  407.             Exit Function
  408.         End If
  409.  
  410.         strVar = Wscript.Arguments.Item(intArgIter)
  411.         If Err.Number Then
  412.             Call Wscript.Echo( "Invalid " & StrVarName & ".")
  413.             Call Wscript.Echo( "Please check the input and try again.")
  414.             Exit Function
  415.         End If
  416.  
  417.         If InStr(strVar, "/") Then
  418.             Call Wscript.Echo( "Invalid " & StrVarName)
  419.             Call Wscript.Echo( "Please check the input and try again.")
  420.             Exit Function
  421.         End If
  422.         blnGetArg = True 'success
  423.     End If
  424. End Function
  425.  
  426. '********************************************************************
  427. '*
  428. '* Function blnConnect()
  429. '*
  430. '* Purpose: Connects to machine strServer.
  431. '*
  432. '* Input:   strServer       a machine name
  433. '*          strNameSpace    a namespace
  434. '*          strUserName     name of the current user
  435. '*          strPassword     password of the current user
  436. '*
  437. '* Output:  objService is returned  as a service object.
  438. '*          strServer is set to local host if left unspecified
  439. '*
  440. '********************************************************************
  441. Private Function blnConnect(ByVal strNameSpace, _
  442.                             ByVal strUserName,  _
  443.                             ByVal strPassword,  _
  444.                             ByRef strServer,    _
  445.                             ByRef objService)
  446.  
  447.     ON ERROR RESUME NEXT
  448.  
  449.     Dim objLocator, objWshNet
  450.  
  451.     blnConnect = False     'There is no error.
  452.  
  453.     'Create Locator object to connect to remote CIM object manager
  454.     Set objLocator = CreateObject("WbemScripting.SWbemLocator")
  455.     If Err.Number then
  456.         Call Wscript.Echo( "Error 0x" & CStr(Hex(Err.Number)) & _
  457.                            " occurred in creating a locator object." )
  458.         If Err.Description <> "" Then
  459.             Call Wscript.Echo( "Error description: " & Err.Description & "." )
  460.         End If
  461.         Err.Clear
  462.         blnConnect = True     'An error occurred
  463.         Exit Function
  464.     End If
  465.  
  466.     'Connect to the namespace which is either local or remote
  467.     Set objService = objLocator.ConnectServer (strServer, strNameSpace, _
  468.        strUserName, strPassword)
  469.     ObjService.Security_.impersonationlevel = 3
  470.     If Err.Number then
  471.         Call Wscript.Echo( "Error 0x" & CStr(Hex(Err.Number)) & _
  472.                            " occurred in connecting to server " _
  473.            & strServer & ".")
  474.         If Err.Description <> "" Then
  475.             Call Wscript.Echo( "Error description: " & Err.Description & "." )
  476.         End If
  477.         Err.Clear
  478.         blnConnect = True     'An error occurred
  479.     End If
  480.  
  481.     'Get the current server's name if left unspecified
  482.     If IsEmpty(strServer) Then
  483.         Set objWshNet = CreateObject("Wscript.Network")
  484.     strServer     = objWshNet.ComputerName
  485.     End If
  486.  
  487. End Function
  488.  
  489. '********************************************************************
  490. '*
  491. '* Sub      VerifyHostIsCscript()
  492. '*
  493. '* Purpose: Determines which program is used to run this script.
  494. '*
  495. '* Input:   None
  496. '*
  497. '* Output:  If host is not cscript, then an error message is printed 
  498. '*          and the script is aborted.
  499. '*
  500. '********************************************************************
  501. Sub VerifyHostIsCscript()
  502.  
  503.     ON ERROR RESUME NEXT
  504.  
  505.     Dim strFullName, strCommand, i, j, intStatus
  506.  
  507.     strFullName = WScript.FullName
  508.  
  509.     If Err.Number then
  510.         Call Wscript.Echo( "Error 0x" & CStr(Hex(Err.Number)) & " occurred." )
  511.         If Err.Description <> "" Then
  512.             Call Wscript.Echo( "Error description: " & Err.Description & "." )
  513.         End If
  514.         intStatus =  CONST_ERROR
  515.     End If
  516.  
  517.     i = InStr(1, strFullName, ".exe", 1)
  518.     If i = 0 Then
  519.         intStatus =  CONST_ERROR
  520.     Else
  521.         j = InStrRev(strFullName, "\", i, 1)
  522.         If j = 0 Then
  523.             intStatus =  CONST_ERROR
  524.         Else
  525.             strCommand = Mid(strFullName, j+1, i-j-1)
  526.             Select Case LCase(strCommand)
  527.                 Case "cscript"
  528.                     intStatus = CONST_CSCRIPT
  529.                 Case "wscript"
  530.                     intStatus = CONST_WSCRIPT
  531.                 Case Else       'should never happen
  532.                     Call Wscript.Echo( "An unexpected program was used to " _
  533.                                        & "run this script." )
  534.                     Call Wscript.Echo( "Only CScript.Exe or WScript.Exe can " _
  535.                                        & "be used to run this script." )
  536.                     intStatus = CONST_ERROR
  537.                 End Select
  538.         End If
  539.     End If
  540.  
  541.     If intStatus <> CONST_CSCRIPT Then
  542.         Call WScript.Echo( "Please run this script using CScript." & vbCRLF & _
  543.              "This can be achieved by" & vbCRLF & _
  544.              "1. Using ""CScript EventLogMon.vbs arguments"" for Windows 95/98 or" _
  545.              & vbCRLF & "2. Changing the default Windows Scripting Host " _
  546.              & "setting to CScript" & vbCRLF & "    using ""CScript " _
  547.              & "//H:CScript //S"" and running the script using" & vbCRLF & _
  548.              "    ""EventLogMon.vbs arguments"" for Windows NT/2000." )
  549.         WScript.Quit
  550.     End If
  551.  
  552. End Sub
  553.  
  554. '********************************************************************
  555. '*
  556. '* Sub WriteLine()
  557. '* Purpose: Writes a text line either to a file or on screen.
  558. '* Input:   strMessage  the string to print
  559. '*          objFile     an output file object
  560. '* Output:  strMessage is either displayed on screen or written to a file.
  561. '*
  562. '********************************************************************
  563. Sub WriteLine(ByVal strMessage, ByVal objFile)
  564.  
  565.     On Error Resume Next
  566.     If IsObject(objFile) then        'objFile should be a file object
  567.         objFile.WriteLine strMessage
  568.     Else
  569.         Call Wscript.Echo( strMessage )
  570.     End If
  571.  
  572. End Sub
  573.  
  574. '********************************************************************
  575. '* 
  576. '* Function blnErrorOccurred()
  577. '*
  578. '* Purpose: Reports error with a string saying what the error occurred in.
  579. '*
  580. '* Input:   strIn        string saying what the error occurred in.
  581. '*
  582. '* Output:  displayed on screen 
  583. '* 
  584. '********************************************************************
  585. Private Function blnErrorOccurred (ByVal strIn)
  586.  
  587.     If Err.Number Then
  588.         Call Wscript.Echo( "Error 0x" & CStr(Hex(Err.Number)) & ": " & strIn)
  589.         If Err.Description <> "" Then
  590.             Call Wscript.Echo( "Error description: " & Err.Description)
  591.         End If
  592.         Err.Clear
  593.         blnErrorOccurred = True
  594.     Else
  595.         blnErrorOccurred = False
  596.     End If
  597.  
  598. End Function
  599.  
  600. '********************************************************************
  601. '* 
  602. '* Function blnOpenFile
  603. '*
  604. '* Purpose: Opens a file.
  605. '*
  606. '* Input:   strFileName        A string with the name of the file.
  607. '*
  608. '* Output:  Sets objOpenFile to a FileSystemObject and setis it to 
  609. '*            Nothing upon Failure.
  610. '* 
  611. '********************************************************************
  612. Private Function blnOpenFile(ByVal strFileName, ByRef objOpenFile)
  613.  
  614.     ON ERROR RESUME NEXT
  615.  
  616.     Dim objFileSystem
  617.  
  618.     Set objFileSystem = Nothing
  619.  
  620.     If IsEmpty(strFileName) OR strFileName = "" Then
  621.         blnOpenFile = False
  622.         Set objOpenFile = Nothing
  623.         Exit Function
  624.     End If
  625.  
  626.     'Create a file object
  627.     Set objFileSystem = CreateObject("Scripting.FileSystemObject")
  628.     If blnErrorOccurred("Could not create filesystem object.") Then
  629.         blnOpenFile = False
  630.         Set objOpenFile = Nothing
  631.         Exit Function
  632.     End If
  633.  
  634.     'Open the file for output
  635.     Set objOpenFile = objFileSystem.OpenTextFile(strFileName, 8, True)
  636.     If blnErrorOccurred("Could not open") Then
  637.         blnOpenFile = False
  638.         Set objOpenFile = Nothing
  639.         Exit Function
  640.     End If
  641.     blnOpenFile = True
  642.  
  643. End Function
  644.  
  645. '********************************************************************
  646. '*                                                                  *
  647. '*                           End of File                            *
  648. '*                                                                  *
  649. '********************************************************************