home *** CD-ROM | disk | FTP | other *** search
/ Chip 2000 May / Chip_2000-05_cd1.bin / zkuste / Perl / ActivePerl-5.6.0.613.msi / 䆊䌷䈹䈙䏵-䞅䞆䞀㡆䞃䄦䠥 / _e1fa42fc46a89a35a321888c3be772ce < prev    next >
Text File  |  2000-03-15  |  11KB  |  385 lines
  1. package HTTP::Date;  # $Date: 1999/05/03 14:04:48 $
  2.  
  3. $VERSION = sprintf("%d.%02d", q$Revision: 1.39 $ =~ /(\d+)\.(\d+)/);
  4.  
  5. require 5.004;
  6. require Exporter;
  7. @ISA = qw(Exporter);
  8. @EXPORT = qw(time2str str2time);
  9. @EXPORT_OK = qw(parse_date time2iso time2isoz);
  10.  
  11. use strict;
  12. require Time::Local;
  13.  
  14. use vars qw(@DoW @MoY %MoY);
  15. @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
  16. @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  17. @MoY{@MoY} = (1..12);
  18.  
  19. my %GMT_ZONE = (GMT => 1, UTC => 1, UT => 1, Z => 1);
  20.  
  21.  
  22. sub time2str (;$)
  23. {
  24.     my $time = shift;
  25.     $time = time unless defined $time;
  26.     my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($time);
  27.     sprintf("%s, %02d %s %04d %02d:%02d:%02d GMT",
  28.         $DoW[$wday],
  29.         $mday, $MoY[$mon], $year+1900,
  30.         $hour, $min, $sec);
  31. }
  32.  
  33.  
  34. sub str2time ($;$)
  35. {
  36.     my $str = shift;
  37.     return unless defined $str;
  38.  
  39.     # fast exit for strictly conforming string
  40.     if ($str =~ /^[SMTWF][a-z][a-z], (\d\d) ([JFMAJSOND][a-z][a-z]) (\d\d\d\d) (\d\d):(\d\d):(\d\d) GMT$/) {
  41.     return eval {
  42.         my $t = Time::Local::timegm($6, $5, $4, $1, $MoY{$2}-1, $3-1900);
  43.         $t < 0 ? undef : $t;
  44.     };
  45.     }
  46.  
  47.     my @d = parse_date($str);
  48.     return unless @d;
  49.     $d[0] -= 1900;  # year
  50.     $d[1]--;        # month
  51.  
  52.     my $tz = pop(@d);
  53.     unless (defined $tz) {
  54.     unless (defined($tz = shift)) {
  55.         return eval { my $t = Time::Local::timelocal(reverse @d);
  56.               $t < 0 ? undef : $t;
  57.                 };
  58.     }
  59.     }
  60.  
  61.     my $offset = 0;
  62.     if ($GMT_ZONE{uc $tz}) {
  63.     # offset already zero
  64.     }
  65.     elsif ($tz =~ /^([-+])?(\d\d?):?(\d\d)?$/) {
  66.     $offset = 3600 * $2;
  67.     $offset += 60 * $3 if $3;
  68.     $offset *= -1 if $1 && $1 ne '-';
  69.     }
  70.     else {
  71.     eval { require Time::Zone } || return;
  72.     $offset = Time::Zone::tz_offset($tz);
  73.     return unless defined $offset;
  74.     }
  75.     
  76.     return eval { my $t = Time::Local::timegm(reverse @d);
  77.           $t < 0 ? undef : $t + $offset;
  78.         };
  79. }
  80.  
  81.  
  82. sub parse_date ($)
  83. {
  84.     local($_) = shift;
  85.     return unless defined;
  86.  
  87.     # More lax parsing below
  88.     s/^\s+//;  # kill leading space
  89.     s/^(?:Sun|Mon|Tue|Wed|Thu|Fri|Sat)[a-z]*,?\s*//i; # Useless weekday
  90.  
  91.     my($day, $mon, $yr, $hr, $min, $sec, $tz, $ampm);
  92.  
  93.     # Then we are able to check for most of the formats with this regexp
  94.     (($day,$mon,$yr,$hr,$min,$sec,$tz) =
  95.         /^
  96.      (\d\d?)               # day
  97.         (?:\s+|[-\/])
  98.      (\w+)                 # month
  99.         (?:\s+|[-\/])
  100.      (\d+)                 # year
  101.      (?:
  102.            (?:\s+|:)       # separator before clock
  103.         (\d\d?):(\d\d)     # hour:min
  104.         (?::(\d\d))?       # optional seconds
  105.      )?                    # optional clock
  106.         \s*
  107.      ([-+]?\d{2,4}|(?![APap][Mm]\b)[A-Za-z]+)? # timezone
  108.         \s*$
  109.     /x)
  110.  
  111.     ||
  112.  
  113.     # Try the ctime and asctime format
  114.     (($mon, $day, $hr, $min, $sec, $tz, $yr) =
  115.     /^
  116.      (\w{1,3})             # month
  117.         \s+
  118.      (\d\d?)               # day
  119.         \s+
  120.      (\d\d?):(\d\d)        # hour:min
  121.      (?::(\d\d))?          # optional seconds
  122.         \s+
  123.      (?:([A-Za-z]+)\s+)?   # optional timezone
  124.      (\d+)                 # year
  125.         \s*$               # allow trailing whitespace
  126.     /x)
  127.  
  128.     ||
  129.  
  130.     # Then the Unix 'ls -l' date format
  131.     (($mon, $day, $yr, $hr, $min, $sec) =
  132.     /^
  133.      (\w{3})               # month
  134.         \s+
  135.      (\d\d?)               # day
  136.         \s+
  137.      (?:
  138.         (\d\d\d\d) |       # year
  139.         (\d{1,2}):(\d{2})  # hour:min
  140.             (?::(\d\d))?       # optional seconds
  141.      )
  142.      \s*$
  143.        /x)
  144.  
  145.     ||
  146.  
  147.     # ISO 8601 format '1996-02-29 12:00:00 -0100' and variants
  148.     (($yr, $mon, $day, $hr, $min, $sec, $tz) =
  149.     /^
  150.       (\d{4})              # year
  151.          [-\/]?
  152.       (\d\d?)              # numerical month
  153.          [-\/]?
  154.       (\d\d?)              # day
  155.      (?:
  156.            (?:\s+|[-:Tt])  # separator before clock
  157.         (\d\d?):?(\d\d)    # hour:min
  158.         (?::?(\d\d))?      # optional seconds
  159.      )?                    # optional clock
  160.         \s*
  161.      ([-+]?\d\d?:?(:?\d\d)?
  162.       |Z|z)?               # timezone  (Z is "zero meridian", i.e. GMT)
  163.         \s*$
  164.     /x)
  165.  
  166.     ||
  167.  
  168.     # Windows 'dir' 11-12-96  03:52PM
  169.     (($mon, $day, $yr, $hr, $min, $ampm) =
  170.         /^
  171.           (\d{2})                # numerical month
  172.              -
  173.           (\d{2})                # day
  174.              -
  175.           (\d{2})                # year
  176.              \s+
  177.           (\d\d?):(\d\d)([APap][Mm])  # hour:min AM or PM
  178.              \s*$
  179.         /x)
  180.  
  181.     ||
  182.     return;  # unrecognized format
  183.  
  184.     # Translate month name to number
  185.     $mon = $MoY{$mon} ||
  186.            $MoY{"\u\L$mon"} ||
  187.        ($mon >= 1 && $mon <= 12 && int($mon)) ||
  188.            return;
  189.  
  190.     # If the year is missing, we assume first date before the current,
  191.     # because of the formats we support such dates are mostly present
  192.     # on "ls -l" listings.
  193.     unless (defined $yr) {
  194.     my $cur_mon;
  195.     ($cur_mon, $yr) = (localtime)[4, 5];
  196.     $yr += 1900;
  197.     $cur_mon++;
  198.     $yr-- if $mon > $cur_mon;
  199.     }
  200.     elsif (length($yr) < 3) {
  201.     # Find "obvious" year
  202.     my $cur_yr = (localtime)[5] + 1900;
  203.     my $m = $cur_yr % 100;
  204.     my $tmp = $yr;
  205.     $yr += $cur_yr - $m;
  206.     $m -= $tmp;
  207.     $yr += ($m > 0) ? 100 : -100
  208.         if abs($m) > 50;
  209.     }
  210.  
  211.     # Make sure clock elements are defined
  212.     $hr  = 0 unless defined($hr);
  213.     $min = 0 unless defined($min);
  214.     $sec = 0 unless defined($sec);
  215.  
  216.     # Compensate for AM/PM
  217.     if ($ampm) {
  218.     $ampm = uc $ampm;
  219.     $hr = 0 if $hr == 12 && $ampm eq 'AM';
  220.     $hr += 12 if $ampm eq 'PM' && $hr != 12;
  221.     }
  222.  
  223.     return($yr, $mon, $day, $hr, $min, $sec, $tz)
  224.     if wantarray;
  225.     
  226.     if (defined $tz) {
  227.     $tz = "Z" if $tz =~ /^(GMT|UTC?|[-+]?0+)$/;
  228.     } else {
  229.     $tz = "";
  230.     }
  231.     return sprintf("%04d-%02d-%02d %02d:%02d:%02d%s",
  232.            $yr, $mon, $day, $hr, $min, $sec, $tz);
  233. }
  234.  
  235.  
  236. sub time2iso (;$)
  237. {
  238.     my $time = shift;
  239.     $time = time unless defined $time;
  240.     my($sec,$min,$hour,$mday,$mon,$year) = localtime($time);
  241.     sprintf("%04d-%02d-%02d %02d:%02d:%02d",
  242.         $year+1900, $mon+1, $mday, $hour, $min, $sec);
  243. }
  244.  
  245.  
  246. sub time2isoz (;$)
  247. {
  248.     my $time = shift;
  249.     $time = time unless defined $time;
  250.     my($sec,$min,$hour,$mday,$mon,$year) = gmtime($time);
  251.     sprintf("%04d-%02d-%02d %02d:%02d:%02dZ",
  252.             $year+1900, $mon+1, $mday, $hour, $min, $sec);
  253. }
  254.  
  255. 1;
  256.  
  257.  
  258. __END__
  259.  
  260. =head1 NAME
  261.  
  262. HTTP::Date - date conversion routines
  263.  
  264. =head1 SYNOPSIS
  265.  
  266.  use HTTP::Date;
  267.  
  268.  $string = time2str($time);    # Format as GMT ASCII time
  269.  $time = str2time($string);    # convert ASCII date to machine time
  270.  
  271. =head1 DESCRIPTION
  272.  
  273. This module provides functions that deal the date formats used by the
  274. HTTP protocol (and then some more).  Only the first two functions,
  275. time2str() and str2time(), are exported by default.
  276.  
  277. =over 4
  278.  
  279. =item time2str( [$time] )
  280.  
  281. The time2str() function converts a machine time (seconds since epoch)
  282. to a string.  If the function is called without an argument, it will
  283. use the current time.
  284.  
  285. The string returned is in the format preferred for the HTTP protocol.
  286. This is a fixed length subset of the format defined by RFC 1123,
  287. represented in Universal Time (GMT).  An example of a time stamp
  288. in this format is:
  289.  
  290.    Sun, 06 Nov 1994 08:49:37 GMT
  291.  
  292. =item str2time( $str [, $zone] )
  293.  
  294. The str2time() function converts a string to machine time.  It returns
  295. C<undef> if the format of $str is unrecognized, or the time is outside
  296. the representable range.  The time formats recognized are the same as
  297. for parse_date().
  298.  
  299. The function also takes an optional second argument that specifies the
  300. default time zone to use when converting the date.  This parameter is
  301. ignored if the zone is found in the date string itself.  If this
  302. parameter is missing, and the date string format does not contain any
  303. zone specification, then the local time zone is assumed.
  304.  
  305. If the zone is not "C<GMT>" or numerical (like "C<-0800>" or
  306. "C<+0100>"), then the C<Time::Zone> module must be installed in order
  307. to get the date recognized.
  308.  
  309. =item parse_date( $str )
  310.  
  311. This function will try to parse a date string, and then return it as a
  312. list of numerical values followed by a (possible undefined) time zone
  313. specifier; ($year, $month, $day, $hour, $min, $sec, $tz).  The $year
  314. returned will B<not> have the number 1900 subtracted from it and the
  315. $month numbers start with 1.
  316.  
  317. In scalar context the numbers are interpolated in a string of the
  318. "YYYY-MM-DD hh:mm:ss TZ"-format and returned.
  319.  
  320. If the date is unrecognized, then the empty list is returned.
  321.  
  322. The function is able to parse the following formats:
  323.  
  324.  "Wed, 09 Feb 1994 22:23:32 GMT"       -- HTTP format
  325.  "Thu Feb  3 17:03:55 GMT 1994"        -- ctime(3) format
  326.  "Thu Feb  3 00:00:00 1994",           -- ANSI C asctime() format
  327.  "Tuesday, 08-Feb-94 14:15:29 GMT"     -- old rfc850 HTTP format
  328.  "Tuesday, 08-Feb-1994 14:15:29 GMT"   -- broken rfc850 HTTP format
  329.  
  330.  "03/Feb/1994:17:03:55 -0700"   -- common logfile format
  331.  "09 Feb 1994 22:23:32 GMT"     -- HTTP format (no weekday)
  332.  "08-Feb-94 14:15:29 GMT"       -- rfc850 format (no weekday)
  333.  "08-Feb-1994 14:15:29 GMT"     -- broken rfc850 format (no weekday)
  334.  
  335.  "1994-02-03 14:15:29 -0100"    -- ISO 8601 format
  336.  "1994-02-03 14:15:29"          -- zone is optional
  337.  "1994-02-03"                   -- only date
  338.  "1994-02-03T14:15:29"          -- Use T as separator
  339.  "19940203T141529Z"             -- ISO 8601 compact format
  340.  "19940203"                     -- only date
  341.  
  342.  "08-Feb-94"         -- old rfc850 HTTP format    (no weekday, no time)
  343.  "08-Feb-1994"       -- broken rfc850 HTTP format (no weekday, no time)
  344.  "09 Feb 1994"       -- proposed new HTTP format  (no weekday, no time)
  345.  "03/Feb/1994"       -- common logfile format     (no time, no offset)
  346.  
  347.  "Feb  3  1994"      -- Unix 'ls -l' format
  348.  "Feb  3 17:03"      -- Unix 'ls -l' format
  349.  
  350.  "11-15-96  03:52PM" -- Windows 'dir' format
  351.  
  352. The parser ignores leading and trailing whitespace.  It also allow the
  353. seconds to be missing and the month to be numerical in most formats.
  354.  
  355. If the year is missing, then we assume that the date is the first
  356. matching date I<before> current month.  If the year is given with only
  357. 2 digits, then parse_date() will select the century that makes the
  358. year closest to the current date.
  359.  
  360. =item time2iso( [$time] )
  361.  
  362. Same as time2str(), but returns a "YYYY-MM-DD hh:mm:ss"-formatted
  363. string representing time in the local time zone.
  364.  
  365. =item time2isoz( [$time] )
  366.  
  367. Same as time2str(), but returns a "YYYY-MM-DD hh:mm:ssZ"-formatted
  368. string representing Universal Time.
  369.  
  370.  
  371. =back
  372.  
  373. =head1 SEE ALSO
  374.  
  375. L<perlfunc/time>, L<Time::Zone>
  376.  
  377. =head1 COPYRIGHT
  378.  
  379. Copyright 1995-1999, Gisle Aas
  380.  
  381. This library is free software; you can redistribute it and/or
  382. modify it under the same terms as Perl itself.
  383.  
  384. =cut
  385.