home *** CD-ROM | disk | FTP | other *** search
/ Chip 2000 May / Chip_2000-05_cd1.bin / zkuste / Perl / ActivePerl-5.6.0.613.msi / 䆊䌷䈹䈙䏵-䞅䞆䞀㡆䞃䄦䠥 / _859ff67f44e6355f8e923f30c5a2eb16 < prev    next >
Text File  |  2000-03-24  |  15KB  |  538 lines
  1. @rem = '--*-Perl-*--
  2. @echo off
  3. if "%OS%" == "Windows_NT" goto WinNT
  4. perl -x -S "%0" %1 %2 %3 %4 %5 %6 %7 %8 %9
  5. goto endofperl
  6. :WinNT
  7. perl -x -S "%0" %*
  8. if NOT "%COMSPEC%" == "%SystemRoot%\system32\cmd.exe" goto endofperl
  9. if %errorlevel% == 9009 echo You do not have Perl in your PATH.
  10. if errorlevel 1 goto script_failed_so_exit_with_non_zero_val 2>nul
  11. goto endofperl
  12. @rem ';
  13. #!perl -w
  14. #line 15
  15.  
  16. # $Id: lwp-request.PL,v 1.38 1999/06/01 10:40:51 gisle Exp $
  17. #
  18. # Simple user agent using LWP library.
  19.  
  20. =head1 NAME
  21.  
  22. lwp-request, GET, HEAD, POST - Simple WWW user agent
  23.  
  24. =head1 SYNOPSIS
  25.  
  26.  lwp-request [-aeEdvhx] [-m method] [-b <base URL>] [-t <timeout>]
  27.              [-i <if-modified-since>] [-c <content-type>] [-C <credentials>]
  28.              [-p <proxy-url>] [-o <format>] <url>...
  29.  
  30. =head1 DESCRIPTION
  31.  
  32. This program can be used to send requests to WWW servers and your
  33. local file system. The request content for POST and PUT
  34. methods is read from stdin.  The content of the response is printed on
  35. stdout.  Error messages are printed on stderr.  The program returns a
  36. status value indicating the number of URLs that failed.
  37.  
  38. The options are:
  39.  
  40. =over 4
  41.  
  42. =item -m <method>
  43.  
  44. Set which method to use for the request.  If this option is not used,
  45. then the method is derived from the name of the program.
  46.  
  47. =item -f
  48.  
  49. Force request through, even if the program believes that the method is
  50. illegal.  The server might reject the request eventually.
  51.  
  52. =item -b <uri>
  53.  
  54. This URI will be used as the base URI for resolving all relative URIs
  55. given as argument.
  56.  
  57. =item -t <timeout>
  58.  
  59. Set the timeout value for the requests.  The timeout is the amount of
  60. time that the program will wait for a response from the remote server
  61. before it fails.  The default unit for the timeout value is seconds.
  62. You might append "m" or "h" to the timeout value to make it minutes or
  63. hours, respectively.  The default timeout is '3m', i.e. 3 minutes.
  64.  
  65. =item -i <time>
  66.  
  67. Set the If-Modified-Since header in the request. If I<time> it the
  68. name of a file, use the modification timestamp for this file. If
  69. I<time> is not a file, it is parsed as a literal date. Take a look at
  70. L<HTTP::Date> for recogniced formats.
  71.  
  72. =item -c <content-type>
  73.  
  74. Set the Content-Type for the request.  This option is only allowed for
  75. requests that take a content, i.e. POST and PUT.  You can
  76. force methods to take content by using the C<-f> option together with
  77. C<-c>.  The default Content-Type for POST is
  78. C<application/x-www-form-urlencoded>.  The default Content-type for
  79. the others is C<text/plain>.
  80.  
  81. =item -p <proxy-url>
  82.  
  83. Set the proxy to be used for the requests.  The program also loads
  84. proxy settings from the environment.  You can disable this with the
  85. C<-P> option.
  86.  
  87. =item -H <header>
  88.  
  89. Send this HTTP header with each request. You can specify several, e.g.:
  90.  
  91.     lwp-request \
  92.     -H 'Referer: http://other.url/' \
  93.     -H 'Host: somehost' \
  94.     http://this.url/
  95.  
  96. =item -C <username>:<password>
  97.  
  98. Provide credentials for documents that are protected by Basic
  99. Authentication.  If the document is protected and you did not specify
  100. the username and password with this option, then you will be prompted
  101. to provide these values.
  102.  
  103. =back
  104.  
  105. The following options controls what is displayed by the program:
  106.  
  107. =over 4
  108.  
  109. =item -u
  110.  
  111. Print request method and absolute URL as requests are made.
  112.  
  113. =item -U
  114.  
  115. Print request headers in addition to request method and absolute URL.
  116.  
  117. =item -s
  118.  
  119. Print response status code.  This option is always on for HEAD requests.
  120.  
  121. =item -S
  122.  
  123. Print response status chain. This shows redirect and autorization
  124. requests that are handled by the library.
  125.  
  126. =item -e
  127.  
  128. Print response headers.  This option is always on for HEAD requests.
  129.  
  130. =item -d
  131.  
  132. Do B<not> print the content of the response.
  133.  
  134. =item -o <format>
  135.  
  136. Process HTML content in various ways before printing it.  If the
  137. content type of the response is not HTML, then this option has no
  138. effect.  The legal format values are; I<text>, I<ps>, I<links>,
  139. I<html> and I<dump>.
  140.  
  141. If you specify the I<text> format then the HTML will be formatted as
  142. plain latin1 text.  If you specify the I<ps> format then it will be
  143. formatted as Postscript.
  144.  
  145. The I<links> format will output all links found in the HTML document.
  146. Relative links will be expanded to absolute ones.
  147.  
  148. The I<html> format will reformat the HTML code and the I<dump> format
  149. will just dump the HTML syntax tree.
  150.  
  151. =item -v
  152.  
  153. Print the version number of the program and quit.
  154.  
  155. =item -h
  156.  
  157. Print usage message and quit.
  158.  
  159. =item -x
  160.  
  161. Extra debugging output.
  162.  
  163. =item -a
  164.  
  165. Set text(ascii) mode for content input and output.  If this option is not 
  166. used, content input and output is done in binary mode.
  167.  
  168. =back
  169.  
  170. Because this program is implemented using the LWP library, it will
  171. only support the protocols that LWP supports.
  172.  
  173. =head1 SEE ALSO
  174.  
  175. L<lwp-mirror>, L<LWP>
  176.  
  177. =head1 COPYRIGHT
  178.  
  179. Copyright 1995-1999 Gisle Aas.
  180.  
  181. This library is free software; you can redistribute it and/or
  182. modify it under the same terms as Perl itself.
  183.  
  184. =head1 AUTHOR
  185.  
  186. Gisle Aas <gisle@aas.no>
  187.  
  188. =cut
  189.  
  190. $progname = $0;
  191. $progname =~ s,.*/,,;  # use basename only
  192. $progname =~ s/\.\w*$//; # strip extension, if any
  193.  
  194. $VERSION = sprintf("%d.%02d", q$Revision: 1.38 $ =~ /(\d+)\.(\d+)/);
  195.  
  196.  
  197. require LWP;
  198. require LWP::Debug;
  199.  
  200. use URI;
  201. use URI::Heuristic qw(uf_uri);
  202.  
  203. use HTTP::Status qw(status_message);
  204. use HTTP::Date qw(time2str str2time);
  205.  
  206.  
  207. # This table lists the methods that are allowed.  It should really be
  208. # a superset for all methods supported for every scheme that may be
  209. # supported by the library.  Currently it might be a bit too HTTP
  210. # specific.  You might use the -f option to force a method through.
  211. #
  212. # "" = No content in request, "C" = Needs content in request
  213. #
  214. %allowed_methods = (
  215.     GET        => "",
  216.     HEAD       => "",
  217.     POST       => "C",
  218.     PUT        => "C",
  219.     DELETE     => "",
  220.     TRACE      => "",
  221.     OPTIONS    => "",
  222. );
  223.  
  224.  
  225. # We make our own specialization of LWP::UserAgent that asks for
  226. # user/password if document is protected.
  227. {
  228.     package RequestAgent;
  229.     @ISA = qw(LWP::UserAgent);
  230.  
  231.     sub new
  232.     { 
  233.     my $self = LWP::UserAgent::new(@_);
  234.     $self->agent("lwp-request/$main::VERSION");
  235.     $self;
  236.     }
  237.  
  238.     sub get_basic_credentials
  239.     {
  240.     my($self, $realm, $uri) = @_;
  241.     if ($main::options{'C'}) {
  242.         return split(':', $main::options{'C'}, 2);
  243.     } elsif (-t) {
  244.         my $netloc = $uri->host_port;
  245.         print "Enter username for $realm at $netloc: ";
  246.         my $user = <STDIN>;
  247.         chomp($user);
  248.         return (undef, undef) unless length $user;
  249.         print "Password: ";
  250.         system("stty -echo");
  251.         my $password = <STDIN>;
  252.         system("stty echo");
  253.         print "\n";  # because we disabled echo
  254.         chomp($password);
  255.         return ($user, $password);
  256.     } else {
  257.         return (undef, undef)
  258.     }
  259.     }
  260. }
  261.  
  262. $method = uc(lc($progname) eq "lwp-request" ? "GET" : $progname);
  263.  
  264. # Parse command line
  265. use Getopt::Long;
  266.  
  267. my @getopt_args = (
  268.     'a', # content i/o in text(ascii) mode
  269.     'm=s', # set method
  270.     'f', # make request even if method is not in %allowed_methods
  271.     'b=s', # base url
  272.     't=s', # timeout
  273.     'i=s', # if-modified-since
  274.     'c=s', # content type for POST
  275.     'C=s', # credentials for basic authorization
  276.     'H=s@', # extra headers, form "Header: value string"
  277.     #
  278.     'u', # display method, URL and headers of request
  279.     'U', # display request headers also
  280.     's', # display status code
  281.     'S', # display whole chain of status codes
  282.     'e', # display response headers (default for HEAD)
  283.     'd', # don't display content
  284.     #
  285.     'h', # print usage
  286.     'v', # print version
  287.     #
  288.     'x', # extra debugging info
  289.     'p=s', # proxy URL
  290.     'P', # don't load proxy setting from environment
  291.     #
  292.     'o=s', # output format
  293. );
  294.  
  295. Getopt::Long::config("noignorecase", "bundling");
  296. unless (GetOptions(\%options, @getopt_args)) {
  297.     usage();
  298. }
  299. if ($options{'v'}) {
  300.     require LWP;
  301.     my $DISTNAME = 'libwww-perl-' . LWP::Version();
  302.     die <<"EOT";
  303. This is lwp-request version $VERSION ($DISTNAME)
  304.  
  305. Copyright 1995-1999, Gisle Aas.
  306.  
  307. This program is free software; you can redistribute it and/or
  308. modify it under the same terms as Perl itself.
  309. EOT
  310. }
  311.  
  312. usage() if $options{'h'} || !@ARGV;
  313.  
  314. LWP::Debug::level('+') if $options{'x'};
  315.  
  316. # Create the user agent object
  317. $ua = RequestAgent->new;
  318.  
  319. # Load proxy settings from *_proxy environment variables.
  320. $ua->env_proxy unless $options{'P'};
  321.  
  322. $method = uc($options{'m'}) if defined $options{'m'};
  323.  
  324. if ($options{'f'}) {
  325.     if ($options{'c'}) {
  326.         $allowed_methods{$method} = "C";  # force content
  327.     } else {
  328.         $allowed_methods{$method} = "";
  329.     }
  330. } elsif (!defined $allowed_methods{$method}) {
  331.     die "$progname: $method is not an allowed method\n";
  332. }
  333.  
  334. if ($method eq "HEAD") {
  335.     $options{'s'} = 1;
  336.     $options{'e'} = 1 unless $options{'d'};
  337.     $options{'d'} = 1;
  338. }
  339.  
  340. if (defined $options{'t'}) {
  341.     $options{'t'} =~ /^(\d+)([smh])?/;
  342.     die "$progname: Illegal timeout value!\n" unless defined $1;
  343.     $timeout = $1;
  344.     $timeout *= 60   if ($2 eq "m");
  345.     $timeout *= 3600 if ($2 eq "h");
  346.     $ua->timeout($timeout);
  347. }
  348.  
  349. if (defined $options{'i'}) {
  350.     if (-e $options{'i'}) {
  351.         $time = (stat _)[9];
  352.     } else {
  353.         $time = str2time($options{'i'});
  354.         die "$progname: Illegal time syntax for -i option\n"
  355.             unless defined $time;
  356.     }
  357.     $options{'i'} = time2str($time);
  358. }
  359.  
  360. $content = undef;
  361. if ($allowed_methods{$method} eq "C") {
  362.     # This request needs some content
  363.     unless (defined $options{'c'}) {
  364.         # set default content type
  365.         $options{'c'} = ($method eq "POST") ?
  366.               "application/x-www-form-urlencoded"
  367.             : "text/plain";
  368.     } else {
  369.         die "$progname: Illegal Content-type format\n"
  370.             unless $options{'c'} =~ m,^[\w\-]+/[\w\-]+(?:\s*;.*)?$,
  371.     }
  372.     print "Please enter content ($options{'c'}) to be ${method}ed:\n"
  373.         if -t;
  374.     binmode STDIN unless -t or $options{'a'};
  375.     $content = join("", <STDIN>);
  376. } else {
  377.     die "$progname: Can't set Content-type for $method requests\n"
  378.         if defined $options{'c'};
  379. }
  380.  
  381. # Set up a request.  We will use the same request object for all URLs.
  382. $request = HTTP::Request->new($method);
  383. $request->header('If-Modified-Since', $options{'i'}) if defined $options{'i'};
  384. for my $user_header (@{ $options{'H'} || [] }) {
  385.     my ($header_name, $header_value) = split /:\s*/, $user_header, 2;
  386.     $request->header($header_name, $header_value);
  387.     $ua->agent($header_value) if lc($header_name) eq "user-agent"; # Ugh!
  388. }
  389. #$request->header('Accept', '*/*');
  390. if ($options{'c'}) { # will always be set for request that wants content
  391.     $request->header('Content-Type', $options{'c'});
  392.     $request->header('Content-Length', length $content);  # Not really needed
  393.     $request->content($content);
  394. }
  395.  
  396. $errors = 0;
  397.  
  398. # Ok, now we perform the requests, one URL at a time
  399. while ($url = shift) {
  400.     # Create the URL object, but protect us against bad URLs
  401.     eval {
  402.     if ($url =~ /^\w+:/ || $options{'b'}) {  # is there any scheme specification
  403.         $url = URI->new($url, $options{'b'});
  404.         $url = $url->abs($options{'b'}) if $options{'b'};
  405.     } else {
  406.         $url = uf_uri($url);
  407.         }
  408.     };
  409.     if ($@) {
  410.     $@ =~ s/at\s+\S+\s+line\s\d+//;
  411.     print STDERR $@;
  412.     $errors++;
  413.     next;
  414.     }
  415.  
  416.     $ua->proxy($url->scheme, $options{'p'}) if $options{'p'};
  417.  
  418.     # Send the request and get a response back from the server
  419.     $request->url($url);
  420.     $response = $ua->request($request);
  421.  
  422.     if ($options{'u'} || $options{'U'}) {
  423.         my $url = $response->request->url->as_string;
  424.         print "$method $url\n";
  425.         print $response->request->headers_as_string, "\n" if $options{'U'};
  426.     }
  427.  
  428.     if ($options{'S'}) {
  429.     printResponseChain($response);
  430.     } elsif ($options{'s'}) {
  431.         print $response->status_line, "\n";
  432.     }
  433.  
  434.     if ($options{'e'}) {
  435.         # Display headers
  436.         print $response->headers_as_string;
  437.         print "\n";  # separate headers and content
  438.     }
  439.  
  440.     if ($response->is_success) {
  441.     unless ($options{'d'}) {
  442.         if ($options{'o'} &&
  443.         $response->content_type eq 'text/html') {
  444.         require HTML::Parse;
  445.         my $html = HTML::Parse::parse_html($response->content);
  446.         {
  447.             $options{'o'} eq 'ps' && do {
  448.             require HTML::FormatPS;
  449.             my $f = HTML::FormatPS->new;
  450.             print $f->format($html);
  451.             last;
  452.             };
  453.             $options{'o'} eq 'text' && do {
  454.             require HTML::FormatText;
  455.             my $f = HTML::FormatText->new;
  456.             print $f->format($html);
  457.             last;
  458.             };
  459.             $options{'o'} eq 'html' && do {
  460.             print $html->as_HTML;
  461.             last;
  462.             };
  463.             $options{'o'} eq 'links' && do {
  464.             my $base = $response->base;
  465.             for ( @{ $html->extract_links } ) {
  466.                 my($link, $elem) = @$_;
  467.                 my $tag = uc $elem->tag;
  468.                 $link = URI->new($link)->abs($base)->as_string;
  469.                 print "$tag\t$link\n";
  470.             }
  471.             last;
  472.             };
  473.             $options{'o'} eq 'dump' && do {
  474.             $html->dump;
  475.             last;
  476.             };
  477.             # It is bad to not notice this before now :-(
  478.             die "Illegal -o option value ($options{'o'})\n";
  479.         }
  480.         } else {
  481.                 binmode STDOUT unless $options{'a'};
  482.         print $response->content;
  483.         }
  484.     }
  485.     } else {
  486.         print STDERR $response->error_as_HTML unless $options{'d'};
  487.         $errors++;
  488.     }
  489. }
  490.  
  491. exit $errors;
  492.  
  493.  
  494. sub printResponseChain
  495. {
  496.     my($response) = @_;
  497.     return unless defined $response;
  498.     printResponseChain($response->previous);
  499.     my $method = $response->request->method;
  500.     my $url = $response->request->url->as_string;
  501.     my $code = $response->code;
  502.     print "$method $url --> ", $response->status_line, "\n";
  503. }
  504.  
  505.  
  506. sub usage
  507. {
  508.     die <<"EOT";
  509. Usage: $progname [-options] <url>...
  510.     -m <method>   use method for the request (default is '$method')
  511.     -f            make request even if $progname believes method is illegal
  512.     -b <base>     Use the specified URL as base
  513.     -t <timeout>  Set timeout value
  514.     -i <time>     Set the If-Modified-Since header on the request
  515.     -c <conttype> use this content-type for POST, PUT, CHECKIN
  516.     -a            Use text mode for content I/O
  517.     -p <proxyurl> use this as a proxy
  518.     -P            don't load proxy settings from environment
  519.     -H <header>   send this HTTP header (you can specify several)
  520.  
  521.     -u            Display method and URL before any response
  522.     -U            Display request headers (implies -u)
  523.     -s            Display response status code
  524.     -S            Display response status chain
  525.     -e            Display response headers
  526.     -d            Do not display content
  527.     -o <format>   Process HTML content in various ways
  528.  
  529.     -v            Show program version
  530.     -h            Print this message
  531.  
  532.     -x            Extra debugging output
  533. EOT
  534. }
  535.  
  536. __END__
  537. :endofperl
  538.