PC Direct 1995 September/PCD0995.ISO/files/intro.dir/00001.ls

Text File | 1995-01-24 | 4.9 KB | 171 lines

global attractLoopList, attractLoopDataList, maxBackgrounds, nextBackground, currentBackground, cQuickTime, gTime, lastClickTime, gPresentingTo, gPresentationLight, gPTimerSet, gPresentationTime, gRedSet, gYellowSet, gPresentationOver, lastBackgroundChange

on startMovie
  set the preLoadEventAbort to 1
  preLoadCast(76, 77)
  memoryManIntro()
  set lastClickTime to the timer
  set cQuickTime to 16
  set currentBackground to "AL1"
  set attractLoopList to [1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12]
  set attractLoopDataList to [[2, "a", 1, "b", 1], [3, "a", 1, "b", 1, "c", 1], [2, "a", 1, "b", 1], [2, "a", 1, "b", 1], [2, "a", 1, "b", 1], [2, "a", 1, "b", 1], [2, "a", 1, "b", 1], [2, "a", 1, "b", 1], [2, "a", 1, "b", 1], [2, "a", 1, "b", 1], [3, "a", 1, "b", 1, "c", 1], [2, "a", 1, "b", 1]]
  set maxBackgrounds to count(attractLoopList)
  set nextBackground to newBackground()
  if not voidp(gPresentingTo) or (gPresentingTo <> EMPTY) then
    put gPresentingTo into field "CompanyDisplay"
  else
    put " " into field "CompanyDisplay"
    put "30" into field "Timer Amount"
  end if
end

on idle
end

on waitFor seconds
  set now to the timer
  repeat while the timer < (now + (seconds * 60))
    if the mouseDown then
      exit
    end if
  end repeat
end

on newBackground
  global lastChoice
  set numChoices to count(attractLoopList)
  if numChoices = 0 then
    set attractLoopList to [1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12]
    set numChoices to maxBackgrounds
  end if
  if numChoices = maxBackgrounds then
    set theOffset to random(maxBackgrounds)
    set theChoice to getAt(attractLoopList, theOffset)
    repeat while theChoice = lastChoice
      set theOffset to random(maxBackgrounds)
      set theChoice to getAt(attractLoopList, theOffset)
    end repeat
  else
    if numChoices = 1 then
      set lastChoice to getAt(attractLoopList, 1)
      set theChoice to lastChoice
      set theOffset to 1
    else
      set theOffset to random(numChoices)
      set theChoice to getAt(attractLoopList, theOffset)
    end if
  end if
  deleteAt(attractLoopList, theOffset)
  return theChoice
end

on preloadBackground whichOne
  set loadList to getAt(attractLoopDataList, whichOne)
  set theFrame to "AL" & string(whichOne)
  preLoad(theFrame, theFrame)
  set numScenes to getAt(loadList, 1)
  repeat with x = 1 to numScenes
    set theFrame to "AL" & string(whichOne) & getAt(loadList, x * 2)
    set firstFrame to label(theFrame)
    preLoad(firstFrame, firstFrame)
  end repeat
end

on changeBackground
  set theFrame to "AL" & string(nextBackground)
  set currentBackground to theFrame
  puppetSprite(3, 0)
  puppetSprite(4, 0)
  puppetSprite(5, 0)
  puppetSprite(6, 0)
  puppetSprite(7, 0)
  go(theFrame)
  puppetSprite(3, 1)
  puppetSprite(4, 1)
  puppetSprite(5, 1)
  puppetSprite(6, 1)
  puppetSprite(7, 1)
  set nextBackground to newBackground()
  set lastBackgroundChange to the ticks
end

on changeHotspot whichOne
  set WhichSprite to the clickOn
  set whichCast to the castNum of sprite WhichSprite
  set myName to the name of cast whichCast
  set theSpot to currentBackground & whichOne
  set myNum to the last word in myName
  put not value(myNum) into word the number of words in myName of myName
  set the castNum of sprite WhichSprite to cast myName
  set lastBackgroundChange to the ticks
  go(theSpot)
end

on puppetsOff
  repeat with x = 3 to 7
    puppetSprite(x, 0)
  end repeat
end

on delayfor n
  startTimer()
  repeat while the timer < n
  end repeat
end

on checkey
  global delaytime
  if the key = "0" then
    set delaytime to 9
  end if
  if the key = "1" then
    set delaytime to 8
  end if
  if the key = "2" then
    set delaytime to 7
  end if
  if the key = "3" then
    set delaytime to 6
  end if
  if the key = "4" then
    set delaytime to 5
  end if
  if the key = "5" then
    set delaytime to 4
  end if
  if the key = "6" then
    set delaytime to 3
  end if
  if the key = "7" then
    set delaytime to 2
  end if
  if the key = "8" then
    set delaytime to 1
  end if
  if the key = "9" then
    set delaytime to 0
  end if
end

on mainButtonSelect whichOne
  global WhichSprite
  set WhichSprite to the clickOn
  puppetSprite(WhichSprite, 1)
  set the castNum of sprite WhichSprite to the number of cast (the name of cast the castNum of sprite WhichSprite && "lit")
  updateStage()
  repeat while the stillDown
  end repeat
  puppetSprite(WhichSprite, 0)
  set thePlaces to [#macromedia: "vision", #tools: "tools", #services: "support", #gallery: "gallery"]
  set destination to getProp(thePlaces, whichOne)
  go(1, destination)
end

on memoryManIntro
  preLoadCast(the number of cast "Volume Down", the number of cast "Quit")
  preLoadCast(the number of cast "Volume Down lit", the number of cast "Quit lit")
  preLoadCast(the number of cast "sound level 0", the number of cast "sound level 6")
  preLoadCast(the number of cast "main macromedia", the number of cast "basic panel")
  preLoadCast(the number of cast "basic panel grey")
end