home *** CD-ROM | disk | FTP | other *** search
/ FreeWare Collection 2 / FreeSoftwareCollection2pd199x-jp.img / fbasic / scanner / gts_16.bas next >
Encoding:
BASIC Source File  |  1990-06-14  |  4.4 KB  |  146 lines
  1. 10 '＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
  2. 20 '＊ F-BASIC386         << SCANNER PROGRAM >>       ＊
  3. 30 '＊   COLOR IMAGE SCANNER  *  16 COLOR 9600bps  *  ＊
  4. 40 '＊   GT-1000(GT-1000mode GT-3000Vmode), GT-4000   ＊
  5. 50 '＊     COPYRIGHT FUJITSU LIMITED 1989             ＊
  6. 60 '＊                                                ＊
  7. 70 '＊   (AUTHOR) : HIDENORI-ISHIKIRIYAMA.            ＊
  8. 80 '＊   (DATE.W) : 1989. 7.13                        ＊
  9. 90 '＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
  10. 100 '
  11. 110 CLS
  12. 120 SCREEN@ 0
  13. 130 COLOR 6 : LOCATE 29,8 : PRINT "   画像処理中 ！！   " : COLOR 7
  14. 140 DEFLNG A-Y
  15. 150 DEFDBL Z
  16. 160 DIM CH(20)
  17. 170 STIM=TIME
  18. 180 CO(0)=4 : CO(1)=2 : CO(2)=1
  19. 190 OPEN "I",#2,"COM0:"
  20. 200 OPEN "O",#1,"COM0:"
  21. 210 ESC$=CHR$(27)
  22. 220 STX$=CHR$(2)
  23. 230 ACK$=CHR$(6)
  24. 240 CAN$=CHR$(24)
  25. 250 '
  26. 260 ' コマンドパラメータ設定
  27. 270 '
  28. 280 COL=1 :                   ' 色指定　　　　　　　Ｃコマンド
  29. 290 DFO=1 :                   ' データフォーマット　Ｄコマンド
  30. 300 MID=0 :                   ' 中間調処理          Ｂコマンド
  31. 310 SZOMX=100 : SZOMY=100 :   ' ズーム設定          Ｈコマンド
  32. 320 R1=100 : R2=100 :         ' 解像度設定          Ｒコマンド
  33. 330 NOU=1 :                   ' 濃度補正            Ｚコマンド
  34. 340 '
  35. 350 '                         ' 読み取り可能範囲 
  36. 360       ' MAX=8*(INT((2.96!*R1*SZOMX/100+.1!)/8))   :'''GT-1000 mode
  37. 370       ' MAY=INT(4.2!*R2*SZOMY/100+.1!)
  38. 380 'MAX=8*(INT((4*R1*SZOMX/100+.1!)/8))               :'''GT-3000V mode
  39. 390 'MAY=INT(6.4!*R2*SZOMY/100+.1!)
  40. 400        MAX=8*(INT((8.56!*R1*SZOMX/100+.1!)/8))   :'''GT-4000
  41. 410        MAY=11.6!*R2*SZOMY/100
  42. 420 '
  43. 430 XST=0 : YST=0 :           ' 読み取り開始位置 　 Ａコマンド
  44. 440 XEN=MAX-1 : YEN=MAY-1 :   ' 読み取り終了位置
  45. 450 IF XEN>639 THEN XEN=639   ' 最大 (0,0)-(639,479) チェック  
  46. 460 IF YEN>479 THEN YEN=479
  47. 470 '
  48. 480 DIM GD$(2,YEN)
  49. 490 '
  50. 500 'コマンド実行
  51. 510 '
  52. 520 SCOM$=ESC$+"C"
  53. 530  PAR$=CHR$(COL) : GOSUB *SENDDATA
  54. 540 SCOM$=ESC$+"D"
  55. 550  PAR$=CHR$(DFO) : GOSUB *SENDDATA
  56. 560 SCOM$=ESC$+"B"
  57. 570  PAR$=CHR$(MID) : GOSUB *SENDDATA
  58. 580 SCOM$=ESC$+"H"
  59. 590  PAR$=CHR$(SZOMX)+CHR$(SZOMY) : GOSUB *SENDDATA
  60. 600 SCOM$=ESC$+"R"
  61. 610  PAR$=CHR$(R1 MOD 256)+CHR$(R1 \ 256)+CHR$(R2 MOD 256)+CHR$(R2 \ 256)
  62. 620  GOSUB *SENDDATA
  63. 630 SCOM$=ESC$+"A"
  64. 640  PAR$=CHR$(XST MOD 256)+CHR$(XST \ 256)+CHR$(YST MOD 256)
  65. 650  PAR$=PAR$+CHR$(YST \ 256)+CHR$((XEN+1) MOD 256)+CHR$((XEN+1) \ 256)
  66. 660  PAR$=PAR$+CHR$((YEN+1) MOD 256)+CHR$((YEN+1) \ 256)
  67. 670  GOSUB *SENDDATA
  68. 680 SCOM$=ESC$+"Z"
  69. 690  PAR$=CHR$(NOU) : GOSUB *SENDDATA
  70. 700 '
  71. 710 PRINT #1,ESC$+"G";
  72. 720 '
  73. 730 'ＭＡＩＮ
  74. 740 '
  75. 750 '     データＲＥＡＤ
  76. 760 '
  77. 770 FOR COL=0 TO 2
  78. 780   FOR L=YST TO YEN
  79. 790  *WAIT
  80. 800    HD$=INPUT$(1,#2) : IF HD$<>STX$ THEN *WAIT
  81. 810    ST$=INPUT$(1,#2)
  82. 820     IF (ASC(ST$) AND &H40)<>0 THEN GOSUB *SENDA : GOTO *WAIT
  83. 830    ST$=INPUT$(2,#2)
  84. 840    GD$(COL,L)=INPUT$((((XEN-XST)-1) \ 8)+1,#2)
  85. 850 ::::::::: IF INKEY$=ESC$ THEN GOSUB *SENDC : END :::::::::: ESC
  86. 860    IF L<>YEN THEN GOSUB *SENDA 
  87. 870   NEXT L
  88. 880 NEXT COL
  89. 890 PRINT #1,ESC$;"@";:DUMMY$=INPUT$(1,#2)
  90. 900 CLOSE
  91. 910 '
  92. 920 '     データ変換
  93. 930 '
  94. 940 FOR COL=0 TO 2
  95. 950  FOR L=YST TO YEN
  96. 960   CC=0
  97. 970   SS=-3
  98. 980   GD$=GD$(COL,L)+"        "
  99. 990   FOR ST=XST TO XEN STEP 32
  100. 1000    SS=SS+4
  101. 1010    Z=ASC(MID$(GD$,SS,1))+ASC(MID$(GD$,SS+1,1))*256
  102. 1020    Z=Z+ASC(MID$(GD$,SS+2,1))*65536+ASC(MID$(GD$,SS+3,1))*16777216
  103. 1030    IF Z>2147483647 THEN Z=Z-4294967296#
  104. 1040    CH(CC)=Z
  105. 1050    CC=CC+1
  106. 1060   NEXT ST
  107. 1070   PUT@ (XST,L)-(XEN,L),CH,OR,CO(COL)
  108. 1080   NEXT L
  109. 1090 NEXT COL
  110. 1100 CLS 4
  111. 1110 END
  112. 1120 '
  113. 1130 'ＳＵＢ．
  114. 1140 '
  115. 1150  *SENDDATA
  116. 1160   PRINT #1,SCOM$;
  117. 1170   A$=INPUT$(1,#2):IF A$ <> ACK$ THEN *ERR
  118. 1180   PRINT #1,PAR$;
  119. 1190   A$=INPUT$(1,#2):IF A$ <> ACK$ THEN *ERR
  120. 1200  RETURN
  121. 1210 '
  122. 1220  *SENDC
  123. 1230   PRINT #1,CAN$;
  124. 1240   RETURN
  125. 1250 '
  126. 1260  *SENDA
  127. 1270   PRINT #1,ACK$;
  128. 1280   RETURN
  129. 1290 '
  130. 1300  *ERR
  131. 1310   CLS
  132. 1320   PRINT "ERROR !"
  133. 1330   PRINT RIGHT$(SCOM$,1);"ｺﾏﾝﾄﾞ ERROR !"
  134. 1340  END
  135. 1350 '
  136. 1360 '
  137. 1370 ' このプログラムはカラーイメージスキャナ ＧＴ-４０００･ＧＴ-１０００
  138. 1380 ' で使用できます。
  139. 1390 ' ３６０－４１０行の式から使用する機種･モードにあったものを選択
  140. 1400 ' して下さい｡   (転送速度は９６００ｂｐｓに設定して実行して下さい。)
  141. 1410 ' 
  142. 1420 ' 読み込みを途中で終了するときは[ＥＳＣ]キーを押して下さい｡
  143. 1430 '
  144. 1440 '＊＊ 読み取りサイズや,解像度などは２８０－４４０行で変更できます。
  145. 1450 '
  146.