home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / xbase / library / clipper / patches / floptst.asm < prev    next >
Encoding:
Assembly Source File  |  1991-09-23  |  10.0 KB  |  237 lines
  1. ; File......: FLOPTST.ASM
  2. ; Author....: Joseph LaCour
  3. ; Date......: $Date:   23 Sep 1991 14:56:42  $
  4. ; Revision..: $Revision:   1.3  $
  5. ; Log file..: $Logfile:   E:/nanfor/src/floptst.asv  $
  6. ; 
  7. ; This is an original work by Joseph LaCour and is placed in the
  8. ; public domain.
  9. ;
  10. ;
  11. ;  ACKNOWLEDGEMENTS:
  12. ;
  13. ;          PAOLO RAMOZZI FOR HIS WORK IN DBDCHECK FOR SHOWING HOW TO
  14. ;          USE INT 13H.
  15. ;
  16. ;
  17. ; Modification history:
  18. ; ---------------------
  19. ;
  20. ; $Log:   E:/nanfor/src/floptst.asv  $
  21. ;  
  22. ;     Rev 1.3   23 Sep 1991 14:56:42   GLENN
  23. ;  Bug reports from Craig Austin, James Finnal, and Ted Means.  Line 128
  24. ;  had MOV FDRIVE,AL which should have been MOV FDRIVE,BL.  This caused the
  25. ;  function to erroneously use the last drive available instead of the one
  26. ;  specified by the calling process.
  27. ;  
  28. ;     Rev 1.2   15 Aug 1991 23:07:48   GLENN
  29. ;  Forest Belt proofread/edited/cleaned up doc
  30. ;  
  31. ;     Rev 1.1   11 May 1991 00:21:42   GLENN
  32. ;  File header changed to conform to Toolkit standard.
  33. ;
  34.  
  35. ;  $DOC$
  36. ;  $FUNCNAME$
  37. ;      FT_FLOPTST()
  38. ;  $CATEGORY$
  39. ;      DOS/BIOS
  40. ;  $ONELINER$
  41. ;      Test diskette drive status
  42. ;  $SYNTAX$
  43. ;      FT_FLOPTST( <nDrive> ) -> nStatus
  44. ;  $ARGUMENTS$
  45. ;      <nDrive> is the diskette drive number, 0 = A:, 1 = B:
  46. ;  $RETURNS$  
  47. ;      -1 - Wrong Parameters
  48. ;       0 - Drive Loaded and ready to read or write
  49. ;       1 - Drive Door Open or Diskette inserted upside down
  50. ;       2 - Diskette is unformatted
  51. ;       3 - Write protected
  52. ;       4 - Undetermined
  53. ;  $DESCRIPTION$
  54. ;      FT_FLOPTST() is designed as a full replacement for ISDRIVE().  Where
  55. ;      ISDRIVE() returns just .T. or .F. depending if the diskette drive is
  56. ;      ready or not, FT_FLOPTST() returns a numeric code designating the
  57. ;      diskette drive's status.
  58. ;
  59. ;      FT_FLOPTST() is particularly useful in backup and restore programs
  60. ;      that need to test the floppy drive before writing/reading from a
  61. ;      floppy disk.
  62. ;  $EXAMPLES$
  63. ;      iStatus := FT_FLOPTST( 1 )
  64.  
  65. ;      DO CASE
  66. ;         CASE iStatus == 1
  67. ;            Qout( "The door to drive A is open." )
  68. ;         CASE iStatus == 2
  69. ;            Qout( "The diskette in drive A is not formatted." )
  70. ;         CASE iStatus == 3
  71. ;            Qout( "The diskette in drive A is write-protected." )
  72. ;         CASE iStatus == 4
  73. ;            Qout( "Something is wrong with drive A, but I don't know what." )
  74. ;      ENDCASE
  75. ;  $END$
  76.  
  77.  
  78. public  FT_FLOPTST
  79.  
  80. EXTRN   __PARNI:FAR
  81. EXTRN   __PARINFO:FAR
  82. EXTRN   __RETNI:FAR
  83.  
  84. _FT_DATASEG  SEGMENT PUBLIC  'DATA'
  85.  
  86. FDRIVE          DB      0
  87. BOOT_SECT       DB      512 DUP (0)
  88.  
  89. _FT_DATASEG  ENDS
  90.  
  91. _NANFOR   SEGMENT 'CODE'
  92.         ASSUME  CS:_NANFOR,DS:_FT_DATASEG,ES:_FT_DATASEG,SS:NOTHING
  93.  
  94.  
  95. FT_FLOPTST      PROC    FAR
  96.  
  97.                 XOR     AX,AX                        ; GET # OF PARAMETERS
  98.                 PUSH    AX                           ;
  99.                 CALL    __PARINFO                    ; CALL INFORMATION FUNCTION
  100.                 ADD     SP,2                         ; FIX UP THE STACK
  101.                 CMP     AL,1                         ; # OF PARAMETERS = 1 ?
  102.                 JNB     GETTYPE                      ; YES. GET THE TYPE
  103.                 JMP     SHORT FERROR                 ; NO. RETURN ERROR
  104.  
  105. GETTYPE:
  106.                 MOV     AX,1                         ; SPECIFY FIRST PARAM
  107.                 PUSH    AX
  108.                 CALL    __PARINFO                    ; CALL INFO FUNCTION
  109.                 ADD     SP,2                         ; FIX UP THE STACK
  110.                 TEST    AX,2                         ; NUMERIC?
  111.                 JNZ     GETDRIVE                     ; YES.  GET DRIVE
  112.                 JMP     SHORT FERROR                 ; NO.  REPORT ERROR
  113.  
  114. GETDRIVE:
  115.                 MOV     AX,1                         ; GET 1ST PARAMETER (drive)
  116.                 push    ax                           ;
  117.                 call    __parni                      ; must be a integer type
  118.                 add     sp,2                         ; fix up the stack
  119.                 push    ax                           ; save drive
  120.                 int     11h                          ; get equipment list
  121.                 mov     ah,0                         ; clear high byte
  122.                 mov     cl,6                         ; set shift count
  123.                 shr     al,cl                        ; shift diskette count
  124.                 pop     bx                           ; restore drive
  125.                 cmp     bl,al                        ; does drive exist?
  126.                 jbe     ParamOk                      ; yes, so continue
  127. derror:         jmp     short Ferror                 ; Invalid drive
  128.  
  129. ParamOk:
  130.                 push    ds                           ; Save DS
  131.                 mov     dx,_FT_DATASEG               ; DATA SEGMENT
  132.                 MOV     DS,DX                        ; IN DS REGISTER
  133.                 MOV     ES,DX                        ; IN ES REGISTER
  134.                 MOV     FDRIVE,BL                    ; SAVE DRIVE NUMBER
  135.                 XOR     AX,AX                        ; RESET DISKETTE SYSTEM
  136.                 INT     13H                          ; CALL BIOS
  137.                 CALL    _FTFLOPT                     ; TEST DISKETTE TYPE
  138.                 POP     DS                           ; RESTORE DS
  139.                 JMP     SHORT EXIT                   ; RETURN
  140.  
  141. FERROR:
  142.                 MOV     AX,-1                        ; BAD PARAMETERS
  143.  
  144. EXIT:
  145.                 PUSH     AX                          ; PUSH RETURN VALUE
  146.                 CALL     __RETNI                     ; AND RETURN IT TO CLIPPER
  147.                 ADD      SP,2                        ; FIX UP THE STACK
  148.  
  149.                 RET                                  ; FAR RETURN TO CLIPPER
  150.  
  151. FT_FLOPTST      ENDP
  152.  
  153. ;-----------------------------------------------------------;
  154. ; LOCAL SUBROUTINE - CALL BIOS INT 13 FOR READ SECTOR       ;
  155. ;-----------------------------------------------------------;
  156.  
  157. _FTINT13        PROC    NEAR
  158.                 PUSH    BX                           ; SAVE REGS
  159.                 PUSH    ES                           ;
  160.                 PUSH    AX                           ;
  161.                 INT     13H                          ; CALL BIOS (read sector)
  162.                 jnc     ftIntRet                     ; Read ok. Exit
  163.                 xor     ax,ax                        ; reset diskette system
  164.                 int     13h                          ; call BIOS
  165.                 pop     ax                           ; restore regs
  166.                 pop     es                           ; for retry
  167.                 push    es                           ; save regs
  168.                 push    ax                           ;
  169.                 int     13h                          ; call BIOS (read sector)
  170.                 jnc     ftIntRet                     ; Read ok. Exit
  171.                 xor     ax,ax                        ; reset diskette system
  172.                 int     13h                          ; call BIOS
  173.                 pop     ax                           ; restore regs
  174.                 pop     es                           ; for retry
  175.                 push    es                           ; save regs
  176.                 push    ax                           ;
  177.                 int     13h                          ; call BIOS (read sector)
  178. ftIntRet:       pop     bx                           ; restore regs
  179.                 pop     es                           ;
  180.                 pop     bx                           ;
  181.                 ret                                  ; near return
  182.  
  183. _ftint13        endp
  184.  
  185. ;-----------------------------------------------------------;
  186. ; Local subroutine - check boot sector                      ;
  187. ;-----------------------------------------------------------;
  188.  
  189. _ftflopt        proc    near
  190.  
  191.                 push    di                           ; preserve
  192.                 mov     di,OFFSET _FT_DataSeg:boot_sect   ; address of buffer
  193. ftflopred:
  194.                 xor     dx,dx                        ; clear DX
  195.                 mov     dl,fdrive                    ; drive number in DL
  196.                 mov     cx,0001h                     ; track 0, sector 1
  197.                 mov     bx,di                        ; buffer addr in ES:BX
  198.                 mov     ax,0201h                     ; read one sector
  199.                 call    _ftint13                     ; call BIOS
  200.                 jnc     Flop1                        ; Read ok. Continue
  201.                 cmp     ah,80h                       ; drive not ready ?
  202.                 je      Flop_out                     ; Yes.
  203.                 cmp     ah,02h                       ; unformatted?
  204.                 je      Flop_for                     ; Yes
  205.                 mov     ax,4                         ; otherwise, unknown
  206.                 jmp     short Flop_End               ; and exit
  207. Flop1:
  208.                 xor     dx,dx                        ; clear DX
  209.                 mov     dl,fdrive                    ; drive number in DL
  210.                 mov     cx,0001h                     ; track 0, sector 1
  211.                 mov     bx,di                        ; buffer addr in ES:BX
  212.                 mov     ax,0301h                     ; write one sector
  213.                 call    _ftint13                     ; call BIOS
  214.                 jnc     Flop_OK                      ; Write ok. Disk s/b AOK
  215.                 cmp     ah,03h                       ; Write protected?
  216.                 jne     Flop_OK                      ; No disk AOK
  217.                 mov     ax,3
  218.                 jmp     short Flop_End
  219. Flop_out:
  220.                 mov     ax,1
  221.                 jmp     short Flop_End
  222. Flop_for:
  223.                 mov     ax,2
  224.                 jmp     short Flop_End
  225. Flop_OK:
  226.                 xor     ax,ax                        ; AX = 0
  227. Flop_End:
  228.                 pop     di                           ; restore
  229.                 ret                                  ; near return
  230.  
  231. _ftflopt        endp
  232.  
  233. _nanfor         ends
  234.                 end
  235.  
  236. 
  237.