home *** CD-ROM | disk | FTP | other *** search
/ Chip 2000 May / Chip_2000-05_cd1.bin / zkuste / Perl / ActivePerl-5.6.0.613.msi / 䆊䌷䈹䈙䏵-䞅䞆䞀㡆䞃䄦䠥 / _7a530d8bf438ec650c278d37e5c6e6e7 < prev    next >
Text File  |  2000-03-24  |  21KB  |  713 lines
  1. @rem = '--*-Perl-*--
  2. @echo off
  3. if "%OS%" == "Windows_NT" goto WinNT
  4. perl -x -S "%0" %1 %2 %3 %4 %5 %6 %7 %8 %9
  5. goto endofperl
  6. :WinNT
  7. perl -x -S "%0" %*
  8. if NOT "%COMSPEC%" == "%SystemRoot%\system32\cmd.exe" goto endofperl
  9. if %errorlevel% == 9009 echo You do not have Perl in your PATH.
  10. if errorlevel 1 goto script_failed_so_exit_with_non_zero_val 2>nul
  11. goto endofperl
  12. @rem ';
  13. #!perl
  14. #line 15
  15.     eval 'exec D:\p4-view\main\Apps\Gecko\MSI\data\ActivePerl\Perl\bin\perl.exe -S $0 ${1+"$@"}'
  16.     if $running_under_some_shell;
  17.  
  18. use Config;
  19. use File::Path qw(mkpath);
  20. use Getopt::Std;
  21.  
  22. getopts('Dd:rlhaQ');
  23. die "-r and -a options are mutually exclusive\n" if ($opt_r and $opt_a);
  24. @inc_dirs = inc_dirs() if $opt_a;
  25.  
  26. my $Exit = 0;
  27.  
  28. my $Dest_dir = $opt_d || $Config{installsitearch};
  29. die "Destination directory $Dest_dir doesn't exist or isn't a directory\n"
  30.     unless -d $Dest_dir;
  31.  
  32. @isatype = split(' ',<<END);
  33.     char    uchar    u_char
  34.     short    ushort    u_short
  35.     int    uint    u_int
  36.     long    ulong    u_long
  37.     FILE    key_t    caddr_t
  38. END
  39.  
  40. @isatype{@isatype} = (1) x @isatype;
  41. $inif = 0;
  42.  
  43. @ARGV = ('-') unless @ARGV;
  44.  
  45. build_preamble_if_necessary();
  46.  
  47. while (defined ($file = next_file())) {
  48.     if (-l $file and -d $file) {
  49.         link_if_possible($file) if ($opt_l);
  50.         next;
  51.     }
  52.  
  53.     # Recover from header files with unbalanced cpp directives
  54.     $t = '';
  55.     $tab = 0;
  56.  
  57.     # $eval_index goes into ``#line'' directives, to help locate syntax errors:
  58.     $eval_index = 1;
  59.  
  60.     if ($file eq '-') {
  61.     open(IN, "-");
  62.     open(OUT, ">-");
  63.     } else {
  64.     ($outfile = $file) =~ s/\.h$/.ph/ || next;
  65.     print "$file -> $outfile\n" unless $opt_Q;
  66.     if ($file =~ m|^(.*)/|) {
  67.         $dir = $1;
  68.         mkpath "$Dest_dir/$dir";
  69.     }
  70.  
  71.     if ($opt_a) { # automagic mode:  locate header file in @inc_dirs
  72.         foreach (@inc_dirs) {
  73.         chdir $_;
  74.         last if -f $file;
  75.         }
  76.     }
  77.  
  78.     open(IN,"$file") || (($Exit = 1),(warn "Can't open $file: $!\n"),next);
  79.     open(OUT,">$Dest_dir/$outfile") || die "Can't create $outfile: $!\n";
  80.     }
  81.  
  82.     print OUT "require '_h2ph_pre.ph';\n\n";
  83.     while (<IN>) {
  84.     chop;
  85.     while (/\\$/) {
  86.         chop;
  87.         $_ .= <IN>;
  88.         chop;
  89.     }
  90.     print OUT "# $_\n" if $opt_D;
  91.  
  92.     if (s:/\*:\200:g) {
  93.         s:\*/:\201:g;
  94.         s/\200[^\201]*\201//g;    # delete single line comments
  95.         if (s/\200.*//) {        # begin multi-line comment?
  96.         $_ .= '/*';
  97.         $_ .= <IN>;
  98.         redo;
  99.         }
  100.     }
  101.     if (s/^\s*\#\s*//) {
  102.         if (s/^define\s+(\w+)//) {
  103.         $name = $1;
  104.         $new = '';
  105.         s/\s+$//;
  106.         if (s/^\(([\w,\s]*)\)//) {
  107.             $args = $1;
  108.                     my $proto = '() ';
  109.             if ($args ne '') {
  110.                         $proto = '';
  111.             foreach $arg (split(/,\s*/,$args)) {
  112.                 $arg =~ s/^\s*([^\s].*[^\s])\s*$/$1/;
  113.                 $curargs{$arg} = 1;
  114.             }
  115.             $args =~ s/\b(\w)/\$$1/g;
  116.             $args = "local($args) = \@_;\n$t    ";
  117.             }
  118.             s/^\s+//;
  119.             expr();
  120.             $new =~ s/(["\\])/\\$1/g;       #"]);
  121.             $new = reindent($new);
  122.             $args = reindent($args);
  123.             if ($t ne '') {
  124.             $new =~ s/(['\\])/\\$1/g;   #']);
  125.             if ($opt_h) {
  126.                 print OUT $t,
  127.                             "eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
  128.                             $eval_index++;
  129.             } else {
  130.                 print OUT $t,
  131.                             "eval 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
  132.             }
  133.             } else {
  134.                       print OUT "unless(defined(\&$name)) {\n    sub $name $proto\{\n\t${args}eval q($new);\n    }\n}\n";
  135.             }
  136.             %curargs = ();
  137.         } else {
  138.             s/^\s+//;
  139.             expr();
  140.             $new = 1 if $new eq '';
  141.             $new = reindent($new);
  142.             $args = reindent($args);
  143.             if ($t ne '') {
  144.             $new =~ s/(['\\])/\\$1/g;        #']);
  145.  
  146.             if ($opt_h) {
  147.                 print OUT $t,"eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name () {",$new,";}' unless defined(\&$name);\n";
  148.                 $eval_index++;
  149.             } else {
  150.                 print OUT $t,"eval 'sub $name () {",$new,";}' unless defined(\&$name);\n";
  151.             }
  152.             } else {
  153.                 # Shunt around such directives as `#define FOO FOO':
  154.                 next if " \&$name" eq $new;
  155.  
  156.                       print OUT $t,"unless(defined(\&$name)) {\n    sub $name () {\t",$new,";}\n}\n";
  157.             }
  158.         }
  159.         } elsif (/^(include|import)\s*[<"](.*)[>"]/) {
  160.         ($incl = $2) =~ s/\.h$/.ph/;
  161.         print OUT $t,"require '$incl';\n";
  162.         } elsif(/^include_next\s*[<"](.*)[>"]/) {
  163.         ($incl = $1) =~ s/\.h$/.ph/;
  164.         print OUT ($t,
  165.                "eval {\n");
  166.                 $tab += 4;
  167.                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  168.         print OUT ($t,
  169.                "my(\%INCD) = map { \$INC{\$_} => 1 } ",
  170.                "(grep { \$_ eq \"$incl\" } keys(\%INC));\n");
  171.         print OUT ($t,
  172.                "my(\@REM) = map { \"\$_/$incl\" } ",
  173.                "(grep { not exists(\$INCD{\"\$_/$incl\"})",
  174.                "and -f \"\$_/$incl\" } \@INC);\n");
  175.         print OUT ($t,
  176.                "require \"\$REM[0]\" if \@REM;\n");
  177.                 $tab -= 4;
  178.                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  179.                 print OUT ($t,
  180.                "};\n");
  181.         print OUT ($t,
  182.                "warn(\$\@) if \$\@;\n");
  183.         } elsif (/^ifdef\s+(\w+)/) {
  184.         print OUT $t,"if(defined(&$1)) {\n";
  185.         $tab += 4;
  186.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  187.         } elsif (/^ifndef\s+(\w+)/) {
  188.         print OUT $t,"unless(defined(&$1)) {\n";
  189.         $tab += 4;
  190.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  191.         } elsif (s/^if\s+//) {
  192.         $new = '';
  193.         $inif = 1;
  194.         expr();
  195.         $inif = 0;
  196.         print OUT $t,"if($new) {\n";
  197.         $tab += 4;
  198.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  199.         } elsif (s/^elif\s+//) {
  200.         $new = '';
  201.         $inif = 1;
  202.         expr();
  203.         $inif = 0;
  204.         $tab -= 4;
  205.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  206.         print OUT $t,"}\n elsif($new) {\n";
  207.         $tab += 4;
  208.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  209.         } elsif (/^else/) {
  210.         $tab -= 4;
  211.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  212.         print OUT $t,"} else {\n";
  213.         $tab += 4;
  214.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  215.         } elsif (/^endif/) {
  216.         $tab -= 4;
  217.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  218.         print OUT $t,"}\n";
  219.         } elsif(/^undef\s+(\w+)/) {
  220.         print OUT $t, "undef(&$1) if defined(&$1);\n";
  221.         } elsif(/^error\s+(".*")/) {
  222.         print OUT $t, "die($1);\n";
  223.         } elsif(/^error\s+(.*)/) {
  224.         print OUT $t, "die(\"", quotemeta($1), "\");\n";
  225.         } elsif(/^warning\s+(.*)/) {
  226.         print OUT $t, "warn(\"", quotemeta($1), "\");\n";
  227.         } elsif(/^ident\s+(.*)/) {
  228.         print OUT $t, "# $1\n";
  229.         }
  230.      } elsif(/^\s*(typedef\s*)?enum\s*(\s+[a-zA-Z_]\w*\s*)?\{/) {
  231.         until(/\}.*?;/) {
  232.         chomp($next = <IN>);
  233.         $_ .= $next;
  234.         print OUT "# $next\n" if $opt_D;
  235.         }
  236.         s@/\*.*?\*/@@g;
  237.         s/\s+/ /g;
  238.         /^\s?(typedef\s?)?enum\s?([a-zA-Z_]\w*)?\s?\{(.*)\}\s?([a-zA-Z_]\w*)?\s?;/;
  239.         ($enum_subs = $3) =~ s/\s//g;
  240.         @enum_subs = split(/,/, $enum_subs);
  241.         $enum_val = -1;
  242.         for $enum (@enum_subs) {
  243.         ($enum_name, $enum_value) = $enum =~ /^([a-zA-Z_]\w*)(=.+)?$/;
  244.         $enum_value =~ s/^=//;
  245.         $enum_val = (length($enum_value) ? $enum_value : $enum_val + 1);
  246.         if ($opt_h) {
  247.             print OUT ($t,
  248.                    "eval(\"\\n#line $eval_index $outfile\\n",
  249.                    "sub $enum_name () \{ $enum_val; \}\") ",
  250.                    "unless defined(\&$enum_name);\n");
  251.             ++ $eval_index;
  252.         } else {
  253.             print OUT ($t,
  254.                    "eval(\"sub $enum_name () \{ $enum_val; \}\") ",
  255.                    "unless defined(\&$enum_name);\n");
  256.         }
  257.         }
  258.     }
  259.     }
  260.     print OUT "1;\n";
  261.  
  262.     $is_converted{$file} = 1;
  263.     queue_includes_from($file) if ($opt_a);
  264. }
  265.  
  266. exit $Exit;
  267.  
  268. sub reindent($) {
  269.     my($text) = shift;
  270.     $text =~ s/\n/\n    /g;
  271.     $text =~ s/        /\t/g;
  272.     $text;
  273. }
  274.  
  275. sub expr {
  276.     if(keys(%curargs)) {
  277.     my($joined_args) = join('|', keys(%curargs));
  278.     }
  279.     while ($_ ne '') {
  280.     s/^\&\&// && do { $new .= " &&"; next;}; # handle && operator
  281.     s/^\&([\(a-z\)]+)/$1/i;    # hack for things that take the address of
  282.     s/^(\s+)//        && do {$new .= ' '; next;};
  283.     s/^(0X[0-9A-F]+)[UL]*//i    && do {$new .= lc($1); next;};
  284.     s/^(-?\d+\.\d+E[-+]\d+)F?//i    && do {$new .= $1; next;};
  285.     s/^(\d+)\s*[LU]*//i    && do {$new .= $1; next;};
  286.     s/^("(\\"|[^"])*")//    && do {$new .= $1; next;};
  287.     s/^'((\\"|[^"])*)'//    && do {
  288.         if ($curargs{$1}) {
  289.         $new .= "ord('\$$1')";
  290.         } else {
  291.         $new .= "ord('$1')";
  292.         }
  293.         next;
  294.     };
  295.         # replace "sizeof(foo)" with "{foo}"
  296.         # also, remove * (C dereference operator) to avoid perl syntax
  297.         # problems.  Where the %sizeof array comes from is anyone's
  298.         # guess (c2ph?), but this at least avoids fatal syntax errors.
  299.         # Behavior is undefined if sizeof() delimiters are unbalanced.
  300.         # This code was modified to able to handle constructs like this:
  301.         #   sizeof(*(p)), which appear in the HP-UX 10.01 header files.
  302.         s/^sizeof\s*\(// && do {
  303.             $new .= '$sizeof';
  304.             my $lvl = 1;  # already saw one open paren
  305.             # tack { on the front, and skip it in the loop
  306.             $_ = "{" . "$_";
  307.             my $index = 1;
  308.             # find balanced closing paren
  309.             while ($index <= length($_) && $lvl > 0) {
  310.                 $lvl++ if substr($_, $index, 1) eq "(";
  311.                 $lvl-- if substr($_, $index, 1) eq ")";
  312.                 $index++;
  313.             }
  314.             # tack } on the end, replacing )
  315.             substr($_, $index - 1, 1) = "}";
  316.             # remove pesky * operators within the sizeof argument
  317.             substr($_, 0, $index - 1) =~ s/\*//g;
  318.             next;
  319.         };
  320.     # Eliminate typedefs
  321.     /\(([\w\s]+)[\*\s]*\)\s*[\w\(]/ && do {
  322.         foreach (split /\s+/, $1) {  # Make sure all the words are types,
  323.         last unless ($isatype{$_} or $_ eq 'struct');
  324.         }
  325.         s/\([\w\s]+[\*\s]*\)// && next;      # then eliminate them.
  326.     };
  327.     # struct/union member, including arrays:
  328.     s/^([_A-Z]\w*(\[[^\]]+\])?((\.|->)[_A-Z]\w*(\[[^\]]+\])?)+)//i && do {
  329.         $id = $1;
  330.         $id =~ s/(\.|(->))([^\.\-]*)/->\{$3\}/g;
  331.         $id =~ s/\b([^\$])($joined_args)/$1\$$2/g if length($joined_args);
  332.         while($id =~ /\[\s*([^\$\&\d\]]+)\]/) {
  333.         my($index) = $1;
  334.         $index =~ s/\s//g;
  335.         if(exists($curargs{$index})) {
  336.             $index = "\$$index";
  337.         } else {
  338.             $index = "&$index";
  339.         }
  340.         $id =~ s/\[\s*([^\$\&\d\]]+)\]/[$index]/;
  341.         }
  342.         $new .= " (\$$id)";
  343.     };
  344.     s/^([_a-zA-Z]\w*)//    && do {
  345.         $id = $1;
  346.         if ($id eq 'struct') {
  347.         s/^\s+(\w+)//;
  348.         $id .= ' ' . $1;
  349.         $isatype{$id} = 1;
  350.         } elsif ($id =~ /^((un)?signed)|(long)|(short)$/) {
  351.         while (s/^\s+(\w+)//) { $id .= ' ' . $1; }
  352.         $isatype{$id} = 1;
  353.         }
  354.         if ($curargs{$id}) {
  355.         $new .= "\$$id";
  356.         $new .= '->' if /^[\[\{]/;
  357.         } elsif ($id eq 'defined') {
  358.         $new .= 'defined';
  359.         } elsif (/^\(/) {
  360.         s/^\((\w),/("$1",/ if $id =~ /^_IO[WR]*$/i;    # cheat
  361.         $new .= " &$id";
  362.         } elsif ($isatype{$id}) {
  363.         if ($new =~ /{\s*$/) {
  364.             $new .= "'$id'";
  365.         } elsif ($new =~ /\(\s*$/ && /^[\s*]*\)/) {
  366.             $new =~ s/\(\s*$//;
  367.             s/^[\s*]*\)//;
  368.         } else {
  369.             $new .= q(').$id.q(');
  370.         }
  371.         } else {
  372.         if ($inif && $new !~ /defined\s*\($/) {
  373.             $new .= '(defined(&' . $id . ') ? &' . $id . ' : 0)';
  374.         } elsif (/^\[/) {
  375.             $new .= " \$$id";
  376.         } else {
  377.             $new .= ' &' . $id;
  378.         }
  379.         }
  380.         next;
  381.     };
  382.     s/^(.)// && do { if ($1 ne '#') { $new .= $1; } next;};
  383.     }
  384. }
  385.  
  386.  
  387. # Handle recursive subdirectories without getting a grotesquely big stack.
  388. # Could this be implemented using File::Find?
  389. sub next_file
  390. {
  391.     my $file;
  392.  
  393.     while (@ARGV) {
  394.         $file = shift @ARGV;
  395.  
  396.         if ($file eq '-' or -f $file or -l $file) {
  397.             return $file;
  398.         } elsif (-d $file) {
  399.             if ($opt_r) {
  400.                 expand_glob($file);
  401.             } else {
  402.                 print STDERR "Skipping directory `$file'\n";
  403.             }
  404.         } elsif ($opt_a) {
  405.             return $file;
  406.         } else {
  407.             print STDERR "Skipping `$file':  not a file or directory\n";
  408.         }
  409.     }
  410.  
  411.     return undef;
  412. }
  413.  
  414.  
  415. # Put all the files in $directory into @ARGV for processing.
  416. sub expand_glob
  417. {
  418.     my ($directory)  = @_;
  419.  
  420.     $directory =~ s:/$::;
  421.  
  422.     opendir DIR, $directory;
  423.         foreach (readdir DIR) {
  424.             next if ($_ eq '.' or $_ eq '..');
  425.  
  426.             # expand_glob() is going to be called until $ARGV[0] isn't a
  427.             # directory; so push directories, and unshift everything else.
  428.             if (-d "$directory/$_") { push    @ARGV, "$directory/$_" }
  429.             else                    { unshift @ARGV, "$directory/$_" }
  430.         }
  431.     closedir DIR;
  432. }
  433.  
  434.  
  435. # Given $file, a symbolic link to a directory in the C include directory,
  436. # make an equivalent symbolic link in $Dest_dir, if we can figure out how.
  437. # Otherwise, just duplicate the file or directory.
  438. sub link_if_possible
  439. {
  440.     my ($dirlink)  = @_;
  441.     my $target  = eval 'readlink($dirlink)';
  442.  
  443.     if ($target =~ m:^\.\./: or $target =~ m:^/:) {
  444.         # The target of a parent or absolute link could leave the $Dest_dir
  445.         # hierarchy, so let's put all of the contents of $dirlink (actually,
  446.         # the contents of $target) into @ARGV; as a side effect down the
  447.         # line, $dirlink will get created as an _actual_ directory.
  448.         expand_glob($dirlink);
  449.     } else {
  450.         if (-l "$Dest_dir/$dirlink") {
  451.             unlink "$Dest_dir/$dirlink" or
  452.                 print STDERR "Could not remove link $Dest_dir/$dirlink:  $!\n";
  453.         }
  454.  
  455.         if (eval 'symlink($target, "$Dest_dir/$dirlink")') {
  456.             print "Linking $target -> $Dest_dir/$dirlink\n";
  457.  
  458.             # Make sure that the link _links_ to something:
  459.             if (! -e "$Dest_dir/$target") {
  460.                 mkpath("$Dest_dir/$target", 0755) or
  461.                     print STDERR "Could not create $Dest_dir/$target/\n";
  462.             }
  463.         } else {
  464.             print STDERR "Could not symlink $target -> $Dest_dir/$dirlink:  $!\n";
  465.         }
  466.     }
  467. }
  468.  
  469.  
  470. # Push all #included files in $file onto our stack, except for STDIN
  471. # and files we've already processed.
  472. sub queue_includes_from
  473. {
  474.     my ($file)    = @_;
  475.     my $line;
  476.  
  477.     return if ($file eq "-");
  478.  
  479.     open HEADER, $file or return;
  480.         while (defined($line = <HEADER>)) {
  481.             while (/\\$/) { # Handle continuation lines
  482.                 chop $line;
  483.                 $line .= <HEADER>;
  484.             }
  485.  
  486.             if ($line =~ /^#\s*include\s+<(.*?)>/) {
  487.                 push(@ARGV, $1) unless $is_converted{$1};
  488.             }
  489.         }
  490.     close HEADER;
  491. }
  492.  
  493.  
  494. # Determine include directories; $Config{usrinc} should be enough for (all
  495. # non-GCC?) C compilers, but gcc uses an additional include directory.
  496. sub inc_dirs
  497. {
  498.     my $from_gcc    = `$Config{cc} -v 2>&1`;
  499.     $from_gcc       =~ s:^Reading specs from (.*?)/specs\b.*:$1/include:s;
  500.  
  501.     length($from_gcc) ? ($from_gcc, $Config{usrinc}) : ($Config{usrinc});
  502. }
  503.  
  504.  
  505. # Create "_h2ph_pre.ph", if it doesn't exist or was built by a different
  506. # version of h2ph.
  507. sub build_preamble_if_necessary
  508. {
  509.     # Increment $VERSION every time this function is modified:
  510.     my $VERSION     = 2;
  511.     my $preamble    = "$Dest_dir/_h2ph_pre.ph";
  512.  
  513.     # Can we skip building the preamble file?
  514.     if (-r $preamble) {
  515.         # Extract version number from first line of preamble:
  516.         open  PREAMBLE, $preamble or die "Cannot open $preamble:  $!";
  517.             my $line = <PREAMBLE>;
  518.             $line =~ /(\b\d+\b)/;
  519.         close PREAMBLE            or die "Cannot close $preamble:  $!";
  520.  
  521.         # Don't build preamble if a compatible preamble exists:
  522.         return if $1 == $VERSION;
  523.     }
  524.  
  525.     my (%define) = _extract_cc_defines();
  526.  
  527.     open  PREAMBLE, ">$preamble" or die "Cannot open $preamble:  $!";
  528.         print PREAMBLE "# This file was created by h2ph version $VERSION\n";
  529.  
  530.         foreach (sort keys %define) {
  531.             if ($opt_D) {
  532.                 print PREAMBLE "# $_=$define{$_}\n";
  533.             }
  534.  
  535.             if ($define{$_} =~ /^\d+$/) {
  536.                 print PREAMBLE
  537.                     "unless (defined &$_) { sub $_() { $define{$_} } }\n\n";
  538.             } elsif ($define{$_} =~ /^\w+$/) {
  539.                 print PREAMBLE
  540.                     "unless (defined &$_) { sub $_() { &$define{$_} } }\n\n";
  541.             } else {
  542.                 print PREAMBLE
  543.                     "unless (defined &$_) { sub $_() { \"",
  544.                     quotemeta($define{$_}), "\" } }\n\n";
  545.             }
  546.         }
  547.     close PREAMBLE               or die "Cannot close $preamble:  $!";
  548. }
  549.  
  550.  
  551. # %Config contains information on macros that are pre-defined by the
  552. # system's compiler.  We need this information to make the .ph files
  553. # function with perl as the .h files do with cc.
  554. sub _extract_cc_defines
  555. {
  556.     my %define;
  557.     my $allsymbols = join " ", @Config{ccsymbols, cppsymbols, cppccsymbols};
  558.  
  559.     # Split compiler pre-definitions into `key=value' pairs:
  560.     foreach (split /\s+/, $allsymbols) {
  561.         /(.+?)=(.+)/ and $define{$1} = $2;
  562.  
  563.         if ($opt_D) {
  564.             print STDERR "$_:  $1 -> $2\n";
  565.         }
  566.     }
  567.  
  568.     return %define;
  569. }
  570.  
  571.  
  572. 1;
  573.  
  574. ##############################################################################
  575. __END__
  576.  
  577. =head1 NAME
  578.  
  579. h2ph - convert .h C header files to .ph Perl header files
  580.  
  581. =head1 SYNOPSIS
  582.  
  583. B<h2ph [-d destination directory] [-r | -a] [-l] [headerfiles]>
  584.  
  585. =head1 DESCRIPTION
  586.  
  587. I<h2ph>
  588. converts any C header files specified to the corresponding Perl header file
  589. format.
  590. It is most easily run while in /usr/include:
  591.  
  592.     cd /usr/include; h2ph * sys/*
  593.  
  594. or
  595.  
  596.     cd /usr/include; h2ph -r -l .
  597.  
  598. The output files are placed in the hierarchy rooted at Perl's
  599. architecture dependent library directory.  You can specify a different
  600. hierarchy with a B<-d> switch.
  601.  
  602. If run with no arguments, filters standard input to standard output.
  603.  
  604. =head1 OPTIONS
  605.  
  606. =over 4
  607.  
  608. =item -d destination_dir
  609.  
  610. Put the resulting B<.ph> files beneath B<destination_dir>, instead of
  611. beneath the default Perl library location (C<$Config{'installsitsearch'}>).
  612.  
  613. =item -r
  614.  
  615. Run recursively; if any of B<headerfiles> are directories, then run I<h2ph>
  616. on all files in those directories (and their subdirectories, etc.).  B<-r>
  617. and B<-a> are mutually exclusive.
  618.  
  619. =item -a
  620.  
  621. Run automagically; convert B<headerfiles>, as well as any B<.h> files
  622. which they include.  This option will search for B<.h> files in all
  623. directories which your C compiler ordinarily uses.  B<-a> and B<-r> are
  624. mutually exclusive.
  625.  
  626. =item -l
  627.  
  628. Symbolic links will be replicated in the destination directory.  If B<-l>
  629. is not specified, then links are skipped over.
  630.  
  631. =item -h
  632.  
  633. Put ``hints'' in the .ph files which will help in locating problems with
  634. I<h2ph>.  In those cases when you B<require> a B<.ph> file containing syntax
  635. errors, instead of the cryptic
  636.  
  637.     [ some error condition ] at (eval mmm) line nnn
  638.  
  639. you will see the slightly more helpful
  640.  
  641.     [ some error condition ] at filename.ph line nnn
  642.  
  643. However, the B<.ph> files almost double in size when built using B<-h>.
  644.  
  645. =item -D
  646.  
  647. Include the code from the B<.h> file as a comment in the B<.ph> file.
  648. This is primarily used for debugging I<h2ph>.
  649.  
  650. =item -Q
  651.  
  652. ``Quiet'' mode; don't print out the names of the files being converted.
  653.  
  654. =back
  655.  
  656. =head1 ENVIRONMENT
  657.  
  658. No environment variables are used.
  659.  
  660. =head1 FILES
  661.  
  662.  /usr/include/*.h
  663.  /usr/include/sys/*.h
  664.  
  665. etc.
  666.  
  667. =head1 AUTHOR
  668.  
  669. Larry Wall
  670.  
  671. =head1 SEE ALSO
  672.  
  673. perl(1)
  674.  
  675. =head1 DIAGNOSTICS
  676.  
  677. The usual warnings if it can't read or write the files involved.
  678.  
  679. =head1 BUGS
  680.  
  681. Doesn't construct the %sizeof array for you.
  682.  
  683. It doesn't handle all C constructs, but it does attempt to isolate
  684. definitions inside evals so that you can get at the definitions
  685. that it can translate.
  686.  
  687. It's only intended as a rough tool.
  688. You may need to dicker with the files produced.
  689.  
  690. Doesn't run with C<use strict>
  691.  
  692. You have to run this program by hand; it's not run as part of the Perl
  693. installation.
  694.  
  695. Doesn't handle complicated expressions built piecemeal, a la:
  696.  
  697.     enum {
  698.         FIRST_VALUE,
  699.         SECOND_VALUE,
  700.     #ifdef ABC
  701.         THIRD_VALUE
  702.     #endif
  703.     };
  704.  
  705. Doesn't necessarily locate all of your C compiler's internally-defined
  706. symbols.
  707.  
  708. =cut
  709.  
  710.  
  711. __END__
  712. :endofperl
  713.