home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD2.mdf / c / library / os2 / vmem / ultostr.asm < prev    next >
Encoding:
Assembly Source File  |  1993-03-01  |  3.7 KB  |  129 lines
  1.  
  2. ; ULTOSTR.ASM - Copyright (c) 1992 M.B.Mallory
  3. ; 
  4. ; Assembler: MicroSoft Macro Assembler 6.00B
  5. ;
  6. ; Converts an unsigned 32 bit integer to a formatted string as in
  7. ; the following example:        1,234,567.89
  8. ;
  9. ; IBM C Set/2 calling prototype:
  10. ; CHAR * _System ULongToString (ULONG number, LONG width, LONG dec_places);
  11. ;
  12. ; Note: IBM does not require leading underscores on public symbols.
  13.  
  14. .386
  15.  
  16. BUFSIZE         equ     80
  17. MAX_DECIMALS    equ     30
  18. number          equ     <[ebp+8]>
  19. str_width       equ     <[ebp+12]>
  20. dec_places      equ     <[ebp+16]>
  21.  
  22.  
  23. BSS32   segment FLAT dword public 'BSS'
  24.  
  25. Buffer  db      BUFSIZE dup (?)
  26.  
  27. BSS32   ends
  28. DGROUP  group   BSS32
  29.  
  30.         assume  cs:FLAT, ds:FLAT
  31.  
  32.         public  ULongToString
  33.  
  34. CODE32  segment FLAT dword public 'CODE'
  35.  
  36. ULongToString   proc 
  37.         
  38.         push    ebp
  39.         mov     ebp, esp        ; create stack frame
  40.         push    ebx
  41.         push    edi
  42.         push    esi
  43.  
  44.         xor     edi, edi
  45.         cmp     dword ptr str_width, BUFSIZE-1  
  46.         ja      @Exit           ; width out of range, return NULL pointer
  47.  
  48.         mov     ebx, dec_places
  49.         cmp     ebx, MAX_DECIMALS
  50.         ja      @Exit           ; decimal places out of range, return NULL
  51.  
  52.         mov     eax, number
  53.         mov     ecx, 3          ; three digits between thousand separators
  54.         mov     esi, 10         ; divisor for radix 10
  55.  
  56.         mov     edi, offset FLAT:Buffer
  57.         add     edi, BUFSIZE-1
  58.         push    edi                     ; save pointer to end of string
  59.         mov     byte ptr [edi], 0       ; string terminator
  60.  
  61.         align   4
  62. EmitDigit:
  63.         xor     edx, edx
  64.         div     esi             ; get a digit in edx
  65.         add     edx, 30h        ; convert to ascii
  66.         dec     edi
  67.         mov     [edi], dl       ; add it to string
  68.         or      eax, eax        ; is quotient = 0 ?
  69.         jz      PadDecimal      ;   yes, jump out of loop
  70.                                 ;   no, see if decimal point required
  71.         dec     ebx
  72.         jg      EmitDigit       ; haven't reached decimal point
  73.         jz      PutPeriod       ; insert a period
  74.                                 ; else fall through
  75.         loop    EmitDigit
  76.         mov     ecx, 3          ; reload thousands digits
  77.         dec     edi
  78.         mov     byte ptr [edi], ','     ; insert comma
  79.         jmp     short EmitDigit
  80.  
  81. PutPeriod:
  82.         dec     edi
  83.         mov     byte ptr [edi], '.'     ; insert period
  84.         jmp     short EmitDigit
  85.  
  86. PadDecimal:
  87.         dec     ebx             ; if called for, has period been inserted?
  88.         jl      PadWidth        ;   none called for, move on
  89.         jz      @@2             ;   jump, then insert it
  90.         mov     ecx, ebx        ;   pad with zeros, then insert it
  91.  
  92.         align   4
  93. @@1:    dec     edi
  94.         mov     byte ptr [edi], '0'     ; pad decimal with zeros
  95.         loop    @@1
  96.  
  97. @@2:    dec     edi
  98.         mov     byte ptr [edi], '.'     ; insert period
  99.         dec     edi
  100.         mov     byte ptr [edi], '0'     ; 1 zero preceeds decimal point
  101.  
  102. PadWidth:
  103.         pop     eax             ; get end of string
  104.         sub     eax, edi        ; calc number of characters in string
  105.         mov     ecx, str_width
  106.         sub     ecx, eax        ; calc remaining width, if any
  107.         jle     @Exit           ;   width already exceeded, jump
  108.  
  109.         align   4
  110. @@3:    dec     edi
  111.         mov     byte ptr [edi], 20h     ; fill width with spaces
  112.         loop    @@3
  113.         
  114. @Exit:
  115.         mov     eax, edi        ; return pointer to string
  116.         pop     esi
  117.         pop     edi
  118.         pop     ebx
  119.         pop     ebp
  120.         ret
  121.  
  122. ULongToString   endp
  123.  
  124. CODE32  ends
  125.  
  126. end
  127.  
  128. 
  129.