home *** CD-ROM | disk | FTP | other *** search
/ Turbo Toolbox / Turbo_Toolbox.iso / 1989 / 10 / anwendg / zbau.bas < prev   
Encoding:
BASIC Source File  |  1989-07-19  |  2.0 KB  |  54 lines
  1. 10 ' BASIC-Programm:
  2. 20 ' Einlesen der Feldnamen aus der temporären Datei
  3. 30 ' TEMP1.TXT und Zuweisen zu einem einzigen String:
  4. 40 ' Die Feldnamen werden mit dem Zeichen ";" voneinander
  5. 50 ' getrennt, die Anführungszeichen eliminiert.
  6. 60 ' Copyright 1989 Jürgen Liskowskis & TOOLBOX
  7. 100 :
  8. 150 OPEN "I",#1,"TEMP1.TXT":' Datei öffnen
  9. 160   WHILE NOT EOF(1):' Schleife bis EOF
  10. 170      LINE INPUT #1, FELD1$:' Einlesen eines Feldnamens
  11. 179      ' Anführungszeichen löschen:
  12. 180      FELD1$=MID$(FELD1$,2,LEN(FELD1$)-2)
  13. 190     SATZ$=SATZ$+FELD1$+";":' String aufbauen
  14. 200  WEND:' Ende der Schleife EOF
  15. 210 CLOSE:' Datei schließen
  16. 220 :
  17. 229 ' Letztes Semikolon löschen:
  18. 230 SATZ$=LEFT$ ( SATZ$, LEN ( SATZ$ ) - 1 )
  19. 240 :
  20. 250 ' Die temporäre Datei wird einfach überschrieben,
  21. 260 ' da sie nicht mehr gebraucht wird. Alle Informationen
  22. 270 ' sind im String SATZ$.
  23. 280 :
  24. 290 OPEN "O",#1,"TEMP1.TXT":' Datei wieder öffnen
  25. 300  PRINT #1,SATZ$:' Zusammengebauten String schreiben
  26. 310 CLOSE:' Datei schließen
  27. 320 :
  28. 330 ' Umbau der eigentlichen Adreßdatei:
  29. 340 OPEN "I",#1,"TEMP2.TXT":' Adreßdatei öffnen
  30. 350 OPEN "A",#2,"UMBAU.$$$"
  31. 360 :
  32. 370 WHILE NOT EOF(1):' bis in Adreßdatei EOF erreicht.
  33. 380  LINE INPUT #1, S$:' Adreßsatz lesen
  34. 390  FOR X=1 TO LEN(S$):' vom ersten bis letzten Zeichen
  35. 400    ZX$=MID$(S$,X,1):' Ein Zeichen herausnehmen
  36. 409    ' Wenn Zeichen, dann in Semikolon wandeln:
  37. 410    IF ZX$="," THEN MID$(S$,X,1)=";"
  38. 420  NEXT:' Ein Adreßsatz abgearbeitet.
  39. 430  PRINT #2,S$:' Satz in temporäre Datei schreiben
  40. 440 WEND
  41. 450 CLOSE:' Beide Dateien schließen
  42. 460 :
  43. 470 KILL "TEMP2.TXT":' Brauchen wir nicht mehr
  44. 480 NAME "UMBAU.$$$" AS "TEMP2.TXT":' Umbenennen
  45. 490 :
  46. 500 ' Beide temporären Dateien auf eine dritte kopieren:
  47. 510 ' Geht mit DOS am schnellsten.
  48. 520 SHELL "COPY TEMP1.TXT + TEMP2.TXT TEMP3.TXT"
  49. 530 :
  50. 540 ' Dateien löschen. Werden nicht mehr gebraucht.
  51. 550 KILL "TEMP1.TXT"
  52. 560 KILL "TEMP2.TXT"
  53. 570 SYSTEM: 'Zurück nach dBase
  54.