Visual Basic 4 Unleashed/Visual_Basic_4_Unleashed_SAMS_Publishing_1995.iso/pronexus/sys/vbvfax.bas

BASIC Source File | 1994-04-03 | 9.5 KB | 297 lines

Option Explicit

'   VBVoice WinFax Pro Version 3.0 Interface

'   This file contains interface functions to allow VBVoice developers to
'   interface with Delrina's WinFax Pro product using DDE communications.

'   The constant VbvFaxPath must be adjusted to suit your system's setup.
'   Please adjust accordingly.  The next two constants are not likely to
'   change from system to system.
Const LINK_NONE = 0
Const LINK_MANUAL = 2

Const VbvFaxPath$ = "C:\apps\WINFAX"
Const VbvFaxApplication$ = "FAXMNG"
Const VbvFaxFullPath$ = "C:\apps\WINFAX\FAXMNG.EXE"

'       Run-time error codes.
Global Const NoWinFaxResponse = 282

'       Function declarations to get and set strings in .INI files.
Declare Function GetPrivateProfileString Lib "Kernel" (ByVal lpAppName As String, ByVal lpKeyName As String, ByVal lpDefault As String, ByVal lpReturnedSTRING As String, ByVal nSize As Integer, ByVal lpFileName As String) As Integer
Declare Function WritePrivateProfileString Lib "Kernel" (ByVal lpAppName As String, ByVal lpKeyName As String, ByVal lpSTRING As String, ByVal lplFileName As String) As Integer

'**************
'       VbvLinkPoke
'**************
'       Poke some values into a DDE link.

'       Parameters:
'               DDELink - a text box (not necessarily visible!) which is used to
'                       link to DDE.  The form containing this text box must be loaded.
'               LinkItem$ - a string identifying which property is being poked.
'               Text$ - a string containing the value being poked.

'********************
'       VbvSetDestination
'********************
'       Set the destination name and number in the fax manager.

'       Parameters:
'               DDELink - a text box (not necessarily visible!) which is used to
'                       link to DDE.  The form containing this text box must be loaded.
'               DestinationNumber$ - the fax number being dialed.
'               RecipientName$ - the name of the fax's recipient.

'****************
'       VbvGetPrinter
'****************
'       Get the current default printer for the system.

'       Returns:
'               A string describing the current printer settings in WIN.INI.

'********************
'       VbvActivateWinFax
'********************
'       Read WinFax settings from WIN.INI and set it as the default device.

'****************
'       VbvSetPrinter
'****************
'       Set a printer description as the default printer.

'***************
'       VbvPrintFile
'***************
'       Print off a given file to the WinFax fax manager.  Note that it is assumed
'       by this function that the file is already formatted as expected.  Thus text
'       files are assumed to have been formatted already with page breaks and
'       margins.  If this is not the case, an preprocessing function of some sort
'       should be created to format the text file into a temporary text file
'       first.  This temporary text file should then be printed instead.

'*************
'       VbvSendFax
'*************
'       Send a file to the fax manager.  This function is the entry point into the
'       fax transmission portion of the library.

'       Parameters:
'               DDELink - a text box (not necessarily visible!) which is used to
'                       link to DDE.  The form containing this text box must be loaded.
'               RecipientName$ - the name of the fax's recipient.
'               DestinationNumber$ - the fax number being dialed.
'               FaxFile$ - the ascii file being transmitted.
'               CoverFile$ - the ascii text file used as a cover sheet.

'**************
'       VbvFaxSetup
'**************
'       This function should be called once at the beginning of your program to
'       establish a DDE link with WinFax.  The calling function should check for an
'       error return in case we had a more serious problem than the fax manager
'       not being loaded.

'       Parameters:
'               DDELink - a text box (not necessarily visible!) which is used to
'                       link to DDE.  The form containing this text box must be loaded.

'*****************
'       VbvFaxShutdown
'*****************
'       This function should be called once at the end of your program to terminate
'       the DDE link to WinFax's manager.

'       Parameters:
'               DDELink - a text box (not necessarily visible!) which is used to
'                       link to DDE.  The form containing this text box must be loaded.

Sub VbvActivateWinFax ()

    Dim WinFaxSettings$     'string containing WinFax's settings
    Dim retStr As String * 255      'buffer for string returned from win.ini
    Dim retStrSize%         'length of returned string
    Dim retCode%

    'Get WinFax settings.
    retStrSize% = GetPrivateProfileString("devices", "WINFAX", "", retStr$, 255, "win.ini")
    WinFaxSettings$ = Left$(retStr$, retStrSize%)
    If WinFaxSettings$ = "" Then
        MsgBox "The WinFax device driver is not installed."
        Error 712
        Exit Sub
    Else
        WinFaxSettings$ = "WINFAX," + WinFaxSettings$
    End If

    'Set WinFax as the default device.
    retCode% = WritePrivateProfileString("windows", "device", WinFaxSettings$, "win.ini")
    If retCode% = 0 Then
        MsgBox "Error updating system default printer.", 16
        Error 712
    End If

End Sub

Sub vbvfaxsetup (DDELink As TextBox)

    On Error GoTo StartUpWinFax
    DDELink.LinkMode = LINK_NONE
    DDELink.LinkTopic = VbvFaxApplication + "|" + "Transmit"
    DDELink.LinkMode = LINK_MANUAL

    'Adjust the following to taste.
    'The alternative resolution value is "LOW".
    Call VbvLinkPoke(DDELink, "SendFax", "resolution(""HIGH"")")

    Exit Sub

StartUpWinFax:  'Start up the WinFax manager if it isn't already.

    Dim retCode

    If Err = NoWinFaxResponse Then

        On Error Resume Next
        retCode = Shell(VbvFaxFullPath, 6)

        If Err = 0 Then Resume  'If we still can't get it, we'll abort.

    End If

End Sub

Sub vbvfaxshutdown (DDELink As TextBox)

    DDELink.LinkMode = LINK_NONE

End Sub

Function VbvGetPrinter () As String

    Dim retStr     As String * 255   'buffer for string returned from win.ini
    Dim retStrSize%         'length of returned string

    'Get current printer from WIN.INI.
    retStrSize% = GetPrivateProfileString("windows", "device", "", retStr$, 255, "win.ini")

    'Return current printer setting.
    VbvGetPrinter = Left$(retStr$, retStrSize%)

End Function

Sub VbvLinkPoke (DDELink As TextBox, Item$, ByVal Value$)

    DDELink.LinkItem = Item$
    DDELink.Text = Value$
    DDELink.LinkMode = LINK_MANUAL
    DDELink.LinkPoke

End Sub

Sub vbvprintfile (ByVal File$)

    Dim TextLine$

    'Adjust the following lines to change font features.
    Printer.FontName = "Times New Roman"
    Printer.FontItalic = False
    Printer.FontBold = False
    Printer.FontSize = 12

    Open File$ For Input As #1

    'Print off one line at a time.
    Do While Not EOF(1)

        Input #1, TextLine$
        Printer.Print ; TextLine$
        DoEvents

    Loop

    Close #1

    'Note that, since multiple files may be printed to the fax in a single
    'session, we do not send the Printer.EndDoc statement.  This is the
    'responsibility of the calling function.

End Sub

Sub VbVRequestItem (DDELink As TextBox, Item$, ByVal Value$)
    DDELink.LinkItem = Item$
    DDELink.LinkRequest
    Value$ = DDELink.Text
End Sub

Sub vbvsendfax (DDELink As TextBox, ByVal RecipientName$, ByVal DestinationNumber$, ByVal FaxFile$, ByVal CoverFile$)

    Dim Destination$, OldPrinter$

    On Error GoTo EndSendFax
    Call VbvSetDestination(DDELink, DestinationNumber$, RecipientName$)

    On Error Resume Next
    OldPrinter$ = VbvGetPrinter()
    Call VbvActivateWinFax

    'If there's no error, send the fax.
    If Err = 0 Then

        On Error GoTo EndSendFax

        Call vbvprintfile(CoverFile$)
        Printer.NewPage                                 'don't merge cover with text
        Call vbvprintfile(FaxFile$)
        Printer.EndDoc                                  'make sure that file is sent!

        'return default printer to previous setting
        Call vbvsetprinter(OldPrinter$)

    End If
    Exit Sub
EndSendFax:

    MsgBox Error$
'   VbvWinFaxDisconnect (DDELink)
    Exit Sub

End Sub

'this sub allows a fax to be scheduled, sent to multiple recipeints,
'allows name, company, subkect, keywords and billing code to be
'specified. Use this instead of vbv
'IMPORTANT NOTE : this functions not tested yet ....
Sub vbvSetDestDetailed (DDELink As TextBox, ByVal faxnum$, ByVal sendtime As Variant, ByVal toname$, ByVal company$, ByVal subject$, ByVal keywords$, ByVal billingcode$)
Dim sendtimestr$, senddatestr$
sendtimestr = Format(sendtime, "hh:mm:ss")
senddatestr = Format(sendtime, "mm/dd/yy")
Call VbvLinkPoke(DDELink, "SendFax", "recipient(" + faxnum$ + "," + sendtimestr + "," + senddatestr + "," + toname$ + "," + company$ + "," + subject$ + "," + keywords$ + "," + billingcode$)

End Sub

Sub VbvSetDestination (DDELink As TextBox, ByVal DestinationNumber$, ByVal RecipientName$)

    Call VbvLinkPoke(DDELink, "Receiver", RecipientName$)
    Call VbvLinkPoke(DDELink, "Fax Number", DestinationNumber$)

End Sub

Sub vbvsetprinter (Printer$)

    Dim retStr As String * 255
    Dim retCode%

    'Update WIN.INI with given device.
    retCode% = WritePrivateProfileString("windows", "device", Printer$, "win.ini")

    If retCode% = 0 Then
        MsgBox "Could not reset device'" + Printer$ + "'", 16
        Error 712
    End If

End Sub