home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD2.mdf / c / library / mslang / stepon / _temp302.scp < prev    next >
Encoding:
Text File  |  1994-05-04  |  14.1 KB  |  362 lines
  1. '         ^^^^^^^^^^
  2. '            This program is configured in table part: Choose radio button Table
  3. '
  4. ' Hint:
  5. ' You're allowed to use this script or parts of changed or unchanged in your StepOne
  6. ' installation. 
  7. ' This script features professional installations for Windows and is full of hints and
  8. ' examples for your work with StepOne.
  9. ' If you change the table part (view: Table) of the script to your needs,
  10. ' you have a very good installation.
  11. ' One of the highlights of StepOne is the possibility to improve this installation script with 
  12. ' the powerful script language, so you have full control of the whole installation process.
  13. ' 
  14. ' If you start this program without making changes, a new path will be created.
  15. ' If you edit the tables of the Table part corresponding to your needs you get a full installation.
  16.  
  17. ' If you start this script within StepIt, the StepOne FastCodeBuilder, you have to set the path
  18. ' of the to be copied files with menue FASTCODE - SETTINGS - COMMANDLINE, i.e. 'a:'.
  19. ' If the path is followed with a space and -1, you're abled to get the information that
  20. ' StepOne was started within StepIt.
  21. ' ***************************************************************************************************
  22.  
  23. ' ***************************************************************************************************
  24. ' The command line (View: FastCode - Settings - Commandline)which StepIt.exe or Install.exe (FirstStep) 
  25. ' passes through is saved in a variable.
  26. Len "ln", "{_command}"
  27. If "{ln}" = "0"
  28.     Label "NoSourcePath"
  29.     PathBox "command", "Please choose the path of the to be installed files.", "Choose source path", "{_bootdrv}\", "\", "*.*", "0", "&OK;&End"
  30.     if "{command}" = ""
  31.         end
  32.     endif
  33. Else
  34.     Let "command", "{_command}"
  35. EndIf
  36. DirExist "res", "{command}"
  37. If "{res}" = "0"
  38.     Goto "NoSourcePath"
  39. EndIf
  40.  
  41. Split "sourcepath",    "{command}"," ","1"
  42. Split "StepIt",        "{command}"," ","2"
  43.  
  44. Let "prgname", "{prginfos[1;1]}"
  45. Let "mainprg", "{prginfos[2;1]}"
  46.  
  47. ' Look if program runs
  48. GoSub "CheckPrg","{mainprg}"
  49. ' Welcome the user and give hints of using the installation
  50. GoSub "Welcome"
  51. ' Checking VBX files if they are loaded or installed in the Windows directory
  52. GoSub "CheckLibraries"    
  53.  
  54. Label "copyloop"
  55. ' The user can choose the installation path
  56. GoSub "GetTargetPath",  "{prginfos[3;1]}"
  57. ' Create the choosen path
  58. GoSub "CreatePath"
  59. If "{path}" = "0"
  60.     ' If create operation fails or user choosed anything other
  61.     Goto "CopyLoop"
  62. EndIf
  63.  
  64. ' Install files
  65. GoSub "Copying"
  66. If "{space}" = "-1"
  67.     ' Copying failed because of unsufficient disk space.
  68.     ' User has to choose another drive.
  69.     Goto "CopyLoop"
  70. EndIf
  71.  
  72. ' Add icon(s) in Program Manager group
  73. GoSub "ProgMan"
  74.  
  75. ' Add Extension(s)in Registration Database
  76. GoSub "RegBase"
  77.  
  78. ' Edit program INI file(s)
  79. GoSub "PrgINIs"
  80. If "{prginfos[4;1]}" = "-1"
  81.     GoSub "ShareExe"
  82. EndIf
  83.  
  84. ' Inform user about end of installation.
  85. ' Name of program is passed through to give user the possibility to start program immediately.
  86. GoSub "PrgEnd"
  87. ' End of installation
  88. End
  89.  
  90. ' *************************************************************
  91. Sub "Welcome"
  92.     ' Show main window
  93.     Window "-1", "{prgname} Installation", "Welcome", "Welcome to installation of {prgname}. Installation program will lead you through all neccessary steps.{_nl}{_nl}Press Continue to start installation.{_nl}{_nl}Press keys Ctrl and C together to cancel installation.", "", "43;23;960;888", "9"
  94.      GetUserInput "&Continue"
  95. EndSub
  96.  
  97. ' ***************************************************************************************************
  98. Sub "GetTargetPath"
  99.     Parameter targetpath    
  100.     Window "-1", "", "Choose target path", "Please select the path where {prgname} should be installed to."
  101.     Label "GetTargetPath1"
  102.     ' If {ret} is a complete path, 'pathbox' uses only the part after the last backslash.
  103.     ' In example 'c:\windows\system' will be used from 'PathBox' paramter 'Additional Path' as 'system'.
  104.     ' PathBox parameter DefaultPath can contain a relative path, i.e.: 'c:\windows\..' get to 'c:\'.
  105.     PathBox "targetpath", "Please choose the path for {prgname}.", "", "{_windowsdir}\..", "{GetTargetPath:targetpath}", "", "0", "&OK;&Cancel"
  106.     If "{targetpath}" = ""
  107.         ' User has choosed 'Cancel'. AskEnd asks the user if he want to end the program.
  108.         'If user chooses 'Yes', AskEnd works like End.
  109.         AskEnd
  110.         Goto "GetTargetPath1"    
  111.     EndIf
  112. EndSub
  113. ' ***************************************************************************************************
  114. ' New VBX and DLL files can be installed if they aren't loaded.
  115. Sub "CheckLibraries"
  116.     ' If installation program is started within StepIt, check for libraries
  117.     ' isn't neccessary. StepIt uses 
  118.     ' cscombo.vbx, csdialog.vbx, csform.vbx, ss3d.vbx, ss3d2.vbx, qpro200.dll
  119.     ' Some installation programs would fail at this point.
  120.     ' If you don't use the libraries you should set the if selection as remark.
  121.     If "{StepIt}" <> "-1"
  122.         ' Gets number of elements
  123.         GetTableElementCount "number_vbx", "vbxtable"
  124.         For "i", "1", "{number_vbx}"
  125.             FileExist "wfound", "{_windowsdir}\{vbxtable[1;i]}"
  126.              If "{wfound}" = "-1"
  127.                 GoSub "CorrectVBX", "{i}"
  128.             EndIf
  129.         Next
  130.     EndIf
  131. EndSub
  132. ' *********************************************************************************************
  133. Sub "CorrectVBX"
  134.     Parameter "iVbx"
  135.     Label "Active"
  136.     'Copies a common used file    from windows to system directory to force version control
  137.     'It isn't checked if any of the common used files are installed anywhere on the users
  138.     'system. So, nevertheless version conflicts may occure. But this procedure
  139.     'fixed the common mistake to install vbx and dll in the windows directory.
  140.     IsTaskActive "res", "{vbxtable[1;i]}"
  141.     If "{res}" = "-1"
  142.         MsgBox "res", "'{vbxtable[1;i]}' is in use. Please exit the application which uses the file and try it again.{_NL}If you aren't sure which application uses the library please exit all applications except of the Program Manager and this program.", "", "&Retry;&Program End"
  143.         If "{res}" = "2"
  144.             AskEnd
  145.         Else
  146.             Goto "Active"
  147.         EndIf
  148.     Else
  149.         MsgBox "correct", "'{vbxtable[1;i]}' was found in your Windows directory. {_nl}Libraries like '{vbxtable[1;i]}' should be installed in System directory.{_nl}Should installation program '{vbxtable[1;i]}' correct the problem? To be sure that '{prgname}' runs correctly you should choose 'Correct'!", "", "&Correct;&Ignore"
  150.          If "{correct}" = "1"
  151.             Copy "{_windowsdir}\{vbxtable[1;i]}", "{_systemdir}\{vbxtable[1;i]}", "2" 
  152.             If "{_err}" = "0"
  153.                 Del "{_windowsdir}\{vbxtable[1;i]}"
  154.             Else
  155.                 OutBox "'{vbxtable[1;i]}' couldn't be moved to System directory. If '{prgname}' doesn't run you should repeat the installation."
  156.             EndIf
  157.         EndIf
  158.       EndIf
  159. EndSub
  160.  
  161. ' ***************************************************************************************************
  162. Sub "CheckPrg"
  163.     Parameter "p"
  164.     Label "CheckPrg2"
  165.     IsTaskActive "res","{CheckPrg:p}"
  166.     If "{res}" = "-1"
  167.         MsgBox "ret", "{CheckPrg:p} is active. To install a newer version you have to close it first, to be sure that version control works correct. Should installation program close {PrⁿfePrg:p} for you?", "", "&Task close;&Retry;&Program end"
  168.         If "{ret}" = "1"
  169.             TaskStop "{CheckPrg:p}"
  170.         EndIf
  171.         If "{ret}" = "3"
  172.             End
  173.         EndIf
  174.         Goto "CheckPrg2"
  175.     Else
  176.         Goto "CheckPrg1"
  177.     EndIf
  178. Label "CheckPrg1"
  179. EndSub
  180.  
  181. ' ***************************************************************************************************
  182. Sub "CreatePath"
  183.     DirExist "res", "{targetpath}"
  184.     If "{res}" = "0"
  185.         MsgBox "res", "'{targetpath}' doesn't exist.{_nl}Do you want to create the path?", "", "&Create;Change &selection;&Program end"
  186.         If "{res}" = "3"
  187.             End
  188.         EndIf
  189.         If "{res}" = "2"
  190.             Let "directory", "0"    
  191.             Goto "CreatePath1"    
  192.         EndIf
  193.         MkDir "{targetpath}"
  194.         If "{_err}" = "-1"
  195.             OutBox "During creation of path '{targetpath}' an error occurs. Please choose another path."
  196.             Let "directory", "0"        
  197.         Else
  198.             Let "directory", "-1"
  199.         EndIf
  200.     Else
  201.         Let "directory", "-1"
  202.     EndIf
  203. Label "CreatePath1"
  204. EndSub
  205.  
  206. ' ***************************************************************************************************
  207. Sub "Copying"
  208.     Window "-1", "", "Copying...", " "
  209.     SplitPathName "todrv", "{targetpath}", "5"
  210.     ' StepOne calcs the total of all file lengths and substracts the sum of
  211.     ' the file lengths which will be overwritten. The minimum isn't 0
  212.     ' indeed it is the length of the longest file, which should be installed
  213.     ' if the installation is on the same drive as temp drive.
  214.     CalcFileTable "targetbytes", "targettable", "{sourcepath}", "{targetpath}", "3"
  215.     CalcFileTable "systembytes", "systemtable", "{sourcepath}", "{_systemdir}", "3"
  216.     ' Checks if two given paths have the same drive name
  217.     If "{_systemdir}" := "{targetpath}"
  218.         Compute "tofreebytes","{tofreebytes}" + "{targetbytes}"
  219.     Else
  220.         GetDiskFree "systemfreebytes", "{_systemdir}"    
  221.         If "{systembytes}" > "{systemfreebytes}"
  222.             OutBox "On drive{_nl}'{todrv}'{_nl}isn't enough space free. {systembytes} bytes free space required.{_nl}Please free enough space on drive and retry installation."
  223.             End
  224.         EndIf
  225.     EndIf
  226.     GetDiskFree "tofreebytes", "{targetpath}"
  227.     If "{targetbytes}" > "{tofreebytes}"
  228.         OutBox "On drive{_nl}'{todrv}'{_nl}isn't enough space free. Please choose another drive."
  229.         Let "space", "-1"
  230.         Goto "Copying_end"
  231.     Else
  232.         Window "-1", "", "Copying...", "Please be patient..."
  233.         GetTableLineCount "number_copy", "targettable"
  234.         If "{number_copy}" > "0"
  235.             CopyFileTable "targettable", "{sourcepath}", "{targetpath}", "1", "0"
  236.             If "{_err}" = "-1"
  237.                 MsgBox "res", "During copying occurs errors. Do you want to continue installation nevertheless?", "", "&OK;&Program end"
  238.                 If "{res}" = "2"
  239.                     End
  240.                 EndIf
  241.             EndIf
  242.         EndIf
  243.         If "{StepIt}" <> "-1"
  244.             GetTableLineCount "number_copy", "systemtable"
  245.             If "{number_copy}" > "0"
  246.                 Window "-1", "", "Copying system files..."
  247.                 CopyFileTable "systemtable", "{sourcepath}", "{_systemdir}", "1", "0"
  248.                 'Make sure, dialog will be closed
  249.                 CopyFileTable
  250.                 If "{_err}" = "-1"
  251.                     MsgBox "res", "During copying occurs errors. Do you want to continue installation nevertheless?", "", "&OK;&Program end"
  252.                     If "{res}" = "2"
  253.                         End
  254.                     EndIf
  255.                 EndIf
  256.             EndIf
  257.         EndIf
  258.         Let "space", "0"    
  259.     EndIf
  260.     Label "copying_end"
  261. EndSub
  262.  
  263. ' ***************************************************************************************************
  264. Sub "ProgMan"
  265.     ' Get number of elements
  266.     GetTableLineCount "number_prg", "prgmantable"
  267.     If "{number_prg}" > "0"
  268.         Window "-1", "", "Installing icons...", "Please be patient..."
  269.         Let "i", "1"
  270.         Let "tmp",""
  271.         Label "ProgMan1"    
  272.         If "{tmp}" <>  "{prgmantable[i;1]}"
  273.             Let "tmp", "{prgmantable[i;1]}"
  274.             DDEExecute "ProgMan", "ProgMan", "", "[creategroup({prgmantable[i;1]})]"
  275.             If "{_err}" = "-1"
  276.                 OutBox "Group '{prgmantable[i;1]}' couldn't be created in Program Manager."
  277.             EndIf
  278.         EndIf
  279.         GoSub "icon","{prgmantable[i;1]}","{targetpath}\{prgmantable[i;2]}","{prgmantable[i;3]}"
  280.         Compute "i", "{i}" + "1"
  281.         If "{i}" <= "{number_prg}"
  282.             Goto "ProgMan1"
  283.         EndIf
  284.     EndIf
  285. EndSub
  286.  
  287. ' ***************************************************************************************************
  288. Sub "Icon"
  289. Parameter "group","name","title"
  290.     ' Sets the group window so that 'replaceitem' can find the group window
  291.     DDEExecute "ProgMan", "ProgMan", "", "[showgroup({icon:group},1)]"
  292.     DDEExecute "ProgMan", "ProgMan", "", "[showgroup({icon:group},2)]"
  293.     ' Deletes icon and saves position...
  294.     DDEExecute "ProgMan", "ProgMan", "", "[replaceitem({icon:title})]"
  295.     ' ... Additem can use it
  296.     DDEExecute "ProgMan", "ProgMan", "", "[additem({icon:name},{icon:title},,)]"
  297.     If "{_err}" = "-1"
  298.         OutBox "'{prgname}' icon couldn't be installed in Program Manager."
  299.     EndIf
  300.     ' Brings group window on top, so user can find it immediately.
  301.     DDEExecute "ProgMan", "ProgMan", "", "[showgroup({icon:group},1)]"
  302. EndSub
  303. ' ***************************************************************************************************
  304. Sub "RegBase"
  305.     ' Gets number of elements
  306.     GetTableLineCount "number_reg", "regbasetable"
  307.     If "{number_reg}" > "0"
  308.         Let "i", "1"
  309.         Label "RegBase1"    
  310.         RegBaseWrite "{regbasetable[i;2]}", "{regbasetable[i;3]}"
  311.         RegBaseWrite "{regbasetable[i;3]}", "{regbasetable[i;4]}"
  312.         RegBaseWrite "{regbasetable[i;3]}\shell\open\command", "{targetpath}\{regbasetable[i;5]}"
  313.         If "{regbasetable[i;1]}" <> "CMD"
  314.             RegBaseWrite "{regbasetable[i;3]}\shell\open\ddeexec", "{regbasetable[i;6]}"
  315.             RegBaseWrite "{regbasetable[i;3]}\shell\open\ddeexec\application", "{regbasetable[i;7]}"
  316.             RegBaseWrite "{regbasetable[i;3]}\shell\open\ddeexec\topic", "{regbasetable[i;8]}"
  317.         EndIf
  318.         Compute "i", "{i}" + "1"
  319.         If "{i}" <= "{number_reg}"
  320.             Goto "RegBase1"
  321.         EndIf
  322.     EndIf    
  323. EndSub
  324.  
  325. ' ***************************************************************************************************
  326. Sub "PrgINIs"
  327.     ' Gets number of elements
  328.     GetTableLineCount "number_ini", "initable"
  329.     If "{number_ini}" > "0"
  330.         Let "i","1"
  331.         Label "PrgINIs1"
  332.         INIWrite "{initable[i;1]}","{initable[i;2]}","{initable[i;3]}","{initable[i;4]}"
  333.         Compute "i", "{i}" + "1"
  334.         If "{i}" <= "{number_ini}"
  335.             Goto "PrgINIs1"
  336.         EndIf
  337.     EndIf
  338. EndSub
  339.  
  340. ' ***************************************************************************************************
  341. Sub "ShareExe"
  342.     If "{_locking}" = "0"
  343.         MsgBox "addlocking", "'{prgname}' needs a network or SHARE for his database. Installation program can install SHARE in your AUTOEXEC.BAT and restarts your system after end of installation to let the changes effect. Do you want to add SHARE? To make the changes on yourself choose 'Not install'.", "SHARE.EXE", "&Install;&Not install"
  344.         If "{addlocking}" = "1"
  345.             AddShareExe
  346.         EndIf    
  347.     EndIf
  348. EndSub
  349.  
  350. Sub "PrgEnd"
  351.     Window "-1", "", "Ready!", "It's completed. Installation of '{prgname}' is finished."
  352.     GetUserInput "&OK"
  353.     If "{addlocking}" = "1"
  354.         MsgBox "reboot", "Installation program has add SHARE.EXE to your AUTOEXEC.BAT. To let the changes effect you've to restart your system. Should installation program makes a restart?", "Warmstart", "&Restart;&No Restart"
  355.         If "{reboot}" = "1"
  356.             ReBoot "3"
  357.         Else
  358.             OutBox "Before start of {prgname} you've to restart your system."
  359.         EndIf
  360.     EndIf
  361. EndSub
  362.