home *** CD-ROM | disk | FTP | other *** search
/ Chip 2000 May / Chip_2000-05_cd1.bin / zkuste / Perl / ActivePerl-5.6.0.613.msi / 䆊䌷䈹䈙䏵-䞅䞆䞀㡆䞃䄦䠥 / _2c892b5237681f980ac52e33dacc8d9b < prev    next >
Text File  |  2000-03-15  |  9KB  |  282 lines
  1. =head1 NAME
  2.  
  3. lwpcook - libwww-perl cookbook
  4.  
  5. =head1 DESCRIPTION
  6.  
  7. This document contain some examples that show typical usage of the
  8. libwww-perl library.  You should consult the documentation for the
  9. individual modules for more detail.
  10.  
  11. All examples should be runnable programs. You can, in most cases, test
  12. the code sections by piping the program text directly to perl.
  13.  
  14.  
  15.  
  16. =head1 GET
  17.  
  18. It is very easy to use this library to just fetch documents from the
  19. net.  The LWP::Simple module provides the get() function that return
  20. the document specified by its URL argument:
  21.  
  22.   use LWP::Simple;
  23.   $doc = get 'http://www.sn.no/libwww-perl/';
  24.  
  25. or, as a perl one-liner using the getprint() function:
  26.  
  27.   perl -MLWP::Simple -e 'getprint "http://www.sn.no/libwww-perl/"'
  28.  
  29. or, how about fetching the latest perl by running this command:
  30.  
  31.   perl -MLWP::Simple -e '
  32.     getstore "ftp://ftp.sunet.se/pub/lang/perl/CPAN/src/latest.tar.gz",
  33.              "perl.tar.gz"'
  34.  
  35. You will probably first want to find a CPAN site closer to you by
  36. running something like the following command:
  37.  
  38.   perl -MLWP::Simple -e 'getprint "http://www.perl.com/perl/CPAN/CPAN.html"'
  39.  
  40. Enough of this simple stuff!  The LWP object oriented interface gives
  41. you more control over the request sent to the server.  Using this
  42. interface you have full control over headers sent and how you want to
  43. handle the response returned.
  44.  
  45.   use LWP::UserAgent;
  46.   $ua = new LWP::UserAgent;
  47.   $ua->agent("$0/0.1 " . $ua->agent);
  48.   # $ua->agent("Mozilla/8.0") # pretend we are very capable browser
  49.  
  50.   $req = new HTTP::Request 'GET' => 'http://www.sn.no/libwww-perl';
  51.   $req->header('Accept' => 'text/html');
  52.  
  53.   # send request
  54.   $res = $ua->request($req);
  55.  
  56.   # check the outcome
  57.   if ($res->is_success) {
  58.      print $res->content;
  59.   } else {
  60.      print "Error: " . $res->status_line . "\n";
  61.   }
  62.  
  63. The lwp-request program (alias GET) that is distributed with the
  64. library can also be used to fetch documents from WWW servers.
  65.   
  66.  
  67.  
  68. =head1 HEAD
  69.  
  70. If you just want to check if a document is present (i.e. the URL is
  71. valid) try to run code that looks like this:
  72.  
  73.   use LWP::Simple;
  74.  
  75.   if (head($url)) {
  76.      # ok document exists
  77.   }
  78.  
  79. The head() function really returns a list of meta-information about
  80. the document.  The first three values of the list returned are the
  81. document type, the size of the document, and the age of the document.
  82.  
  83. More control over the request or access to all header values returned
  84. require that you use the object oriented interface described for GET
  85. above.  Just s/GET/HEAD/g.
  86.  
  87.  
  88. =head1 POST
  89.  
  90. There is no simple procedural interface for posting data to a WWW server.  You
  91. must use the object oriented interface for this. The most common POST
  92. operation is to access a WWW form application:
  93.  
  94.   use LWP::UserAgent;
  95.   $ua = new LWP::UserAgent;
  96.  
  97.   my $req = new HTTP::Request 'POST','http://www.perl.com/cgi-bin/BugGlimpse';
  98.   $req->content_type('application/x-www-form-urlencoded');
  99.   $req->content('match=www&errors=0');
  100.  
  101.   my $res = $ua->request($req);
  102.   print $res->as_string;
  103.  
  104. Lazy people use the HTTP::Request::Common module to set up a suitable
  105. POST request message (it handles all the escaping issues) and has a
  106. suitable default for the content_type:
  107.  
  108.   use HTTP::Request::Common qw(POST);
  109.   use LWP::UserAgent;
  110.   $ua = new LWP::UserAgent;
  111.  
  112.   my $req = POST 'http://www.perl.com/cgi-bin/BugGlimpse',
  113.                 [ search => 'www', errors => 0 ];
  114.  
  115.   print $ua->request($req)->as_string;
  116.  
  117. The lwp-request program (alias POST) that is distributed with the
  118. library can also be used for posting data.
  119.  
  120.  
  121.  
  122. =head1 PROXIES
  123.  
  124. Some sites use proxies to go through fire wall machines, or just as
  125. cache in order to improve performance.  Proxies can also be used for
  126. accessing resources through protocols not supported directly (or
  127. supported badly :-) by the libwww-perl library.
  128.  
  129. You should initialize your proxy setting before you start sending
  130. requests:
  131.  
  132.   use LWP::UserAgent;
  133.   $ua = new LWP::UserAgent;
  134.   $ua->env_proxy; # initialize from environment variables
  135.   # or
  136.   $ua->proxy(ftp  => 'http://proxy.myorg.com');
  137.   $ua->proxy(wais => 'http://proxy.myorg.com');
  138.   $ua->no_proxy(qw(no se fi));
  139.  
  140.   my $req = HTTP::Request->new(GET => 'wais://xxx.com/');
  141.   print $ua->request($req)->as_string;
  142.  
  143. The LWP::Simple interface will call env_proxy() for you automatically.
  144. Applications that use the $ua->env_proxy() method will normally not
  145. use the $ua->proxy() and $ua->no_proxy() methods.
  146.  
  147. Some proxies also require that you send it a username/password in
  148. order to let requests through.  You should be able to add the
  149. required header, with something like this:
  150.  
  151.  use LWP::UserAgent;
  152.  
  153.  $ua = new LWP::UserAgent;
  154.  $ua->proxy(['http', 'ftp'] => 'http://proxy.myorg.com');
  155.  
  156.  $req = new HTTP::Request 'GET',"http://www.perl.com";
  157.  $req->proxy_authorization_basic("proxy_user", "proxy_password");
  158.  
  159.  $res = $ua->request($req);
  160.  print $res->content if $res->is_success;
  161.  
  162. Replace C<proxy.myorg.com>, C<proxy_user> and
  163. C<proxy_password> with something suitable for your site.
  164.  
  165.  
  166. =head1 ACCESS TO PROTECTED DOCUMENTS
  167.  
  168. Documents protected by basic authorization can easily be accessed
  169. like this:
  170.  
  171.   use LWP::UserAgent;
  172.   $ua = new LWP::UserAgent;
  173.   $req = new HTTP::Request GET => 'http://www.sn.no/secret/';
  174.   $req->authorization_basic('aas', 'mypassword');
  175.   print $ua->request($req)->as_string;
  176.  
  177. The other alternative is to provide a subclass of I<LWP::UserAgent> that
  178. overrides the get_basic_credentials() method. Study the I<lwp-request>
  179. program for an example of this.
  180.  
  181. =head1 HTTPS
  182.  
  183. URLs with https scheme are accessed in exactly the same way as with
  184. http scheme, provided that an SSL interface module for LWP has been
  185. properly installed (see the F<README.SSL> file found in the
  186. libwww-perl distribution for more details).  If no SSL interface is
  187. installed for LWP to use, then you will get "501 Protocol scheme
  188. 'https' is not supported" errors when accessing such URLs.
  189.  
  190. Here's an example of fetching and printing a WWW page using SSL:
  191.  
  192.   use LWP::UserAgent;
  193.  
  194.   my $ua = LWP::UserAgent->new;
  195.   my $req = HTTP::Request->new(GET => 'https://www.helsinki.fi/');
  196.   my $res = $ua->request($req);
  197.   if ($res->is_success) {
  198.       print $res->as_string;
  199.   } else {
  200.       print "Failed: ", $res->status_line, "\n";
  201.   }
  202.  
  203. =head1 MIRRORING
  204.  
  205. If you want to mirror documents from a WWW server, then try to run
  206. code similar to this at regular intervals:
  207.  
  208.   use LWP::Simple;
  209.  
  210.   %mirrors = (
  211.      'http://www.sn.no/'             => 'sn.html',
  212.      'http://www.perl.com/'          => 'perl.html',
  213.      'http://www.sn.no/libwww-perl/' => 'lwp.html',
  214.      'gopher://gopher.sn.no/'        => 'gopher.html',
  215.   );
  216.  
  217.   while (($url, $localfile) = each(%mirrors)) {
  218.      mirror($url, $localfile);
  219.   }
  220.  
  221. Or, as a perl one-liner:
  222.  
  223.   perl -MLWP::Simple -e 'mirror("http://www.perl.com/", "perl.html")';
  224.  
  225. The document will not be transfered unless it has been updated.
  226.  
  227.  
  228.  
  229. =head1 LARGE DOCUMENTS
  230.  
  231. If the document you want to fetch is too large to be kept in memory,
  232. then you have two alternatives.  You can instruct the library to write
  233. the document content to a file (second $ua->request() argument is a file
  234. name):
  235.  
  236.   use LWP::UserAgent;
  237.   $ua = new LWP::UserAgent;
  238.  
  239.   my $req = new HTTP::Request 'GET',
  240.                 'http://www.sn.no/~aas/perl/www/libwww-perl-5.00.tar.gz';
  241.   $res = $ua->request($req, "libwww-perl.tar.gz");
  242.   if ($res->is_success) {
  243.      print "ok\n";
  244.   }
  245.  
  246. Or you can process the document as it arrives (second $ua->request()
  247. argument is a code reference):
  248.  
  249.   use LWP::UserAgent;
  250.   $ua = new LWP::UserAgent;
  251.   $URL = 'ftp://ftp.unit.no/pub/rfc/rfc-index.txt';
  252.  
  253.   my $expected_length;
  254.   my $bytes_received = 0;
  255.   $ua->request(HTTP::Request->new('GET', $URL),
  256.                sub {
  257.                    my($chunk, $res) = @_;
  258.                    $bytes_received += length($chunk);
  259.                unless (defined $expected_length) {
  260.                   $expected_length = $res->content_length || 0;
  261.                    }
  262.            if ($expected_length) {
  263.                 printf STDERR "%d%% - ",
  264.                               100 * $bytes_received / $expected_length;
  265.                    }
  266.                print STDERR "$bytes_received bytes received\n";
  267.  
  268.                    # XXX Should really do something with the chunk itself
  269.                # print $chunk;
  270.                });
  271.  
  272.  
  273.  
  274. =head1 COPYRIGHT
  275.  
  276. Copyright 1996-1999, Gisle Aas
  277.  
  278. This library is free software; you can redistribute it and/or
  279. modify it under the same terms as Perl itself.
  280.  
  281.  
  282.