home *** CD-ROM | disk | FTP | other *** search
/ Chip 2000 May / Chip_2000-05_cd1.bin / zkuste / Perl / ActivePerl-5.6.0.613.msi / 䆊䌷䈹䈙䏵-䞅䞆䞀㡆䞃䄦䠥 / _34f87e757c245ad68f1d2985f3aff0b1 < prev    next >
Text File  |  2000-03-24  |  36KB  |  1,143 lines
  1. @rem = '--*-Perl-*--
  2. @echo off
  3. if "%OS%" == "Windows_NT" goto WinNT
  4. perl -x -S "%0" %1 %2 %3 %4 %5 %6 %7 %8 %9
  5. goto endofperl
  6. :WinNT
  7. perl -x -S "%0" %*
  8. if NOT "%COMSPEC%" == "%SystemRoot%\system32\cmd.exe" goto endofperl
  9. if %errorlevel% == 9009 echo You do not have Perl in your PATH.
  10. if errorlevel 1 goto script_failed_so_exit_with_non_zero_val 2>nul
  11. goto endofperl
  12. @rem ';
  13. #!perl
  14. #line 15
  15.     eval 'exec D:\p4-view\main\Apps\Gecko\MSI\data\ActivePerl\Perl\bin\perl.exe -S $0 ${1+"$@"}'
  16.     if $running_under_some_shell;
  17.  
  18. my $config_tag1 = 'v5.6.0 - Fri Mar 24 12:36:06 2000';
  19.  
  20. my $patchlevel_date = 953765293;
  21. my $patch_tags = '+ACTIVEPERL_LOCAL_PATCHES_ENTRY ';
  22. my @patches = (
  23.     'ACTIVEPERL_LOCAL_PATCHES_ENTRY'
  24. );
  25.  
  26. use Config;
  27. use File::Spec;        # keep perlbug Perl 5.005 compatible
  28. use Getopt::Std;
  29. use strict;
  30.  
  31. sub paraprint;
  32.  
  33. BEGIN {
  34.     eval "use Mail::Send;";
  35.     $::HaveSend = ($@ eq "");
  36.     eval "use Mail::Util;";
  37.     $::HaveUtil = ($@ eq "");
  38. };
  39.  
  40. my $Version = "1.28";
  41.  
  42. # Changed in 1.06 to skip Mail::Send and Mail::Util if not available.
  43. # Changed in 1.07 to see more sendmail execs, and added pipe output.
  44. # Changed in 1.08 to use correct address for sendmail.
  45. # Changed in 1.09 to close the REP file before calling it up in the editor.
  46. #                 Also removed some old comments duplicated elsewhere.
  47. # Changed in 1.10 to run under VMS without Mail::Send; also fixed
  48. #                 temp filename generation.
  49. # Changed in 1.11 to clean up some text and removed Mail::Send deactivator.
  50. # Changed in 1.12 to check for editor errors, make save/send distinction
  51. #                 clearer and add $ENV{REPLYTO}.
  52. # Changed in 1.13 to hopefully make it more difficult to accidentally
  53. #                 send mail
  54. # Changed in 1.14 to make the prompts a little more clear on providing
  55. #                 helpful information. Also let file read fail gracefully.
  56. # Changed in 1.15 to add warnings to stop people using perlbug for non-bugs.
  57. #                 Also report selected environment variables.
  58. # Changed in 1.16 to include @INC, and allow user to re-edit if no changes.
  59. # Changed in 1.17 Win32 support added.  GSAR 97-04-12
  60. # Changed in 1.18 add '-ok' option for reporting build success. CFR 97-06-18
  61. # Changed in 1.19 '-ok' default not '-v'
  62. #                 add local patch information
  63. #                 warn on '-ok' if this is an old system; add '-okay'
  64. # Changed in 1.20 Added patchlevel.h reading and version/config checks
  65. # Changed in 1.21 Added '-nok' for reporting build failure DFD 98-05-05
  66. # Changed in 1.22 Heavy reformatting & minor bugfixes HVDS 98-05-10
  67. # Changed in 1.23 Restore -ok(ay): say 'success'; don't prompt
  68. # Changed in 1.24 Added '-F<file>' to save report HVDS 98-07-01
  69. # Changed in 1.25 Warn on failure to open save file. HVDS 98-07-12
  70. # Changed in 1.26 Don't require -t STDIN for -ok. HVDS 98-07-15
  71. # Changed in 1.27 Added Mac OS and File::Spec support CNANDOR 99-07-27
  72. # Changed in 1.28 Additional questions for Perlbugtron RFOLEY 20.03.2000
  73.  
  74. # TODO: - Allow the user to re-name the file on mail failure, and
  75. #       make sure failure (transmission-wise) of Mail::Send is
  76. #       accounted for.
  77. #       - Test -b option
  78.  
  79. my( $file, $usefile, $cc, $address, $perlbug, $testaddress, $filename,
  80.     $subject, $from, $verbose, $ed, $outfile, $Is_MacOS, $category, $severity, 
  81.     $fh, $me, $Is_MSWin32, $Is_VMS, $msg, $body, $andcc, %REP, $ok);
  82.  
  83. my $perl_version = $^V ? sprintf("v%vd", $^V) : $];
  84.  
  85. my $config_tag2 = "$perl_version - $Config{cf_time}";
  86.  
  87. Init();
  88.  
  89. if ($::opt_h) { Help(); exit; }
  90. if ($::opt_d) { Dump(*STDOUT); exit; }
  91. if (!-t STDIN && !($ok and not $::opt_n)) {
  92.     paraprint <<EOF;
  93. Please use perlbug interactively. If you want to
  94. include a file, you can use the -f switch.
  95. EOF
  96.     die "\n";
  97. }
  98. if (!-t STDOUT && !$outfile) { Dump(*STDOUT); exit; }
  99.  
  100. Query();
  101. Edit() unless $usefile || ($ok and not $::opt_n);
  102. NowWhat();
  103. Send();
  104.  
  105. exit;
  106.  
  107. sub ask_for_alternatives {
  108.     my $name = shift;
  109.     my $default = shift;
  110.     my @alts = @_;
  111.     my $alt = "";
  112.     paraprint <<EOF;
  113. Please pick a \u$name from the following:
  114.  
  115.     @alts
  116.  
  117. EOF
  118.     my $err = 0;
  119.     my $joined_alts = join('|', @alts);
  120.     do {
  121.     if ($err++ > 5) {
  122.         die "Invalid $name: aborting.\n";
  123.     }
  124.     print "Please enter a \u$name [$default]: ";
  125.     $alt = <>;
  126.     chomp $alt;
  127.     if ($alt =~ /^\s*$/) {
  128.         $alt = $default;
  129.     }
  130.     } while ($alt !~ /^($joined_alts)$/i);
  131.     lc $alt;
  132. }
  133.  
  134. sub Init {
  135.     # -------- Setup --------
  136.  
  137.     $Is_MSWin32 = $^O eq 'MSWin32';
  138.     $Is_VMS = $^O eq 'VMS';
  139.     $Is_MacOS = $^O eq 'MacOS';
  140.  
  141.     @ARGV = split m/\s+/,
  142.         MacPerl::Ask('Provide command-line args here (-h for help):')
  143.         if $Is_MacOS && $MacPerl::Version =~ /App/;
  144.  
  145.     if (!getopts("dhva:s:b:f:F:r:e:SCc:to:n:")) { Help(); exit; };
  146.  
  147.     # This comment is needed to notify metaconfig that we are
  148.     # using the $perladmin, $cf_by, and $cf_time definitions.
  149.  
  150.     # -------- Configuration ---------
  151.  
  152.     # perlbug address
  153.     $perlbug = 'perlbug@perl.com';
  154.  
  155.     # Test address
  156.     $testaddress = 'perlbug-test@perl.com';
  157.  
  158.     # Target address
  159.     $address = $::opt_a || ($::opt_t ? $testaddress : $perlbug);
  160.  
  161.     # Users address, used in message and in Reply-To header
  162.     $from = $::opt_r || "";
  163.  
  164.     # Include verbose configuration information
  165.     $verbose = $::opt_v || 0;
  166.  
  167.     # Subject of bug-report message
  168.     $subject = $::opt_s || "";
  169.  
  170.     # Send a file
  171.     $usefile = ($::opt_f || 0);
  172.  
  173.     # File to send as report
  174.     $file = $::opt_f || "";
  175.  
  176.     # File to output to
  177.     $outfile = $::opt_F || "";
  178.  
  179.     # Body of report
  180.     $body = $::opt_b || "";
  181.  
  182.     # Editor
  183.     $ed = $::opt_e || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
  184.     || ($Is_VMS && "edit/tpu")
  185.     || ($Is_MSWin32 && "notepad")
  186.     || ($Is_MacOS && '')
  187.     || "vi";
  188.  
  189.     # Not OK - provide build failure template by finessing OK report
  190.     if ($::opt_n) {
  191.     if (substr($::opt_n, 0, 2) eq 'ok' )    {
  192.         $::opt_o = substr($::opt_n, 1);
  193.     } else {
  194.         Help();
  195.         exit();
  196.     }
  197.     }
  198.  
  199.     # OK - send "OK" report for build on this system
  200.     $ok = 0;
  201.     if ($::opt_o) {
  202.     if ($::opt_o eq 'k' or $::opt_o eq 'kay') {
  203.         my $age = time - $patchlevel_date;
  204.         if ($::opt_o eq 'k' and $age > 60 * 24 * 60 * 60 ) {
  205.         my $date = localtime $patchlevel_date;
  206.         print <<"EOF";
  207. "perlbug -ok" and "perlbug -nok" do not report on Perl versions which
  208. are more than 60 days old.  This Perl version was constructed on
  209. $date.  If you really want to report this, use
  210. "perlbug -okay" or "perlbug -nokay".
  211. EOF
  212.         exit();
  213.         }
  214.         # force these options
  215.         unless ($::opt_n) {
  216.         $::opt_S = 1; # don't prompt for send
  217.         $::opt_b = 1; # we have a body
  218.         $body = "Perl reported to build OK on this system.\n";
  219.         }
  220.         $::opt_C = 1; # don't send a copy to the local admin
  221.         $::opt_s = 1; # we have a subject line
  222.         $subject = ($::opt_n ? 'Not ' : '')
  223.             . "OK: perl $perl_version ${patch_tags}on"
  224.             ." $::Config{'archname'} $::Config{'osvers'} $subject";
  225.         $category = "install";
  226.         $severity = "none";
  227.         $ok = 1;
  228.     } else {
  229.         Help();
  230.         exit();
  231.     }
  232.     }
  233.  
  234.     # Possible administrator addresses, in order of confidence
  235.     # (Note that cf_email is not mentioned to metaconfig, since
  236.     # we don't really want it. We'll just take it if we have to.)
  237.     #
  238.     # This has to be after the $ok stuff above because of the way
  239.     # that $::opt_C is forced.
  240.     $cc = $::opt_C ? "" : (
  241.     $::opt_c || $::Config{'perladmin'}
  242.     || $::Config{'cf_email'} || $::Config{'cf_by'}
  243.     );
  244.  
  245.     # My username
  246.     $me = $Is_MSWin32 ? $ENV{'USERNAME'}
  247.         : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
  248.         : $Is_MacOS ? $ENV{'USER'}
  249.         : eval { getpwuid($<) };    # May be missing
  250.  
  251.     $from = $::Config{'cf_email'}
  252.        if !$from && $::Config{'cf_email'} && $::Config{'cf_by'} && $me &&
  253.                ($me eq $::Config{'cf_by'});
  254. } # sub Init
  255.  
  256. sub Query {
  257.     # Explain what perlbug is
  258.     unless ($ok) {
  259.     paraprint <<EOF;
  260. This program provides an easy way to create a message reporting a bug
  261. in perl, and e-mail it to $address.  It is *NOT* intended for
  262. sending test messages or simply verifying that perl works, *NOR* is it
  263. intended for reporting bugs in third-party perl modules.  It is *ONLY*
  264. a means of reporting verifiable problems with the core perl distribution,
  265. and any solutions to such problems, to the people who maintain perl.
  266.  
  267. If you're just looking for help with perl, try posting to the Usenet
  268. newsgroup comp.lang.perl.misc.  If you're looking for help with using
  269. perl with CGI, try posting to comp.infosystems.www.programming.cgi.
  270. EOF
  271.     }
  272.  
  273.     # Prompt for subject of message, if needed
  274.     unless ($subject) {
  275.     paraprint <<EOF;
  276. First of all, please provide a subject for the
  277. message. It should be a concise description of
  278. the bug or problem. "perl bug" or "perl problem"
  279. is not a concise description.
  280. EOF
  281.     print "Subject: ";
  282.     $subject = <>;
  283.  
  284.     my $err = 0;
  285.     while ($subject !~ /\S/) {
  286.         print "\nPlease enter a subject: ";
  287.         $subject = <>;
  288.         if ($err++ > 5) {
  289.         die "Aborting.\n";
  290.         }
  291.     }
  292.     chop $subject;
  293.     }
  294.  
  295.     # Prompt for return address, if needed
  296.     unless ($from) {
  297.     # Try and guess return address
  298.     my $guess;
  299.  
  300.     $guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || '';
  301.         if ($Is_MacOS) {
  302.             require Mac::InternetConfig;
  303.             $guess = $Mac::InternetConfig::InternetConfig{
  304.                 Mac::InternetConfig::kICEmail()
  305.             };
  306.         }
  307.  
  308.     unless ($guess) {
  309.         my $domain;
  310.         if ($::HaveUtil) {
  311.         $domain = Mail::Util::maildomain();
  312.         } elsif ($Is_MSWin32) {
  313.         $domain = $ENV{'USERDOMAIN'};
  314.         } else {
  315.         require Sys::Hostname;
  316.         $domain = Sys::Hostname::hostname();
  317.         }
  318.         if ($domain) {
  319.         if ($Is_VMS && !$::Config{'d_socket'}) {
  320.             $guess = "$domain\:\:$me";
  321.         } else {
  322.             $guess = "$me\@$domain" if $domain;
  323.         }
  324.         }
  325.     }
  326.  
  327.     if ($guess) {
  328.         unless ($ok) {
  329.         paraprint <<EOF;
  330. Your e-mail address will be useful if you need to be contacted. If the
  331. default shown is not your full internet e-mail address, please correct it.
  332. EOF
  333.         }
  334.     } else {
  335.         paraprint <<EOF;
  336. So that you may be contacted if necessary, please enter
  337. your full internet e-mail address here.
  338. EOF
  339.     }
  340.  
  341.     if ($ok && $guess) {
  342.         # use it
  343.         $from = $guess;
  344.     } else {
  345.         # verify it
  346.         print "Your address [$guess]: ";
  347.         $from = <>;
  348.         chop $from;
  349.         $from = $guess if $from eq '';
  350.     }
  351.     }
  352.  
  353.     if ($from eq $cc or $me eq $cc) {
  354.     # Try not to copy ourselves
  355.     $cc = "yourself";
  356.     }
  357.  
  358.     # Prompt for administrator address, unless an override was given
  359.     if( !$::opt_C and !$::opt_c ) {
  360.     paraprint <<EOF;
  361. A copy of this report can be sent to your local
  362. perl administrator. If the address is wrong, please
  363. correct it, or enter 'none' or 'yourself' to not send
  364. a copy.
  365. EOF
  366.     print "Local perl administrator [$cc]: ";
  367.     my $entry = scalar <>;
  368.     chop $entry;
  369.  
  370.     if ($entry ne "") {
  371.         $cc = $entry;
  372.         $cc = '' if $me eq $cc;
  373.     }
  374.     }
  375.  
  376.     $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
  377.     $andcc = " and $cc" if $cc;
  378.  
  379.     # Prompt for editor, if no override is given
  380. editor:
  381.     unless ($::opt_e || $::opt_f || $::opt_b) {
  382.     paraprint <<EOF;
  383. Now you need to supply the bug report. Try to make
  384. the report concise but descriptive. Include any
  385. relevant detail. If you are reporting something
  386. that does not work as you think it should, please
  387. try to include example of both the actual
  388. result, and what you expected.
  389.  
  390. Some information about your local
  391. perl configuration will automatically be included
  392. at the end of the report. If you are using any
  393. unusual version of perl, please try and confirm
  394. exactly which versions are relevant.
  395.  
  396. You will probably want to use an editor to enter
  397. the report. If "$ed" is the editor you want
  398. to use, then just press Enter, otherwise type in
  399. the name of the editor you would like to use.
  400.  
  401. If you would like to use a prepared file, type
  402. "file", and you will be asked for the filename.
  403. EOF
  404.     print "Editor [$ed]: ";
  405.     my $entry =scalar <>;
  406.     chop $entry;
  407.  
  408.     $usefile = 0;
  409.     if ($entry eq "file") {
  410.         $usefile = 1;
  411.     } elsif ($entry ne "") {
  412.         $ed = $entry;
  413.     }
  414.     }
  415.  
  416.     # Prompt for category of bug
  417.     $category ||= ask_for_alternatives("category", "core",
  418.                      qw(core docs install
  419.                     library utilities));
  420.  
  421.     # Prompt for severity of bug
  422.     $severity ||= ask_for_alternatives("severity", "low",
  423.                        qw(critical high medium
  424.                       low wishlist none));
  425.  
  426.     # Generate scratch file to edit report in
  427.     $filename = filename();
  428.  
  429.     # Prompt for file to read report from, if needed
  430.     if ($usefile and !$file) {
  431. filename:
  432.     paraprint <<EOF;
  433. What is the name of the file that contains your report?
  434. EOF
  435.     print "Filename: ";
  436.     my $entry = scalar <>;
  437.     chop $entry;
  438.  
  439.     if ($entry eq "") {
  440.         paraprint <<EOF;
  441. No filename? I'll let you go back and choose an editor again.
  442. EOF
  443.         goto editor;
  444.     }
  445.  
  446.     unless (-f $entry and -r $entry) {
  447.         paraprint <<EOF;
  448. I'm sorry, but I can't read from `$entry'. Maybe you mistyped the name of
  449. the file? If you don't want to send a file, just enter a blank line and you
  450. can get back to the editor selection.
  451. EOF
  452.         goto filename;
  453.     }
  454.     $file = $entry;
  455.     }
  456.  
  457.     # Generate report
  458.     open(REP,">$filename");
  459.     my $reptype = !$ok ? "bug" : $::opt_n ? "build failure" : "success";
  460.  
  461.     print REP <<EOF;
  462. This is a $reptype report for perl from $from,
  463. generated with the help of perlbug $Version running under perl $perl_version.
  464.  
  465. EOF
  466.  
  467.     if ($body) {
  468.     print REP $body;
  469.     } elsif ($usefile) {
  470.     open(F, "<$file")
  471.         or die "Unable to read report file from `$file': $!\n";
  472.     while (<F>) {
  473.         print REP $_
  474.     }
  475.     close(F);
  476.     } else {
  477.     print REP <<EOF;
  478.  
  479. -----------------------------------------------------------------
  480. [Please enter your report here]
  481.  
  482.  
  483.  
  484. [Please do not change anything below this line]
  485. -----------------------------------------------------------------
  486. EOF
  487.     }
  488.     Dump(*REP);
  489.     close(REP);
  490.  
  491.     # read in the report template once so that
  492.     # we can track whether the user does any editing.
  493.     # yes, *all* whitespace is ignored.
  494.     open(REP, "<$filename");
  495.     while (<REP>) {
  496.     s/\s+//g;
  497.     $REP{$_}++;
  498.     }
  499.     close(REP);
  500. } # sub Query
  501.  
  502. sub Dump {
  503.     local(*OUT) = @_;
  504.  
  505.     print OUT <<EFF;
  506. ---
  507. Flags:
  508.     category=$category
  509.     severity=$severity
  510. ---
  511. EFF
  512.     print OUT "This perlbug was built using Perl $config_tag1\n",
  513.         "It is being executed now by  Perl $config_tag2.\n\n"
  514.     if $config_tag2 ne $config_tag1;
  515.  
  516.     print OUT <<EOF;
  517. Site configuration information for perl $perl_version:
  518.  
  519. EOF
  520.     if ($::Config{cf_by} and $::Config{cf_time}) {
  521.     print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
  522.     }
  523.     print OUT Config::myconfig;
  524.  
  525.     if (@patches) {
  526.     print OUT join "\n    ", "Locally applied patches:", @patches;
  527.     print OUT "\n";
  528.     };
  529.  
  530.     print OUT <<EOF;
  531.  
  532. ---
  533. \@INC for perl $perl_version:
  534. EOF
  535.     for my $i (@INC) {
  536.     print OUT "    $i\n";
  537.     }
  538.  
  539.     print OUT <<EOF;
  540.  
  541. ---
  542. Environment for perl $perl_version:
  543. EOF
  544.     my @env =
  545.         qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
  546.     push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
  547.     push @env, grep /^(?:PERL|LC_|LANG)/, keys %ENV;
  548.     my %env;
  549.     @env{@env} = @env;
  550.     for my $env (sort keys %env) {
  551.     print OUT "    $env",
  552.         exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
  553.         "\n";
  554.     }
  555.     if ($verbose) {
  556.     print OUT "\nComplete configuration data for perl $perl_version:\n\n";
  557.     my $value;
  558.     foreach (sort keys %::Config) {
  559.         $value = $::Config{$_};
  560.         $value =~ s/'/\\'/g;
  561.         print OUT "$_='$value'\n";
  562.     }
  563.     }
  564. } # sub Dump
  565.  
  566. sub Edit {
  567.     # Edit the report
  568.     if ($usefile || $body) {
  569.     paraprint <<EOF;
  570. Please make sure that the name of the editor you want to use is correct.
  571. EOF
  572.     print "Editor [$ed]: ";
  573.     my $entry =scalar <>;
  574.     chop $entry;
  575.     $ed = $entry unless $entry eq '';
  576.     }
  577.  
  578. tryagain:
  579.     my $sts = system("$ed $filename") unless $Is_MacOS;
  580.     if ($Is_MacOS) {
  581.         require ExtUtils::MakeMaker;
  582.         ExtUtils::MM_MacOS::launch_file($filename);
  583.         paraprint <<EOF;
  584. Press Enter when done.
  585. EOF
  586.         scalar <>;
  587.     }
  588.     if ($sts) {
  589.     paraprint <<EOF;
  590. The editor you chose (`$ed') could apparently not be run!
  591. Did you mistype the name of your editor? If so, please
  592. correct it here, otherwise just press Enter.
  593. EOF
  594.     print "Editor [$ed]: ";
  595.     my $entry =scalar <>;
  596.     chop $entry;
  597.  
  598.     if ($entry ne "") {
  599.         $ed = $entry;
  600.         goto tryagain;
  601.     } else {
  602.         paraprint <<EOF;
  603. You may want to save your report to a file, so you can edit and mail it
  604. yourself.
  605. EOF
  606.     }
  607.     }
  608.  
  609.     return if ($ok and not $::opt_n) || $body;
  610.     # Check that we have a report that has some, eh, report in it.
  611.     my $unseen = 0;
  612.  
  613.     open(REP, "<$filename");
  614.     # a strange way to check whether any significant editing
  615.     # have been done: check whether any new non-empty lines
  616.     # have been added. Yes, the below code ignores *any* space
  617.     # in *any* line.
  618.     while (<REP>) {
  619.     s/\s+//g;
  620.     $unseen++ if $_ ne '' and not exists $REP{$_};
  621.     }
  622.  
  623.     while ($unseen == 0) {
  624.     paraprint <<EOF;
  625. I am sorry but it looks like you did not report anything.
  626. EOF
  627.     print "Action (Retry Edit/Cancel) ";
  628.     my ($action) = scalar(<>);
  629.     if ($action =~ /^[re]/i) { # <R>etry <E>dit
  630.         goto tryagain;
  631.     } elsif ($action =~ /^[cq]/i) { # <C>ancel, <Q>uit
  632.         Cancel();
  633.     }
  634.     }
  635. } # sub Edit
  636.  
  637. sub Cancel {
  638.     1 while unlink($filename);  # remove all versions under VMS
  639.     print "\nCancelling.\n";
  640.     exit(0);
  641. }
  642.  
  643. sub NowWhat {
  644.     # Report is done, prompt for further action
  645.     if( !$::opt_S ) {
  646.     while(1) {
  647.         paraprint <<EOF;
  648. Now that you have completed your report, would you like to send
  649. the message to $address$andcc, display the message on
  650. the screen, re-edit it, or cancel without sending anything?
  651. You may also save the message as a file to mail at another time.
  652. EOF
  653.       retry:
  654.         print "Action (Send/Display/Edit/Cancel/Save to File): ";
  655.         my $action = scalar <>;
  656.         chop $action;
  657.  
  658.         if ($action =~ /^(f|sa)/i) { # <F>ile/<Sa>ve
  659.         print "\n\nName of file to save message in [perlbug.rep]: ";
  660.         my $file = scalar <>;
  661.         chop $file;
  662.         $file = "perlbug.rep" if $file eq "";
  663.  
  664.         unless (open(FILE, ">$file")) {
  665.             print "\nError opening $file: $!\n\n";
  666.             goto retry;
  667.         }
  668.         open(REP, "<$filename");
  669.         print FILE "To: $address\nSubject: $subject\n";
  670.         print FILE "Cc: $cc\n" if $cc;
  671.         print FILE "Reply-To: $from\n" if $from;
  672.         print FILE "\n";
  673.         while (<REP>) { print FILE }
  674.         close(REP);
  675.         close(FILE);
  676.  
  677.         print "\nMessage saved in `$file'.\n";
  678.         exit;
  679.         } elsif ($action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
  680.         # Display the message
  681.         open(REP, "<$filename");
  682.         while (<REP>) { print $_ }
  683.         close(REP);
  684.         } elsif ($action =~ /^se/i) { # <S>end
  685.         # Send the message
  686.         print "Are you certain you want to send this message?\n"
  687.             . 'Please type "yes" if you are: ';
  688.         my $reply = scalar <STDIN>;
  689.         chop $reply;
  690.         if ($reply eq "yes") {
  691.             last;
  692.         } else {
  693.             paraprint <<EOF;
  694. That wasn't a clear "yes", so I won't send your message. If you are sure
  695. your message should be sent, type in "yes" (without the quotes) at the
  696. confirmation prompt.
  697. EOF
  698.         }
  699.         } elsif ($action =~ /^[er]/i) { # <E>dit, <R>e-edit
  700.         # edit the message
  701.         Edit();
  702.         } elsif ($action =~ /^[qc]/i) { # <C>ancel, <Q>uit
  703.         Cancel();
  704.         } elsif ($action =~ /^s/) {
  705.         paraprint <<EOF;
  706. I'm sorry, but I didn't understand that. Please type "send" or "save".
  707. EOF
  708.         }
  709.     }
  710.     }
  711. } # sub NowWhat
  712.  
  713. sub Send {
  714.     # Message has been accepted for transmission -- Send the message
  715.     if ($outfile) {
  716.     open SENDMAIL, ">$outfile" or die "Couldn't open '$outfile': $!\n";
  717.     goto sendout;
  718.     }
  719.     if ($::HaveSend) {
  720.     $msg = new Mail::Send Subject => $subject, To => $address;
  721.     $msg->cc($cc) if $cc;
  722.     $msg->add("Reply-To",$from) if $from;
  723.  
  724.     $fh = $msg->open;
  725.     open(REP, "<$filename");
  726.     while (<REP>) { print $fh $_ }
  727.     close(REP);
  728.     $fh->close;
  729.  
  730.     print "\nMessage sent.\n";
  731.     } elsif ($Is_VMS) {
  732.     if ( ($address =~ /@/ and $address !~ /^\w+%"/) or
  733.          ($cc      =~ /@/ and $cc      !~ /^\w+%"/) ) {
  734.         my $prefix;
  735.         foreach (qw[ IN MX SMTP UCX PONY WINS ], '') {
  736.         $prefix = "$_%", last if $ENV{"MAIL\$PROTOCOL_$_"};
  737.         }
  738.         $address = qq[${prefix}"$address"] unless $address =~ /^\w+%"/;
  739.         $cc = qq[${prefix}"$cc"] unless !$cc || $cc =~ /^\w+%"/;
  740.     }
  741.     $subject =~ s/"/""/g; $address =~ s/"/""/g; $cc =~ s/"/""/g;
  742.     my $sts = system(qq[mail/Subject="$subject" $filename. "$address","$cc"]);
  743.     if ($sts) {
  744.         die <<EOF;
  745. Can't spawn off mail
  746.     (leaving bug report in $filename): $sts
  747. EOF
  748.     }
  749.     } else {
  750.     my $sendmail = "";
  751.     for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
  752.         $sendmail = $_, last if -e $_;
  753.     }
  754.     if ($^O eq 'os2' and $sendmail eq "") {
  755.         my $path = $ENV{PATH};
  756.         $path =~ s:\\:/: ;
  757.         my @path = split /$Config{'path_sep'}/, $path;
  758.         for (@path) {
  759.         $sendmail = "$_/sendmail", last if -e "$_/sendmail";
  760.         $sendmail = "$_/sendmail.exe", last if -e "$_/sendmail.exe";
  761.         }
  762.     }
  763.  
  764.     paraprint(<<"EOF"), die "\n" if $sendmail eq "";
  765. I am terribly sorry, but I cannot find sendmail, or a close equivalent, and
  766. the perl package Mail::Send has not been installed, so I can't send your bug
  767. report. We apologize for the inconvenience.
  768.  
  769. So you may attempt to find some way of sending your message, it has
  770. been left in the file `$filename'.
  771. EOF
  772.     open(SENDMAIL, "|$sendmail -t") || die "'|$sendmail -t' failed: $!";
  773. sendout:
  774.     print SENDMAIL "To: $address\n";
  775.     print SENDMAIL "Subject: $subject\n";
  776.     print SENDMAIL "Cc: $cc\n" if $cc;
  777.     print SENDMAIL "Reply-To: $from\n" if $from;
  778.     print SENDMAIL "\n\n";
  779.     open(REP, "<$filename");
  780.     while (<REP>) { print SENDMAIL $_ }
  781.     close(REP);
  782.  
  783.     if (close(SENDMAIL)) {
  784.         printf "\nMessage %s.\n", $outfile ? "saved" : "sent";
  785.     } else {
  786.         warn "\nSendmail returned status '", $? >> 8, "'\n";
  787.     }
  788.     }
  789.     1 while unlink($filename);  # remove all versions under VMS
  790. } # sub Send
  791.  
  792. sub Help {
  793.     print <<EOF;
  794.  
  795. A program to help generate bug reports about perl5, and mail them.
  796. It is designed to be used interactively. Normally no arguments will
  797. be needed.
  798.  
  799. Usage:
  800. $0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
  801.     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
  802. $0  [-v] [-r returnaddress] [-ok | -okay | -nok | -nokay]
  803.  
  804. Simplest usage:  run "$0", and follow the prompts.
  805.  
  806. Options:
  807.  
  808.   -v    Include Verbose configuration data in the report
  809.   -f    File containing the body of the report. Use this to
  810.         quickly send a prepared message.
  811.   -F    File to output the resulting mail message to, instead of mailing.
  812.   -S    Send without asking for confirmation.
  813.   -a    Address to send the report to. Defaults to `$address'.
  814.   -c    Address to send copy of report to. Defaults to `$cc'.
  815.   -C    Don't send copy to administrator.
  816.   -s    Subject to include with the message. You will be prompted
  817.         if you don't supply one on the command line.
  818.   -b    Body of the report. If not included on the command line, or
  819.         in a file with -f, you will get a chance to edit the message.
  820.   -r    Your return address. The program will ask you to confirm
  821.         this if you don't give it here.
  822.   -e    Editor to use.
  823.   -t    Test mode. The target address defaults to `$testaddress'.
  824.   -d    Data mode (the default if you redirect or pipe output.)
  825.         This prints out your configuration data, without mailing
  826.         anything. You can use this with -v to get more complete data.
  827.   -ok   Report successful build on this system to perl porters
  828.         (use alone or with -v). Only use -ok if *everything* was ok:
  829.         if there were *any* problems at all, use -nok.
  830.   -okay As -ok but allow report from old builds.
  831.   -nok  Report unsuccessful build on this system to perl porters
  832.         (use alone or with -v). You must describe what went wrong
  833.         in the body of the report which you will be asked to edit.
  834.   -nokay As -nok but allow report from old builds.
  835.   -h    Print this help message.
  836.  
  837. EOF
  838. }
  839.  
  840. sub filename {
  841.     my $dir = $Is_VMS ? 'sys$scratch:'
  842.     : ($Is_MSWin32 && $ENV{'TEMP'}) ? $ENV{'TEMP'}
  843.         : $Is_MacOS ? $ENV{'TMPDIR'}
  844.     : '/tmp';
  845.     $filename = "bugrep0$$";
  846. #    $dir .= "\\" if $Is_MSWin32 and $dir !~ m|[\\/]$|;
  847.     $filename++ while -e File::Spec->catfile($dir, $filename);
  848.     $filename = File::Spec->catfile($dir, $filename);
  849. }
  850.  
  851. sub paraprint {
  852.     my @paragraphs = split /\n{2,}/, "@_";
  853.     print "\n\n";
  854.     for (@paragraphs) {   # implicit local $_
  855.     s/(\S)\s*\n/$1 /g;
  856.     write;
  857.     print "\n";
  858.     }
  859. }
  860.  
  861. format STDOUT =
  862. ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
  863. $_
  864. .
  865.  
  866. __END__
  867.  
  868. =head1 NAME
  869.  
  870. perlbug - how to submit bug reports on Perl
  871.  
  872. =head1 SYNOPSIS
  873.  
  874. B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
  875. S<[ B<-b> I<body> | B<-f> I<inputfile> ]> S<[ B<-F> I<outputfile> ]>
  876. S<[ B<-r> I<returnaddress> ]>
  877. S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
  878. S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-h> ]>
  879.  
  880. B<perlbug> S<[ B<-v> ]> S<[ B<-r> I<returnaddress> ]>
  881. S<[ B<-ok> | B<-okay> | B<-nok> | B<-nokay> ]>
  882.  
  883. =head1 DESCRIPTION
  884.  
  885. A program to help generate bug reports about perl or the modules that
  886. come with it, and mail them.
  887.  
  888. If you have found a bug with a non-standard port (one that was not part
  889. of the I<standard distribution>), a binary distribution, or a
  890. non-standard module (such as Tk, CGI, etc), then please see the
  891. documentation that came with that distribution to determine the correct
  892. place to report bugs.
  893.  
  894. C<perlbug> is designed to be used interactively. Normally no arguments
  895. will be needed.  Simply run it, and follow the prompts.
  896.  
  897. If you are unable to run B<perlbug> (most likely because you don't have
  898. a working setup to send mail that perlbug recognizes), you may have to
  899. compose your own report, and email it to B<perlbug@perl.com>.  You might
  900. find the B<-d> option useful to get summary information in that case.
  901.  
  902. In any case, when reporting a bug, please make sure you have run through
  903. this checklist:
  904.  
  905. =over 4
  906.  
  907. =item What version of Perl you are running?
  908.  
  909. Type C<perl -v> at the command line to find out.
  910.  
  911. =item Are you running the latest released version of perl?
  912.  
  913. Look at http://www.perl.com/ to find out.  If it is not the latest
  914. released version, get that one and see whether your bug has been
  915. fixed.  Note that bug reports about old versions of Perl, especially
  916. those prior to the 5.0 release, are likely to fall upon deaf ears.
  917. You are on your own if you continue to use perl1 .. perl4.
  918.  
  919. =item Are you sure what you have is a bug?
  920.  
  921. A significant number of the bug reports we get turn out to be documented
  922. features in Perl.  Make sure the behavior you are witnessing doesn't fall
  923. under that category, by glancing through the documentation that comes
  924. with Perl (we'll admit this is no mean task, given the sheer volume of
  925. it all, but at least have a look at the sections that I<seem> relevant).
  926.  
  927. Be aware of the familiar traps that perl programmers of various hues
  928. fall into.  See L<perltrap>.
  929.  
  930. Check in L<perldiag> to see what any Perl error message(s) mean.
  931. If message isn't in perldiag, it probably isn't generated by Perl.
  932. Consult your operating system documentation instead.
  933.  
  934. If you are on a non-UNIX platform check also L<perlport>, as some
  935. features may be unimplemented or work differently.
  936.  
  937. Try to study the problem under the Perl debugger, if necessary.
  938. See L<perldebug>.
  939.  
  940. =item Do you have a proper test case?
  941.  
  942. The easier it is to reproduce your bug, the more likely it will be
  943. fixed, because if no one can duplicate the problem, no one can fix it.
  944. A good test case has most of these attributes: fewest possible number
  945. of lines; few dependencies on external commands, modules, or
  946. libraries; runs on most platforms unimpeded; and is self-documenting.
  947.  
  948. A good test case is almost always a good candidate to be on the perl
  949. test suite.  If you have the time, consider making your test case so
  950. that it will readily fit into the standard test suite.
  951.  
  952. Remember also to include the B<exact> error messages, if any.
  953. "Perl complained something" is not an exact error message.
  954.  
  955. If you get a core dump (or equivalent), you may use a debugger
  956. (B<dbx>, B<gdb>, etc) to produce a stack trace to include in the bug
  957. report.  NOTE: unless your Perl has been compiled with debug info
  958. (often B<-g>), the stack trace is likely to be somewhat hard to use
  959. because it will most probably contain only the function names and not
  960. their arguments.  If possible, recompile your Perl with debug info and
  961. reproduce the dump and the stack trace.
  962.  
  963. =item Can you describe the bug in plain English?
  964.  
  965. The easier it is to understand a reproducible bug, the more likely it
  966. will be fixed.  Anything you can provide by way of insight into the
  967. problem helps a great deal.  In other words, try to analyze the
  968. problem (to the extent you can) and report your discoveries.
  969.  
  970. =item Can you fix the bug yourself?
  971.  
  972. A bug report which I<includes a patch to fix it> will almost
  973. definitely be fixed.  Use the C<diff> program to generate your patches
  974. (C<diff> is being maintained by the GNU folks as part of the B<diffutils>
  975. package, so you should be able to get it from any of the GNU software
  976. repositories).  If you do submit a patch, the cool-dude counter at
  977. perlbug@perl.com will register you as a savior of the world.  Your
  978. patch may be returned with requests for changes, or requests for more
  979. detailed explanations about your fix.
  980.  
  981. Here are some clues for creating quality patches: Use the B<-c> or
  982. B<-u> switches to the diff program (to create a so-called context or
  983. unified diff).  Make sure the patch is not reversed (the first
  984. argument to diff is typically the original file, the second argument
  985. your changed file).  Make sure you test your patch by applying it with
  986. the C<patch> program before you send it on its way.  Try to follow the
  987. same style as the code you are trying to patch.  Make sure your patch
  988. really does work (C<make test>, if the thing you're patching supports
  989. it).
  990.  
  991. =item Can you use C<perlbug> to submit the report?
  992.  
  993. B<perlbug> will, amongst other things, ensure your report includes
  994. crucial information about your version of perl.  If C<perlbug> is unable
  995. to mail your report after you have typed it in, you may have to compose
  996. the message yourself, add the output produced by C<perlbug -d> and email
  997. it to B<perlbug@perl.com>.  If, for some reason, you cannot run
  998. C<perlbug> at all on your system, be sure to include the entire output
  999. produced by running C<perl -V> (note the uppercase V).
  1000.  
  1001. Whether you use C<perlbug> or send the email manually, please make
  1002. your Subject line informative.  "a bug" not informative.  Neither is
  1003. "perl crashes" nor "HELP!!!".  These don't help.
  1004. A compact description of what's wrong is fine.
  1005.  
  1006. =back
  1007.  
  1008. Having done your bit, please be prepared to wait, to be told the bug
  1009. is in your code, or even to get no reply at all.  The Perl maintainers
  1010. are busy folks, so if your problem is a small one or if it is difficult
  1011. to understand or already known, they may not respond with a personal reply.
  1012. If it is important to you that your bug be fixed, do monitor the
  1013. C<Changes> file in any development releases since the time you submitted
  1014. the bug, and encourage the maintainers with kind words (but never any
  1015. flames!).  Feel free to resend your bug report if the next released
  1016. version of perl comes out and your bug is still present.
  1017.  
  1018. =head1 OPTIONS
  1019.  
  1020. =over 8
  1021.  
  1022. =item B<-a>
  1023.  
  1024. Address to send the report to.  Defaults to `perlbug@perl.com'.
  1025.  
  1026. =item B<-b>
  1027.  
  1028. Body of the report.  If not included on the command line, or
  1029. in a file with B<-f>, you will get a chance to edit the message.
  1030.  
  1031. =item B<-C>
  1032.  
  1033. Don't send copy to administrator.
  1034.  
  1035. =item B<-c>
  1036.  
  1037. Address to send copy of report to.  Defaults to the address of the
  1038. local perl administrator (recorded when perl was built).
  1039.  
  1040. =item B<-d>
  1041.  
  1042. Data mode (the default if you redirect or pipe output).  This prints out
  1043. your configuration data, without mailing anything.  You can use this
  1044. with B<-v> to get more complete data.
  1045.  
  1046. =item B<-e>
  1047.  
  1048. Editor to use.
  1049.  
  1050. =item B<-f>
  1051.  
  1052. File containing the body of the report.  Use this to quickly send a
  1053. prepared message.
  1054.  
  1055. =item B<-F>
  1056.  
  1057. File to output the results to instead of sending as an email. Useful
  1058. particularly when running perlbug on a machine with no direct internet
  1059. connection.
  1060.  
  1061. =item B<-h>
  1062.  
  1063. Prints a brief summary of the options.
  1064.  
  1065. =item B<-ok>
  1066.  
  1067. Report successful build on this system to perl porters. Forces B<-S>
  1068. and B<-C>. Forces and supplies values for B<-s> and B<-b>. Only
  1069. prompts for a return address if it cannot guess it (for use with
  1070. B<make>). Honors return address specified with B<-r>.  You can use this
  1071. with B<-v> to get more complete data.   Only makes a report if this
  1072. system is less than 60 days old.
  1073.  
  1074. =item B<-okay>
  1075.  
  1076. As B<-ok> except it will report on older systems.
  1077.  
  1078. =item B<-nok>
  1079.  
  1080. Report unsuccessful build on this system.  Forces B<-C>.  Forces and
  1081. supplies a value for B<-s>, then requires you to edit the report
  1082. and say what went wrong.  Alternatively, a prepared report may be
  1083. supplied using B<-f>.  Only prompts for a return address if it
  1084. cannot guess it (for use with B<make>). Honors return address
  1085. specified with B<-r>.  You can use this with B<-v> to get more
  1086. complete data.  Only makes a report if this system is less than 60
  1087. days old.
  1088.  
  1089. =item B<-nokay>
  1090.  
  1091. As B<-nok> except it will report on older systems.
  1092.  
  1093. =item B<-r>
  1094.  
  1095. Your return address.  The program will ask you to confirm its default
  1096. if you don't use this option.
  1097.  
  1098. =item B<-S>
  1099.  
  1100. Send without asking for confirmation.
  1101.  
  1102. =item B<-s>
  1103.  
  1104. Subject to include with the message.  You will be prompted if you don't
  1105. supply one on the command line.
  1106.  
  1107. =item B<-t>
  1108.  
  1109. Test mode.  The target address defaults to `perlbug-test@perl.com'.
  1110.  
  1111. =item B<-v>
  1112.  
  1113. Include verbose configuration data in the report.
  1114.  
  1115. =back
  1116.  
  1117. =head1 AUTHORS
  1118.  
  1119. Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently I<doc>tored
  1120. by Gurusamy Sarathy (E<lt>gsar@activestate.comE<gt>), Tom Christiansen
  1121. (E<lt>tchrist@perl.comE<gt>), Nathan Torkington (E<lt>gnat@frii.comE<gt>),
  1122. Charles F. Randall (E<lt>cfr@pobox.comE<gt>), Mike Guy
  1123. (E<lt>mjtg@cam.a.ukE<gt>), Dominic Dunlop (E<lt>domo@computer.orgE<gt>),
  1124. Hugo van der Sanden (E<lt>hv@crypt0.demon.co.ukE<gt>),
  1125. Jarkko Hietaniemi (E<lt>jhi@iki.fiE<gt>), Chris Nandor
  1126. (E<lt>pudge@pobox.comE<gt>), Jon Orwant (E<lt>orwant@media.mit.eduE<gt>,
  1127. and Richard Foley (E<lt>richard@rfi.netE<gt>).
  1128.  
  1129. =head1 SEE ALSO
  1130.  
  1131. perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
  1132. diff(1), patch(1), dbx(1), gdb(1)
  1133.  
  1134. =head1 BUGS
  1135.  
  1136. None known (guess what must have been used to report them?)
  1137.  
  1138. =cut
  1139.  
  1140.  
  1141. __END__
  1142. :endofperl
  1143.