home *** CD-ROM | disk | FTP | other *** search
/ Chip 2000 May / Chip_2000-05_cd1.bin / zkuste / Perl / ActivePerl-5.6.0.613.msi / 䆊䌷䈹䈙䏵-䞅䞆䞀㡆䞃䄦䠥 / _bae15fc5d7462f3644cbdb22e836dfee < prev    next >
Text File  |  2000-03-23  |  35KB  |  881 lines
  1. <HTML>
  2. <HEAD>
  3. <TITLE>perldsc - Perl Data Structures Cookbook</TITLE>
  4. <LINK REL="stylesheet" HREF="../../Active.css" TYPE="text/css">
  5. <LINK REV="made" HREF="mailto:">
  6. </HEAD>
  7.  
  8. <BODY>
  9. <TABLE BORDER=0 CELLPADDING=0 CELLSPACING=0 WIDTH=100%>
  10. <TR><TD CLASS=block VALIGN=MIDDLE WIDTH=100% BGCOLOR="#cccccc">
  11. <STRONG><P CLASS=block> perldsc - Perl Data Structures Cookbook</P></STRONG>
  12. </TD></TR>
  13. </TABLE>
  14.  
  15. <A NAME="__index__"></A>
  16. <!-- INDEX BEGIN -->
  17.  
  18. <UL>
  19.  
  20.     <LI><A HREF="#name">NAME</A></LI>
  21.     <LI><A HREF="#description">DESCRIPTION</A></LI>
  22.     <LI><A HREF="#references">REFERENCES</A></LI>
  23.     <LI><A HREF="#common mistakes">COMMON MISTAKES</A></LI>
  24.     <LI><A HREF="#caveat on precedence">CAVEAT ON PRECEDENCE</A></LI>
  25.     <LI><A HREF="#why you should always use strict">WHY YOU SHOULD ALWAYS <CODE>use strict</CODE></A></LI>
  26.     <LI><A HREF="#debugging">DEBUGGING</A></LI>
  27.     <LI><A HREF="#code examples">CODE EXAMPLES</A></LI>
  28.     <LI><A HREF="#arrays of arrays">ARRAYS OF ARRAYS</A></LI>
  29.     <UL>
  30.  
  31.         <LI><A HREF="#declaration of a array of arrays">Declaration of a ARRAY OF ARRAYS</A></LI>
  32.         <LI><A HREF="#generation of a array of arrays">Generation of a ARRAY OF ARRAYS</A></LI>
  33.         <LI><A HREF="#access and printing of a array of arrays">Access and Printing of a ARRAY OF ARRAYS</A></LI>
  34.     </UL>
  35.  
  36.     <LI><A HREF="#hashes of arrays">HASHES OF ARRAYS</A></LI>
  37.     <UL>
  38.  
  39.         <LI><A HREF="#declaration of a hash of arrays">Declaration of a HASH OF ARRAYS</A></LI>
  40.         <LI><A HREF="#generation of a hash of arrays">Generation of a HASH OF ARRAYS</A></LI>
  41.         <LI><A HREF="#access and printing of a hash of arrays">Access and Printing of a HASH OF ARRAYS</A></LI>
  42.     </UL>
  43.  
  44.     <LI><A HREF="#arrays of hashes">ARRAYS OF HASHES</A></LI>
  45.     <UL>
  46.  
  47.         <LI><A HREF="#declaration of a array of hashes">Declaration of a ARRAY OF HASHES</A></LI>
  48.         <LI><A HREF="#generation of a array of hashes">Generation of a ARRAY OF HASHES</A></LI>
  49.         <LI><A HREF="#access and printing of a array of hashes">Access and Printing of a ARRAY OF HASHES</A></LI>
  50.     </UL>
  51.  
  52.     <LI><A HREF="#hashes of hashes">HASHES OF HASHES</A></LI>
  53.     <UL>
  54.  
  55.         <LI><A HREF="#declaration of a hash of hashes">Declaration of a HASH OF HASHES</A></LI>
  56.         <LI><A HREF="#generation of a hash of hashes">Generation of a HASH OF HASHES</A></LI>
  57.         <LI><A HREF="#access and printing of a hash of hashes">Access and Printing of a HASH OF HASHES</A></LI>
  58.     </UL>
  59.  
  60.     <LI><A HREF="#more elaborate records">MORE ELABORATE RECORDS</A></LI>
  61.     <UL>
  62.  
  63.         <LI><A HREF="#declaration of more elaborate records">Declaration of MORE ELABORATE RECORDS</A></LI>
  64.         <LI><A HREF="#declaration of a hash of complex records">Declaration of a HASH OF COMPLEX RECORDS</A></LI>
  65.         <LI><A HREF="#generation of a hash of complex records">Generation of a HASH OF COMPLEX RECORDS</A></LI>
  66.     </UL>
  67.  
  68.     <LI><A HREF="#database ties">Database Ties</A></LI>
  69.     <LI><A HREF="#see also">SEE ALSO</A></LI>
  70.     <LI><A HREF="#author">AUTHOR</A></LI>
  71. </UL>
  72. <!-- INDEX END -->
  73.  
  74. <HR>
  75. <P>
  76. <H1><A NAME="name">NAME</A></H1>
  77. <P>perldsc - Perl Data Structures Cookbook</P>
  78. <P>
  79. <HR>
  80. <H1><A NAME="description">DESCRIPTION</A></H1>
  81. <P>The single feature most sorely lacking in the Perl programming language
  82. prior to its 5.0 release was complex data structures.  Even without direct
  83. language support, some valiant programmers did manage to emulate them, but
  84. it was hard work and not for the faint of heart.  You could occasionally
  85. get away with the <CODE>$m{$AoA,$b}</CODE> notation borrowed from <STRONG>awk</STRONG> in which the
  86. keys are actually more like a single concatenated string <CODE>"$AoA$b"</CODE>, but
  87. traversal and sorting were difficult.  More desperate programmers even
  88. hacked Perl's internal symbol table directly, a strategy that proved hard
  89. to develop and maintain--to put it mildly.</P>
  90. <P>The 5.0 release of Perl let us have complex data structures.  You
  91. may now write something like this and all of a sudden, you'd have a array
  92. with three dimensions!</P>
  93. <PRE>
  94.     for $x (1 .. 10) {
  95.         for $y (1 .. 10) {
  96.             for $z (1 .. 10) {
  97.                 $AoA[$x][$y][$z] =
  98.                     $x ** $y + $z;
  99.             }
  100.         }
  101.     }</PRE>
  102. <P>Alas, however simple this may appear, underneath it's a much more
  103. elaborate construct than meets the eye!</P>
  104. <P>How do you print it out?  Why can't you say just <CODE>print @AoA</CODE>?  How do
  105. you sort it?  How can you pass it to a function or get one of these back
  106. from a function?  Is is an object?  Can you save it to disk to read
  107. back later?  How do you access whole rows or columns of that matrix?  Do
  108. all the values have to be numeric?</P>
  109. <P>As you see, it's quite easy to become confused.  While some small portion
  110. of the blame for this can be attributed to the reference-based
  111. implementation, it's really more due to a lack of existing documentation with
  112. examples designed for the beginner.</P>
  113. <P>This document is meant to be a detailed but understandable treatment of the
  114. many different sorts of data structures you might want to develop.  It
  115. should also serve as a cookbook of examples.  That way, when you need to
  116. create one of these complex data structures, you can just pinch, pilfer, or
  117. purloin a drop-in example from here.</P>
  118. <P>Let's look at each of these possible constructs in detail.  There are separate
  119. sections on each of the following:</P>
  120. <UL>
  121. <LI><STRONG><A NAME="item_arrays_of_arrays">arrays of arrays</A></STRONG><BR>
  122.  
  123. <LI><STRONG><A NAME="item_hashes_of_arrays">hashes of arrays</A></STRONG><BR>
  124.  
  125. <LI><STRONG><A NAME="item_arrays_of_hashes">arrays of hashes</A></STRONG><BR>
  126.  
  127. <LI><STRONG><A NAME="item_hashes_of_hashes">hashes of hashes</A></STRONG><BR>
  128.  
  129. <LI><STRONG><A NAME="item_more_elaborate_constructs">more elaborate constructs</A></STRONG><BR>
  130.  
  131. </UL>
  132. <P>But for now, let's look at general issues common to all
  133. these types of data structures.</P>
  134. <P>
  135. <HR>
  136. <H1><A NAME="references">REFERENCES</A></H1>
  137. <P>The most important thing to understand about all data structures in Perl
  138. -- including multidimensional arrays--is that even though they might
  139. appear otherwise, Perl <CODE>@ARRAY</CODE>s and <CODE>%HASH</CODE>es are all internally
  140. one-dimensional.  They can hold only scalar values (meaning a string,
  141. number, or a reference).  They cannot directly contain other arrays or
  142. hashes, but instead contain <EM>references</EM> to other arrays or hashes.</P>
  143. <P>You can't use a reference to a array or hash in quite the same way that you
  144. would a real array or hash.  For C or C++ programmers unused to
  145. distinguishing between arrays and pointers to the same, this can be
  146. confusing.  If so, just think of it as the difference between a structure
  147. and a pointer to a structure.</P>
  148. <P>You can (and should) read more about references in the <CODE>perlref(1)</CODE> man
  149. page.  Briefly, references are rather like pointers that know what they
  150. point to.  (Objects are also a kind of reference, but we won't be needing
  151. them right away--if ever.)  This means that when you have something which
  152. looks to you like an access to a two-or-more-dimensional array and/or hash,
  153. what's really going on is that the base type is
  154. merely a one-dimensional entity that contains references to the next
  155. level.  It's just that you can <EM>use</EM> it as though it were a
  156. two-dimensional one.  This is actually the way almost all C
  157. multidimensional arrays work as well.</P>
  158. <PRE>
  159.     $array[7][12]                       # array of arrays
  160.     $array[7]{string}                   # array of hashes
  161.     $hash{string}[7]                    # hash of arrays
  162.     $hash{string}{'another string'}     # hash of hashes</PRE>
  163. <P>Now, because the top level contains only references, if you try to print
  164. out your array in with a simple <A HREF="../../lib/Pod/perlfunc.html#item_print"><CODE>print()</CODE></A> function, you'll get something
  165. that doesn't look very nice, like this:</P>
  166. <PRE>
  167.     @AoA = ( [2, 3], [4, 5, 7], [0] );
  168.     print $AoA[1][2];
  169.   7
  170.     print @AoA;
  171.   ARRAY(0x83c38)ARRAY(0x8b194)ARRAY(0x8b1d0)</PRE>
  172. <P>That's because Perl doesn't (ever) implicitly dereference your variables.
  173. If you want to get at the thing a reference is referring to, then you have
  174. to do this yourself using either prefix typing indicators, like
  175. <CODE>${$blah}</CODE>, <CODE>@{$blah}</CODE>, <CODE>@{$blah[$i]}</CODE>, or else postfix pointer arrows,
  176. like <CODE>$a->[3]</CODE>, <CODE>$h->{fred}</CODE>, or even <CODE>$ob->method()->[3]</CODE>.</P>
  177. <P>
  178. <HR>
  179. <H1><A NAME="common mistakes">COMMON MISTAKES</A></H1>
  180. <P>The two most common mistakes made in constructing something like
  181. an array of arrays is either accidentally counting the number of
  182. elements or else taking a reference to the same memory location
  183. repeatedly.  Here's the case where you just get the count instead
  184. of a nested array:</P>
  185. <PRE>
  186.     for $i (1..10) {
  187.         @array = somefunc($i);
  188.         $AoA[$i] = @array;      # WRONG!
  189.     }</PRE>
  190. <P>That's just the simple case of assigning an array to a scalar and getting
  191. its element count.  If that's what you really and truly want, then you
  192. might do well to consider being a tad more explicit about it, like this:</P>
  193. <PRE>
  194.     for $i (1..10) {
  195.         @array = somefunc($i);
  196.         $counts[$i] = scalar @array;
  197.     }</PRE>
  198. <P>Here's the case of taking a reference to the same memory location
  199. again and again:</P>
  200. <PRE>
  201.     for $i (1..10) {
  202.         @array = somefunc($i);
  203.         $AoA[$i] = \@array;     # WRONG!
  204.     }</PRE>
  205. <P>So, what's the big problem with that?  It looks right, doesn't it?
  206. After all, I just told you that you need an array of references, so by
  207. golly, you've made me one!</P>
  208. <P>Unfortunately, while this is true, it's still broken.  All the references
  209. in @AoA refer to the <EM>very same place</EM>, and they will therefore all hold
  210. whatever was last in @array!  It's similar to the problem demonstrated in
  211. the following C program:</P>
  212. <PRE>
  213.     #include <pwd.h>
  214.     main() {
  215.         struct passwd *getpwnam(), *rp, *dp;
  216.         rp = getpwnam("root");
  217.         dp = getpwnam("daemon");</PRE>
  218. <PRE>
  219.         printf("daemon name is %s\nroot name is %s\n",
  220.                 dp->pw_name, rp->pw_name);
  221.     }</PRE>
  222. <P>Which will print</P>
  223. <PRE>
  224.     daemon name is daemon
  225.     root name is daemon</PRE>
  226. <P>The problem is that both <CODE>rp</CODE> and <CODE>dp</CODE> are pointers to the same location
  227. in memory!  In C, you'd have to remember to <CODE>malloc()</CODE> yourself some new
  228. memory.  In Perl, you'll want to use the array constructor <CODE>[]</CODE> or the
  229. hash constructor <CODE>{}</CODE> instead.   Here's the right way to do the preceding
  230. broken code fragments:</P>
  231. <PRE>
  232.     for $i (1..10) {
  233.         @array = somefunc($i);
  234.         $AoA[$i] = [ @array ];
  235.     }</PRE>
  236. <P>The square brackets make a reference to a new array with a <EM>copy</EM>
  237. of what's in @array at the time of the assignment.  This is what
  238. you want.</P>
  239. <P>Note that this will produce something similar, but it's
  240. much harder to read:</P>
  241. <PRE>
  242.     for $i (1..10) {
  243.         @array = 0 .. $i;
  244.         @{$AoA[$i]} = @array;
  245.     }</PRE>
  246. <P>Is it the same?  Well, maybe so--and maybe not.  The subtle difference
  247. is that when you assign something in square brackets, you know for sure
  248. it's always a brand new reference with a new <EM>copy</EM> of the data.
  249. Something else could be going on in this new case with the <CODE>@{$AoA[$i]}}</CODE>
  250. dereference on the left-hand-side of the assignment.  It all depends on
  251. whether <CODE>$AoA[$i]</CODE> had been undefined to start with, or whether it
  252. already contained a reference.  If you had already populated @AoA with
  253. references, as in</P>
  254. <PRE>
  255.     $AoA[3] = \@another_array;</PRE>
  256. <P>Then the assignment with the indirection on the left-hand-side would
  257. use the existing reference that was already there:</P>
  258. <PRE>
  259.     @{$AoA[3]} = @array;</PRE>
  260. <P>Of course, this <EM>would</EM> have the ``interesting'' effect of clobbering
  261. @another_array.  (Have you ever noticed how when a programmer says
  262. something is ``interesting'', that rather than meaning ``intriguing'',
  263. they're disturbingly more apt to mean that it's ``annoying'',
  264. ``difficult'', or both?  :-)</P>
  265. <P>So just remember always to use the array or hash constructors with <CODE>[]</CODE>
  266. or <CODE>{}</CODE>, and you'll be fine, although it's not always optimally
  267. efficient.</P>
  268. <P>Surprisingly, the following dangerous-looking construct will
  269. actually work out fine:</P>
  270. <PRE>
  271.     for $i (1..10) {
  272.         my @array = somefunc($i);
  273.         $AoA[$i] = \@array;
  274.     }</PRE>
  275. <P>That's because <A HREF="../../lib/Pod/perlfunc.html#item_my"><CODE>my()</CODE></A> is more of a run-time statement than it is a
  276. compile-time declaration <EM>per se</EM>.  This means that the <A HREF="../../lib/Pod/perlfunc.html#item_my"><CODE>my()</CODE></A> variable is
  277. remade afresh each time through the loop.  So even though it <EM>looks</EM> as
  278. though you stored the same variable reference each time, you actually did
  279. not!  This is a subtle distinction that can produce more efficient code at
  280. the risk of misleading all but the most experienced of programmers.  So I
  281. usually advise against teaching it to beginners.  In fact, except for
  282. passing arguments to functions, I seldom like to see the gimme-a-reference
  283. operator (backslash) used much at all in code.  Instead, I advise
  284. beginners that they (and most of the rest of us) should try to use the
  285. much more easily understood constructors <CODE>[]</CODE> and <CODE>{}</CODE> instead of
  286. relying upon lexical (or dynamic) scoping and hidden reference-counting to
  287. do the right thing behind the scenes.</P>
  288. <P>In summary:</P>
  289. <PRE>
  290.     $AoA[$i] = [ @array ];      # usually best
  291.     $AoA[$i] = \@array;         # perilous; just how my() was that array?
  292.     @{ $AoA[$i] } = @array;     # way too tricky for most programmers</PRE>
  293. <P>
  294. <HR>
  295. <H1><A NAME="caveat on precedence">CAVEAT ON PRECEDENCE</A></H1>
  296. <P>Speaking of things like <CODE>@{$AoA[$i]}</CODE>, the following are actually the
  297. same thing:</P>
  298. <PRE>
  299.     $aref->[2][2]       # clear
  300.     $$aref[2][2]        # confusing</PRE>
  301. <P>That's because Perl's precedence rules on its five prefix dereferencers
  302. (which look like someone swearing: <CODE>$ @ * % &</CODE>) make them bind more
  303. tightly than the postfix subscripting brackets or braces!  This will no
  304. doubt come as a great shock to the C or C++ programmer, who is quite
  305. accustomed to using <CODE>*a[i]</CODE> to mean what's pointed to by the <EM>i'th</EM>
  306. element of <CODE>a</CODE>.  That is, they first take the subscript, and only then
  307. dereference the thing at that subscript.  That's fine in C, but this isn't C.</P>
  308. <P>The seemingly equivalent construct in Perl, <CODE>$$aref[$i]</CODE> first does
  309. the deref of $aref, making it take $aref as a reference to an
  310. array, and then dereference that, and finally tell you the <EM>i'th</EM> value
  311. of the array pointed to by $AoA. If you wanted the C notion, you'd have to
  312. write <CODE>${$AoA[$i]}</CODE> to force the <CODE>$AoA[$i]</CODE> to get evaluated first
  313. before the leading <CODE>$</CODE> dereferencer.</P>
  314. <P>
  315. <HR>
  316. <H1><A NAME="why you should always use strict">WHY YOU SHOULD ALWAYS <CODE>use strict</CODE></A></H1>
  317. <P>If this is starting to sound scarier than it's worth, relax.  Perl has
  318. some features to help you avoid its most common pitfalls.  The best
  319. way to avoid getting confused is to start every program like this:</P>
  320. <PRE>
  321.     #!/usr/bin/perl -w
  322.     use strict;</PRE>
  323. <P>This way, you'll be forced to declare all your variables with <A HREF="../../lib/Pod/perlfunc.html#item_my"><CODE>my()</CODE></A> and
  324. also disallow accidental ``symbolic dereferencing''.  Therefore if you'd done
  325. this:</P>
  326. <PRE>
  327.     my $aref = [
  328.         [ "fred", "barney", "pebbles", "bambam", "dino", ],
  329.         [ "homer", "bart", "marge", "maggie", ],
  330.         [ "george", "jane", "elroy", "judy", ],
  331.     ];</PRE>
  332. <PRE>
  333.     print $aref[2][2];</PRE>
  334. <P>The compiler would immediately flag that as an error <EM>at compile time</EM>,
  335. because you were accidentally accessing <CODE>@aref</CODE>, an undeclared
  336. variable, and it would thereby remind you to write instead:</P>
  337. <PRE>
  338.     print $aref->[2][2]</PRE>
  339. <P>
  340. <HR>
  341. <H1><A NAME="debugging">DEBUGGING</A></H1>
  342. <P>Before version 5.002, the standard Perl debugger didn't do a very nice job of
  343. printing out complex data structures.  With 5.002 or above, the
  344. debugger includes several new features, including command line editing as
  345. well as the <CODE>x</CODE> command to dump out complex data structures.  For
  346. example, given the assignment to $AoA above, here's the debugger output:</P>
  347. <PRE>
  348.     DB<1> x $AoA
  349.     $AoA = ARRAY(0x13b5a0)
  350.        0  ARRAY(0x1f0a24)
  351.           0  'fred'
  352.           1  'barney'
  353.           2  'pebbles'
  354.           3  'bambam'
  355.           4  'dino'
  356.        1  ARRAY(0x13b558)
  357.           0  'homer'
  358.           1  'bart'
  359.           2  'marge'
  360.           3  'maggie'
  361.        2  ARRAY(0x13b540)
  362.           0  'george'
  363.           1  'jane'
  364.           2  'elroy'
  365.           3  'judy'</PRE>
  366. <P>
  367. <HR>
  368. <H1><A NAME="code examples">CODE EXAMPLES</A></H1>
  369. <P>Presented with little comment (these will get their own manpages someday)
  370. here are short code examples illustrating access of various
  371. types of data structures.</P>
  372. <P>
  373. <HR>
  374. <H1><A NAME="arrays of arrays">ARRAYS OF ARRAYS</A></H1>
  375. <P>
  376. <H2><A NAME="declaration of a array of arrays">Declaration of a ARRAY OF ARRAYS</A></H2>
  377. <PRE>
  378.  @AoA = (
  379.         [ "fred", "barney" ],
  380.         [ "george", "jane", "elroy" ],
  381.         [ "homer", "marge", "bart" ],
  382.       );</PRE>
  383. <P>
  384. <H2><A NAME="generation of a array of arrays">Generation of a ARRAY OF ARRAYS</A></H2>
  385. <PRE>
  386.  # reading from file
  387.  while ( <> ) {
  388.      push @AoA, [ split ];
  389.  }</PRE>
  390. <PRE>
  391.  # calling a function
  392.  for $i ( 1 .. 10 ) {
  393.      $AoA[$i] = [ somefunc($i) ];
  394.  }</PRE>
  395. <PRE>
  396.  # using temp vars
  397.  for $i ( 1 .. 10 ) {
  398.      @tmp = somefunc($i);
  399.      $AoA[$i] = [ @tmp ];
  400.  }</PRE>
  401. <PRE>
  402.  # add to an existing row
  403.  push @{ $AoA[0] }, "wilma", "betty";</PRE>
  404. <P>
  405. <H2><A NAME="access and printing of a array of arrays">Access and Printing of a ARRAY OF ARRAYS</A></H2>
  406. <PRE>
  407.  # one element
  408.  $AoA[0][0] = "Fred";</PRE>
  409. <PRE>
  410.  # another element
  411.  $AoA[1][1] =~ s/(\w)/\u$1/;</PRE>
  412. <PRE>
  413.  # print the whole thing with refs
  414.  for $aref ( @AoA ) {
  415.      print "\t [ @$aref ],\n";
  416.  }</PRE>
  417. <PRE>
  418.  # print the whole thing with indices
  419.  for $i ( 0 .. $#AoA ) {
  420.      print "\t [ @{$AoA[$i]} ],\n";
  421.  }</PRE>
  422. <PRE>
  423.  # print the whole thing one at a time
  424.  for $i ( 0 .. $#AoA ) {
  425.      for $j ( 0 .. $#{ $AoA[$i] } ) {
  426.          print "elt $i $j is $AoA[$i][$j]\n";
  427.      }
  428.  }</PRE>
  429. <P>
  430. <HR>
  431. <H1><A NAME="hashes of arrays">HASHES OF ARRAYS</A></H1>
  432. <P>
  433. <H2><A NAME="declaration of a hash of arrays">Declaration of a HASH OF ARRAYS</A></H2>
  434. <PRE>
  435.  %HoA = (
  436.         flintstones        => [ "fred", "barney" ],
  437.         jetsons            => [ "george", "jane", "elroy" ],
  438.         simpsons           => [ "homer", "marge", "bart" ],
  439.       );</PRE>
  440. <P>
  441. <H2><A NAME="generation of a hash of arrays">Generation of a HASH OF ARRAYS</A></H2>
  442. <PRE>
  443.  # reading from file
  444.  # flintstones: fred barney wilma dino
  445.  while ( <> ) {
  446.      next unless s/^(.*?):\s*//;
  447.      $HoA{$1} = [ split ];
  448.  }</PRE>
  449. <PRE>
  450.  # reading from file; more temps
  451.  # flintstones: fred barney wilma dino
  452.  while ( $line = <> ) {
  453.      ($who, $rest) = split /:\s*/, $line, 2;
  454.      @fields = split ' ', $rest;
  455.      $HoA{$who} = [ @fields ];
  456.  }</PRE>
  457. <PRE>
  458.  # calling a function that returns a list
  459.  for $group ( "simpsons", "jetsons", "flintstones" ) {
  460.      $HoA{$group} = [ get_family($group) ];
  461.  }</PRE>
  462. <PRE>
  463.  # likewise, but using temps
  464.  for $group ( "simpsons", "jetsons", "flintstones" ) {
  465.      @members = get_family($group);
  466.      $HoA{$group} = [ @members ];
  467.  }</PRE>
  468. <PRE>
  469.  # append new members to an existing family
  470.  push @{ $HoA{"flintstones"} }, "wilma", "betty";</PRE>
  471. <P>
  472. <H2><A NAME="access and printing of a hash of arrays">Access and Printing of a HASH OF ARRAYS</A></H2>
  473. <PRE>
  474.  # one element
  475.  $HoA{flintstones}[0] = "Fred";</PRE>
  476. <PRE>
  477.  # another element
  478.  $HoA{simpsons}[1] =~ s/(\w)/\u$1/;</PRE>
  479. <PRE>
  480.  # print the whole thing
  481.  foreach $family ( keys %HoA ) {
  482.      print "$family: @{ $HoA{$family} }\n"
  483.  }</PRE>
  484. <PRE>
  485.  # print the whole thing with indices
  486.  foreach $family ( keys %HoA ) {
  487.      print "family: ";
  488.      foreach $i ( 0 .. $#{ $HoA{$family} } ) {
  489.          print " $i = $HoA{$family}[$i]";
  490.      }
  491.      print "\n";
  492.  }</PRE>
  493. <PRE>
  494.  # print the whole thing sorted by number of members
  495.  foreach $family ( sort { @{$HoA{$b}} <=> @{$HoA{$a}} } keys %HoA ) {
  496.      print "$family: @{ $HoA{$family} }\n"
  497.  }</PRE>
  498. <PRE>
  499.  # print the whole thing sorted by number of members and name
  500.  foreach $family ( sort {
  501.                             @{$HoA{$b}} <=> @{$HoA{$a}}
  502.                                         ||
  503.                                     $a cmp $b
  504.             } keys %HoA )
  505.  {
  506.      print "$family: ", join(", ", sort @{ $HoA{$family} }), "\n";
  507.  }</PRE>
  508. <P>
  509. <HR>
  510. <H1><A NAME="arrays of hashes">ARRAYS OF HASHES</A></H1>
  511. <P>
  512. <H2><A NAME="declaration of a array of hashes">Declaration of a ARRAY OF HASHES</A></H2>
  513. <PRE>
  514.  @AoH = (
  515.         {
  516.             Lead     => "fred",
  517.             Friend   => "barney",
  518.         },
  519.         {
  520.             Lead     => "george",
  521.             Wife     => "jane",
  522.             Son      => "elroy",
  523.         },
  524.         {
  525.             Lead     => "homer",
  526.             Wife     => "marge",
  527.             Son      => "bart",
  528.         }
  529.   );</PRE>
  530. <P>
  531. <H2><A NAME="generation of a array of hashes">Generation of a ARRAY OF HASHES</A></H2>
  532. <PRE>
  533.  # reading from file
  534.  # format: LEAD=fred FRIEND=barney
  535.  while ( <> ) {
  536.      $rec = {};
  537.      for $field ( split ) {
  538.          ($key, $value) = split /=/, $field;
  539.          $rec->{$key} = $value;
  540.      }
  541.      push @AoH, $rec;
  542.  }</PRE>
  543. <PRE>
  544.  # reading from file
  545.  # format: LEAD=fred FRIEND=barney
  546.  # no temp
  547.  while ( <> ) {
  548.      push @AoH, { split /[\s+=]/ };
  549.  }</PRE>
  550. <PRE>
  551.  # calling a function  that returns a key/value pair list, like
  552.  # "lead","fred","daughter","pebbles"
  553.  while ( %fields = getnextpairset() ) {
  554.      push @AoH, { %fields };
  555.  }</PRE>
  556. <PRE>
  557.  # likewise, but using no temp vars
  558.  while (<>) {
  559.      push @AoH, { parsepairs($_) };
  560.  }</PRE>
  561. <PRE>
  562.  # add key/value to an element
  563.  $AoH[0]{pet} = "dino";
  564.  $AoH[2]{pet} = "santa's little helper";</PRE>
  565. <P>
  566. <H2><A NAME="access and printing of a array of hashes">Access and Printing of a ARRAY OF HASHES</A></H2>
  567. <PRE>
  568.  # one element
  569.  $AoH[0]{lead} = "fred";</PRE>
  570. <PRE>
  571.  # another element
  572.  $AoH[1]{lead} =~ s/(\w)/\u$1/;</PRE>
  573. <PRE>
  574.  # print the whole thing with refs
  575.  for $href ( @AoH ) {
  576.      print "{ ";
  577.      for $role ( keys %$href ) {
  578.          print "$role=$href->{$role} ";
  579.      }
  580.      print "}\n";
  581.  }</PRE>
  582. <PRE>
  583.  # print the whole thing with indices
  584.  for $i ( 0 .. $#AoH ) {
  585.      print "$i is { ";
  586.      for $role ( keys %{ $AoH[$i] } ) {
  587.          print "$role=$AoH[$i]{$role} ";
  588.      }
  589.      print "}\n";
  590.  }</PRE>
  591. <PRE>
  592.  # print the whole thing one at a time
  593.  for $i ( 0 .. $#AoH ) {
  594.      for $role ( keys %{ $AoH[$i] } ) {
  595.          print "elt $i $role is $AoH[$i]{$role}\n";
  596.      }
  597.  }</PRE>
  598. <P>
  599. <HR>
  600. <H1><A NAME="hashes of hashes">HASHES OF HASHES</A></H1>
  601. <P>
  602. <H2><A NAME="declaration of a hash of hashes">Declaration of a HASH OF HASHES</A></H2>
  603. <PRE>
  604.  %HoH = (
  605.         flintstones => {
  606.                 lead      => "fred",
  607.                 pal       => "barney",
  608.         },
  609.         jetsons     => {
  610.                 lead      => "george",
  611.                 wife      => "jane",
  612.                 "his boy" => "elroy",
  613.         },
  614.         simpsons    => {
  615.                 lead      => "homer",
  616.                 wife      => "marge",
  617.                 kid       => "bart",
  618.         },
  619.  );</PRE>
  620. <P>
  621. <H2><A NAME="generation of a hash of hashes">Generation of a HASH OF HASHES</A></H2>
  622. <PRE>
  623.  # reading from file
  624.  # flintstones: lead=fred pal=barney wife=wilma pet=dino
  625.  while ( <> ) {
  626.      next unless s/^(.*?):\s*//;
  627.      $who = $1;
  628.      for $field ( split ) {
  629.          ($key, $value) = split /=/, $field;
  630.          $HoH{$who}{$key} = $value;
  631.      }</PRE>
  632. <PRE>
  633.  # reading from file; more temps
  634.  while ( <> ) {
  635.      next unless s/^(.*?):\s*//;
  636.      $who = $1;
  637.      $rec = {};
  638.      $HoH{$who} = $rec;
  639.      for $field ( split ) {
  640.          ($key, $value) = split /=/, $field;
  641.          $rec->{$key} = $value;
  642.      }
  643.  }</PRE>
  644. <PRE>
  645.  # calling a function  that returns a key,value hash
  646.  for $group ( "simpsons", "jetsons", "flintstones" ) {
  647.      $HoH{$group} = { get_family($group) };
  648.  }</PRE>
  649. <PRE>
  650.  # likewise, but using temps
  651.  for $group ( "simpsons", "jetsons", "flintstones" ) {
  652.      %members = get_family($group);
  653.      $HoH{$group} = { %members };
  654.  }</PRE>
  655. <PRE>
  656.  # append new members to an existing family
  657.  %new_folks = (
  658.      wife => "wilma",
  659.      pet  => "dino",
  660.  );</PRE>
  661. <PRE>
  662.  for $what (keys %new_folks) {
  663.      $HoH{flintstones}{$what} = $new_folks{$what};
  664.  }</PRE>
  665. <P>
  666. <H2><A NAME="access and printing of a hash of hashes">Access and Printing of a HASH OF HASHES</A></H2>
  667. <PRE>
  668.  # one element
  669.  $HoH{flintstones}{wife} = "wilma";</PRE>
  670. <PRE>
  671.  # another element
  672.  $HoH{simpsons}{lead} =~ s/(\w)/\u$1/;</PRE>
  673. <PRE>
  674.  # print the whole thing
  675.  foreach $family ( keys %HoH ) {
  676.      print "$family: { ";
  677.      for $role ( keys %{ $HoH{$family} } ) {
  678.          print "$role=$HoH{$family}{$role} ";
  679.      }
  680.      print "}\n";
  681.  }</PRE>
  682. <PRE>
  683.  # print the whole thing  somewhat sorted
  684.  foreach $family ( sort keys %HoH ) {
  685.      print "$family: { ";
  686.      for $role ( sort keys %{ $HoH{$family} } ) {
  687.          print "$role=$HoH{$family}{$role} ";
  688.      }
  689.      print "}\n";
  690.  }</PRE>
  691. <PRE>
  692.  # print the whole thing sorted by number of members
  693.  foreach $family ( sort { keys %{$HoH{$b}} <=> keys %{$HoH{$a}} } keys %HoH ) {
  694.      print "$family: { ";
  695.      for $role ( sort keys %{ $HoH{$family} } ) {
  696.          print "$role=$HoH{$family}{$role} ";
  697.      }
  698.      print "}\n";
  699.  }</PRE>
  700. <PRE>
  701.  # establish a sort order (rank) for each role
  702.  $i = 0;
  703.  for ( qw(lead wife son daughter pal pet) ) { $rank{$_} = ++$i }</PRE>
  704. <PRE>
  705.  # now print the whole thing sorted by number of members
  706.  foreach $family ( sort { keys %{ $HoH{$b} } <=> keys %{ $HoH{$a} } } keys %HoH ) {
  707.      print "$family: { ";
  708.      # and print these according to rank order
  709.      for $role ( sort { $rank{$a} <=> $rank{$b} }  keys %{ $HoH{$family} } ) {
  710.          print "$role=$HoH{$family}{$role} ";
  711.      }
  712.      print "}\n";
  713.  }</PRE>
  714. <P>
  715. <HR>
  716. <H1><A NAME="more elaborate records">MORE ELABORATE RECORDS</A></H1>
  717. <P>
  718. <H2><A NAME="declaration of more elaborate records">Declaration of MORE ELABORATE RECORDS</A></H2>
  719. <P>Here's a sample showing how to create and use a record whose fields are of
  720. many different sorts:</P>
  721. <PRE>
  722.      $rec = {
  723.          TEXT      => $string,
  724.          SEQUENCE  => [ @old_values ],
  725.          LOOKUP    => { %some_table },
  726.          THATCODE  => \&some_function,
  727.          THISCODE  => sub { $_[0] ** $_[1] },
  728.          HANDLE    => \*STDOUT,
  729.      };</PRE>
  730. <PRE>
  731.      print $rec->{TEXT};</PRE>
  732. <PRE>
  733.      print $rec->{SEQUENCE}[0];
  734.      $last = pop @ { $rec->{SEQUENCE} };</PRE>
  735. <PRE>
  736.      print $rec->{LOOKUP}{"key"};
  737.      ($first_k, $first_v) = each %{ $rec->{LOOKUP} };</PRE>
  738. <PRE>
  739.      $answer = $rec->{THATCODE}->($arg);
  740.      $answer = $rec->{THISCODE}->($arg1, $arg2);</PRE>
  741. <PRE>
  742.      # careful of extra block braces on fh ref
  743.      print { $rec->{HANDLE} } "a string\n";</PRE>
  744. <PRE>
  745.      use FileHandle;
  746.      $rec->{HANDLE}->autoflush(1);
  747.      $rec->{HANDLE}->print(" a string\n");</PRE>
  748. <P>
  749. <H2><A NAME="declaration of a hash of complex records">Declaration of a HASH OF COMPLEX RECORDS</A></H2>
  750. <PRE>
  751.      %TV = (
  752.         flintstones => {
  753.             series   => "flintstones",
  754.             nights   => [ qw(monday thursday friday) ],
  755.             members  => [
  756.                 { name => "fred",    role => "lead", age  => 36, },
  757.                 { name => "wilma",   role => "wife", age  => 31, },
  758.                 { name => "pebbles", role => "kid",  age  =>  4, },
  759.             ],
  760.         },</PRE>
  761. <PRE>
  762.         jetsons     => {
  763.             series   => "jetsons",
  764.             nights   => [ qw(wednesday saturday) ],
  765.             members  => [
  766.                 { name => "george",  role => "lead", age  => 41, },
  767.                 { name => "jane",    role => "wife", age  => 39, },
  768.                 { name => "elroy",   role => "kid",  age  =>  9, },
  769.             ],
  770.          },</PRE>
  771. <PRE>
  772.         simpsons    => {
  773.             series   => "simpsons",
  774.             nights   => [ qw(monday) ],
  775.             members  => [
  776.                 { name => "homer", role => "lead", age  => 34, },
  777.                 { name => "marge", role => "wife", age => 37, },
  778.                 { name => "bart",  role => "kid",  age  =>  11, },
  779.             ],
  780.          },
  781.       );</PRE>
  782. <P>
  783. <H2><A NAME="generation of a hash of complex records">Generation of a HASH OF COMPLEX RECORDS</A></H2>
  784. <PRE>
  785.      # reading from file
  786.      # this is most easily done by having the file itself be
  787.      # in the raw data format as shown above.  perl is happy
  788.      # to parse complex data structures if declared as data, so
  789.      # sometimes it's easiest to do that</PRE>
  790. <PRE>
  791.      # here's a piece by piece build up
  792.      $rec = {};
  793.      $rec->{series} = "flintstones";
  794.      $rec->{nights} = [ find_days() ];</PRE>
  795. <PRE>
  796.      @members = ();
  797.      # assume this file in field=value syntax
  798.      while (<>) {
  799.          %fields = split /[\s=]+/;
  800.          push @members, { %fields };
  801.      }
  802.      $rec->{members} = [ @members ];</PRE>
  803. <PRE>
  804.      # now remember the whole thing
  805.      $TV{ $rec->{series} } = $rec;</PRE>
  806. <PRE>
  807.      ###########################################################
  808.      # now, you might want to make interesting extra fields that
  809.      # include pointers back into the same data structure so if
  810.      # change one piece, it changes everywhere, like for example
  811.      # if you wanted a {kids} field that was a reference
  812.      # to an array of the kids' records without having duplicate
  813.      # records and thus update problems.
  814.      ###########################################################
  815.      foreach $family (keys %TV) {
  816.          $rec = $TV{$family}; # temp pointer
  817.          @kids = ();
  818.          for $person ( @{ $rec->{members} } ) {
  819.              if ($person->{role} =~ /kid|son|daughter/) {
  820.                  push @kids, $person;
  821.              }
  822.          }
  823.          # REMEMBER: $rec and $TV{$family} point to same data!!
  824.          $rec->{kids} = [ @kids ];
  825.      }</PRE>
  826. <PRE>
  827.      # you copied the array, but the array itself contains pointers
  828.      # to uncopied objects. this means that if you make bart get
  829.      # older via</PRE>
  830. <PRE>
  831.      $TV{simpsons}{kids}[0]{age}++;</PRE>
  832. <PRE>
  833.      # then this would also change in
  834.      print $TV{simpsons}{members}[2]{age};</PRE>
  835. <PRE>
  836.      # because $TV{simpsons}{kids}[0] and $TV{simpsons}{members}[2]
  837.      # both point to the same underlying anonymous hash table</PRE>
  838. <PRE>
  839.      # print the whole thing
  840.      foreach $family ( keys %TV ) {
  841.          print "the $family";
  842.          print " is on during @{ $TV{$family}{nights} }\n";
  843.          print "its members are:\n";
  844.          for $who ( @{ $TV{$family}{members} } ) {
  845.              print " $who->{name} ($who->{role}), age $who->{age}\n";
  846.          }
  847.          print "it turns out that $TV{$family}{lead} has ";
  848.          print scalar ( @{ $TV{$family}{kids} } ), " kids named ";
  849.          print join (", ", map { $_->{name} } @{ $TV{$family}{kids} } );
  850.          print "\n";
  851.      }</PRE>
  852. <P>
  853. <HR>
  854. <H1><A NAME="database ties">Database Ties</A></H1>
  855. <P>You cannot easily tie a multilevel data structure (such as a hash of
  856. hashes) to a dbm file.  The first problem is that all but GDBM and
  857. Berkeley DB have size limitations, but beyond that, you also have problems
  858. with how references are to be represented on disk.  One experimental
  859. module that does partially attempt to address this need is the MLDBM
  860. module.  Check your nearest CPAN site as described in <A HREF="../../lib/Pod/perlmodlib.html">the perlmodlib manpage</A> for
  861. source code to MLDBM.</P>
  862. <P>
  863. <HR>
  864. <H1><A NAME="see also">SEE ALSO</A></H1>
  865. <P>perlref(1), perllol(1), perldata(1), <CODE>perlobj(1)</CODE></P>
  866. <P>
  867. <HR>
  868. <H1><A NAME="author">AUTHOR</A></H1>
  869. <P>Tom Christiansen <<EM><A HREF="mailto:tchrist@perl.com">tchrist@perl.com</A></EM>></P>
  870. <P>Last update:
  871. Wed Oct 23 04:57:50 MET DST 1996</P>
  872. <TABLE BORDER=0 CELLPADDING=0 CELLSPACING=0 WIDTH=100%>
  873. <TR><TD CLASS=block VALIGN=MIDDLE WIDTH=100% BGCOLOR="#cccccc">
  874. <STRONG><P CLASS=block> perldsc - Perl Data Structures Cookbook</P></STRONG>
  875. </TD></TR>
  876. </TABLE>
  877.  
  878. </BODY>
  879.  
  880. </HTML>
  881.