home *** CD-ROM | disk | FTP | other *** search
/ Chip 2000 May / Chip_2000-05_cd1.bin / zkuste / Perl / ActivePerl-5.6.0.613.msi / 䆊䌷䈹䈙䏵-䞅䞆䞀㡆䞃䄦䠥 / _a4c2d60bbd5f76a6ef82804502174f4d < prev    next >
Text File  |  2000-03-24  |  22KB  |  805 lines
  1. @rem = '--*-Perl-*--
  2. @echo off
  3. if "%OS%" == "Windows_NT" goto WinNT
  4. perl -x -S "%0" %1 %2 %3 %4 %5 %6 %7 %8 %9
  5. goto endofperl
  6. :WinNT
  7. perl -x -S "%0" %*
  8. if NOT "%COMSPEC%" == "%SystemRoot%\system32\cmd.exe" goto endofperl
  9. if %errorlevel% == 9009 echo You do not have Perl in your PATH.
  10. if errorlevel 1 goto script_failed_so_exit_with_non_zero_val 2>nul
  11. goto endofperl
  12. @rem ';
  13. #!perl
  14. #line 15
  15.     eval 'exec perl -S $0 "$@"'
  16.     if 0;
  17.  
  18. require 5.003;
  19.  
  20. my $VERSION = '20000000.00_00';
  21.  
  22. =head1 NAME
  23.  
  24. dprofpp - display perl profile data
  25.  
  26. =head1 SYNOPSIS
  27.  
  28. dprofpp [B<-a>|B<-z>|B<-l>|B<-v>|B<-U>] [B<-s>|B<-r>|B<-u>] [B<-q>] [B<-F>] [B<-I|-E>] [B<-O cnt>] [B<-A>] [B<-R>] [B<-S>] [B<-g subroutine>] [profile]
  29.  
  30. dprofpp B<-T> [B<-F>] [B<-g subroutine>] [profile]
  31.  
  32. dprofpp B<-t> [B<-F>] [B<-g subroutine>] [profile]
  33.  
  34. dprofpp B<-p script> [B<-Q>] [other opts]
  35.  
  36. dprofpp B<-V> [profile]
  37.  
  38. =head1 DESCRIPTION
  39.  
  40. The I<dprofpp> command interprets profile data produced by a profiler, such
  41. as the Devel::DProf profiler.  Dprofpp will read the file F<tmon.out> and
  42. will display the 15 subroutines which are using the most time.  By default
  43. the times for each subroutine are given exclusive of the times of their
  44. child subroutines.
  45.  
  46. To profile a Perl script run the perl interpreter with the B<-d> switch.  So
  47. to profile script F<test.pl> with Devel::DProf the following command should
  48. be used.
  49.  
  50.     $ perl5 -d:DProf test.pl
  51.  
  52. Then run dprofpp to analyze the profile.  The output of dprofpp depends
  53. on the flags to the program and the version of Perl you're using.
  54.  
  55.     $ dprofpp -u
  56.     Total Elapsed Time =    1.67 Seconds
  57.          User Time =    0.61 Seconds
  58.     Exclusive Times
  59.     %Time Seconds     #Calls sec/call Name
  60.      52.4   0.320          2   0.1600 main::foo
  61.      45.9   0.280        200   0.0014 main::bar
  62.      0.00   0.000          1   0.0000 DynaLoader::import
  63.      0.00   0.000          1   0.0000 main::baz
  64.  
  65. The dprofpp tool can also run the profiler before analyzing the profile
  66. data.  The above two commands can be executed with one dprofpp command.
  67.  
  68.     $ dprofpp -u -p test.pl
  69.  
  70. Consult L<Devel::DProf/"PROFILE FORMAT"> for a description of the raw profile.
  71.  
  72. =head1 OUTPUT
  73.  
  74. Columns are:
  75.  
  76. =over 4
  77.  
  78. =item %Time
  79.  
  80. Percentage of time spent in this routine.
  81.  
  82. =item #Calls
  83.  
  84. Number of calls to this routine.
  85.  
  86. =item sec/call
  87.  
  88. Average number of seconds per call to this routine.
  89.  
  90. =item Name
  91.  
  92. Name of routine.
  93.  
  94. =item CumulS
  95.  
  96. Time (in seconds) spent in this routine and routines called from it.
  97.  
  98. =item ExclSec
  99.  
  100. Time (in seconds) spent in this routine (not including those called
  101. from it).
  102.  
  103. =item Csec/c
  104.  
  105. Average time (in seconds) spent in each call of this routine
  106. (including those called from it).
  107.  
  108. =back
  109.  
  110. =head1 OPTIONS
  111.  
  112. =over 5
  113.  
  114. =item B<-a>
  115.  
  116. Sort alphabetically by subroutine names.
  117.  
  118. =item B<-A>
  119.  
  120. Count timing for autoloaded subroutine as timing for C<*::AUTOLOAD>.
  121. Otherwise the time to autoload it is counted as time of the subroutine
  122. itself (there is no way to separate autoload time from run time).
  123.  
  124. This is going to be irrelevant with newer Perls.  They will inform
  125. C<Devel::DProf> I<when> the C<AUTOLOAD> switches to actual subroutine,
  126. so a separate statistics for C<AUTOLOAD> will be collected no matter
  127. whether this option is set.
  128.  
  129. =item B<-R>
  130.  
  131. Count anonymous subroutines defined in the same package separately.
  132.  
  133. =item B<-E>
  134.  
  135. (default)  Display all subroutine times exclusive of child subroutine times.
  136.  
  137. =item B<-F>
  138.  
  139. Force the generation of fake exit timestamps if dprofpp reports that the
  140. profile is garbled.  This is only useful if dprofpp determines that the
  141. profile is garbled due to missing exit timestamps.  You're on your own if
  142. you do this.  Consult the BUGS section.
  143.  
  144. =item B<-I>
  145.  
  146. Display all subroutine times inclusive of child subroutine times.
  147.  
  148. =item B<-l>
  149.  
  150. Sort by number of calls to the subroutines.  This may help identify
  151. candidates for inlining.
  152.  
  153. =item B<-O cnt>
  154.  
  155. Show only I<cnt> subroutines.  The default is 15.
  156.  
  157. =item B<-p script>
  158.  
  159. Tells dprofpp that it should profile the given script and then interpret its
  160. profile data.  See B<-Q>.
  161.  
  162. =item B<-Q>
  163.  
  164. Used with B<-p> to tell dprofpp to quit after profiling the script, without
  165. interpreting the data.
  166.  
  167. =item B<-q>
  168.  
  169. Do not display column headers.
  170.  
  171. =item B<-r>
  172.  
  173. Display elapsed real times rather than user+system times.
  174.  
  175. =item B<-s>
  176.  
  177. Display system times rather than user+system times.
  178.  
  179. =item B<-T>
  180.  
  181. Display subroutine call tree to stdout.  Subroutine statistics are
  182. not displayed.
  183.  
  184. =item B<-t>
  185.  
  186. Display subroutine call tree to stdout.  Subroutine statistics are not
  187. displayed.  When a function is called multiple consecutive times at the same
  188. calling level then it is displayed once with a repeat count.
  189.  
  190. =item B<-S>
  191.  
  192. Display I<merged> subroutine call tree to stdout.  Statistics is
  193. displayed for each branch of the tree.  
  194.  
  195. When a function is called multiple (I<not necessarily consecutive>)
  196. times in the same branch then all these calls go into one branch of
  197. the next level.  A repeat count is output together with combined
  198. inclusive, exclusive and kids time.
  199.  
  200. Branches are sorted w.r.t. inclusive time.
  201.  
  202. =item B<-U>
  203.  
  204. Do not sort.  Display in the order found in the raw profile.
  205.  
  206. =item B<-u>
  207.  
  208. Display user times rather than user+system times.
  209.  
  210. =item B<-V>
  211.  
  212. Print dprofpp's version number and exit.  If a raw profile is found then its
  213. XS_VERSION variable will be displayed, too.
  214.  
  215. =item B<-v>
  216.  
  217. Sort by average time spent in subroutines during each call.  This may help
  218. identify candidates for inlining. 
  219.  
  220. =item B<-z>
  221.  
  222. (default) Sort by amount of user+system time used.  The first few lines
  223. should show you which subroutines are using the most time.
  224.  
  225. =item B<-g> C<subroutine>
  226.  
  227. Ignore subroutines except C<subroutine> and whatever is called from it.
  228.  
  229. =back
  230.  
  231. =head1 ENVIRONMENT
  232.  
  233. The environment variable B<DPROFPP_OPTS> can be set to a string containing
  234. options for dprofpp.  You might use this if you prefer B<-I> over B<-E> or
  235. if you want B<-F> on all the time.
  236.  
  237. This was added fairly lazily, so there are some undesirable side effects.
  238. Options on the commandline should override options in DPROFPP_OPTS--but
  239. don't count on that in this version.
  240.  
  241. =head1 BUGS
  242.  
  243. Applications which call _exit() or exec() from within a subroutine
  244. will leave an incomplete profile.  See the B<-F> option.
  245.  
  246. Any bugs in Devel::DProf, or any profiler generating the profile data, could
  247. be visible here.  See L<Devel::DProf/BUGS>.
  248.  
  249. Mail bug reports and feature requests to the perl5-porters mailing list at
  250. F<E<lt>perl5-porters@perl.orgE<gt>>.  Bug reports should include the
  251. output of the B<-V> option.
  252.  
  253. =head1 FILES
  254.  
  255.     dprofpp        - profile processor
  256.     tmon.out    - raw profile
  257.  
  258. =head1 SEE ALSO
  259.  
  260. L<perl>, L<Devel::DProf>, times(2)
  261.  
  262. =cut
  263.  
  264. use Getopt::Std 'getopts';
  265. use Config '%Config';
  266.  
  267. Setup: {
  268.     my $options = 'O:g:lzaAvuTtqrRsUFEIp:QVS';
  269.  
  270.     $Monfile = 'tmon.out';
  271.     if( exists $ENV{DPROFPP_OPTS} ){
  272.         my @tmpargv = @ARGV;
  273.         @ARGV = split( ' ', $ENV{DPROFPP_OPTS} );
  274.         getopts( $options );
  275.         if( @ARGV ){
  276.             # there was a filename.
  277.             $Monfile = shift;
  278.         }
  279.         @ARGV = @tmpargv;
  280.     }
  281.  
  282.     getopts( $options );
  283.     if( @ARGV ){
  284.         # there was a filename, it overrides any earlier name.
  285.         $Monfile = shift;
  286.     }
  287.  
  288. # -O cnt    Specifies maximum number of subroutines to display.
  289. # -a        Sort by alphabetic name of subroutines.
  290. # -z        Sort by user+system time spent in subroutines. (default)
  291. # -l        Sort by number of calls to subroutines.
  292. # -v        Sort by average amount of time spent in subroutines.
  293. # -T        Show call tree.
  294. # -t        Show call tree, compressed.
  295. # -q        Do not print column headers.
  296. # -u        Use user time rather than user+system time.
  297. # -s        Use system time rather than user+system time.
  298. # -r        Use real elapsed time rather than user+system time.
  299. # -U        Do not sort subroutines.
  300. # -E        Sub times are reported exclusive of child times. (default)
  301. # -I        Sub times are reported inclusive of child times.
  302. # -V        Print dprofpp's version.
  303. # -p script    Specifies name of script to be profiled.
  304. # -Q        Used with -p to indicate the dprofpp should quit after
  305. #        profiling the script, without interpreting the data.
  306. # -A        count autoloaded to *AUTOLOAD
  307. # -R        count anonyms separately even if from the same package
  308. # -g subr    count only those who are SUBR or called from SUBR
  309. # -S        Create statistics for all the depths
  310.  
  311.     if( defined $opt_V ){
  312.         my $fh = 'main::fh';
  313.         print "$0 version: $VERSION\n";
  314.         open( $fh, "<$Monfile" ) && do {
  315.             local $XS_VERSION = 'early';
  316.             header($fh);
  317.             close( $fh );
  318.             print "XS_VERSION: $XS_VERSION\n";
  319.         };
  320.         exit(0);
  321.     }
  322.     $cnt = $opt_O || 15;
  323.     $sort = 'by_time';
  324.     $sort = 'by_ctime' if defined $opt_I;
  325.     $sort = 'by_calls' if defined $opt_l;
  326.     $sort = 'by_alpha' if defined $opt_a;
  327.     $sort = 'by_avgcpu' if defined $opt_v;
  328.     $incl_excl = 'Exclusive';
  329.     $incl_excl = 'Inclusive' if defined $opt_I;
  330.     $whichtime = 'User+System';
  331.     $whichtime = 'System' if defined $opt_s;
  332.     $whichtime = 'Real' if defined $opt_r;
  333.     $whichtime = 'User' if defined $opt_u;
  334.  
  335.     if( defined $opt_p ){
  336.         my $prof = 'DProf';
  337.         my $startperl = $Config{'startperl'};
  338.  
  339.         $startperl =~ s/^#!//; # remove shebang
  340.         run_profiler( $opt_p, $prof, $startperl );
  341.         $Monfile = 'tmon.out';  # because that's where it is
  342.         exit(0) if defined $opt_Q;
  343.     }
  344.     elsif( defined $opt_Q ){
  345.         die "-Q is meaningful only when used with -p\n";
  346.     }
  347. }
  348.  
  349. Main: {
  350.     my $monout = $Monfile;
  351.     my $fh = 'main::fh';
  352.     local $names = {};
  353.     local $times = {};   # times in hz
  354.     local $ctimes = {};  # Cumulative times in hz
  355.     local $calls = {};
  356.     local $persecs = {}; # times in seconds
  357.     local $idkeys = [];
  358.     local $runtime; # runtime in seconds
  359.     my @a = ();
  360.     my $a;
  361.     local $rrun_utime = 0;    # user time in hz
  362.     local $rrun_stime = 0;    # system time in hz
  363.     local $rrun_rtime = 0;    # elapsed run time in hz
  364.     local $rrun_ustime = 0;    # user+system time in hz
  365.     local $hz = 0;
  366.     local $deep_times = {count => 0 , kids => {}, incl_time => 0};
  367.     local $time_precision = 2;
  368.     local $overhead = 0;
  369.  
  370.     open( $fh, "<$monout" ) || die "Unable to open $monout\n";
  371.  
  372.     header($fh);
  373.  
  374.     $rrun_ustime = $rrun_utime + $rrun_stime;
  375.  
  376.     $~ = 'STAT';
  377.     if( ! $opt_q ){
  378.         $^ = 'CSTAT_top';
  379.     }
  380.  
  381.     parsestack( $fh, $names, $calls, $times, $ctimes, $idkeys );
  382.  
  383.     settime( \$runtime, $hz ) unless $opt_g;
  384.  
  385.     exit(0) if $opt_T || $opt_t;
  386.  
  387.     if( $opt_v ){
  388.         percalc( $calls, ($opt_I ? $ctimes : $times), $persecs, $idkeys );
  389.     }
  390.     if( ! $opt_U ){
  391.         @a = sort $sort @$idkeys;
  392.         $a = \@a;
  393.     }
  394.     else {
  395.         $a = $idkeys;
  396.     }
  397.     display( $runtime, $hz, $names, $calls, $times, $ctimes, $cnt, $a,
  398.          $deep_times);
  399. }
  400.  
  401.  
  402. # Sets $runtime to user, system, real, or user+system time.  The
  403. # result is given in seconds.
  404. #
  405. sub settime {
  406.   my( $runtime, $hz ) = @_;
  407.  
  408.   $hz ||= 1;
  409.   
  410.   if( $opt_r ){
  411.     $$runtime = ($rrun_rtime - $overhead - $over_rtime * $total_marks/$over_tests/2)/$hz;
  412.   }
  413.   elsif( $opt_s ){
  414.     $$runtime = ($rrun_stime - $overhead - $over_stime * $total_marks/$over_tests/2)/$hz;
  415.   }
  416.   elsif( $opt_u ){
  417.     $$runtime = ($rrun_utime - $overhead - $over_utime * $total_marks/$over_tests/2)/$hz;
  418.   }
  419.   else{
  420.     $$runtime = ($rrun_ustime - $overhead - ($over_utime + $over_stime) * $total_marks/$over_tests/2)/$hz;
  421.   }
  422.   $$runtime = 0 unless $$runtime > 0;
  423. }
  424.  
  425. sub exclusives_in_tree {
  426.   my( $deep_times ) = @_;
  427.   my $kids_time = 0;
  428.   my $kid;
  429.   # When summing, take into account non-rounded-up kids time.
  430.   for $kid (keys %{$deep_times->{kids}}) {
  431.     $kids_time += $deep_times->{kids}{$kid}{incl_time};
  432.   }
  433.   $kids_time = 0 unless $kids_time >= 0;
  434.   $deep_times->{excl_time} = $deep_times->{incl_time} - $kids_time;
  435.   $deep_times->{excl_time} = 0 unless $deep_times->{excl_time} >= 0;
  436.   for $kid (keys %{$deep_times->{kids}}) {
  437.     exclusives_in_tree($deep_times->{kids}{$kid});
  438.   }
  439.   $deep_times->{incl_time} = 0 unless $deep_times->{incl_time} >= 0;
  440.   $deep_times->{kids_time} = $kids_time;
  441. }
  442.  
  443. sub kids_by_incl { $kids{$b}{incl_time} <=> $kids{$a}{excl_time} 
  444.            or $a cmp $b }
  445.  
  446. sub display_tree {
  447.   my( $deep_times, $name, $level ) = @_;
  448.   exclusives_in_tree($deep_times);
  449.   
  450.   my $kid;
  451.   local *kids = $deep_times->{kids}; # %kids
  452.  
  453.   my $time;
  454.   if (%kids) {
  455.     $time = sprintf '%.*fs = (%.*f + %.*f)', 
  456.       $time_precision, $deep_times->{incl_time}/$hz,
  457.         $time_precision, $deep_times->{excl_time}/$hz,
  458.           $time_precision, $deep_times->{kids_time}/$hz;
  459.   } else {
  460.     $time = sprintf '%.*f', $time_precision, $deep_times->{incl_time}/$hz;
  461.   }
  462.   print ' ' x (2*$level), "$name x $deep_times->{count}  \t${time}s\n"
  463.     if $deep_times->{count};
  464.  
  465.   for $kid (sort kids_by_incl keys %kids) {
  466.     display_tree( $deep_times->{kids}{$kid}, $kid, $level + 1 );
  467.   }  
  468. }
  469.  
  470. # Report the times in seconds.
  471. sub display {
  472.     my( $runtime, $hz, $names, $calls, $times, $ctimes, $cnt, 
  473.         $idkeys, $deep_times ) = @_;
  474.     my( $x, $key, $s, $cs );
  475.     #format: $ncalls, $name, $secs, $percall, $pcnt
  476.  
  477.     if ($opt_S) {
  478.       display_tree( $deep_times, 'toplevel', -1 )
  479.     } else {
  480.       for( $x = 0; $x < @$idkeys; ++$x ){
  481.         $key = $idkeys->[$x];
  482.         $ncalls = $calls->{$key};
  483.         $name = $names->{$key};
  484.         $s = $times->{$key}/$hz;
  485.         $secs = sprintf("%.3f", $s );
  486.         $cs = $ctimes->{$key}/$hz;
  487.         $csecs = sprintf("%.3f", $cs );
  488.         $percall = sprintf("%.4f", $s/$ncalls );
  489.         $cpercall = sprintf("%.4f", $cs/$ncalls );
  490.         $pcnt = sprintf("%.2f",
  491.                 $runtime? ((($opt_I ? $csecs : $secs) / $runtime) * 100.0): 0 );
  492.         write;
  493.         $pcnt = $secs = $ncalls = $percall = "";
  494.         write while( length $name );
  495.         last unless --$cnt;
  496.       }      
  497.     }
  498. }
  499.  
  500. sub move_keys {
  501.   my ($source, $dest) = @_;
  502.   my $kid;
  503.   
  504.   for $kid (keys %$source) {
  505.     if (exists $dest->{$kid}) {
  506.       $dest->{count} += $source->{count};
  507.       $dest->{incl_time} += $source->{incl_time};
  508.       move_keys($source->{kids},$dest->{kids});
  509.     } else {
  510.       $dest->{$kid} = delete $source->{$kid};
  511.     }
  512.   }
  513. }
  514.  
  515. sub add_to_tree {
  516.   my ($curdeep_times, $name, $t) = @_;
  517.   if ($name ne $curdeep_times->[-1]{name} and $opt_A) {
  518.     $name = $curdeep_times->[-1]{name};
  519.   }
  520.   die "Shorted?!" unless @$curdeep_times >= 2;
  521.   $curdeep_times->[-2]{kids}{$name} = { count => 0 , kids => {}, 
  522.                     incl_time => 0,
  523.                       } 
  524.     unless exists $curdeep_times->[-2]{kids}{$name};
  525.   my $entry = $curdeep_times->[-2]{kids}{$name};
  526.   # Now transfer to the new node (could not do earlier, since name can change)
  527.   $entry->{count}++;
  528.   $entry->{incl_time} += $t - $curdeep_times->[-1]{enter_stamp};
  529.   # Merge the kids?
  530.   move_keys($curdeep_times->[-1]->{kids},$entry->{kids});
  531.   pop @$curdeep_times;
  532. }
  533.  
  534. sub parsestack {
  535.     my( $fh, $names, $calls, $times, $ctimes, $idkeys ) = @_;
  536.     my( $dir, $name );
  537.     my( $t, $syst, $realt, $usert );
  538.     my( $x, $z, $c, $id, $pack );
  539.     my @stack = ();
  540.     my @tstack = ();
  541.     my $tab = 3;
  542.     my $in = 0;
  543.  
  544.     # remember last call depth and function name
  545.     my $l_in = $in;
  546.     my $l_name = '';
  547.     my $repcnt = 0;
  548.     my $repstr = '';
  549.     my $dprof_t = 0;
  550.     my $dprof_stamp;
  551.     my %cv_hash;
  552.     my $in_level = not defined $opt_g; # Level deep in report grouping
  553.     my $curdeep_times = [$deep_times];
  554.  
  555.     my $over_per_call;
  556.     if   ( $opt_u )    {    $over_per_call = $over_utime        }
  557.     elsif( $opt_s )    {    $over_per_call = $over_stime        }
  558.     elsif( $opt_r )    {    $over_per_call = $over_rtime        }
  559.     else        {    $over_per_call = $over_utime + $over_stime }
  560.     $over_per_call /= 2*$over_tests; # distribute over entry and exit
  561.  
  562.     while(<$fh>){
  563.         next if /^#/;
  564.         last if /^PART/;
  565.  
  566.         chop;
  567.         if (/^&/) {
  568.           ($dir, $id, $pack, $name) = split;
  569.           if ($opt_R and ($name =~ /::(__ANON_|END)$/)) {
  570.             $name .= "($id)";
  571.           }
  572.           $cv_hash{$id} = "$pack\::$name";
  573.           next;
  574.         }
  575.         ($dir, $usert, $syst, $realt, $name) = split;
  576.  
  577.         my $ot = $t;
  578.         if ( $dir eq '/' ) {
  579.           $syst = $stack[-1][0];
  580.           $usert = '&';
  581.           $dir = '-';
  582.           #warn("Inserted exit for $stack[-1][0].\n")
  583.         }
  584.         if (defined $realt) { # '+ times nam' '- times nam' or '@ incr'
  585.           if   ( $opt_u )    {    $t = $usert        }
  586.           elsif( $opt_s )    {    $t = $syst        }
  587.           elsif( $opt_r )    {    $t = $realt        }
  588.           else            {    $t = $usert + $syst    }
  589.           $t += $ot, next if $dir eq '@'; # Increments there
  590.         } else {
  591.           # "- id" or "- & name"
  592.           $name = defined $syst ? $syst : $cv_hash{$usert};
  593.         }
  594.  
  595.         next unless $in_level or $name eq $opt_g or $dir eq '*';
  596.         if ( $dir eq '-' or $dir eq '*' ) {
  597.               my $ename = $dir eq '*' ? $stack[-1][0]  : $name;
  598.             $overhead += $over_per_call;
  599.               if ($name eq "Devel::DProf::write") {
  600.               $dprof_t += $t - $dprof_stamp;
  601.               next;
  602.               } elsif (defined $opt_g and $ename eq $opt_g) {
  603.               $in_level--;
  604.             }
  605.             add_to_tree($curdeep_times, $ename,
  606.                     $t - $dprof_t - $overhead) if $opt_S;
  607.             exitstamp( \@stack, \@tstack, 
  608.                    $t - $dprof_t - $overhead, 
  609.                    $times, $ctimes, $ename, \$in, $tab, 
  610.                    $curdeep_times );
  611.         } 
  612.         next unless $in_level or $name eq $opt_g;
  613.         if( $dir eq '+' or $dir eq '*' ){
  614.               if ($name eq "Devel::DProf::write") {
  615.               $dprof_stamp = $t;
  616.               next;
  617.               } elsif (defined $opt_g and $name eq $opt_g) {
  618.               $in_level++;
  619.               }
  620.             $overhead += $over_per_call;
  621.             if( $opt_T ){
  622.                 print ' ' x $in, "$name\n";
  623.                 $in += $tab;
  624.             }
  625.             elsif( $opt_t ){
  626.                 # suppress output on same function if the
  627.                 # same calling level is called.
  628.                 if ($l_in == $in and $l_name eq $name) {
  629.                     $repcnt++;
  630.                 } else {
  631.                     $repstr = ' ('.++$repcnt.'x)'
  632.                          if $repcnt;
  633.                     print ' ' x $l_in, "$l_name$repstr\n"
  634.                         if $l_name ne '';
  635.                     $repstr = '';
  636.                     $repcnt = 0;
  637.                     $l_in = $in;
  638.                     $l_name = $name;
  639.                 }
  640.                 $in += $tab;
  641.             }
  642.             if( ! defined $names->{$name} ){
  643.                 $names->{$name} = $name;
  644.                 $times->{$name} = 0;
  645.                 $ctimes->{$name} = 0;
  646.                 push( @$idkeys, $name );
  647.             }
  648.             $calls->{$name}++;
  649.             push @$curdeep_times, { kids => {}, 
  650.                         name => $name, 
  651.                         enter_stamp => $t - $dprof_t - $overhead,
  652.                           } if $opt_S;
  653.             $x = [ $name, $t - $dprof_t - $overhead ];
  654.             push( @stack, $x );
  655.  
  656.             # my children will put their time here
  657.             push( @tstack, 0 );
  658.         } elsif ($dir ne '-'){
  659.             die "Bad profile: $_";
  660.             }
  661.     }
  662.     if( $opt_t ){
  663.         $repstr = ' ('.++$repcnt.'x)' if $repcnt;
  664.         print ' ' x $l_in, "$l_name$repstr\n";
  665.     }
  666.  
  667.     if( @stack ){
  668.         if( ! $opt_F ){
  669.             warn "Garbled profile is missing some exit time stamps:\n";
  670.             foreach $x (@stack) {
  671.                 print $x->[0],"\n";
  672.             }
  673.             die "Try rerunning dprofpp with -F.\n";
  674.             # I don't want -F to be default behavior--yet
  675.             #  9/18/95 dmr
  676.         }
  677.         else{
  678.             warn( "Faking " . scalar( @stack ) . " exit timestamp(s).\n");
  679.             foreach $x ( reverse @stack ){
  680.                 $name = $x->[0];
  681.                 exitstamp( \@stack, \@tstack, 
  682.                        $t - $dprof_t - $overhead, $times, 
  683.                        $ctimes, $name, \$in, $tab, 
  684.                        $curdeep_times );
  685.                 add_to_tree($curdeep_times, $name,
  686.                         $t - $dprof_t - $overhead)
  687.                   if $opt_S;
  688.             }
  689.         }
  690.     }
  691.     if (defined $opt_g) {
  692.       $runtime = $ctimes->{$opt_g}/$hz;
  693.       $runtime = 0 unless $runtime > 0;
  694.     }
  695. }
  696.  
  697. sub exitstamp {
  698.     my($stack, $tstack, $t, $times, $ctimes, $name, $in, $tab, $deep) = @_;
  699.     my( $x, $c, $z );
  700.  
  701.     $x = pop( @$stack );
  702.     if( ! defined $x ){
  703.         die "Garbled profile, missing an enter time stamp";
  704.     }
  705.     if( $x->[0] ne $name ){
  706.       if ($x->[0] =~ /::AUTOLOAD$/) {
  707.         if ($opt_A) {
  708.           $name = $x->[0];
  709.         }
  710.       } elsif ( $opt_F ) {
  711.         warn( "Garbled profile, faking exit timestamp:\n\t$name => $x->[0].\n");
  712.         $name = $x->[0];
  713.       } else {
  714.         foreach $z (@stack, $x) {
  715.           print $z->[0],"\n";
  716.         }
  717.         die "Garbled profile, unexpected exit time stamp";
  718.       }
  719.     }
  720.     if( $opt_T || $opt_t ){
  721.         $$in -= $tab;
  722.     }
  723.     # collect childtime
  724.     $c = pop( @$tstack );
  725.     # total time this func has been active
  726.     $z = $t - $x->[1];
  727.     $ctimes->{$name} += $z;
  728.     $times->{$name} += ($z > $c)? $z - $c: 0;
  729.     # pass my time to my parent
  730.     if( @$tstack ){
  731.         $c = pop( @$tstack );
  732.         push( @$tstack, $c + $z );
  733.     }
  734. }
  735.  
  736.  
  737. sub header {
  738.     my $fh = shift;
  739.     chop($_ = <$fh>);
  740.     if( ! /^#fOrTyTwO$/ ){
  741.         die "Not a perl profile";
  742.     }
  743.     while(<$fh>){
  744.         next if /^#/;
  745.         last if /^PART/;
  746.         eval;
  747.     }
  748.     $over_tests = 1 unless $over_tests;
  749.     $time_precision = length int ($hz - 1);    # log ;-)
  750. }
  751.  
  752.  
  753. # Report avg time-per-function in seconds
  754. sub percalc {
  755.     my( $calls, $times, $persecs, $idkeys ) = @_;
  756.     my( $x, $t, $n, $key );
  757.  
  758.     for( $x = 0; $x < @$idkeys; ++$x ){
  759.         $key = $idkeys->[$x];
  760.         $n = $calls->{$key};
  761.         $t = $times->{$key} / $hz;
  762.         $persecs->{$key} = $t ? $t / $n : 0;
  763.     }
  764. }
  765.  
  766.  
  767. # Runs the given script with the given profiler and the given perl.
  768. sub run_profiler {
  769.     my $script = shift;
  770.     my $profiler = shift;
  771.     my $startperl = shift;
  772.  
  773.     system $startperl, "-d:$profiler", $script;
  774.     if( $? / 256 > 0 ){
  775.         die "Failed: $startperl -d:$profiler $script: $!";
  776.     }
  777. }
  778.  
  779.  
  780. sub by_time { $times->{$b} <=> $times->{$a} }
  781. sub by_ctime { $ctimes->{$b} <=> $ctimes->{$a} }
  782. sub by_calls { $calls->{$b} <=> $calls->{$a} }
  783. sub by_alpha { $names->{$a} cmp $names->{$b} }
  784. sub by_avgcpu { $persecs->{$b} <=> $persecs->{$a} }
  785.  
  786.  
  787. format CSTAT_top =
  788. Total Elapsed Time = @>>>>>>> Seconds
  789. (($rrun_rtime - $overhead - $over_rtime * $total_marks/$over_tests/2) / $hz)
  790.   @>>>>>>>>>> Time = @>>>>>>> Seconds
  791. $whichtime, $runtime
  792. @<<<<<<<< Times
  793. $incl_excl
  794. %Time ExclSec CumulS #Calls sec/call Csec/c  Name
  795. .
  796.  
  797. format STAT =
  798.  ^>>>   ^>>>> ^>>>>> ^>>>>>   ^>>>>> ^>>>>>  ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
  799. $pcnt, $secs, $csecs, $ncalls, $percall, $cpercall, $name
  800. .
  801.  
  802.  
  803. __END__
  804. :endofperl
  805.