home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD2.mdf / c / library / dos / grafik / xlib / xtext.asm < prev    next >
Encoding:
Assembly Source File  |  1992-11-12  |  10.8 KB  |  359 lines
  1. ;-----------------------------------------------------------------------
  2. ; MODULE XTEXT
  3. ;
  4. ; Point functions all MODE X 256 Color resolutions
  5. ;
  6. ; Compile with Tasm.
  7. ; C callable.
  8. ;
  9. ;
  10. ; ****** XLIB - Mode X graphics library                ****************
  11. ; ******                                               ****************
  12. ; ****** Written By Themie Gouthas                     ****************
  13. ;
  14. ; egg@dstos3.dsto.gov.au
  15. ; teg@bart.dsto.gov.au
  16. ;-----------------------------------------------------------------------
  17.  
  18.  
  19. include xlib.inc
  20. include xtext.inc
  21.  
  22. .data
  23.  
  24. _FontDriverActive db 0
  25.  
  26.  
  27. _CharHeight   db         0
  28. _CharWidth    db         0
  29. _FontPtr      dw  2 dup (0)
  30. _FirstChar    db         0
  31.  
  32. _UserFontPtr   dw  2 dup (0)
  33. _UserChHeight  db         0
  34. _UserChWidth   db         0
  35. _UserFirstCh   db         0
  36.  
  37.  
  38. F8x8Ptr       dw  2 dup (0)
  39. F8x14Ptr      dw  2 dup (0)
  40.  
  41. ; This is a look up table for the mirror image of a byte eg
  42. ; a byte with the value 11001010 has a corresponding byte in the table
  43. ; 01010011. This is necessary as the VGA rom font bits are the reverse
  44. ; order of what we need for the Mode X. If you know a better-faster way
  45. ; TELL ME!
  46.  
  47. MirrorTable  label byte
  48.     db   0,128, 64,192, 32,160, 96,224, 16,144, 80,208, 48,176,112,240
  49.     db   8,136, 72,200, 40,168,104,232, 24,152, 88,216, 56,184,120,248
  50.     db   4,132, 68,196, 36,164,100,228, 20,148, 84,212, 52,180,116,244
  51.     db  12,140, 76,204, 44,172,108,236, 28,156, 92,220, 60,188,124,252
  52.     db   2,130, 66,194, 34,162, 98,226, 18,146, 82,210, 50,178,114,242
  53.     db  10,138, 74,202, 42,170,106,234, 26,154, 90,218, 58,186,122,250
  54.     db   6,134, 70,198, 38,166,102,230, 22,150, 86,214, 54,182,118,246
  55.     db  14,142, 78,206, 46,174,110,238, 30,158, 94,222, 62,190,126,254
  56.     db   1,129, 65,193, 33,161, 97,225, 17,145, 81,209, 49,177,113,241
  57.     db   9,137, 73,201, 41,169,105,233, 25,153, 89,217, 57,185,121,249
  58.     db   5,133, 69,197, 37,165,101,229, 21,149, 85,213, 53,181,117,245
  59.     db  13,141, 77,205, 45,173,109,237, 29,157, 93,221, 61,189,125,253
  60.     db   3,131, 67,195, 35,163, 99,227, 19,147, 83,211, 51,179,115,243
  61.     db  11,139, 75,203, 43,171,107,235, 27,155, 91,219, 59,187,123,251
  62.     db   7,135, 71,199, 39,167,103,231, 23,151, 87,215, 55,183,119,247
  63.     db  15,143, 79,207, 47,175,111,239, 31,159, 95,223, 63,191,127,255
  64.  
  65. MirrorTableOffs dw         ?
  66. .code
  67.  
  68. ;----------------------------------------------------------------------
  69. ; x_text_init    - Initializes the Mode X text driver and sets the
  70. ;                  default font (VGA ROM 8x8)
  71. ;
  72. ; C caller:
  73. ;
  74. ;  x_text_init()
  75. ;
  76. ; Written by Themie Gouthas
  77. ;----------------------------------------------------------------------
  78. _x_text_init proc
  79.   push bp
  80.  
  81.   mov  [_FontDriverActive],TRUE
  82.   mov  ax,1130h                   ; AH = BIOS generator function
  83.                   ; AL = BIOS get font pointer subfunction
  84.   push ax                         ; Save Video interrupt function parameters
  85.   mov  bh,3                       ; Select 8x8 VGA ROM font
  86.   int  10h                        ; Call BIOS video interrupt
  87.   mov  word ptr [F8x8Ptr],bp      ; Save 8x8 Font address in FontPtr table
  88.   mov  word ptr [F8x8Ptr+2],es
  89.  
  90.   mov  word ptr [_FontPtr],bp     ; Default font = 8x8 ROM font
  91.   mov  word ptr [_FontPtr+2],es
  92.  
  93.   pop  ax                         ; Recall Video interrupt function parameters
  94.   mov  bh,2                       ; Select 8x14 VGA ROM font
  95.   int  10h                        ; Call BIOS video interrupt
  96.   mov  word ptr [F8x14Ptr],bp     ; Save 8x14 Font address in FontPtr table
  97.   mov  word ptr [F8x14Ptr+2],es
  98.  
  99.  
  100.   mov  al,8
  101.   mov  [_CharHeight],al            ; Set the font character heights
  102.   mov  [_CharWidth] ,al            ; Set the font character widths
  103.  
  104.   mov  dx,offset MirrorTable       ; Initialize mirror table offset
  105.   mov  [MirrorTableOffs],dx
  106.  
  107.   pop  bp
  108.   ret
  109. _x_text_init endp
  110.  
  111.  
  112. ;----------------------------------------------------------------------
  113. ; x_set_font - Mode X Set current font for text drawing
  114. ;
  115. ; C caller:
  116. ;
  117. ;  x_set_font(int FontID)
  118. ;
  119. ; PARAMETERS  FontID    0 = VGA ROM 8x8
  120. ;                       1 = VGA ROM 8x14
  121. ;                       2 = User defined bitmapped font
  122. ;
  123. ;
  124. ; WARNING: A user font must be registered before setting FontID 2
  125. ;
  126. ; Written by Themie Gouthas
  127. ;----------------------------------------------------------------------
  128.  
  129. _x_set_font proc
  130.   ARG FontID:word
  131.   push bp
  132.   mov  bp,sp
  133.  
  134.   xor  dx,dx             ; Clear DX - Mirror table offset (0 for non ROM fonts)
  135.   mov  cx,FontID
  136.   cmp  cx,2
  137.  
  138.   jne  @@not_userfont     ; Do we have a user font
  139.   mov  ax,[_UserFontPtr]   ; Yes - Activate it
  140.   mov  [_FontPtr],ax
  141.  
  142.   mov  ax,[_UserFontPtr+2]
  143.   mov  [_FontPtr+2],ax
  144.  
  145.   mov  al,[_UserChHeight]
  146.   mov  [_CharHeight],al   ; Set the font character heights
  147.  
  148.   mov  al,[_UserChWidth]
  149.   mov  [_CharWidth],al    ; Set the font character heights
  150.  
  151.   mov  al,[_UserFirstCh]
  152.   mov  [_FirstChar],al
  153.   jmp  short @@done
  154.  
  155. @@not_userfont:              ; We have a ROM font
  156.  
  157.   mov  dx,offset MirrorTable
  158.   mov  [_CharWidth],8        ; Set the font character widths
  159.   mov  [_FirstChar],0        ; Character sets start at ascii 0
  160.   cmp  cx,1                  ; Do we have an 8x14 ROM font
  161.   jne  @@not_8x14font        ; No, we have 8x8 - jump
  162.  
  163.   mov  ax,[F8x14Ptr]         ; Yes Activate it
  164.   mov  [_FontPtr],ax
  165.  
  166.   mov  ax,[F8x14Ptr+2]
  167.   mov  [_FontPtr+2],ax
  168.  
  169.   mov  [_CharHeight],14    ; Set the font character heights
  170.   jmp  short @@done
  171.  
  172. @@not_8x14font:
  173.   mov  ax,[F8x8Ptr]        ; Activate the 8x8 ROM Font
  174.   mov  [_FontPtr],ax
  175.  
  176.   mov  ax,[F8x8Ptr+2]
  177.   mov  [_FontPtr+2],ax
  178.  
  179.   mov  [_CharHeight],8     ; Set the font character heights
  180.  
  181. @@done:
  182.   mov  [MirrorTableOffs],dx
  183.  
  184.   pop  bp
  185.   ret
  186. _x_set_font endp
  187.  
  188.  
  189. ;----------------------------------------------------------------------
  190. ; x_register_userfont - Mode X register user font
  191. ;
  192. ; C caller:
  193. ;
  194. ;  x_register_userfont(void far *user_font)
  195. ;
  196. ;
  197. ; NOTES  registering a user font deregisters the previous user font
  198. ;        User fonts may be at most 8 pixels wide
  199. ;
  200. ;
  201. ; USER FONT STRUCTURE
  202. ;
  203. ;  Word:  ascii code of first char in font
  204. ;  Byte:  Height of chars in font
  205. ;  Byte:  Width of chars in font
  206. ;  n*h*Byte: the font data where n = number of chars and h = height
  207. ;      of chars
  208. ;
  209. ; WARNING: The onus is on the program to ensure that all characters
  210. ;          drawn whilst this font is active, are within the range of
  211. ;          characters defined.
  212. ;
  213. ; Written by Themie Gouthas
  214. ;----------------------------------------------------------------------
  215. _x_register_userfont proc
  216.   ARG  FontToRegister:dword
  217.   push bp
  218.   mov  bp,sp
  219.   push si
  220.  
  221.   mov  ax,word ptr [FontToRegister]
  222.   mov  bx,word ptr [FontToRegister+2]
  223.   add  ax,4
  224.   mov  [_UserFontPtr],ax
  225.   mov  [_UserFontPtr+2],bx
  226.  
  227.   push ds
  228.   lds  si,[FontToRegister]
  229.   lodsw
  230.   mov  bx,ax
  231.   lodsw
  232.   pop  ds
  233.  
  234.   mov  [_UserChHeight],al
  235.   mov  [_UserChWidth],ah
  236.   mov  [_UserFirstCh],bl
  237.   pop  si
  238.   pop  bp
  239.   ret
  240. _x_register_userfont endp
  241.  
  242.  
  243. ;----------------------------------------------------------------------
  244. ; x_char_put - Mode X Draw a text character at the specified location
  245. ;
  246. ;
  247. ; C caller:
  248. ;
  249. ;  x_char_put(char ch, int x, int y, unsigned ScrnOffs, unsigned Color)
  250. ;
  251. ; PARAMETERS  ch        char to draw
  252. ;             x,y       screen coords at which to draw ch
  253. ;             ScrnOffs  Starting offset of page on whih to draw
  254. ;          Color     Color of the text
  255. ;
  256. ; NOTES:  Uses the current font settings. See SetFont, InitTextDriver,
  257. ;         RegisterUserFont
  258. ;
  259. ; WARNING: InitTextDriver must be called before using this function
  260. ;
  261. ;
  262. ; Written by Themie Gouthas
  263. ;----------------------------------------------------------------------
  264. _x_char_put  proc
  265.   ARG  Chr:byte,X:word,Y:word,ScrnOffs:word,Color:word
  266.   LOCAL ScreenInc:word,Hold:word=LocalStk
  267.   push bp
  268.   mov  bp,sp
  269.   sub  sp,LocalStk
  270.   push si
  271.   push di
  272.   push ds
  273.  
  274.   cld
  275.   mov  ax,[_ScrnLogicalByteWidth] ; AX = Virtual screen width
  276.   mov  bx,ax                      ; copy Virt screen width and decrement
  277.   sub  bx,3                       ; by the max number of bytes (whole or part)
  278.                   ; that a character row may occupy on the screen
  279.   mov  [ScreenInc],bx             ; Save it to the local stack var. SceenInc
  280.   mul  [Y]                        ; Find the starting dest. screen address of
  281.   mov  di,[X]                     ;  the character to draw
  282.   mov  cx,di
  283.   shr  di,2
  284.   add  di,ax
  285.   add  di,[ScrnOffs]              ; Dont forget to compensate for page
  286.  
  287.   mov  ax,SCREEN_SEG              ; ES:DI -> first screen dest. byte of char
  288.   mov  es,ax
  289.  
  290.   and  cx,3                       ; CH = 0, CL = Plane of first pixel
  291.  
  292.   mov  bx,[MirrorTableOffs]       ; set BX to offset of mirror table for XLAT
  293.   mov  al,[_CharHeight]           ; AL = Character height, AH = 0
  294.   xor  ah,ah
  295.   mov  ch,al                      ; CL = Character height
  296.   mov  dl,[Chr]                   ; User fonts may have incomplete charsets
  297.   sub  dl,[_FirstChar]            ;  this compensates for fonts not starting at
  298.                   ;  ascii value 0
  299.   mul  dl                         ; Mult AX by character to draw giving offset
  300.                   ; of first character byte in font table
  301.  
  302.   lds  si,dword ptr [_FontPtr]    ; DS:SI -> beggining of required font
  303.   add  si,ax                      ; DS:SI -> first byte of req. char
  304.  
  305.   mov  dx,SC_INDEX                ; Prepare for VGA out's
  306.  
  307. @@MainLoop:
  308.  
  309.   lodsb               ; load character byte into AL
  310.   or   bx,bx          ; if BX=0 -> User font, so no need to mirror data
  311.   jz   @@DontMirror
  312.   push ds
  313.   mov  dx,@data       ; Set DS to the Mirror lookup table's segment
  314.   mov  ds,dx          ; - BX should already contain the offset addr of table
  315.   xlatb               ; AL is now replaced by the corresponding table entry
  316.   pop  ds             ; Restore previous data segment
  317.   mov  dx,SC_INDEX    ; Restore DX
  318.  
  319. @@DontMirror:
  320.   xor  ah,ah          ; shift the byte for the dest plane and save it
  321.   shl  ax,cl
  322.   mov  [Hold],ax
  323.  
  324.   mov  ah,al                 ; output high nibble of first byte of shifted char
  325.   mov  al,MAP_MASK
  326.   out  dx,ax
  327.   mov  al,byte ptr [Color]
  328.   stosb
  329.                  ; output low nibble of first byte of shifted char
  330.   mov  ax,[Hold]
  331.   shl  ax,4
  332.   mov  al,MAP_MASK
  333.   out  dx,ax
  334.   mov  al,byte ptr [Color]
  335.   stosb
  336.  
  337.   mov  ax,[Hold]             ; output high nibble of last byte of shifted char
  338.   mov  al,MAP_MASK           ; completing the drawing of one character row
  339.   out  dx,ax
  340.   mov  al,byte ptr [Color]
  341.   stosb
  342.  
  343.   add  di,[ScreenInc]        ; Now move to the next screen row and do the same
  344.   dec  ch                    ; any remaining character bytes
  345.   jnz  @@MainLoop
  346.   pop  ds
  347.   mov  ah,0
  348.   mov  al,[_CharWidth]       ; return the character width (for string fuctions
  349.   pop  di                    ; using this character drawing function).
  350.   pop  si
  351.   mov  sp,bp
  352.   pop  bp
  353.   ret
  354. _x_char_put endp
  355.  
  356.  
  357. end
  358.  
  359.