home *** CD-ROM | disk | FTP | other *** search
/ Chip 1999 March / Chip_1999-03_cd.bin / ovladace / Drivers / ALBIOS12.EXE / BIOS.EXE / BLD_BIOS.BAT < prev    next >
DOS Batch File  |  1997-07-24  |  5KB  |  156 lines
  1. @echo off
  2.  
  3. REM BIOS Zip Batch file, Ver 0.6, 7/2/97
  4.  
  5. REM This batch file zips up BIOS files into a self-extracting file suitable
  6. REM for posting on the web, BBS, Notes, the FTP server, etc.
  7.  
  8.  
  9. REM Variable Description
  10. REM %1 is the product name
  11. REM %2 is the BIOS version e.g. 1.00.03.BT0
  12. REM %3 is the name for the self-extracting zip file that will be posted,
  13. REM    e.g. 10003BT0.  Note, no file extension.
  14. REM %4 is the directory location of the files to be zipped
  15.  
  16. REM Sample command line is
  17. REM BLD_BIOS ADVANCED/MN 1.00.03.BT0 10003BT0 C:\WORK\BIOS 
  18.  
  19. REM check for correct command line
  20. IF "%3" == "" GOTO NOPARM
  21.  
  22. REM ask user if parameters are correct
  23. ECHO.
  24. ECHO The product name is %1
  25. ECHO The BIOS version is %2
  26. ECHO The BBS file name is %3.EXE
  27. ECHO The directory location is %4
  28. ECHO.
  29. ECHO If these are not correct, hit the CTRL-C key combination to exit
  30. ECHO the batch file. 
  31. PAUSE
  32.  
  33. REM if specified directory is the current directory, take special steps
  34. SET WDR=%4
  35. IF "%4" == "" SET WDR=.
  36.  
  37. REM delete old files
  38. IF EXIST BIOS.ZIP DEL BIOS.ZIP > NUL:
  39. IF EXIST BIOS.EXE BIOS.EXE > NUL:
  40. IF EXIST %3.ZIP DEL %3.ZIP > NUL:
  41. IF EXIST %3.EXE DEL %3.EXE > NUL:
  42.  
  43. REM remove read only attribute from unused files
  44. IF EXIST CUTUSER.* ATTRIB %WDR%\CUTUSER.BAT > NUL:
  45. IF EXIST CHANGES.* ATTRIB %WDR%\CHANGES.TXT > NUL:
  46.  
  47. REM delete unused files
  48. IF EXIST CUTUSER.* DEL %WDR%\CUTUSER.BAT > NUL:
  49. IF EXIST CHANGES.* DEL %WDR%\CHANGES.TXT > NUL:
  50.  
  51. REM IF NOT "%4" == "" COPY README.TXT %WDR%\README.TXT
  52.  
  53. REM make sure that the license, readme and bioinstr files are included 
  54. REM in the directory with the BIOS files
  55. IF EXIST %WDR%\LICENSE.TXT GOTO :NEXT 
  56. GOTO :MISSING
  57. :NEXT
  58. IF EXIST %WDR%\BIOINSTR.TXT GOTO :NEXT1
  59. GOTO :MISSING
  60. :NEXT1
  61. IF EXIST %WDR%\README.TXT GOTO :NEXT2
  62. GOTO :MISSING
  63. :NEXT2
  64. IF EXIST %WDR%\MK_BOOTZ.EXE GOTO :CONTINUE
  65.  
  66. :MISSING
  67. ECHO One of the following files is not included in the same directory 
  68. ECHO as the BIOS files: LICENSE.TXT, BIOINSTR.TXT, README.TXT, MK_BOOTZ.EXE
  69. ECHO Please move the appropriate file(s) into that directory 
  70. ECHO and rerun this batch file
  71. GOTO :END
  72.  
  73. :CONTINUE
  74. REM zip up the BIOS files, excluding the license, bios and mk_boot instruction files
  75. PKZIP -X%WDR%\LICENSE.TXT -X%WDR%\BIOINSTR.TXT -X%WDR%\MK_BOOTZ.EXE BIOS %WDR%\*.* > NUL:
  76.  
  77. REM remove the BLD_BIOS.BAT file from the zip file
  78. IF "%4" == "" PKZIP -D BIOS BLD_BIOS.BAT > NUL:
  79.  
  80. REM remove the message.txt from the zip file if it is present
  81. IF EXIST %WDR%\MESSAGE.TXT PKZIP -D BIOS %WDR%\MESSAGE.TXT > NUL:
  82.  
  83. REM create AGREE.TXT file
  84. ECHO  > AGREE.TXT
  85. ECHO. >> AGREE.TXT
  86. ECHO. >> AGREE.TXT
  87. ECHO Unzip these files to a bootable floppy disk by typing "BIOS A:" >> AGREE.TXT
  88. ECHO. >> AGREE.TXT
  89. ECHO ╔═════════════════════════════════════════════════════════════════════════════╗>> AGREE.TXT
  90. ECHO ║                       INTEL END USER LICENSE AGREEMENT                      ║>> AGREE.TXT
  91. ECHO ║ If you unzip this file, you will be bound by the terms of the agreement.    ║>> AGREE.TXT
  92. ECHO ╚═════════════════════════════════════════════════════════════════════════════╝>> AGREE.TXT
  93. ECHO. >> AGREE.TXT
  94. ECHO. >> AGREE.TXT
  95. ECHO. >> AGREE.TXT
  96.  
  97.  
  98. REM  Then, Zip the "Agree to license" text to the BIOS Zip file
  99. PKZIP -z BIOS < AGREE.TXT > NUL:
  100.  
  101. REM Now make this BIOS file self extracting
  102. @ZIP2EXE BIOS > NUL:
  103.  
  104. REM create COMMENTS.TXT file
  105. ECHO  > COMMENTS.TXT
  106. ECHO. >> COMMENTS.TXT
  107. ECHO. >> COMMENTS.TXT
  108. ECHO This is the %1 BIOS Update. >> COMMENTS.TXT
  109. ECHO The files contained in this ZIP file allow you to update your  >> COMMENTS.TXT
  110. ECHO %1 system BIOS to version %2. >> COMMENTS.TXT
  111. ECHO. >> COMMENTS.TXT
  112. ECHO For Instructions on how to update your BIOS, read BIOINSTR.TXT. >> COMMENTS.TXT
  113. ECHO. >> COMMENTS.TXT
  114.  
  115. IF EXIST %WDR%\MESSAGE.TXT MORE < %WDR%\MESSAGE.TXT >>COMMENTS.TXT
  116.  
  117. ECHO ╔═════════════════════════════════════════════════════════════════════════════╗>> COMMENTS.TXT
  118. ECHO ║                       INTEL END USER LICENSE AGREEMENT                      ║>> COMMENTS.TXT
  119. ECHO ║ Before you run the enclosed EXE file you must first read and agree to the   ║>> COMMENTS.TXT
  120. ECHO ║ end-user license agreement enclosed in the file LICENSE.TXT included in     ║>> COMMENTS.TXT
  121. ECHO ║ this ZIP file.  If you do not agree to the terms of this agreement,         ║>> COMMENTS.TXT
  122. ECHO ║ promptly delete this ZIP file and the files it contained.                   ║>> COMMENTS.TXT
  123. ECHO ╚═════════════════════════════════════════════════════════════════════════════╝>> COMMENTS.TXT
  124. ECHO. >> COMMENTS.TXT
  125. ECHO. >> COMMENTS.TXT
  126.  
  127. REM OK, on the home stretch...Zip the BIOS.EXE, the instruction file,
  128. REM the MK_BOOT file & the LICENSE file together
  129. PKZIP %3 %WDR%\BIOINSTR.TXT %WDR%\LICENSE.TXT %WDR%\MK_BOOTZ.EXE BIOS.EXE > NUL:
  130.  
  131. REM And add the front end comments to it
  132. PKZIP %3 -z < COMMENTS.TXT > NUL:
  133.  
  134. REM Finally, make this file self-extracting...
  135. ZIP2EXE %3 > NUL:
  136.  
  137. REM Now clean up.
  138. DEL AGREE.TXT
  139. DEL COMMENTS.TXT
  140. DEL BIOS.ZIP
  141. DEL BIOS.EXE
  142. DEL %3.ZIP
  143.  
  144. ECHO BIOS ZIP FILE IS NOW READY FOR EXPORT TO CUSTOMERS
  145.  
  146. GOTO END
  147.  
  148. :NOPARM
  149. ECHO.
  150. ECHO BLD_BIOS prod_name bios_ver bios_file_name bios_file_directory
  151. ECHO.
  152. GOTO END
  153.  
  154. :END
  155.  
  156.