home *** CD-ROM | disk | FTP | other *** search
/ Chip 2000 May / Chip_2000-05_cd1.bin / zkuste / Perl / ActivePerl-5.6.0.613.msi / 䆊䌷䈹䈙䏵-䞅䞆䞀㡆䞃䄦䠥 / _52f7af7da960fa4b724d9ed5148cab48 < prev    next >
Encoding:
Text File  |  2000-03-23  |  14.4 KB  |  522 lines
  1. #!perl -w
  2.  
  3. # $Id: lwp-request.PL,v 1.38 1999/06/01 10:40:51 gisle Exp $
  4. #
  5. # Simple user agent using LWP library.
  6.  
  7. =head1 NAME
  8.  
  9. lwp-request, GET, HEAD, POST - Simple WWW user agent
  10.  
  11. =head1 SYNOPSIS
  12.  
  13.  lwp-request [-aeEdvhx] [-m method] [-b <base URL>] [-t <timeout>]
  14.              [-i <if-modified-since>] [-c <content-type>] [-C <credentials>]
  15.              [-p <proxy-url>] [-o <format>] <url>...
  16.  
  17. =head1 DESCRIPTION
  18.  
  19. This program can be used to send requests to WWW servers and your
  20. local file system. The request content for POST and PUT
  21. methods is read from stdin.  The content of the response is printed on
  22. stdout.  Error messages are printed on stderr.  The program returns a
  23. status value indicating the number of URLs that failed.
  24.  
  25. The options are:
  26.  
  27. =over 4
  28.  
  29. =item -m <method>
  30.  
  31. Set which method to use for the request.  If this option is not used,
  32. then the method is derived from the name of the program.
  33.  
  34. =item -f
  35.  
  36. Force request through, even if the program believes that the method is
  37. illegal.  The server might reject the request eventually.
  38.  
  39. =item -b <uri>
  40.  
  41. This URI will be used as the base URI for resolving all relative URIs
  42. given as argument.
  43.  
  44. =item -t <timeout>
  45.  
  46. Set the timeout value for the requests.  The timeout is the amount of
  47. time that the program will wait for a response from the remote server
  48. before it fails.  The default unit for the timeout value is seconds.
  49. You might append "m" or "h" to the timeout value to make it minutes or
  50. hours, respectively.  The default timeout is '3m', i.e. 3 minutes.
  51.  
  52. =item -i <time>
  53.  
  54. Set the If-Modified-Since header in the request. If I<time> it the
  55. name of a file, use the modification timestamp for this file. If
  56. I<time> is not a file, it is parsed as a literal date. Take a look at
  57. L<HTTP::Date> for recogniced formats.
  58.  
  59. =item -c <content-type>
  60.  
  61. Set the Content-Type for the request.  This option is only allowed for
  62. requests that take a content, i.e. POST and PUT.  You can
  63. force methods to take content by using the C<-f> option together with
  64. C<-c>.  The default Content-Type for POST is
  65. C<application/x-www-form-urlencoded>.  The default Content-type for
  66. the others is C<text/plain>.
  67.  
  68. =item -p <proxy-url>
  69.  
  70. Set the proxy to be used for the requests.  The program also loads
  71. proxy settings from the environment.  You can disable this with the
  72. C<-P> option.
  73.  
  74. =item -H <header>
  75.  
  76. Send this HTTP header with each request. You can specify several, e.g.:
  77.  
  78.     lwp-request \
  79.     -H 'Referer: http://other.url/' \
  80.     -H 'Host: somehost' \
  81.     http://this.url/
  82.  
  83. =item -C <username>:<password>
  84.  
  85. Provide credentials for documents that are protected by Basic
  86. Authentication.  If the document is protected and you did not specify
  87. the username and password with this option, then you will be prompted
  88. to provide these values.
  89.  
  90. =back
  91.  
  92. The following options controls what is displayed by the program:
  93.  
  94. =over 4
  95.  
  96. =item -u
  97.  
  98. Print request method and absolute URL as requests are made.
  99.  
  100. =item -U
  101.  
  102. Print request headers in addition to request method and absolute URL.
  103.  
  104. =item -s
  105.  
  106. Print response status code.  This option is always on for HEAD requests.
  107.  
  108. =item -S
  109.  
  110. Print response status chain. This shows redirect and autorization
  111. requests that are handled by the library.
  112.  
  113. =item -e
  114.  
  115. Print response headers.  This option is always on for HEAD requests.
  116.  
  117. =item -d
  118.  
  119. Do B<not> print the content of the response.
  120.  
  121. =item -o <format>
  122.  
  123. Process HTML content in various ways before printing it.  If the
  124. content type of the response is not HTML, then this option has no
  125. effect.  The legal format values are; I<text>, I<ps>, I<links>,
  126. I<html> and I<dump>.
  127.  
  128. If you specify the I<text> format then the HTML will be formatted as
  129. plain latin1 text.  If you specify the I<ps> format then it will be
  130. formatted as Postscript.
  131.  
  132. The I<links> format will output all links found in the HTML document.
  133. Relative links will be expanded to absolute ones.
  134.  
  135. The I<html> format will reformat the HTML code and the I<dump> format
  136. will just dump the HTML syntax tree.
  137.  
  138. =item -v
  139.  
  140. Print the version number of the program and quit.
  141.  
  142. =item -h
  143.  
  144. Print usage message and quit.
  145.  
  146. =item -x
  147.  
  148. Extra debugging output.
  149.  
  150. =item -a
  151.  
  152. Set text(ascii) mode for content input and output.  If this option is not 
  153. used, content input and output is done in binary mode.
  154.  
  155. =back
  156.  
  157. Because this program is implemented using the LWP library, it will
  158. only support the protocols that LWP supports.
  159.  
  160. =head1 SEE ALSO
  161.  
  162. L<lwp-mirror>, L<LWP>
  163.  
  164. =head1 COPYRIGHT
  165.  
  166. Copyright 1995-1999 Gisle Aas.
  167.  
  168. This library is free software; you can redistribute it and/or
  169. modify it under the same terms as Perl itself.
  170.  
  171. =head1 AUTHOR
  172.  
  173. Gisle Aas <gisle@aas.no>
  174.  
  175. =cut
  176.  
  177. $progname = $0;
  178. $progname =~ s,.*/,,;  # use basename only
  179. $progname =~ s/\.\w*$//; # strip extension, if any
  180.  
  181. $VERSION = sprintf("%d.%02d", q$Revision: 1.38 $ =~ /(\d+)\.(\d+)/);
  182.  
  183.  
  184. require LWP;
  185. require LWP::Debug;
  186.  
  187. use URI;
  188. use URI::Heuristic qw(uf_uri);
  189.  
  190. use HTTP::Status qw(status_message);
  191. use HTTP::Date qw(time2str str2time);
  192.  
  193.  
  194. # This table lists the methods that are allowed.  It should really be
  195. # a superset for all methods supported for every scheme that may be
  196. # supported by the library.  Currently it might be a bit too HTTP
  197. # specific.  You might use the -f option to force a method through.
  198. #
  199. # "" = No content in request, "C" = Needs content in request
  200. #
  201. %allowed_methods = (
  202.     GET        => "",
  203.     HEAD       => "",
  204.     POST       => "C",
  205.     PUT        => "C",
  206.     DELETE     => "",
  207.     TRACE      => "",
  208.     OPTIONS    => "",
  209. );
  210.  
  211.  
  212. # We make our own specialization of LWP::UserAgent that asks for
  213. # user/password if document is protected.
  214. {
  215.     package RequestAgent;
  216.     @ISA = qw(LWP::UserAgent);
  217.  
  218.     sub new
  219.     { 
  220.     my $self = LWP::UserAgent::new(@_);
  221.     $self->agent("lwp-request/$main::VERSION");
  222.     $self;
  223.     }
  224.  
  225.     sub get_basic_credentials
  226.     {
  227.     my($self, $realm, $uri) = @_;
  228.     if ($main::options{'C'}) {
  229.         return split(':', $main::options{'C'}, 2);
  230.     } elsif (-t) {
  231.         my $netloc = $uri->host_port;
  232.         print "Enter username for $realm at $netloc: ";
  233.         my $user = <STDIN>;
  234.         chomp($user);
  235.         return (undef, undef) unless length $user;
  236.         print "Password: ";
  237.         system("stty -echo");
  238.         my $password = <STDIN>;
  239.         system("stty echo");
  240.         print "\n";  # because we disabled echo
  241.         chomp($password);
  242.         return ($user, $password);
  243.     } else {
  244.         return (undef, undef)
  245.     }
  246.     }
  247. }
  248.  
  249. $method = uc(lc($progname) eq "lwp-request" ? "GET" : $progname);
  250.  
  251. # Parse command line
  252. use Getopt::Long;
  253.  
  254. my @getopt_args = (
  255.     'a', # content i/o in text(ascii) mode
  256.     'm=s', # set method
  257.     'f', # make request even if method is not in %allowed_methods
  258.     'b=s', # base url
  259.     't=s', # timeout
  260.     'i=s', # if-modified-since
  261.     'c=s', # content type for POST
  262.     'C=s', # credentials for basic authorization
  263.     'H=s@', # extra headers, form "Header: value string"
  264.     #
  265.     'u', # display method, URL and headers of request
  266.     'U', # display request headers also
  267.     's', # display status code
  268.     'S', # display whole chain of status codes
  269.     'e', # display response headers (default for HEAD)
  270.     'd', # don't display content
  271.     #
  272.     'h', # print usage
  273.     'v', # print version
  274.     #
  275.     'x', # extra debugging info
  276.     'p=s', # proxy URL
  277.     'P', # don't load proxy setting from environment
  278.     #
  279.     'o=s', # output format
  280. );
  281.  
  282. Getopt::Long::config("noignorecase", "bundling");
  283. unless (GetOptions(\%options, @getopt_args)) {
  284.     usage();
  285. }
  286. if ($options{'v'}) {
  287.     require LWP;
  288.     my $DISTNAME = 'libwww-perl-' . LWP::Version();
  289.     die <<"EOT";
  290. This is lwp-request version $VERSION ($DISTNAME)
  291.  
  292. Copyright 1995-1999, Gisle Aas.
  293.  
  294. This program is free software; you can redistribute it and/or
  295. modify it under the same terms as Perl itself.
  296. EOT
  297. }
  298.  
  299. usage() if $options{'h'} || !@ARGV;
  300.  
  301. LWP::Debug::level('+') if $options{'x'};
  302.  
  303. # Create the user agent object
  304. $ua = RequestAgent->new;
  305.  
  306. # Load proxy settings from *_proxy environment variables.
  307. $ua->env_proxy unless $options{'P'};
  308.  
  309. $method = uc($options{'m'}) if defined $options{'m'};
  310.  
  311. if ($options{'f'}) {
  312.     if ($options{'c'}) {
  313.         $allowed_methods{$method} = "C";  # force content
  314.     } else {
  315.         $allowed_methods{$method} = "";
  316.     }
  317. } elsif (!defined $allowed_methods{$method}) {
  318.     die "$progname: $method is not an allowed method\n";
  319. }
  320.  
  321. if ($method eq "HEAD") {
  322.     $options{'s'} = 1;
  323.     $options{'e'} = 1 unless $options{'d'};
  324.     $options{'d'} = 1;
  325. }
  326.  
  327. if (defined $options{'t'}) {
  328.     $options{'t'} =~ /^(\d+)([smh])?/;
  329.     die "$progname: Illegal timeout value!\n" unless defined $1;
  330.     $timeout = $1;
  331.     $timeout *= 60   if ($2 eq "m");
  332.     $timeout *= 3600 if ($2 eq "h");
  333.     $ua->timeout($timeout);
  334. }
  335.  
  336. if (defined $options{'i'}) {
  337.     if (-e $options{'i'}) {
  338.         $time = (stat _)[9];
  339.     } else {
  340.         $time = str2time($options{'i'});
  341.         die "$progname: Illegal time syntax for -i option\n"
  342.             unless defined $time;
  343.     }
  344.     $options{'i'} = time2str($time);
  345. }
  346.  
  347. $content = undef;
  348. if ($allowed_methods{$method} eq "C") {
  349.     # This request needs some content
  350.     unless (defined $options{'c'}) {
  351.         # set default content type
  352.         $options{'c'} = ($method eq "POST") ?
  353.               "application/x-www-form-urlencoded"
  354.             : "text/plain";
  355.     } else {
  356.         die "$progname: Illegal Content-type format\n"
  357.             unless $options{'c'} =~ m,^[\w\-]+/[\w\-]+(?:\s*;.*)?$,
  358.     }
  359.     print "Please enter content ($options{'c'}) to be ${method}ed:\n"
  360.         if -t;
  361.     binmode STDIN unless -t or $options{'a'};
  362.     $content = join("", <STDIN>);
  363. } else {
  364.     die "$progname: Can't set Content-type for $method requests\n"
  365.         if defined $options{'c'};
  366. }
  367.  
  368. # Set up a request.  We will use the same request object for all URLs.
  369. $request = HTTP::Request->new($method);
  370. $request->header('If-Modified-Since', $options{'i'}) if defined $options{'i'};
  371. for my $user_header (@{ $options{'H'} || [] }) {
  372.     my ($header_name, $header_value) = split /:\s*/, $user_header, 2;
  373.     $request->header($header_name, $header_value);
  374.     $ua->agent($header_value) if lc($header_name) eq "user-agent"; # Ugh!
  375. }
  376. #$request->header('Accept', '*/*');
  377. if ($options{'c'}) { # will always be set for request that wants content
  378.     $request->header('Content-Type', $options{'c'});
  379.     $request->header('Content-Length', length $content);  # Not really needed
  380.     $request->content($content);
  381. }
  382.  
  383. $errors = 0;
  384.  
  385. # Ok, now we perform the requests, one URL at a time
  386. while ($url = shift) {
  387.     # Create the URL object, but protect us against bad URLs
  388.     eval {
  389.     if ($url =~ /^\w+:/ || $options{'b'}) {  # is there any scheme specification
  390.         $url = URI->new($url, $options{'b'});
  391.         $url = $url->abs($options{'b'}) if $options{'b'};
  392.     } else {
  393.         $url = uf_uri($url);
  394.         }
  395.     };
  396.     if ($@) {
  397.     $@ =~ s/at\s+\S+\s+line\s\d+//;
  398.     print STDERR $@;
  399.     $errors++;
  400.     next;
  401.     }
  402.  
  403.     $ua->proxy($url->scheme, $options{'p'}) if $options{'p'};
  404.  
  405.     # Send the request and get a response back from the server
  406.     $request->url($url);
  407.     $response = $ua->request($request);
  408.  
  409.     if ($options{'u'} || $options{'U'}) {
  410.         my $url = $response->request->url->as_string;
  411.         print "$method $url\n";
  412.         print $response->request->headers_as_string, "\n" if $options{'U'};
  413.     }
  414.  
  415.     if ($options{'S'}) {
  416.     printResponseChain($response);
  417.     } elsif ($options{'s'}) {
  418.         print $response->status_line, "\n";
  419.     }
  420.  
  421.     if ($options{'e'}) {
  422.         # Display headers
  423.         print $response->headers_as_string;
  424.         print "\n";  # separate headers and content
  425.     }
  426.  
  427.     if ($response->is_success) {
  428.     unless ($options{'d'}) {
  429.         if ($options{'o'} &&
  430.         $response->content_type eq 'text/html') {
  431.         require HTML::Parse;
  432.         my $html = HTML::Parse::parse_html($response->content);
  433.         {
  434.             $options{'o'} eq 'ps' && do {
  435.             require HTML::FormatPS;
  436.             my $f = HTML::FormatPS->new;
  437.             print $f->format($html);
  438.             last;
  439.             };
  440.             $options{'o'} eq 'text' && do {
  441.             require HTML::FormatText;
  442.             my $f = HTML::FormatText->new;
  443.             print $f->format($html);
  444.             last;
  445.             };
  446.             $options{'o'} eq 'html' && do {
  447.             print $html->as_HTML;
  448.             last;
  449.             };
  450.             $options{'o'} eq 'links' && do {
  451.             my $base = $response->base;
  452.             for ( @{ $html->extract_links } ) {
  453.                 my($link, $elem) = @$_;
  454.                 my $tag = uc $elem->tag;
  455.                 $link = URI->new($link)->abs($base)->as_string;
  456.                 print "$tag\t$link\n";
  457.             }
  458.             last;
  459.             };
  460.             $options{'o'} eq 'dump' && do {
  461.             $html->dump;
  462.             last;
  463.             };
  464.             # It is bad to not notice this before now :-(
  465.             die "Illegal -o option value ($options{'o'})\n";
  466.         }
  467.         } else {
  468.                 binmode STDOUT unless $options{'a'};
  469.         print $response->content;
  470.         }
  471.     }
  472.     } else {
  473.         print STDERR $response->error_as_HTML unless $options{'d'};
  474.         $errors++;
  475.     }
  476. }
  477.  
  478. exit $errors;
  479.  
  480.  
  481. sub printResponseChain
  482. {
  483.     my($response) = @_;
  484.     return unless defined $response;
  485.     printResponseChain($response->previous);
  486.     my $method = $response->request->method;
  487.     my $url = $response->request->url->as_string;
  488.     my $code = $response->code;
  489.     print "$method $url --> ", $response->status_line, "\n";
  490. }
  491.  
  492.  
  493. sub usage
  494. {
  495.     die <<"EOT";
  496. Usage: $progname [-options] <url>...
  497.     -m <method>   use method for the request (default is '$method')
  498.     -f            make request even if $progname believes method is illegal
  499.     -b <base>     Use the specified URL as base
  500.     -t <timeout>  Set timeout value
  501.     -i <time>     Set the If-Modified-Since header on the request
  502.     -c <conttype> use this content-type for POST, PUT, CHECKIN
  503.     -a            Use text mode for content I/O
  504.     -p <proxyurl> use this as a proxy
  505.     -P            don't load proxy settings from environment
  506.     -H <header>   send this HTTP header (you can specify several)
  507.  
  508.     -u            Display method and URL before any response
  509.     -U            Display request headers (implies -u)
  510.     -s            Display response status code
  511.     -S            Display response status chain
  512.     -e            Display response headers
  513.     -d            Do not display content
  514.     -o <format>   Process HTML content in various ways
  515.  
  516.     -v            Show program version
  517.     -h            Print this message
  518.  
  519.     -x            Extra debugging output
  520. EOT
  521. }
  522.