home *** CD-ROM | disk | FTP | other *** search
/ back2roots/padua / padua.7z / padua / misc / kill2090.lzh / KILL2090.S < prev    next >
Encoding:
Text File  |  1990-10-16  |  7.7 KB  |  314 lines
  1. ; kill 2090 - by J Davis 08/1990
  2. ; ---------
  3. ;
  4. ; version 1.0 
  5. ;
  6. ; THIS MUST BE ASSEMBLED TO FORCELOAD TO CHIPMEM!!!
  7. ;
  8. ; very simple program to reboot 2000 with all autoconfig boards off
  9. ;
  10. ; this allows you to boot off floppies without worrying about
  11. ; rogue programs attacking your hard-disk
  12. ; 
  13. ; the drive is only killed until the next reboot - so ctrl-amiga-amiga
  14. ; will re-anable it
  15. ; 
  16. ; how it does it -
  17. ;                 this is basically a modified version of the 'official'
  18. ;                 reboot code in the rkm:hardware, with the addition of
  19. ;          a coldcapture routine that 'fakes out' all the expansion 
  20. ;          boards, stopping exec from seeing/using them
  21. ; 
  22. ;
  23. ; YES THIS IS A HACK!! It manipulates the system in a manner contrary
  24. ; to the rkm quidelines - so don't blame me if it doesn't work!! :-)
  25. ;
  26. ;
  27. ; changes for version .05(beta)
  28. ;
  29. ;    sends 5 flashes when cold capt code starts
  30. ;    back to brute force approach to finding all boards
  31. ;
  32. ; changes for version .06(beta)
  33. ;
  34. ;    now sends all boards that don't support shut_up to $200000
  35. ;    ( instead of $d00000 as before ). This gets around problems
  36. ;    with memory boards overlaying the custom chips and killing the
  37. ;    whole system
  38. ;
  39. ; changes for version 1.0 
  40. ; 
  41. ;    added code to switch super agnus to PAL/NTSC
  42. ;
  43. ;    by altering the conditional compilation switches Go_NTSC and
  44. ;    Kill_boards, you can set whether to switch to PAL or NTSC at
  45. ;    boot-time, and also whether to just reset, or kill exp boards
  46. ;    as well, giving four possible versions of this program
  47.  
  48.  
  49. ;===========================================================
  50. ; vary these flags to build all 4 possible versions
  51.  
  52. kill_boards    equ    0    ; set to 0 to just build reset program
  53.  
  54. go_ntsc        equ    0    ; set to 1 will toggle superAgnus to NTSC
  55.                 ; set to 0 will toggle to PAL
  56.  
  57. ;=============================================
  58.  
  59. forbid        equ    -$084    ; offsets for various exec and int calls
  60. getmsg        equ    -$174    ; saves long includes and compile times
  61. replymsg    equ    -$17a
  62. waitport    equ    -$180
  63. findtask    equ    -$126
  64. autoreq        equ    -$15c
  65. openlib        equ    -$228
  66. closelib    equ    -$19e
  67. supervisor    equ     -$01e    
  68.  
  69. attnflags    equ    $128    ; offset for execbase.attnflags word
  70. afb_68020    equ    1<<1    ; bit mask for 020 flag
  71.  
  72. pr_cli        equ    $0Ac    ; process cli flag offset
  73. pr_msgport    equ    $05c    ; process msgport offset
  74.  
  75. ; hisoft devpac and Argasm don't support the 010+ movec command!
  76. ; so we jam them in as consts instead
  77. movec_cacr_d0    equ     %0000000000000010
  78. movec_d0_cacr    equ    %1000000000000010
  79.  
  80. ;=========================================
  81.  
  82.         section    main,code_c        ; make sure we're in CHIP
  83.  
  84. startup:    move.l    $4,a6
  85.         move.l    #0,a1
  86.         jsr    findtask(a6)        ; find ourselves
  87.  
  88.         move.l    d0,a4            ; save our process pointer
  89.  
  90.         move.l    pr_cli(a4),d0
  91.         bne    fromdos            ; was a DOS startup
  92.  
  93.         ; was started from WB
  94.  
  95.         lea    pr_msgport(a4),a0
  96.         jsr    waitport(a6)        ; wait for startup msg
  97.         lea    pr_msgport(a4),a0
  98.         jsr    getmsg(a6)        ; get the wb msg
  99.  
  100.         move.l    d0,wbmsg        ; save pointer to our startup msg
  101.         move.l    #1,wb            ; flag we started from wb
  102.  
  103. fromdos:    lea    intuiname,a1
  104.         move.l    #0,d0
  105.         move.l    $4,a6
  106.         jsr    openlib(a6)         ; open intuition lib
  107.  
  108.         move.l    d0,a6            ; save ibase
  109.         
  110.         move.l    #0,a0            ; window to display in
  111.         move.l    #bodyitext,a1        ; body text
  112.         move.l    #yesitext,a2         ; postive text
  113.         move.l    #noitext,a3          ; negative text
  114.         move.l    #0,d0            ; pflags
  115.         move.l    #0,d1            ; nflags
  116.         move.l    #460,d2            ; width
  117.         move.l    #60,d3            ; height
  118.         jsr    autoreq(a6)        ; request user confirmation
  119.  
  120.         cmp.l    #0,d0
  121.         bne    reboot            ; user selected ok, kill!
  122.  
  123.         ; user cancelled reboot
  124.         
  125.         move.l    a6,a1            ; close intuition lib
  126.         move.l    $4,a6
  127.         jsr    closelib(A6)
  128.         
  129. exit:        move.l    wb,d0
  130.         cmp.l    #0,d0            ; was this a CLI invocation
  131.         beq    exit_dos
  132.  
  133.         ; workbench exit
  134.  
  135.         move.l    $4,a6
  136.         jsr    forbid(a6)        ; lock out everyone else
  137.  
  138.         move.l    wbmsg,a1
  139.         jsr    replymsg(a6)        ; reply to Wbstartup msg
  140.  
  141. exit_dos:    move.l    #0,d0            ; return with return code 0
  142.         rts            
  143.  
  144.  
  145.  
  146. ;=====================================
  147. ; the following does the actual reboot 
  148.         
  149. reboot:        jsr    instcold        ; install coldcapture handler
  150.                         ; exec will run coldcapt once and then
  151.                         ; kill it - exactly what we want!    
  152.     
  153.         move.l    $4,a6             ; RESET must be run in Smode, so go to it
  154.         move.l    #reboot_c,a5        ; code to run in supervisor mode
  155.         jsr    supervisor(A6)        ; go into supervisor mode
  156.  
  157.         cnop    0,4            ; longword align code
  158.         
  159. reboot_c:    move.l    $4,a6
  160.         btst.b    #afb_68020,attnflags+1(a6)
  161.         beq    kill            ; is system 020/030 powered ?
  162.  
  163.         ; if it is an 020 or 030, take extra steps for cache 
  164.     
  165.         dc.w    movec_cacr_d0       ; twiddle the cache control reg
  166.         bset.l    #3,d0
  167.         dc.w    movec_d0_cacr
  168.      
  169.          bra    kill
  170.      
  171.          cnop    0,4            ; long word align code
  172.  
  173. kill:        move.l    #$2,a1            ; where to jump to in rom
  174.         reset
  175.         jmp (a1)            ; now run reset code in rom
  176.  
  177.  
  178.  
  179. ;=======================================
  180. ; routine to install coldcapture handler
  181.  
  182. instcold:    move.l    $4,a6            ; get execbase
  183.         lea    cold,a0            ; get address of our coldcapt routine
  184.         move.l    a0,$2a(a6)        ; set coldcapture vect
  185.  
  186.         lea    34(a6),a0        ; start of checksummed area in execbase
  187.         move.w    #$16,d0            ; number of checksummed words
  188.         move.w    #$0,d1            ; clear counter
  189.     
  190. sum:        add.w    (A0)+,d1        ; sum execbase and update checksum
  191.         dbf    d0,sum
  192.     
  193.         not.w    d1
  194.         move.w    d1,82(a6)        ; save fixed checksum
  195.  
  196.         rts
  197.  
  198.  
  199. ;===========================================================================
  200. ; our actual cold capture handler, flashes led,zaps boards,toggles agnus etc
  201.  
  202. cold:        move.w    #$0f8a,$dff180    ; set screen colour to pink
  203.  
  204.     IFNE     go_ntsc        ; go_ntsc=1 switch to ntsc
  205.         move.w    #$00,$dff1dc    ; set NTSC mode on agnus
  206.     ELSEIF
  207.         move.w    #$20,$dff1dc    ; set PAL mode on agnus
  208.     ENDC
  209.  
  210.  
  211.         move.l    #9,d0            ; flash power led 5 times 
  212.                         ; to let know we're running
  213.  
  214. lloop:        bchg    #1,$bfe001        ; toggle led
  215.         move.l    #$ffff,d1
  216. lwait:        dbf    d1,lwait        ; delay
  217.         dbf    d0,lloop
  218.  
  219.  
  220.     IFNE    kill_boards            ; kill_boards=1, so add kill code
  221.  
  222.         move.l    #$7,d1            ; max no boards we fix = 8 
  223.  
  224. bchk:        move.w    $e80008,d0        ; get flag byte from board
  225.         not.w    d0            ; invert
  226.         btst.l    #14,d0            ; see if board supports shut_up
  227.         beq    shut_up            ; bit=0 means board shuts up ok
  228.  
  229.         ; board doesn't support shut up, so 
  230.         ; config board to $200000 (only gap big enough for 8mb
  231.         ; boards)
  232.     
  233.         move.w    #$0000,$e8004a      ; fake board out to $200000
  234.         move.w    #$2000,$e80048  
  235.         
  236.         bra    nboard            ; carry on
  237.  
  238. shut_up:    move.b    #$ff,$e8004c        ; tell the board to shut up
  239.  
  240. nboard:        dbf    d1,bchk            ; loop thru all boards
  241.     ENDC
  242.  
  243. bexit:        jmp    (a5)            ; chain thru to rest of reset routine
  244.     
  245. ;=============================================================
  246.         
  247. wb:        dc.l    0            ; run mode flag 0=dos process 1=wbprocess
  248. wbmsg:        dc.l    0            ; where we save our workbench msg
  249.  
  250. intuiname:    dc.b    "intuition.library",0
  251.  
  252. ; stuff for our autorequester
  253.  
  254. bodyitext:    dc.b    0           ; front pen
  255.         dc.b    1           ; back pen
  256.         dc.b    0           ; draw mode
  257.         dc.w    70           ; leftedge
  258.         dc.w    6           ; topedge
  259.         dc.l    0           ; textattr = default
  260.         dc.l    bodytext1      ; actual text
  261.         dc.l    bodyitext2     ; next
  262.  
  263. bodyitext2:    dc.b    0           ; front pen
  264.         dc.b    1           ; back pen
  265.         dc.b    0           ; draw mode
  266.         dc.w    35           ; leftedge
  267.         dc.w    15          ; topedge
  268.         dc.l    0           ; textattr = default
  269.         dc.l    bodytext2     ; actual text
  270.         dc.l    0            ; next
  271.  
  272.         
  273. yesitext:    dc.b    2        ; front pen
  274.         dc.b    1        ; back pen
  275.         dc.b    0        ; draw mode
  276.         dc.w    4        ; leftedge
  277.         dc.w    4        ; topedge
  278.         dc.l    0        ; textattr = default
  279.         dc.l    yestext        ; actual text
  280.         dc.l    0        ; next
  281.         
  282. noitext:    dc.b    2        ; front pen
  283.         dc.b    1        ; back pen
  284.         dc.b    0        ; draw mode
  285.         dc.w    4        ; leftedge
  286.         dc.w    4        ; topedge
  287.         dc.l    0        ; textattr = default
  288.         dc.l    notext        ; actual text
  289.         dc.l    0        ; next        
  290.  
  291.         ; actual text for our requester
  292.  
  293.     IFNE    kill_boards
  294. bodytext1:    dc.b    "Kill2090"
  295.         ELSEIF
  296. bodytext1:    dc.b    " Reset"
  297.     ENDC
  298.         
  299.         dc.b     " by J Davis, 08-1990 v1.0 "
  300.  
  301.     IFNE    go_ntsc    
  302.         dc.b    "NTSC"
  303.     ELSEIF
  304.         dc.b    "PAL "
  305.     ENDC
  306.         dc.b    0
  307.  
  308. bodytext2:    dc.b    "About to kill system, finish ALL disk activity",0
  309.  
  310. yestext:    dc.b    "Go ahead, make my day!",0
  311. notext:        dc.b    "No, I was just kidding!",0
  312.  
  313.         END
  314.