home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / library / dos / tp_util / mcblist.pas < prev    next >
Encoding:
Pascal/Delphi Source File  |  1990-06-08  |  53.3 KB  |  1,928 lines
  1.  
  2. PROGRAM MCBLIST;
  3. {
  4.   LISTE DER MEMORY- CONTROL- BLOCKS UND EINIGES MEHR
  5.   PAUL SCHUBERT, ROTTWEILER STR. 8, 6000 FRANKFURT 1, 069 / 231145
  6.  
  7.   COMPILIEREN MIT TURBO PASCAL >= 5.0
  8.   TURBO PROFESSIONAL WIRD BENÖTIGT
  9. }
  10. {$F+}
  11.  
  12. USES  IVSWAP,           { MUß AM ANFANG DES PROGRAMMS STEHEN }
  13.       TPCRT,DOS,TPDOS,SELECTD,NEATUNIT,
  14.       TPSTRING,TPWINDOW,TPSTRDEV,
  15.       TPENHKBD,TPEMS,TPEXTMEM,TPMOUSE,
  16.       TPTIMER,DETECTRD,NOBREAK;
  17.  
  18.  
  19. CONST INTFNAME  = 'MCBLIST.SAV';
  20.       FILEID    : POINTER = PTR($1234,$5689);
  21.  
  22.       TANORM    : BYTE = $07; { TEXTATTRIBUT NORMALE ANZEIGE }
  23.       TAKOPF    : BYTE = $4E; { TEXTATTRIBUT KOPFZEILEN }
  24.       TAFREI    : BYTE = $08; { TEXTATTRIBUT FREIER MCB }
  25.       TAPROM    : BYTE = $0A; { TEXTATTRIBUT MCB FÜR EPROM }
  26.       TAFRAM    : BYTE = $09; { TEXTATTRIBUT MCB FÜR FREIES RAM }
  27.       TAVEKT    : BYTE = $0F; { TEXTATTRIBUT INTERRUPT- VEKTOR- ANZEIGE }
  28.       TAVALT    : BYTE = $02; { TEXTATTRIBUT ALTER VEKTOR }
  29.       TAVNEU    : BYTE = $1F; { TEXTATTRIBUT NEUER VEKTOR }
  30.       TASPEC    : BYTE = $0D; { SPEZIELLE AUSSAGEN }
  31.       TAMUTTER  : BYTE = $0C; { MUTTERPROZESS- ANZEIGE }
  32.       TAMROM    : BYTE = $1E; { ROM IN DER MEMORY- MAP A000..F000 }
  33.       TAMRAM    : BYTE = $1F; { RAM IN DER MEMORY- MAP A000..F000 }
  34.       TAINAKT   : BYTE = $08; { INAKTIV- ATTRIBUT FÜR FENSTERRAHMEN }
  35.  
  36.       MAXWIND   = 7;   { ANZAHL FENSTER OHNE ALERT(AWIN) UND MESSAGE(BWIN) }
  37.  
  38.       KOPFZATT  : FLEXATTRS = ($1E,$1B,$1E,$1C);
  39.  
  40. TYPE  MCBNAM = ARRAY[1..8] OF CHAR;
  41.  
  42. TYPE  MCBTYP = RECORD
  43.         ID    : CHAR;
  44.         PSP   : WORD;
  45.         LEN   : WORD;
  46.         FILL  : ARRAY[1..3] OF BYTE;
  47.         N     : MCBNAM;
  48.       END;
  49.       MCBPTR = ^MCBTYP;
  50.  
  51. TYPE  MCBREGTYP = RECORD
  52.         MCBR : MCBTYP;
  53.         ADDR : WORD;
  54.         ATTR : BYTE;
  55.       END;
  56.  
  57. TYPE  CHARRAY = ARRAY[1..20] OF CHAR;
  58.       BYTEARR = ARRAY[1..20] OF BYTE;
  59.  
  60. TYPE  PSPTYP = RECORD
  61. {00}    INTR20  : WORD;                  { INT 20H }
  62. {02}    ENDBL   : WORD;                  { END OF ALLOCATION BLOCK }
  63. {04}    F1      : ARRAY[1..6] OF BYTE;
  64. {0A}    I22PTR  : POINTER;               { POINTER AUF INT 22H }
  65. {0E}    I23PTR  : POINTER;               { POINTER AUF INT 23H }
  66. {12}    I24PTR  : POINTER;               { POINTER AUF INT 24H }
  67. {16}    CMDSEG  : WORD;                  { SEGMENT DES MUTTERPROZESSES }
  68. {18}    HNDTAB  : ARRAY[1..20] OF BYTE;  { HANDLE- TABELLE }
  69. {2C}    ENVSEG  : WORD;                  { ENVIRONMENT- SEGMENT }
  70. {2E}    F2      : POINTER;               { IRGENDWOHIN IM COMMAND.COM }
  71. {32}    HNDMAX  : WORD;                  { MAXIMALE ANZAHL HANDLES }
  72. {34}    HNDPTR  : POINTER;               { POINTER AUF HANDLE- TABELLE }
  73. {38}    F3      : ARRAY[1..24] OF BYTE;
  74. { 4 * $FF UND 12 * $00 }
  75. {50}    INTR21  : WORD;                  { INT 21H }
  76. {52}    F4      : ARRAY[1..10] OF BYTE;
  77. { $CB UND 9 * $00 }
  78. {5C}    FCB1    : ARRAY[1..16] OF BYTE;
  79. {6C}    FCB2    : ARRAY[1..16] OF BYTE;
  80. {7C}    F5      : ARRAY[1..4] OF BYTE;
  81. {80}    CMDLIN  : STRING[127];
  82.       END;
  83.  
  84. TYPE  SOF     = RECORD O,S : WORD; END;
  85.       PSPPTR  = ^PSPTYP;
  86.  
  87. TYPE  WPTYPE = RECORD
  88.         X,Y,L,W,W0  : INTEGER;
  89.         F           : BOOLEAN;
  90.       END;
  91.  
  92. TYPE  BUFFERTYP = RECORD
  93.         NXT   : POINTER;
  94.         F1    : ARRAY[1..6] OF BYTE;
  95.         DRV   : POINTER;
  96.         F2    : ARRAY[1..2] OF BYTE;
  97.         DATA  : ARRAY[0..$1FF] OF BYTE;
  98.       END;
  99.  
  100. TYPE  DITTYP = RECORD
  101.         NXT  : POINTER;
  102.         F1   : ARRAY[1..9] OF BYTE;
  103.         DRV  : POINTER;
  104.         F2   : ARRAY[1..21] OF BYTE;
  105.         NAME : ARRAY[1..11] OF CHAR;
  106.         F3   : ARRAY[1..4] OF BYTE;
  107.       END;
  108.  
  109.  
  110. VAR   I,J,K,
  111.       MCBC                      : INTEGER;
  112.       TA,TA0,SIZMOD             : BYTE;
  113.       CH1,CH2                   : CHAR;
  114.       P1,KT1,KA1,KT2,KA2,
  115.       DUMPADDR                  : STRING;
  116.       MCBLEN                    : LONGINT;
  117.       OLDMEM,OLDMEMF,
  118.       OLDMEMG,OLDMEMJ           : POINTER;
  119.       FILERR,KA,
  120.       AUS,CONFIG,URENV,QUIET,
  121.       HATPAR,HATFREI,DOS4,
  122.       DRDOS,LCD                 : BOOLEAN;
  123.       VON,BIS,MCBEND,CMDPSP,
  124.       MS,MO,MSM,MOM,MSN,MON,
  125.       CHEF,MEMSIZE              : WORD;
  126.  
  127.       MCB                       : MCBPTR;
  128.       MP,HP                     : POINTER;
  129.       MCBA                      : ARRAY[1..50] OF MCBREGTYP;
  130.       MCBAP,MCBDP               : BYTE;
  131.  
  132.       BUF                       : INTPTR;
  133.       F                         : FILE OF POINTER;
  134.  
  135.       MODVEC                    : POINTER ABSOLUTE $50:$30;
  136.  
  137.       SC                        : ARRAY[1..MAXWIND] OF VSCREEN;
  138.       WI                        : ARRAY[1..MAXWIND] OF WINDOWPTR;
  139.       WP                        : ARRAY[1..MAXWIND] OF WPTYPE;
  140.       ZEI                       : WORD;
  141.       SPA,WN,WNM,SPM,CX,CY      : BYTE;
  142.       AWIN,BWIN,WDP             : WINDOWPTR;
  143.  
  144.       XMSENTRY                  : POINTER;
  145.       HMBUF                     : ARRAY[0..127] OF BYTE;
  146.       RAX,RBX,RCX,RDX           : WORD;
  147.       WS                        : STRING[MAXWIND];
  148.  
  149.       MSP                       : MOUSESTATEPTR;
  150.       MSPSIZE                   : WORD;
  151.       MSX,MSY                   : BYTE;
  152.       BUT                       : BUTTONSTATUS;
  153.       MAUSAKT                   : BOOLEAN;
  154.  
  155.  
  156. PROCEDURE MOUSEORKEY;           FORWARD;
  157. PROCEDURE ALERT(TEXT:STRING);   FORWARD;
  158. PROCEDURE MESSAGE(TEXT:STRING); FORWARD;
  159.  
  160.  
  161. FUNCTION NEUERMAUSTREIBER:BOOLEAN;
  162. VAR   R  : REGISTERS;
  163. BEGIN
  164.   NEUERMAUSTREIBER := FALSE;
  165.   IF NOT MOUSEINSTALLED THEN EXIT;
  166.   WITH R DO BEGIN
  167.     AX := 21;
  168.     BX := $FFFF;
  169.     INTR($33,R);
  170.     IF BX = $FFFF THEN EXIT;
  171.   END; { WITH R }
  172.   NEUERMAUSTREIBER := TRUE;
  173. END; { NEUERMAUSTREIBER }
  174.  
  175.  
  176. PROCEDURE INIMAUS;
  177. BEGIN
  178.   IF NEUERMAUSTREIBER THEN BEGIN
  179.     IF NOT MAUSAKT THEN BEGIN
  180.       MAUSAKT := TRUE;
  181.       MSPSIZE := MOUSESTATEBUFFERSIZE;
  182.       GETMEM(MSP,MSPSIZE);
  183.     END;
  184.     SAVEMOUSESTATE(MSP,FALSE);
  185.     INITIALIZEMOUSE;
  186.     ENABLEEVENTHANDLING;
  187.     FULLMOUSEWINDOW;
  188.     BLOCKMOUSECURSOR;
  189.     MOUSEGOTOXY(MSX,MSY);
  190.   END ELSE MAUSAKT := FALSE;
  191. END;
  192.  
  193.  
  194. PROCEDURE NEWDELAY(ZEIT:WORD);
  195. VAR   START,STOP  : LONGINT;
  196.       R           : REAL;
  197. BEGIN
  198.   START := READTIMER;
  199.   REPEAT
  200.     R := ELAPSEDTIME(START,STOP); { ZEITVERBRATER IST FÜR 20 MHz- NEAT NÖTIG }
  201.     STOP := READTIMER;
  202.   UNTIL ROUND(ELAPSEDTIME(START,STOP)) >= ZEIT;
  203. END;
  204.  
  205.  
  206. PROCEDURE DUMPBLOCK;
  207. VAR   I,J  : WORD;
  208.       MP   : ^BYTEARR;
  209.       MC   : ^CHARRAY ABSOLUTE MP;
  210. BEGIN
  211.   MP := PTR(MS,MO);
  212.   GOTOXY(1,1);
  213.   WRITE(HEXW(MS+(MO SHR 4)),':0000   Adresse -> ',DUMPADDR); CLREOL;
  214.  
  215.   FOR I := 0 TO 7 DO BEGIN
  216.     GOTOXY(1,I + 2);
  217.     WRITE(HEXW(MS),':',HEXW(MO+16*I),' ');
  218.     FOR J := 1 TO 16 DO BEGIN
  219.       WRITE(HEXB(MP^[16*I+J]),' ');
  220.       IF (J <> 16) AND ((J AND 3) = 0) THEN WRITE(' ');
  221.     END; { NEXT J }
  222.  
  223.     FOR J := 1 TO 16 DO BEGIN
  224.       IF MP^[16*I+J] IN [0..31,127]
  225.         THEN WRITE('·')
  226.         ELSE WRITE(MC^[16*I+J]);
  227.     END; { NEXT J }
  228.  
  229.   END; { NEXT I }
  230. END; { DUMPBLOCK }
  231.  
  232.  
  233. PROCEDURE TMESSAGE;
  234. VAR   P    : WINDOWPTR;
  235.       CH1  : CHAR;
  236.       S    : STRING;
  237. BEGIN
  238.   IF NOT ACTIVATEWINDOW(BWIN) THEN ALERT('FEHLER ACTIVATEWINDOW');
  239.   HIDDENCURSOR;
  240.   CLRSCR;
  241.   FASTWRITE('═══════════════',HI(WINDMIN),LO(WINDMIN)+23,$2B);
  242.   S := 'Drücken Sie jetzt nicht die DEL- Taste !';
  243.   GOTOXY( ((LO(WINDMAX)-LO(WINDMIN))-LENGTH(S)) SHR 1 ,2);
  244.   WRITE(S);
  245.   WHILE KEYPRESSED DO CH1 := READKEY;
  246.   REPEAT
  247.     IF CTRLALTDEL THEN BEGIN
  248.       CLRSCR;
  249.       S := 'Das sollten Sie doch NICHT tun !';
  250.       GOTOXY( ((LO(WINDMAX)-LO(WINDMIN))-LENGTH(S)) SHR 1 ,2);
  251.       WRITE(S);
  252.     END;
  253.   UNTIL KEYPRESSED OR ((KBDFLAGS AND $0C) <> $0C);
  254.   WHILE KEYPRESSED DO CH1 := READKEY;
  255.   P := ERASETOPWINDOW;
  256. END;
  257.  
  258.  
  259. PROCEDURE MOUSEORKEY;
  260. VAR   I        : WORD;
  261.       INPS,TS  : STRING;
  262.       STA,STO  : LONGINT;
  263. LABEL MAUSENDE;
  264. BEGIN
  265.   IF MAUSAKT THEN BEGIN
  266.     BLOCKMOUSECURSOR;
  267.     SHOWMOUSE;
  268.     STA := READTIMER;
  269.     REPEAT
  270.       IF (KBDFLAGS AND $0C) = $0C THEN BEGIN
  271.         MOUSEWHEREXY(MSX,MSY,BUT);
  272.         TMESSAGE;
  273.         MOUSEGOTOXY(MSX,MSY);
  274.       END;
  275.       IF BREAK THEN BEGIN
  276.         MOUSEWHEREXY(MSX,MSY,BUT);
  277.         MESSAGE('Programm beenden mit <Alt-Esc>');
  278.         MOUSEGOTOXY(MSX,MSY);
  279.       END;
  280.       IF WN = 99 THEN BEGIN
  281.         STO := READTIMER;
  282.         STO := READTIMER; { 2 MAL LESEN, WEGEN GEFAHREN BEI HOHEM TAKT }
  283.         IF ROUND(ELAPSEDTIME(STA,STO)) >= 250 THEN BEGIN
  284.           MOUSEWHEREXY(MSX,MSY,BUT);
  285.           STUFFKEY(0);
  286.           HIDEMOUSE;
  287.           EXIT;
  288.         END;
  289.       END;
  290.     UNTIL KEYPRESSED OR MOUSEPRESSED;
  291.     MOUSEWHEREXY(MSX,MSY,BUT);
  292.     IF MOUSEPRESSED THEN BEGIN
  293.       SOUND(4000);
  294.       NEWDELAY(5);
  295.       NOSOUND;
  296.       NEWDELAY(100);
  297.       MOUSEWHEREXY(MSX,MSY,BUT);
  298.       IF BUT = BOTHBUTTONS THEN BEGIN
  299.         STUFFKEY(27);
  300.         GOTO MAUSENDE;
  301.       END ELSE BEGIN
  302.         FASTREAD(80,MSY,1,INPS);
  303.         I := MSX;
  304.         CASE INPS[I] OF
  305.           '═' : BEGIN
  306.                   WHILE (I > 1) AND (NOT (INPS[I] IN ['╒','╘'])) DO DEC(I);
  307.                   IF INPS[I] = '╘' THEN BEGIN
  308.                     IF BUT = RIGHTBUTTON THEN STUFFKEY(77 SHL 8);
  309.                     IF BUT = LEFTBUTTON  THEN STUFFKEY(80 SHL 8);
  310.                   END;
  311.                   IF INPS[I] = '╒' THEN BEGIN
  312.                     IF BUT = RIGHTBUTTON THEN STUFFKEY(75 SHL 8);
  313.                     IF BUT = LEFTBUTTON  THEN STUFFKEY(72 SHL 8);
  314.                   END;
  315.                   IF (WN = 99) THEN BEGIN
  316.                     IF BUT = RIGHTBUTTON THEN NEWDELAY(100);
  317.                     IF BUT = LEFTBUTTON  THEN GOTO MAUSENDE;
  318.                   END;
  319.                   IF NOT KEYPRESSED THEN STUFFKEY(0);
  320.                   HIDEMOUSE;
  321.                   EXIT;
  322.                 END;
  323.           '╒' : BEGIN
  324.                   STUFFKEY(71 SHL 8);
  325.                   GOTO MAUSENDE;
  326.                 END;
  327.           '╛' : BEGIN
  328.                   STUFFKEY(79 SHL 8);
  329.                   GOTO MAUSENDE;
  330.                 END;
  331.         END; { CASE INPS[I] }
  332.         CASE MSY OF
  333.           1 : BEGIN
  334.                 CASE MSX OF
  335.                    1..10 : STUFFKEY(59 SHL 8);
  336.                   13..22 : STUFFKEY(60 SHL 8);
  337.                   27..39 : STUFFKEY(61 SHL 8);
  338.                   43..54 : STUFFKEY(62 SHL 8);
  339.                   56..67 : STUFFKEY(63 SHL 8);
  340.                   69..80 : STUFFKEY(64 SHL 8);
  341.                 END; { CASE MSX }
  342.                 GOTO MAUSENDE;
  343.               END;
  344.           2 : BEGIN
  345.                 CASE MSX OF
  346.                    1..11 : STUFFKEY(65 SHL 8);
  347.                   13..25 : STUFFKEY(66 SHL 8);
  348.                   27..36 : STUFFKEY(67 SHL 8);
  349.                   38..52 : STUFFKEY(88 SHL 8);
  350.                   54..65 : STUFFKEY(92 SHL 8);
  351.                   67..80 : STUFFKEY($100);
  352.                 END; { CASE MSX }
  353.                 GOTO MAUSENDE;
  354.               END;
  355.         ELSE { CASE MSY }
  356. { EINIGE AUSGEWÄHLTE BUCHSTABEN PER MAUSKLICK IN DEN TASTATURBUFFER BEFÖRDERN }
  357.           IF INPS[I] IN ['+','-'] THEN BEGIN
  358.             STUFFKEY(BYTE(INPS[I]));
  359.             GOTO MAUSENDE;
  360.           END;
  361. { WENN BIS HIER NOCH NICHTS BESONDERES UNTER DEM MAUSCURSOR GEFUNDEN WURDE,
  362.   WIRD EINE HEX- EINGABE VERSUCHT }
  363.           IF NOT (INPS[MSX] IN ['0'..'9','A'..'F']) THEN GOTO MAUSENDE;
  364.           WHILE (I > 1) AND (UPCASE(INPS[I]) IN ['0'..'9','A'..'F']) DO DEC(I);
  365.           DELETE(INPS,1,I);
  366.  
  367. { GGF. AUTOMATISCH DEBUG AKTIVIEREN }
  368.           IF WN <> 99 THEN STUFFKEY(67 SHL 8);
  369.           TS := '';
  370.  
  371.           IF (KBDFLAGS AND 4) = 4 THEN BEGIN
  372.             IF STR2WORD('$'+COPY(INPS,1,2),I) THEN ;
  373.             TS := HEXW(MEMW[0:I*4+2]) + ':' + HEXW(MEMW[0:I*4]) + ^M;
  374.             FOR I := 1 TO LENGTH(TS) DO STUFFKEY(BYTE(TS[I]));
  375.             GOTO MAUSENDE;
  376.           END;
  377.           IF (BUT = CENTERBUTTON) OR
  378.              ((BUT = LEFTBUTTON) AND ((KBDFLAGS AND 3) <> 0)) THEN BEGIN
  379.             IF INPS[3] = ' ' THEN BEGIN
  380.               DELETE(INPS,3,1);
  381.               IF INPS[3] = ' ' THEN DELETE(INPS,3,1);
  382.               TS := ':' + COPY(INPS,3,2) + COPY(INPS,1,2);
  383.             END ELSE BEGIN
  384.               FOR I := 1 TO 4 DO STUFFKEY(BYTE(INPS[I]));
  385.               STUFFKEY(BYTE(':'));
  386.             END;
  387.             DELETE(INPS,1,4);
  388.             FOR I := 1 TO 3 DO IF INPS[1] IN [':',' '] THEN DELETE(INPS,1,1);
  389.           END;
  390.  
  391.           IF INPS[3] = ' ' THEN BEGIN
  392.             DELETE(INPS,3,1);
  393.             IF INPS[3] = ' ' THEN DELETE(INPS,3,1);
  394.             STUFFKEY(BYTE(INPS[3]));
  395.             STUFFKEY(BYTE(INPS[4]));
  396.             STUFFKEY(BYTE(INPS[1]));
  397.             STUFFKEY(BYTE(INPS[2]));
  398.           END ELSE FOR I := 1 TO 4 DO STUFFKEY(BYTE(INPS[I]));
  399.           IF BUT = LEFTBUTTON THEN STUFFKEY(BYTE(':'));
  400.           FOR I := 1 TO LENGTH(TS) DO STUFFKEY(BYTE(TS[I]));
  401.  
  402.           STUFFKEY(13);
  403.           GOTO MAUSENDE;
  404.         END; { CASE MSY }
  405.       END; { IF BUT }
  406.     END;
  407.     IF NOT KEYPRESSED THEN STUFFKEY(0);
  408.     HIDEMOUSE;
  409.   END ELSE BEGIN
  410.     REPEAT
  411.       IF (KBDFLAGS AND $0C) = $0C THEN TMESSAGE;
  412.       IF BREAK THEN MESSAGE('Programm beenden mit <Alt-Esc>');
  413.       IF WN = 99 THEN DUMPBLOCK;
  414.     UNTIL KEYPRESSED;
  415.   END;
  416.   EXIT;
  417. MAUSENDE:
  418.   IF NOT KEYPRESSED THEN STUFFKEY(0);
  419.   REPEAT MOUSEWHEREXY(MSX,MSY,BUT); UNTIL BUT = NOBUTTON;
  420.   HIDEMOUSE;
  421. END; { MOUSEORKEY }
  422.  
  423.  
  424. {$I MCBLIST1}
  425.  
  426. PROCEDURE FIRSTMCB;
  427. VAR   R  : REGISTERS;
  428. BEGIN
  429. { ERSTEN MCB HOLEN }
  430.   MCBC   := 1;
  431.   CMDPSP := $FFFF;
  432.   KA     := FALSE;
  433.   AUS    := FALSE;
  434.   CONFIG := FALSE;
  435.   URENV  := FALSE;
  436.   WITH R DO BEGIN
  437.     AH := $52;
  438.     MSDOS(R);
  439.     HP := POINTER(MEML[ES:BX-4]);
  440.   END; { WITH R }
  441.   MCB := HP;
  442. { DA HABEN WIR DEN 1. MCB }
  443. END;
  444.  
  445.  
  446. PROCEDURE DISPPTR(ES,BX:WORD;OFF:INTEGER);
  447. BEGIN
  448.   WRITE(TPSTR,OFF:4,' = ',HEXW(ES),':',HEXW(BX+OFF),' -> ');
  449.   WRITE(TPSTR,HEXW(SOF(MEML[ES:BX+OFF]).S),':',
  450.               HEXW(SOF(MEML[ES:BX+OFF]).O));
  451.   VWRITELN;
  452. END; { DISPPTR }
  453.  
  454.  
  455. PROCEDURE MCBNAME(MCB:MCBPTR);
  456. CONST NULL : ARRAY[1..8] OF CHAR = #0#0#0#0#0#0#0#0;
  457. VAR   I  : BYTE;
  458. BEGIN
  459.   IF MCB^.N = NULL THEN EXIT;
  460.   FOR I := 1 TO 8 DO
  461.     IF MCB^.N[I] IN [#1..#$1F,#$2A,#$2E,#$3A..#$3F,#$7F,#$A8..#$FF] THEN EXIT;
  462.   WRITE(TPSTR,'[',MCB^.N,']');
  463.   VWRITE;
  464. END; { MCBNAME }
  465.  
  466.  
  467. PROCEDURE DRIVERDIS;
  468. VAR   I,NR     : INTEGER;
  469.       DRVCNT   : BYTE;
  470.       NBD      : BYTE;
  471.       MCB      : MCBPTR;
  472.       MCB2     : WORD;
  473.       L        : LONGINT;
  474.       BFPTR    : ^POINTER;
  475.       HP       : ^BYTEARR;
  476.       CHP      : ^CHARRAY;
  477.       R        : REGISTERS;
  478.       DRV      : STRING;
  479.       F        : SEARCHREC;
  480.       DIT      : ^DITTYP;
  481.  
  482. FUNCTION DOS4DRIVER:BOOLEAN;
  483. VAR   SCHLUSS  : WORD;
  484.       MCB      : MCBPTR;
  485.       R        : REGISTERS;
  486. BEGIN
  487.   DOS4DRIVER := FALSE;
  488.   IF NOT DOS4 THEN EXIT;
  489.  
  490.   TEXTATTR := TAKOPF;
  491.   WRITE(TPSTR,'  PSP   Länge    ( DOS >= 4.0 SUB-MCBs )                                      ');
  492.   VWRITELN;
  493.   TEXTATTR := TA;
  494.  
  495.   R.AH := $52;
  496.   MSDOS(R);
  497.   MCB := POINTER(MEML[R.ES:R.BX-4]);
  498.  
  499.   WHILE (MCB^.PSP <> 8) DO BEGIN
  500.     MCB := PTR(SOF(MCB).S+SUCC(MCB^.LEN),0);
  501.   END;
  502.  
  503.   SCHLUSS := SOF(MCB).S + SUCC(MCB^.LEN);
  504.   INC(SOF(MCB).S);
  505.   WHILE (MCB^.PSP = SUCC(SOF(MCB).S)) AND
  506.         (SOF(MCB).S <> SCHLUSS) DO BEGIN
  507.     WRITE(TPSTR,'  ');
  508.     WRITE(TPSTR,HEXW(MCB^.PSP),MCB^.LEN*16:7);
  509. (*
  510.     WRITE(TPSTR,' ',HEXB(MCB^.FILL[1]));
  511.     WRITE(TPSTR,' ',HEXB(MCB^.FILL[2]));
  512.     WRITE(TPSTR,' ',HEXB(MCB^.FILL[3]));
  513. *)
  514.     WRITE(TPSTR,' ');
  515.     CASE MCB^.ID OF
  516.       'D' : WRITE(TPSTR,'DEVICE=    ');
  517.       'F' : WRITE(TPSTR,'FILES=     ');
  518.       'X' : WRITE(TPSTR,'FCBS=      ');
  519.       'B' : WRITE(TPSTR,'BUFFERS=   ');
  520.       'L' : WRITE(TPSTR,'LASTDRIVE= ');
  521.       'S' : WRITE(TPSTR,'STACKS=    ');
  522.     ELSE
  523.       WRITE(TPSTR,'???????? ');
  524.     END; { CASE MCB^.ID }
  525.     MCBNAME(MCB);
  526.     VWRITELN;
  527.     MCB := PTR(SOF(MCB).S+SUCC(MCB^.LEN),0);
  528.   END;
  529.   VWRITELN;
  530.   DOS4DRIVER := TRUE;
  531. END; { DOS4DRIVER }
  532.  
  533. PROCEDURE GETNBD;
  534. { GET NUMBER OF BLOCKDEVICES }
  535. BEGIN
  536.   NBD := 0;
  537.   R.AH := $52;
  538.   MSDOS(R);
  539.   HP := POINTER(MEML[R.ES:R.BX+12]); { LETZTER TREIBER }
  540.   WHILE (SOF(HP).O <> $FFFF) DO BEGIN
  541.     IF ((HP^[6] AND $80) = 0) THEN INC(NBD,HP^[11]);
  542.     HP := POINTER(MEML[SOF(HP).S:SOF(HP).O]);
  543.   END; { WHILE }
  544. END;  { GETNBD }
  545.  
  546. PROCEDURE DISPLAYPATHS;
  547. VAR   I,J  : WORD;
  548.       CHP  : ^CHARRAY;
  549.       DC   : CHAR;
  550.       F    : SEARCHREC;
  551. BEGIN
  552.   TEXTATTR := TAKOPF;
  553.   VWRITELNS(' Liste der PATHs ( SUBST / JOIN ) : ');
  554.   TEXTATTR := TA;
  555.   R.AH := $52;
  556.   MSDOS(R);
  557.   CHP := PTR(MEMW[R.ES:R.BX+24],0);
  558.   FOR I := 1 TO NUMBEROFDRIVES DO BEGIN
  559.     IF (CHP^[2] <> ':') OR (CHP^[3] <> '\') THEN EXIT;
  560.     WRITE(TPSTR,CHR(I+$40),': = ');
  561.     VWRITE;
  562.     TEXTATTR := $0B;
  563.     J := 1;
  564.     DC := CHP^[1];
  565.     WHILE (J < 65) AND (CHP^[J] <> #0) DO BEGIN
  566.       WRITE(TPSTR,CHP^[J]);
  567.       INC(J);
  568.     END; { WHILE }
  569.     IF ((ORD(DC) - $40) <> I) THEN BEGIN
  570.       VWRITE;
  571.       TEXTATTR := $0E;
  572.       FINDFIRST(CHR(I+$40)+':\*.*',ANYFILE,F);
  573.       IF DOSERROR = 3 THEN WRITE(TPSTR,' (JOIN)')
  574.                       ELSE WRITE(TPSTR,' (SUBST)');
  575.     END;
  576.     VWRITELN;
  577.     TEXTATTR := TA;
  578.     IF DOS4 THEN INC(SOF(CHP).O,88) ELSE INC(SOF(CHP).O,81);
  579.   END;
  580. END; { DISPLAYPATHS }
  581.  
  582. PROCEDURE BUFFERANZEIGE;
  583. VAR   NR   : BYTE;
  584.       R    : REGISTERS;
  585.       BFP  : ^BUFFERTYP;
  586.  
  587. PROCEDURE BUFFERINHALT;
  588. VAR   I  : BYTE;
  589. BEGIN
  590.   WRITE(TPSTR,NR:3,'  ');
  591.   WRITE(TPSTR,HEXW(SOF(BFP).S),'->');
  592.   WRITE(TPSTR,HEXPTR(BFP^.NXT),' ');
  593.   FOR I := 1 TO 6 DO WRITE(TPSTR,HEXB(BFP^.F1[I]),' ');
  594.   WRITE(TPSTR,HEXPTR(BFP^.DRV),' ');
  595.   FOR I := 1 TO 2 DO WRITE(TPSTR,HEXB(BFP^.F2[I]),' ');
  596.   VWRITELN;
  597.   INC(NR);
  598. END; { BUFFERINHALT }
  599.  
  600. BEGIN { BUFFERANZEIGE }
  601.   IF DOS4 THEN EXIT; { ICH WEIß NOCH NICHT, WIE DAS GEHT }
  602.  
  603.   TEXTATTR := TAKOPF;
  604.   VWRITELNS(' BUFFERS = Liste : ');
  605.   VWRITELNS(' NR. ADDR   NEXT                        DRIVER          ');
  606.   TEXTATTR := TA;
  607.   R.AH := $52;
  608.   MSDOS(R);
  609.   NR := 1;
  610.   BFP := PTR(MEMW[R.ES:R.BX+20],0);
  611. (*
  612. SO SOLLTE MAN ES BEI DOS3.3 NICHT MACHEN, ABER BEI DOS4 SCHEINT DAS SCHON
  613. EHER ZU STIMMEN
  614.   BFP := PTR(MEMW[R.ES:R.BX-6],0);
  615. *)
  616.   REPEAT
  617.     BUFFERINHALT;
  618.     BFP := BFP^.NXT;
  619.   UNTIL (BFP^.NXT = PTR($FFFF,$FFFF));
  620.   BUFFERINHALT;
  621. END; { BUFFERANZEIGE }
  622.  
  623. PROCEDURE DITANZEIGE;
  624. VAR   I,NR  : BYTE;
  625.  
  626. FUNCTION DITNAME:BOOLEAN;
  627. VAR   I  : BYTE;
  628. BEGIN
  629.   DITNAME := FALSE;
  630.   FOR I := 1 TO 11 DO
  631.     IF DIT^.NAME[I] IN [#0..#$1F,#$2A,#$2E,#$3A..#$3F,#$7F,#$A8..#$FF] THEN EXIT;
  632.   DITNAME := TRUE;
  633. END; { DITNAME }
  634.  
  635. PROCEDURE DITINHALT;
  636. BEGIN
  637.   WRITE(TPSTR,NR:3,' ');
  638.   WRITE(TPSTR,HEXPTR(DIT^.NXT),' ');
  639.   WRITE(TPSTR,DIT^.NAME,' ');
  640.   WRITE(TPSTR,HEXPTR(DIT^.DRV),' ');
  641.   VWRITELN;
  642.   IF DOS4 THEN INC(SOF(DIT).O,59) ELSE INC(SOF(DIT).O,53);
  643.   INC(NR);
  644. END; { DITINHALT }
  645.  
  646. BEGIN { DITANZEIGE }
  647.   TEXTATTR := TAKOPF;
  648.   VWRITELNS(' DIT - LISTE                         ');
  649.   TEXTATTR := TA;
  650.   NR := 1;
  651.   REPEAT
  652.     DITINHALT;
  653.   UNTIL NOT DITNAME;
  654.   DIT := BFPTR^;
  655.   REPEAT
  656.     DITINHALT;
  657.   UNTIL NOT DITNAME;
  658. END; { DITANZEIGE }
  659.  
  660. BEGIN { DRIVERDIS }
  661.   IF SETWINDOW(4,$07,100,80,TRUE) THEN EXIT;
  662.  
  663.   GETNBD;
  664.   WITH R DO BEGIN
  665.     AH := $52;
  666.     MSDOS(R);
  667.     MCB   := POINTER(MEML[ES:BX-4]);
  668. {
  669.   ES:BX-8 IST EIN DYNAMISCHER BUFFER- ZEIGER
  670.     BFPTR := POINTER(MEML[ES:BX-8]);
  671. }
  672.     BFPTR := POINTER(MEML[ES:BX+4]);
  673.     DIT   := POINTER(MEML[ES:BX+4]);
  674.     MCB2  := SOF(MCB).S+SUCC(MCB^.LEN);
  675.     NR    := 1;
  676.     HP    := POINTER(MEML[ES:BX+12]); { LETZTER TREIBER }
  677.     VON   := SOF(BFPTR^).S;
  678.     BIS   := PRED(MCB2);
  679.     WHILE VON > BIS DO BEGIN
  680.       SOF(MCB).S := SOF(MCB).S + SUCC(MCB^.LEN);
  681.       BIS := PRED(SOF(MCB).S);
  682.     END;
  683.   END; { WITH R }
  684.  
  685.   IF NOT DOS4DRIVER THEN BEGIN
  686.     VWRITELNS('  --- FILES,BUFFERS,STACKS,MCBS ---');
  687.     L := SUCC(BIS - VON); L := L SHL 4;
  688.     WRITE(TPSTR,'    ',HEXW(VON),'-',HEXW(BIS),' len=',L:5,' ->');
  689.     VWRITE;
  690.     VECTANZ;
  691.     VWRITELN;
  692.   END;
  693.  
  694.   TEXTATTR := TAKOPF;
  695.   WRITE(TPSTR,'     ADRESSE   NAME    ATTR                                                   ');
  696.   VWRITELN;
  697.   TEXTATTR := TA;
  698.   DRVCNT   := 0;
  699.   BIS := PRED(VON);
  700.  
  701.   WHILE (SOF(HP).O <> $FFFF) DO BEGIN
  702.     VON := SOF(HP).S;
  703.     DRV := '';
  704.     WRITE(TPSTR,NR:2,': ',HEXPTR(HP),' ');
  705.     INC(NR);
  706.     IF ((HP^[6] AND $80) = 0) THEN BEGIN
  707. { ANZEIGE LAUFWERKSTREIBER - LAUFWERKSBEZEICHNER }
  708.       DRV := CHR(NBD-DRVCNT-HP^[11]+$41);
  709.       WRITE(TPSTR,DRV,':');
  710.       IF HP^[11] = 1 THEN BEGIN
  711.         WRITE(TPSTR,'      ');
  712.         IF POS(DRV,RAMDRIVES) > 0 THEN BEGIN
  713.           FINDFIRST(DRV+':\*.*',VOLUMEID,F);
  714.           IF DOSERROR = 0 THEN DRV := F.NAME
  715.                           ELSE DRV := '';
  716.         END ELSE DRV := '';
  717.         IF LENGTH(DRV) > 8 THEN DELETE(DRV,9,1);
  718.       END ELSE BEGIN
  719.         DRV := '';
  720.         WRITE(TPSTR,'..',CHR(NBD-DRVCNT+$40),':');
  721.         WRITE(TPSTR,'  ');
  722.       END;
  723.       INC(DRVCNT,HP^[11]);
  724.     END ELSE BEGIN
  725. { ANZEIGE TREIBER - ID }
  726.       FOR I := 11 TO 18 DO WRITE(TPSTR,CHR(HP^[I]));
  727.     END;
  728.     WRITE(TPSTR,' ',HEXB(HP^[6]),HEXB(HP^[5]));
  729. (*
  730.     WRITE(TPSTR,' ',HEXB(HP^[8]),HEXB(HP^[7]));
  731.     WRITE(TPSTR,' ',HEXB(HP^[10]),HEXB(HP^[9]));
  732. *)
  733.     IF SOF(HP).S <> $70 THEN BEGIN
  734.       WRITE(TPSTR,' - ');
  735.       I := 19;
  736.       WHILE HP^[I] IN [10,13,32..126] DO BEGIN
  737.         IF (HP^[I] >= 32) THEN BEGIN
  738.           WRITE(TPSTR,CHR(HP^[I]));
  739.         END;
  740.         INC(I);
  741.       END; { WHILE }
  742.     END; { IF SOF(HP).S <> $70 }
  743.     IF DRV <> '' THEN BEGIN
  744.       VWRITE;
  745.       TEXTATTR := $0E;
  746.       WRITE(TPSTR,DRV);
  747.     END;
  748.     HP := POINTER(MEML[SOF(HP).S:SOF(HP).O]);
  749.     VWRITELN;
  750.     TEXTATTR := TA;
  751.  
  752.     IF VON <> $70 THEN BEGIN
  753.       L := SUCC(BIS - VON); L := L SHL 4;
  754.  
  755.       IF L > 120000 THEN BEGIN
  756.         BIS := PRED(MCB2);
  757.         L := SUCC(BIS - VON); L := L SHL 4;
  758.       END;
  759.  
  760.       WRITE(TPSTR,'    ',HEXW(VON),'-',HEXW(BIS),' len=',L:5,' ->');
  761.       VWRITE;
  762.       VECTANZ;
  763.       VWRITELN;
  764.     END;
  765.     BIS := PRED(VON);
  766.   END; { WHILE }
  767.  
  768.   IF NOT DRDOS THEN BEGIN
  769.     DISPLAYPATHS;
  770.     BUFFERANZEIGE;
  771.     DITANZEIGE;
  772.   END;
  773.  
  774.   CLOSEVSCREEN(4);
  775. END; { DRIVERDIS }
  776.  
  777.  
  778. PROCEDURE WRITEMCBLEN;
  779. BEGIN
  780.   CASE SIZMOD OF
  781.     1 : WRITE(TPSTR,MCBLEN*16:7);             { GRÖßE IN BYTES }
  782.     2 : WRITE(TPSTR,MCBLEN*16/1024:6:2,'k');  { GRÖßE IN K-BYTES }
  783.     3 : WRITE(TPSTR,HEXW(MCBLEN):5,'H');      { GRÖßE IN PARAGRAPHS (HEX) }
  784.     4 : WRITE(TPSTR,MCBLEN:5);                { GRÖßE IN PARAGRAPHS (DEZIMAL) }
  785.   END; { CASE SIZMOD }
  786. END; { WRITEMCBLEN }
  787.  
  788.  
  789. PROCEDURE MCBLISTE;
  790. VAR   W      : WORD;
  791.       EMSPF  : POINTER;
  792. BEGIN
  793.   READFILE(FALSE);
  794.   IF NOT QUIET THEN IF SETWINDOW(1,$07,50,120,TRUE) THEN EXIT;
  795.  
  796.   HATFREI := FALSE;
  797.   EMSPF := NIL;
  798.   IF EMSINSTALLED THEN EMSPF := EMSPAGEFRAMEPTR;
  799.  
  800.   OLDMEM  := NIL;
  801.   OLDMEMJ := NIL;
  802.   MCBAP   := 0;
  803.  
  804.   TEXTATTR := TAKOPF;
  805.   WRITE(TPSTR,'    MCB:  PSP:   Länge: ');
  806.   CASE SIZMOD OF
  807.     1 : WRITE(TPSTR,'Bytes           ');
  808.     2 : WRITE(TPSTR,'k Bytes         ');
  809.     3 : WRITE(TPSTR,'Paragraphs (HEX)');
  810.     4 : WRITE(TPSTR,'Paragraphs      ');
  811.   END;
  812.   WRITE(TPSTR,'                                      ');
  813.   VWRITELN;
  814.   TEXTATTR := TA;
  815.  
  816.   FIRSTMCB;
  817.   MCBLEN := SUCC(SOF(HP).S);
  818.   W := DOSVERSION;
  819.   WRITE(TPSTR,'DOS ',HI(W),'.',LO(W),'(');
  820.   WRITEMCBLEN;
  821.   WRITE(TPSTR,') :');
  822.   VWRITE;
  823.  
  824.   MCB := HP;
  825.   VON := 0;
  826.   BIS := SOF(HP).S;
  827.   VECTANZ;
  828.  
  829.   REPEAT
  830.     TEXTATTR := TA;
  831.     IF MCB^.PSP = 0 THEN BEGIN
  832.       TEXTATTR := TAFREI;
  833.       KA := TRUE;
  834.     END ELSE BEGIN
  835.       KA := FALSE;
  836.       IF (MCB^.PSP = $A000) OR
  837.          (MCB^.PSP = $B000) OR
  838.          (MCB^.PSP = $B800) THEN TEXTATTR := TAPROM;
  839.     END;
  840.     IF BIS > VON THEN VON := BIS;
  841.     VWRITELN;
  842.  
  843.     MCBEND := SOF(MCB).S+SUCC(MCB^.LEN);
  844.     IF (MCBEND = $9FFF) OR (MCBEND = $9FFE) THEN TEXTATTR := TAFRAM;
  845.  
  846.     IF (HP = OLDMEMF) THEN BEGIN
  847.       WRITE(TPSTR,'      <─────  save Interrupts  ─────>');
  848.       VWRITELN;
  849.     END;
  850.     IF (HP = OLDMEMG) THEN BEGIN
  851.       WRITE(TPSTR,'      <─────  save Interrupts (jenseits)  ─────>');
  852.       VWRITELN;
  853.     END;
  854.     IF MCB^.ID = 'Z' THEN BEGIN
  855.       TEXTATTR := TAFRAM;
  856.       IF SOF(HP).S > $A000 THEN OLDMEMJ := HP;
  857.       MCBLEN := SUCC(SOF(MCB).S + MCB^.LEN);
  858.       IF (MCBLEN SHR 6) <> MEMSIZE THEN BEGIN
  859.         MCBLEN := LONGINT(LONGINT(MEMSIZE) SHL 10) - MCBLEN SHL 4;
  860.         WRITE(TPSTR,'!!!!! im letzten MCB fehlen ',MCBLEN,' Bytes !!!!!');
  861.         VWRITELN;
  862.       END;
  863.     END;
  864.  
  865.     INC(MCBAP);
  866.     MCBA[MCBAP].MCBR := MCB^;
  867.     MCBA[MCBAP].ADDR := SOF(MCB).S;
  868.     MCBA[MCBAP].ATTR := 0;
  869.  
  870.     WRITE(TPSTR,MCBC:2,': ',HEXW(SOF(HP).S),'  ',HEXW(MCB^.PSP),' ');
  871.     MCBLEN := MCB^.LEN;
  872.     WRITEMCBLEN;
  873.     WRITE(TPSTR,'  ');
  874.     VWRITE;
  875.  
  876.     MCBNAME(MCB);
  877.     IF (MCB^.ID <> 'Z') THEN BEGIN
  878.       MP := MCB; INC(SOF(MP).S);
  879.       IF NOT BATDISP(SOF(MP).S,TRUE) THEN BEGIN
  880.  
  881.         VWRITE;
  882.         TA0 := TEXTATTR;
  883.         TEXTATTR := TASPEC;
  884.         IF URENV AND (MCB^.PSP = CMDPSP) THEN BEGIN
  885.           WRITE(TPSTR,' Ur- Environment');
  886.           MCBA[MCBAP].ATTR := 4;
  887.           URENV  := FALSE;
  888.         END;
  889.         IF CONFIG THEN BEGIN
  890.           WRITE(TPSTR,' ',GETENV('COMSPEC'),'<1>');
  891.           MCBA[MCBAP].ATTR := 2;
  892.           CONFIG := FALSE;
  893.           URENV  := TRUE;
  894.           CMDPSP := MCB^.PSP;
  895.         END;
  896.         IF MCB^.PSP = 8 THEN BEGIN
  897.           WRITE(TPSTR,' CONFIG.SYS');
  898.           CONFIG := TRUE;
  899.           MCBA[MCBAP].ATTR := 6;
  900.         END;
  901.         IF (EMSPF <> NIL) AND (PTR(MCB^.PSP,0) = EMSPF) THEN BEGIN
  902.           WRITE(TPSTR,' EMS Pageframe');
  903.         END;
  904.         IF SUCC(SOF(MCB).S) = CHEF THEN BEGIN
  905.           VWRITE;
  906.           TEXTATTR := TAMUTTER;
  907.           WRITE(TPSTR,' Mutterprozess ');
  908.         END;
  909.         VWRITE;
  910.         TEXTATTR := TA0;
  911.       END;
  912.  
  913.       PSPDISP;
  914.       IF (MCBEND >= $9FFE) AND
  915.          (MCBEND <= $C000) AND
  916.          (MCB^.PSP = 0) THEN BEGIN
  917.         IF NOT HATFREI THEN BEGIN
  918.           WRITE(TPSTR,'--- freier Speicher ---');
  919.           MCBA[MCBAP].ATTR := 7;
  920.         END;
  921.         HATFREI := TRUE;
  922.       END;
  923.     END ELSE BEGIN
  924. { LETZTER MCB HAT ID 'Z' }
  925.       AUS := TRUE;
  926.       IF MCB^.PSP = 0 THEN BEGIN
  927.         WRITE(TPSTR,'--- freier Speicher ');
  928.         IF MCBEND > $A000 THEN WRITE(TPSTR,'(jenseits) ');
  929.         WRITE(TPSTR,'---');
  930.         VWRITE;
  931.         MCBA[MCBAP].ATTR := 7;
  932.       END ELSE PSPDISP;
  933. { FESTLEGEN, WO ENDE FREIER SPEICHER IST }
  934.       IF BIS > $A000 THEN BIS := $EFFF ELSE BIS := $9FFF;
  935. { SONDERFALL JENSEITSSPEICHER BIS <F800 }
  936.       IF VON > $F000 THEN BIS := $F7FF;
  937.       VECTANZ;
  938.     END;
  939.     VWRITE;
  940.  
  941.     IF NOT AUS THEN BEGIN
  942.       INC(MCBC);
  943.       SOF(HP).S := SOF(HP).S + SUCC(MCB^.LEN);
  944.       MCB := HP;
  945.       BIS := SOF(HP).S;
  946.       VECTANZ;
  947.     END;
  948.   UNTIL AUS;
  949.   VWRITELN;
  950.  
  951.  
  952.   IF FILERR THEN BEGIN
  953.     MCBEND := MEMW[$40:$13];
  954.     IF MCBEND <= 640 THEN BEGIN
  955.       IF (MCBEND AND $3F) <> 0 THEN BEGIN
  956.         WRITE(TPSTR,'!!!!! Speichergröße ist kein Vielfaches von 64k !!!!!');
  957.         VWRITELN;
  958.       END;
  959.     END;
  960.     IF (MCBEND AND $1F) <> 0 THEN BEGIN
  961.       WRITE(TPSTR,'!!!!! Speichergröße ist kein Vielfaches von 32k !!!!!');
  962.       VWRITELN;
  963.     END;
  964.     IF (MCBEND AND $0F) <> 0 THEN BEGIN
  965.       WRITE(TPSTR,'!!!!! Speichergröße ist kein Vielfaches von 16k !!!!!');
  966.       VWRITELN;
  967.     END;
  968.   END ELSE BEGIN
  969.     IF MEMSIZE <> MEMW[$40:$13] THEN BEGIN
  970.       WRITE(TPSTR,'!!!!! Virengefahr - Speichergröße ist ungleich SAVE- FILE !!!!!');
  971.       VWRITELN;
  972.     END;
  973.   END;
  974.  
  975.   IF BIS < $C000 THEN BEGIN
  976.     WRITE(TPSTR,'EGA- BIOS C000 :');
  977.     VWRITE;
  978.     VON := SUCC(BIS);
  979.     BIS := $EFFF;
  980.     VECTANZ;
  981.     VWRITELN;
  982.   END;
  983.  
  984.   WRITE(TPSTR,'     BIOS F000 :');
  985.   VWRITE;
  986.   VON := $F000;
  987.   BIS := $FFFF;
  988.   VECTANZ;
  989.  
  990.   TEXTATTR := TA;
  991.   IF NOT QUIET THEN CLOSEVSCREEN(1);
  992. END; { MCBLISTE }
  993.  
  994.  
  995. PROCEDURE MCBLISTENEU;
  996. BEGIN
  997.   CLOSEWINDOW(1);
  998.   CLOSEWINDOW(3);
  999.   CLOSEWINDOW(4);
  1000.   MCBLISTE;
  1001. END; { MCBLISTENEU }
  1002.  
  1003.  
  1004. PROCEDURE KOPFZEILE;
  1005. BEGIN
  1006.   INIMAUS;
  1007.   FASTREAD(80,1,1,KT1);
  1008.   READATTRIBUTE(80,1,1,KA1);
  1009.   FASTREAD(80,2,1,KT2);
  1010.   READATTRIBUTE(80,2,1,KA2);
  1011.   FLEXWRITE('<F1>'^A'-Help,  '^B'<F2>'^A'-MCBs,    '+
  1012.           ^B'<F3>'^A'-INT-VEC,   '^B'<F4>'^A'-MEMORY, '+
  1013.           ^B'<F5>'^A'-DEVICE, '^B'<F6>'^A'-CONFIG ',
  1014.           1,1,KOPFZATT);
  1015.   FLEXWRITE('<F7>'^A'-Close, '^B'<F8>'^A'-MCB-Inf, '+
  1016.           ^B'<F9>'^A'-Dump, '^B'<ShF5>'^A'-Restore, '+
  1017.           ^B'<ShF9>'^A'-Save, '^C'<Alt-Esc>-Ende',
  1018.           2,1,KOPFZATT);
  1019.   QUIET := FALSE;
  1020.   BLOCKCURSOR;
  1021.   GOTOXY(71,2);
  1022. END; { KOPFZEILE }
  1023.  
  1024.  
  1025. PROCEDURE UPDWIN;
  1026. BEGIN
  1027.   MOVEVSCREENTOWINDOW(SC[WN],WP[WN].Y,WP[WN].X);
  1028.   HIDDENCURSOR;
  1029. END; { UPDWIN }
  1030.  
  1031.  
  1032. PROCEDURE DUMP;
  1033. VAR   W        : WORD;
  1034.       CH1,CH2  : CHAR;
  1035.       DW       : WINDOWPTR;
  1036.       S1,S2    : STRING;
  1037.       WNM      : BYTE;
  1038. BEGIN { DUMP }
  1039.   DUMPADDR := '';
  1040.   IF NOT MAKEWINDOW(DW,1,15,80,25,TRUE,TRUE,FALSE,$1E,$70,$70,' DUMP   <Esc> = Ende ')
  1041.     THEN ALERT('FEHLER MAKEWINDOW');
  1042.   IF NOT ACTIVATEWINDOW(DW) THEN ALERT('FEHLER ACTIVATEWINDOW');
  1043.  
  1044.   WNM := WN;
  1045.   WN  := 99;
  1046.   REPEAT
  1047.     HIDDENCURSOR;
  1048.     IF NOT KEYPRESSED THEN DUMPBLOCK;
  1049.     MOUSEORKEY;
  1050.     CH1 := UPCASE(READKEY); IF CH1 = #0 THEN CH2 := READKEY ELSE CH2 := #0;
  1051.  
  1052.     CASE CH1 OF
  1053.        ^M : BEGIN
  1054.               MSN := MS;
  1055.               MON := MO;
  1056.               W := POS(':',DUMPADDR);
  1057.               IF W > 0 THEN BEGIN
  1058.                 S1 := '$' + COPY(DUMPADDR,1,PRED(W));
  1059.                 S2 := '$' + COPY(DUMPADDR,SUCC(W),LENGTH(DUMPADDR)-W+1);
  1060.                 IF STR2WORD(S1,W) THEN MS := W ELSE MS := 0;
  1061.               END ELSE BEGIN
  1062.                 S2 := '$' + DUMPADDR;
  1063.               END;
  1064.               IF STR2WORD(S2,W) THEN MO := W ELSE MO := 0;
  1065.               GOTOXY(1,1); CLREOL;
  1066.               DUMPADDR := '';
  1067.               MSM := MS;
  1068.               MOM := MO;
  1069.             END;
  1070.        ^H : BEGIN
  1071.               IF LENGTH(DUMPADDR) > 0 THEN DELETE(DUMPADDR,LENGTH(DUMPADDR),1);
  1072.             END;
  1073.       ':' : BEGIN
  1074.               IF POS(':',DUMPADDR) = 0 THEN DUMPADDR := DUMPADDR + ':';
  1075.             END;
  1076.  '0'..'9',
  1077.  'A'..'F' : BEGIN
  1078.               DUMPADDR := DUMPADDR + CH1;
  1079.             END;
  1080.     END; {CASE CH1 }
  1081.  
  1082.     CASE CH2 OF
  1083.        #0 : BEGIN END;
  1084.        #1 : BEGIN
  1085.               CH1 := ^[;
  1086.               CH2 := #0;
  1087.               STUFFKEY($100);
  1088.             END;
  1089. {RI}  #77 : BEGIN
  1090.               INC(MO,16);
  1091.             END;
  1092. {LE}  #75 : BEGIN
  1093.               DEC(MO,16);
  1094.             END;
  1095. {UP}  #72 : BEGIN
  1096.               DEC(MO,128);
  1097.             END;
  1098. {DN}  #80 : BEGIN
  1099.               INC(MO,128);
  1100.             END;
  1101. {PU}  #73 : BEGIN
  1102.               DEC(MS);
  1103.             END;
  1104. {PD}  #81 : BEGIN
  1105.               INC(MS);
  1106.             END;
  1107. {HO}  #71 : BEGIN
  1108.               MS := MSM;
  1109.               MO := MOM;
  1110.             END;
  1111. {EN}  #79 : BEGIN
  1112.               W   := MS;
  1113.               MS  := MSN;
  1114.               MSN := W;
  1115.               W   := MO;
  1116.               MO  := MON;
  1117.               MON := W;
  1118.             END;
  1119.  
  1120. {CRI}#116 : BEGIN
  1121.               IF MOVEWINDOW(1,0) THEN HIDDENCURSOR;
  1122.             END;
  1123. {CLE}#115 : BEGIN
  1124.               IF MOVEWINDOW(-1,0) THEN HIDDENCURSOR;
  1125.             END;
  1126. {CUP}#141 : BEGIN
  1127.               IF MOVEWINDOW(0,-1) THEN HIDDENCURSOR;
  1128.             END;
  1129. {CDN}#145 : BEGIN
  1130.               IF MOVEWINDOW(0,1) THEN HIDDENCURSOR;
  1131.             END;
  1132.     ELSE { CASE CH2 }
  1133. {
  1134.   DIE FUNKTIONSTASTEN WERDEN AN DAS ÜBERGEORDNETE PROGRAMM
  1135.   IM TASTATURBUFFER ÜBERGEBEN, DUMP WIRD BEENDET
  1136. }
  1137.       STUFFKEY(BYTE(CH2) SHL 8);
  1138.       CH1 := ^[;
  1139.     END; { CASE CH2 }
  1140.   UNTIL CH1 = ^[;
  1141.   DW := ERASETOPWINDOW;
  1142.   DISPOSEWINDOW(DW);
  1143.   WN := WNM;
  1144. END; { DUMP }
  1145.  
  1146.  
  1147. PROCEDURE MAUSINFO;
  1148. VAR   R  : REGISTERS;
  1149.       I  : WORD;
  1150.       P  : ^CHARRAY;
  1151.       Q  : POINTER;
  1152. BEGIN
  1153.   VWRITELN;
  1154.   GETINTVEC($33,Q);
  1155.   IF (Q = NIL) OR (MEM[SOF(Q).S:SOF(Q).O] = $CF) THEN BEGIN
  1156.     VWRITELNS('  Es ist kein Maustreiber installiert');
  1157.     EXIT;
  1158.   END;
  1159.  
  1160.   IF MAUSAKT THEN BEGIN
  1161.     DISABLEEVENTHANDLING;
  1162.     RESTOREMOUSESTATE(MSP,FALSE);
  1163.   END;
  1164.  
  1165.   WITH R DO BEGIN
  1166. { GET VERSION }
  1167.     AX := 36;
  1168.     BX := $FFFF;
  1169.     INTR($33,R);
  1170.     IF BX = $FFFF THEN BEGIN
  1171.       VWRITELNS('    Maustreiber ist installiert');
  1172.       VWRITELNS('  Funktion 36 (GET VERSION) ist nicht verfügbar');
  1173.     END ELSE BEGIN
  1174.       WRITE(TPSTR,'  Maustreiber Version ',BH,'.',HEXB(BL));
  1175.       VWRITELN;
  1176.       WRITE(TPSTR,'  IRQ = ',CL,'     ');
  1177.       CASE CH OF
  1178.         1 : WRITE(TPSTR,'BUS- Maus');
  1179.         2 : WRITE(TPSTR,'serielle Maus');
  1180.         3 : WRITE(TPSTR,'InPort- Maus');
  1181.         4 : WRITE(TPSTR,'PS/2- Maus');
  1182.         5 : WRITE(TPSTR,'Hewlett-Packard- Maus');
  1183.       ELSE
  1184.         WRITE(TPSTR,'unbekannter Maustyp ',CH);
  1185.       END; { CASE CH }
  1186.       VWRITELN;
  1187.     END;
  1188. { SWAP INTERRUPT ROUTINES }
  1189.     AX := 20;
  1190.     CX := 0;
  1191.     DX := $FFFF;
  1192.     ES := $FFFF;
  1193.     INTR($33,R);
  1194.     IF (ES = $FFFF) AND (DX = $FFFF) THEN BEGIN
  1195.       VWRITELNS('  Funktion 20 (SWAP INTERRUPT SUBROUTINES) ist nicht verfügbar');
  1196.     END ELSE BEGIN
  1197.       AX := 20;
  1198.       WRITE(TPSTR,'  Mausevent auf Adresse ',HEXW(ES),':',HEXW(DX),'   Maske = ',HEXW(CX));
  1199.       VWRITELN;
  1200.       INTR($33,R); { DIE ALTEN WERTE WIEDERHERSTELLEN }
  1201.     END;
  1202. { GET DRIVER STATE STORAGE REQUIREMENT }
  1203.     AX := 21;
  1204.     BX := $FFFF;
  1205.     INTR($33,R);
  1206.     IF BX = $FFFF THEN BEGIN
  1207.       VWRITELNS('  Funktion 22 (SAVE MOUSEDRIVER STATUS) ist nicht verfügbar');
  1208.     END ELSE BEGIN
  1209.       WRITE(TPSTR,'  Größe des Mausstatus- Buffers = ',BX);
  1210.       VWRITELN;
  1211.     END;
  1212. { GET MOUSE SENSITIVITY }
  1213.     AX := 27;
  1214.     BX := $FFFF;
  1215.     INTR($33,R);
  1216.     IF BX = $FFFF THEN BEGIN
  1217.       VWRITELNS('  Funktion 27 (GET MOUSE SENSITIVITY) ist nicht verfügbar');
  1218.     END ELSE BEGIN
  1219.       WRITE(TPSTR,'  Empfindlichkeit hor. = ',BX);
  1220.       WRITE(TPSTR,',  vert. = ',CX);
  1221.       WRITE(TPSTR,',  Schwellwert = ',DX);
  1222.       VWRITELN;
  1223.     END;
  1224. { GET CRT PAGE }
  1225.     AX := 30;
  1226.     BX := $FFFF;
  1227.     INTR($33,R);
  1228.     IF BX = $FFFF THEN BEGIN
  1229.       VWRITELNS('  Funktion 30 (GET CRT PAGE) ist nicht verfügbar');
  1230.     END ELSE BEGIN
  1231.       WRITE(TPSTR,'  Maus- CRT- Page = ',BX);
  1232.       VWRITELN;
  1233.     END;
  1234. { 'GEHEIM'- FUNKTION 'M' }
  1235.     AX := $4D;
  1236.     DI := 0;
  1237.     ES := 0;
  1238.     INTR($33,R);
  1239.     IF PTR(ES,DI) = NIL THEN BEGIN
  1240.     END ELSE BEGIN
  1241.       VWRITELNS('  ''GEHEIMFUNKTION'' 4DH IST INSTALLIERT ');
  1242.       P := PTR(ES,DI);
  1243.       WRITE(TPSTR,'  ',HEXPTR(P),'->');
  1244.       I := 1;
  1245.       WHILE P^[I] IN [' '..#$A7] DO BEGIN
  1246.         WRITE(TPSTR,P^[I]);
  1247.         INC(I);
  1248.       END;
  1249.       VWRITELN;
  1250.     END;
  1251. { 'GEHEIM'- FUNKTION 'm' }
  1252.     AX := $6D;
  1253.     DI := 0;
  1254.     ES := 0;
  1255.     INTR($33,R);
  1256.     IF PTR(ES,DI) = NIL THEN BEGIN
  1257.     END ELSE BEGIN
  1258.       VWRITELNS('  ''GEHEIMFUNKTION'' 6DH IST INSTALLIERT ');
  1259.     END;
  1260.   END; { WITH R }
  1261.   INIMAUS;
  1262. END; { MAUSINFO }
  1263.  
  1264.  
  1265. FUNCTION HIMEMINST:BOOLEAN;
  1266. VAR   I2FPTR  : POINTER ABSOLUTE $0:$BC;
  1267.       R       : REGISTERS;
  1268. BEGIN
  1269.   HIMEMINST := FALSE;
  1270.   IF I2FPTR = NIL THEN EXIT;
  1271.   R.AX := $4300;
  1272.   INTR($2F,R);
  1273.   IF R.AL <> $80 THEN EXIT;
  1274.  
  1275.   R.AX := $4310;
  1276.   INTR($2F,R);
  1277.   SOF(XMSENTRY).S := R.ES;
  1278.   SOF(XMSENTRY).O := R.BX;
  1279.  
  1280.   HIMEMINST := TRUE;
  1281. END; { HIMEMINST }
  1282.  
  1283.  
  1284. PROCEDURE XMS; EXTERNAL;
  1285. {$L XMS}
  1286. {$F+}
  1287. FUNCTION CPU_TYPE:INTEGER; EXTERNAL;
  1288. {$L GETCPU}
  1289. FUNCTION VIDADAP:INTEGER; EXTERNAL;
  1290. {$L VIDEOID}
  1291. {$F-}
  1292.  
  1293.  
  1294. PROCEDURE VADAPTERTEXT(I:BYTE);
  1295. BEGIN
  1296.   CASE I OF
  1297.      0 : WRITE(TPSTR,'nicht vorhanden');
  1298.      1 : WRITE(TPSTR,'MDA Monochrom Display Adapter');
  1299.      2 : WRITE(TPSTR,'CGA Color Graphics Adapter');
  1300.    3,9 : WRITE(TPSTR,'reservierter DCC');
  1301.      4 : WRITE(TPSTR,'EGA Enhanced Graphics Adapter Color Mode');
  1302.      5 : WRITE(TPSTR,'EGA Enhanced Graphics Adapter Monochrom Mode');
  1303.      6 : WRITE(TPSTR,'PGA Professional Graphics Controller');
  1304.      7 : WRITE(TPSTR,'VGA Video Graphics Array mit Monochrom Display');
  1305.      8 : WRITE(TPSTR,'VGA Video Graphics Array mit Color Display');
  1306.     10 : WRITE(TPSTR,'MCGA mit digitalem Color Display');
  1307.     11 : WRITE(TPSTR,'MCGA mit analogem Monochrom Diaplay');
  1308.     12 : WRITE(TPSTR,'MCGA mit analogem Color Display');
  1309.     64 : WRITE(TPSTR,'HGC Hercules Graphics Card');
  1310.   ELSE
  1311.     WRITE(TPSTR,'nicht erkannt');
  1312.   END; { CASE I }
  1313. END; { VADAPTERTEXT }
  1314.  
  1315.  
  1316. PROCEDURE SHADOWDISP(PFBA:WORD);
  1317. VAR   I,J  : WORD;
  1318.  
  1319. PROCEDURE RAMTEST(SEGM:WORD);
  1320. VAR   B1,B2  : BYTE;
  1321.       TA     : BYTE;
  1322. BEGIN
  1323.   NMI(OFF);
  1324.   B1 := MEM[SEGM:0];
  1325.   MEM[SEGM:0] := B1 XOR $FF;
  1326.   B2 := MEM[SEGM:0];
  1327.   MEM[SEGM:0] := B1;
  1328.   TA := TEXTATTR;
  1329.  
  1330.   WRITE(TPSTR,HEXW(SEGM),': ');
  1331.   IF (B1 <> (B2 XOR $FF)) AND (B1 <> B2) THEN BEGIN
  1332.     WRITE(TPSTR,'undefin.');
  1333.   END ELSE BEGIN
  1334.     IF (MEMW[SEGM:0] = $55AA) OR (MEMW[SEGM:0] = $AA55) THEN BEGIN
  1335.       WRITE(TPSTR,'BIOS ');
  1336.     END ELSE BEGIN
  1337.       IF (SEGM >= PFBA) AND (SEGM < (PFBA+$1000)) THEN BEGIN
  1338.         WRITE(TPSTR,' EMS ');
  1339.       END ELSE BEGIN
  1340.         WRITE(TPSTR,'.... ');
  1341.       END;
  1342.     END;
  1343.     VWRITE;
  1344.     IF B1 <> (B2 XOR $FF) THEN WRITE(TPSTR,'...')
  1345.     ELSE BEGIN
  1346.       TEXTATTR := TAMRAM;
  1347.       TEXTCOLOR(15);
  1348.       WRITE(TPSTR,'RAM');
  1349.       VWRITE;
  1350.       TEXTATTR := TA;
  1351.     END;
  1352.   END;
  1353.   WRITE(TPSTR,'  ');
  1354.   VWRITE;
  1355.   NMI(ON);
  1356. END; { RAMTEST }
  1357.  
  1358. BEGIN { SHADOWDISP }
  1359.   FOR I := $0A TO $0F DO BEGIN
  1360.     WRITE(TPSTR,'    ');
  1361.     FOR J := 0 TO 3 DO RAMTEST((I SHL 12) + (J SHL 10));
  1362.     VWRITELN;
  1363.   END; { NEXT I }
  1364. END; { SHADOWDISP }
  1365.  
  1366.  
  1367. PROCEDURE MEMINFO;
  1368. VAR   VERS              : BYTE;
  1369.       PFBP              : POINTER;
  1370.       SRAM,BRAM,
  1371.       XRAM,XRG,XRA,EMG,
  1372.       PFBA,TPAG,PGAV    : WORD;
  1373.       AT                : BOOLEAN;
  1374. BEGIN
  1375.   IF SETWINDOW(5,$1B,50,80,TRUE) THEN EXIT;
  1376.  
  1377.   IF ABS(CPU_TYPE) >= 286 THEN AT := ISAT ELSE AT := FALSE;
  1378.   VWRITELN;
  1379. { --- SYSTEM- RAM }
  1380.   BRAM := MEMW[$40:$13];
  1381.   IF AT THEN BEGIN
  1382.     SRAM := GETPORT(RTC,$15) + (GETPORT(RTC,$16) SHL 8);
  1383.     WRITE(TPSTR,'   System RAM (SETUP) = ',SRAM:4,'k           ');
  1384.     WRITE(TPSTR,'    (BIOS) = ',BRAM:4,'k');
  1385.   END ELSE BEGIN
  1386.     WRITE(TPSTR,'   System RAM = ',BRAM:4,'k');
  1387.   END;
  1388.   VWRITELN;
  1389.   VWRITELN;
  1390.  
  1391. { --- HIMEM- TREIBER }
  1392.   IF HIMEMINST THEN BEGIN
  1393. { XMS VERSION ABFRAGEN }
  1394.     RAX := 0;
  1395.     XMS;
  1396.     WRITE(TPSTR,'   HIMEM- Treiber Version ');
  1397.     WRITE(TPSTR,HEXB(HI(RAX)),'.',HEXB(LO(RAX)));
  1398.     WRITE(TPSTR,' (',HEXB(HI(RBX)),'.',HEXB(LO(RBX)),'),');
  1399.     WRITE(TPSTR,'  HIMEM ist ');
  1400.     IF RDX <> 1 THEN WRITE(TPSTR,'nicht ');
  1401.     WRITE(TPSTR,'vorhanden');
  1402.     VWRITELN;
  1403.     IF RDX = 1 THEN BEGIN
  1404. { HMA ANFORDERN - GRÖßE SOVIEL WIE MÖGLICH }
  1405.       RAX := $0100;
  1406.       RDX := $FFFF;
  1407.       XMS;
  1408.       CASE LO(RBX) OF
  1409.         $00 : BEGIN
  1410.                 WRITE(TPSTR,'   HMA verfügbar = ',RDX,' Bytes');
  1411.                 RAX := $0200; { RELEASE HMA }
  1412.                 XMS;
  1413.               END;
  1414.         $81 : WRITE(TPSTR,'   HMA ist nicht verfügbar, weil VDISK installiert ist');
  1415.         $91 : WRITE(TPSTR,'   HMA ist von einem anderen Programm belegt');
  1416.       ELSE WRITE(TPSTR,'   Request HMA Error ',HEXB(LO(RBX)));
  1417.       END; { CASE LO(RBX) }
  1418.       VWRITELN;
  1419. { XMA ABFRAGEN }
  1420.       RAX := $0800;
  1421.       XMS;
  1422.       WRITE(TPSTR,'   XMA verfügbar = ',RDX,'k Bytes');
  1423.       IF RDX <> RAX THEN WRITE(TPSTR,',    größter Block = ',RAX,'k Bytes');
  1424.       VWRITELN;
  1425. { UMA ANFORDERN }
  1426.       RAX := $1000;
  1427.       RDX := $FFFF;
  1428.       XMS;
  1429.       IF LO(RBX) <> $80 THEN BEGIN
  1430.         CASE LO(RBX) OF
  1431.           $00 : BEGIN
  1432.                   WRITE(TPSTR,'   UMA verfügbar = ',RDX,' Bytes');
  1433.                   WRITE(TPSTR,'   UMA Segment = ',HEXW(RBX));
  1434.                 END;
  1435.           $B0 : WRITE(TPSTR,'   UMA ist zu klein');
  1436.           $B1 : WRITE(TPSTR,'   UMA ist nicht verfügbar');
  1437.         ELSE WRITE(TPSTR,'   Request HMA Error ',HEXB(LO(RBX)));
  1438.         END; { CASE LO(RBX) }
  1439.         VWRITELN;
  1440.       END; { IF LO(RBX) <> $80 }
  1441.     END; { IF RAX = 1 }
  1442.   END ELSE BEGIN
  1443.     WRITE(TPSTR,' Es ist kein HIMEM- Treiber installiert');
  1444.     VWRITELN;
  1445.   END; { IF HIMEMINST }
  1446.   VWRITELN;
  1447.  
  1448. { --- EMS MEMORY }
  1449.   EMG := 0;
  1450.   PFBA := 0;
  1451.   IF EMSINSTALLED THEN BEGIN  { EMM installiert? }
  1452.     VERS := EMSVERSION;
  1453.     PFBP := EMSPAGEFRAMEPTR;
  1454.     PFBA := SOF(PFBP).S;
  1455.     TPAG := EMSTOTALPAGES;
  1456.     EMG  := TPAG * 16;
  1457.     PGAV := EMSPAGESAVAIL;
  1458.     WRITE(TPSTR,'   EMM- Version : ',VERS SHR 4,'.',VERS AND $0F,'                   ');
  1459.     WRITE(TPSTR,'Page Frame = ',HEXW(PFBA),'H');
  1460.     VWRITELN;
  1461.     WRITE(TPSTR,'   EMS- Seiten gesamt = ',TPAG:3,' (',EMG,'k)     ');
  1462.     WRITE(TPSTR,' verfügbar = ',PGAV:3,' (',PGAV*16,'k)');
  1463.     VWRITELN;
  1464.   END ELSE BEGIN
  1465.     VWRITELNS(' Es ist kein EMS- Treiber installiert');
  1466.   END;
  1467.   VWRITELN;
  1468.  
  1469. { --- EXTENDED MEMORY OHNE XMM }
  1470.   IF AT THEN BEGIN
  1471.     XRG := EXTMEMTOTAL SHR 10;
  1472.     XRA := EXTMEMAVAIL;
  1473.     WRITE(TPSTR,'   Extended RAM total = ',XRG:4,'k           ');
  1474.     WRITE(TPSTR,' verfügbar = ',XRA:4,'k');
  1475.     VWRITELN;
  1476.     XRAM := GETPORT(RTC,$30) + (GETPORT(RTC,$31) SHL 8);
  1477.     WRITE(TPSTR,' Extended RAM (SETUP) = ',XRAM:4,'k     ');
  1478.     IF (EMG > 0) AND (XRG > 0) THEN WRITE(TPSTR,'  EMS + Extended = ',EMG+XRG:4,'k');
  1479.     VWRITELN;
  1480.   END;
  1481.  
  1482. { --- DOS VERSION, HANDLES }
  1483.   VWRITELN;
  1484.   WRITE(TPSTR,'   Prozessor = 80',ABS(CPU_TYPE));
  1485.   VWRITELN;
  1486.   I := VIDADAP;
  1487.   WRITE(TPSTR,'   Video Adapter 1 = ');
  1488.   VADAPTERTEXT(HI(I));
  1489.   VWRITELN;
  1490.   WRITE(TPSTR,'   Video Adapter 2 = ');
  1491.   VADAPTERTEXT(LO(I));
  1492.   VWRITELN;
  1493.   IF DRDOS THEN WRITE(TPSTR,'   DRDOS') ELSE WRITE(TPSTR,'   DOS');
  1494.   WRITE(TPSTR,' Version ',HI(DOSVERSION),'.',LO(DOSVERSION));
  1495.   WRITE(TPSTR,'                   ');
  1496.   WRITE(TPSTR,FILEHANDLESLEFT+FILEHANDLESOPEN(TRUE),' File- Handles sind verfügbar');
  1497.   VWRITELN;
  1498.  
  1499. { --- SPEICHERBELEGUNG AB 0A000:0 }
  1500.   VWRITELN;
  1501.   VWRITELNS('          Speicherbelegung A000:0000..F000:FFFF :');
  1502.   VWRITELN;
  1503.   SHADOWDISP(PFBA);
  1504.  
  1505. { --- EIGENEN FREIEN HEAP ANZEIGEN }
  1506.   VWRITELN;
  1507.   WRITE(TPSTR,'  MEMAVAIL = ',MEMAVAIL:8,'           MAXAVAIL = ',MAXAVAIL:8);
  1508.   VWRITELN;
  1509.   WRITE(TPSTR,'  MCBLIST wurde aufgerufen von ',QUELLDIR);
  1510.   VWRITELN;
  1511.   WRITE(TPSTR,'     MCBLIST befindet sich auf ',ZIELDIR);
  1512.   VWRITELN;
  1513. { ALS SCHMANKERL NOCH DEN MUTTERPROZESS ANZEIGEN }
  1514.   WRITE(TPSTR,'  Der Mutterprozess von MCBLIST ist ');
  1515.   IF PSPPTR(PTR(CHEF,0))^.CMDSEG = CHEF THEN BEGIN
  1516.     WRITE(TPSTR,GETENV('COMSPEC'));
  1517.   END ELSE BEGIN
  1518.     WRITE(TPSTR,HOLENAME(PTR(PSPPTR(PTR(CHEF,0))^.ENVSEG,0)));
  1519.   END;
  1520.   VWRITELN;
  1521.   WRITE(TPSTR,'  mit PSP auf Adresse ',HEXW(CHEF),':0000,  Environment ');
  1522.   WRITE(TPSTR,HEXW(PSPPTR(PTR(CHEF,0))^.ENVSEG),':0000');
  1523.   VWRITELN;
  1524. { MAUSTREIBER- INFO HOLEN }
  1525.   MAUSINFO;
  1526.  
  1527.   CLOSEVSCREEN(5);
  1528. END; { MEMINFO }
  1529.  
  1530.  
  1531. PROCEDURE PSPINHALT(PP:PSPPTR);
  1532. VAR   MP    : ^BYTEARR;
  1533. BEGIN
  1534.   IF PP^.INTR20 <> $20CD THEN EXIT;
  1535.   WRITE(TPSTR,'End of allocation block = ',HEXW(PP^.ENDBL));
  1536.   VWRITELN;
  1537.   WRITE(TPSTR,'       INT 22H- Pointer = ',HEXPTR(PP^.I22PTR));
  1538.   VWRITELN;
  1539.   WRITE(TPSTR,'       INT 23H- Pointer = ',HEXPTR(PP^.I23PTR));
  1540.   VWRITELN;
  1541.   WRITE(TPSTR,'       INT 24H- Pointer = ',HEXPTR(PP^.I24PTR));
  1542.   VWRITELN;
  1543.   WRITE(TPSTR,' Mutterprozess- Segment = ',HEXW(PP^.CMDSEG));
  1544.   VWRITELN;
  1545.   WRITE(TPSTR,'   Environment- Segment = ',HEXW(PP^.ENVSEG));
  1546.   VWRITELN;
  1547.   WRITE(TPSTR,'Comandline = ≥',PP^.CMDLIN,'≤');
  1548.   VWRITELN;
  1549.   WRITE(TPSTR,'Handle- Tabelle : ',HEXPTR(PP^.HNDPTR));
  1550.   WRITE(TPSTR,'  Anzahl Handles = ',PP^.HNDMAX);
  1551.   VWRITELN;
  1552.   MP := PP^.HNDPTR;
  1553.   FOR I := 1 TO PP^.HNDMAX DO BEGIN
  1554.     IF MP^[I] <> $FF THEN BEGIN
  1555.       IF I > 1 THEN WRITE(TPSTR,',');
  1556.       WRITE(TPSTR,MP^[I]);
  1557.     END;
  1558.   END;
  1559.   VWRITELN;
  1560. END; { PSPINHALT }
  1561.  
  1562.  
  1563. PROCEDURE MEHRINFO;
  1564. VAR   MP     : ^CHARRAY;
  1565.       PP     : PSPPTR;
  1566.       I,J,K  : INTEGER;
  1567.       TA     : BYTE;
  1568.       R      : REGISTERS;
  1569.       S      : STRING;
  1570. BEGIN
  1571.   IF MCBAP < 1 THEN EXIT;
  1572.   IF MCBDP < 1 THEN MCBDP := 1;
  1573.   IF SETWINDOW(7,$07,60,60,TRUE) THEN CLRVSCREEN(7,$07);
  1574.  
  1575.   TA := TEXTATTR;
  1576.   TEXTATTR := $5B;
  1577.   VWRITELNS('       ''+'',''-'' = MCB- Nummer ändern                  ');
  1578.   TEXTATTR := TA;
  1579.   WRITE(TPSTR,'  MCB ',MCBDP,': ');
  1580.   WRITE(TPSTR,'  ',HEXW(MCBA[MCBDP].ADDR),':0000  ');
  1581.   CASE MCBA[MCBDP].ATTR OF
  1582.     1 : WRITE(TPSTR,'Environment');
  1583.     2 : WRITE(TPSTR,'PSP');
  1584.     3 : WRITE(TPSTR,'Batch');
  1585.     4 : WRITE(TPSTR,'Ur- Environment');
  1586.     5 : WRITE(TPSTR,'Video- RAM und EPROM');
  1587.     6 : WRITE(TPSTR,'CONFIG.SYS');
  1588.     7 : WRITE(TPSTR,'freier Speicher');
  1589.   ELSE
  1590.     WRITE(TPSTR,'nicht identifiziert');
  1591.     VWRITELN;
  1592.     WRITE(TPSTR,'  wahrscheinlich ein Treiber');
  1593.   END; { CASE }
  1594.   IF MCBA[MCBDP].MCBR.PSP = 0 THEN WRITE(TPSTR,' -frei-');
  1595.   VWRITELN;
  1596.   IF MCBA[MCBDP].MCBR.ID = 'Z' THEN VWRITELNS('       letzter MCB');
  1597.   CASE MCBA[MCBDP].ATTR OF
  1598.   1,4 : BEGIN
  1599.           MP := PTR(SUCC(MCBA[MCBDP].ADDR),0);
  1600.           I := 1; J := 0; K := 0;
  1601.           REPEAT
  1602.             IF MP^[I] = #0 THEN BEGIN
  1603.               INC(J);
  1604.               K := 0;
  1605.               IF J = 1 THEN VWRITELN;
  1606.             END ELSE BEGIN
  1607.               WRITE(TPSTR,MP^[I]);
  1608.               INC(K);
  1609.               IF K > 58 THEN BEGIN
  1610.                 VWRITELN;
  1611.                 K := 0;
  1612.               END;
  1613.               J := 0;
  1614.             END;
  1615.             INC(I);
  1616.           UNTIL J = 2;
  1617.           IF MP^[I] = #1 THEN BEGIN
  1618.             VWRITELNS('  Programmname :');
  1619.             INC(I,2);
  1620.             WHILE MP^[I] <> #0 DO BEGIN
  1621.               WRITE(TPSTR,MP^[I]);
  1622.               INC(I);
  1623.             END;
  1624.             VWRITELN;
  1625.           END;
  1626.         END;
  1627.     2 : BEGIN
  1628.           PP := PTR(MCBA[MCBDP].MCBR.PSP,0);
  1629.           PSPINHALT(PP);
  1630.         END;
  1631.     3 : BEGIN
  1632.           IF BATDISP(SUCC(MCBA[MCBDP].ADDR),FALSE) THEN VWRITELN;
  1633.         END;
  1634.     5 : BEGIN
  1635.           FOR I := 1 TO 25 DO BEGIN
  1636.             DEACTIVATEVSCREEN;
  1637.             FASTREAD(60,I,1,S);
  1638.             ACTIVATEVSCREEN(SC[7]);
  1639.             VWRITELNS(S);
  1640.           END;
  1641.         END;
  1642.     6 : BEGIN
  1643.           R.AH := $52;
  1644.           MSDOS(R);
  1645.           WRITE(TPSTR,'    MSDOS(52)  ES:BX (',HEXPTR(PTR(R.ES,R.BX)),')');
  1646.           VWRITELN;
  1647.           FOR I := -3 TO 10 DO DISPPTR(R.ES,R.BX,I*4);
  1648.         END;
  1649.     7 : BEGIN
  1650.           PP := PTR(SUCC(MCBA[MCBDP].ADDR),0);
  1651.           PSPINHALT(PP);
  1652.         END;
  1653.   END; { CASE }
  1654.  
  1655.   CLOSEVSCREEN(7);
  1656. END; { MEHRINFO }
  1657.  
  1658.  
  1659.  
  1660. BEGIN { MAIN }
  1661.   CHECKBREAK := FALSE;
  1662.   CHECKSNOW  := FALSE;
  1663.  
  1664.   QUIET  := TRUE;
  1665.   WNM    := 0;
  1666.   SIZMOD := 1;
  1667.   MS     := 0;
  1668.   MSM    := 0;
  1669.   MSN    := 0;
  1670.   MO     := 0;
  1671.   MOM    := 0;
  1672.   MON    := 0;
  1673.   KT1    := '';
  1674.   MCBAP  := 0;
  1675.   MCBDP  := 1;
  1676.   HATPAR := FALSE;
  1677.   FILERR := TRUE;
  1678.  
  1679.   CX := WHEREX;
  1680.   CY := WHEREY;
  1681.   MSX := 1;
  1682.   MSY := 1;
  1683.   BUT := NOBUTTON;
  1684.   MAUSAKT := FALSE;
  1685.  
  1686.   TEXTATTR := TANORM;
  1687.   TA := TEXTATTR;
  1688.   IF NOT ENTFERNE(MEMW[PREFIXSEG:$2C]) THEN {};
  1689.   IF NOT ENTFERNE(PREFIXSEG) THEN {};
  1690.   CHEF := PSPPTR(PTR(PREFIXSEG,0))^.CMDSEG;
  1691.  
  1692.   EXPLODE := TRUE;
  1693.   SOUNDFLAGW := FALSE;
  1694.   EXPLODEDELAY := 3;
  1695.   DOS4 := (HI(DOSVERSION) >= 4);
  1696.   DRDOS := GETENV('OS') = 'DRDOS';
  1697.   IF DRDOS THEN DOS4 := FALSE;
  1698.  
  1699. { VIDEOATTRIBUTE FÜR LCD- DIPLAY }
  1700.   LCD := FALSE;
  1701.   IF (STUPCASE(GETENV('CRT'))='LCD') THEN BEGIN
  1702.     TAKOPF := $62;
  1703.     TAFREI := $30;
  1704.     TAFRAM := $37;
  1705.     TAVALT := $02;
  1706.     TAVNEU := $4F; { TEXTATTRIBUT NEUER VEKTOR }
  1707.     TAINAKT := $04;
  1708.     LCD := TRUE;
  1709.   END;
  1710. { VIDEO- ATTRIBUTE FÜR MONOCHROM- DIAPLAY }
  1711.   IF (LO(LASTMODE) = 7)  THEN BEGIN
  1712.     TAFREI := $01;
  1713.     TAVALT := $01;
  1714.     TAMROM := $10;
  1715.     TAMRAM := $10;
  1716.     TAINAKT := $02;
  1717.   END;
  1718.  
  1719.   IF NOT MAKEWINDOW(BWIN,10,12,70,16,TRUE,TRUE,FALSE,$1F,$2B,$AE,' Taste drücken ')
  1720.     THEN ALERT('FEHLER MAKEWINDOW');
  1721.   IF NOT MAKEWINDOW(WI[1],1,3,80,25,TRUE,TRUE,TRUE,$07,$5F,$5E,' Memory Control Blocks ')
  1722.     THEN ALERT('FEHLER MAKEWINDOW');
  1723.   IF NOT MAKEWINDOW(WI[2],2,8,79,24,TRUE,TRUE,TRUE,$70,$1C,$1E,' was das Alles bedeutet ')
  1724.     THEN ALERT('FEHLER MAKEWINDOW');
  1725.   IF NOT MAKEWINDOW(WI[3],4,16,77,25,TRUE,TRUE,TRUE,$07,$49,$4B,' Interrupt- Vektoren ')
  1726.     THEN ALERT('FEHLER MAKEWINDOW');
  1727.   IF NOT MAKEWINDOW(WI[4],22,6,79,22,TRUE,TRUE,TRUE,$07,$31,$31,' Device Treiber ')
  1728.     THEN ALERT('FEHLER MAKEWINDOW');
  1729.   IF NOT MAKEWINDOW(WI[5],4,3,76,15,TRUE,TRUE,TRUE,$1B,$2B,$2F,' Speicherkonfiguration ')
  1730.     THEN ALERT('FEHLER MAKEWINDOW');
  1731.   IF NOT MAKEWINDOW(WI[6],2,3,50,18,TRUE,TRUE,TRUE,$07,$60,$6E,' C:\CONFIG.SYS ')
  1732.     THEN ALERT('FEHLER MAKEWINDOW');
  1733.   IF NOT MAKEWINDOW(WI[7],30,12,80,25,TRUE,TRUE,TRUE,$07,$51,$5B,' MCB - INFO ')
  1734.     THEN ALERT('FEHLER MAKEWINDOW');
  1735.  
  1736. { WINDOW- PARAMETER INITIALISIEREN }
  1737.   FOR I := 1 TO MAXWIND DO BEGIN
  1738.     SETINACTIVEFRAME(WI[I],'┌└┐┘─│',TAINAKT,TAINAKT);
  1739.     RESETWINPAR(I);
  1740.   END;
  1741.   WN := 1;
  1742.   WS := '';
  1743.  
  1744.   IF PARAMCOUNT > 0 THEN BEGIN
  1745.     P1 := STUPCASE(PARAMSTR(1));
  1746.     IF (LENGTH(P1) > 0) AND (P1[1] = '/') THEN DELETE(P1,1,1);
  1747.     IF (LENGTH(P1) > 0) AND (P1[1] = '-') THEN DELETE(P1,1,1);
  1748.     IF P1 = '?'  THEN BEGIN
  1749.                         KOPFZEILE;
  1750.                         HATPAR := TRUE;
  1751.                         HELP;
  1752.                       END;
  1753.     IF P1 = 'R'  THEN BEGIN
  1754.                         RESTOREINTS(FALSE,FALSE);
  1755.                         HALT;
  1756.                       END;
  1757.     IF P1 = 'RM' THEN BEGIN
  1758.                         RESTOREINTS(TRUE,FALSE);
  1759.                         HALT;
  1760.                       END;
  1761.     IF P1 = 'S'  THEN BEGIN
  1762.                         MCBLISTE;
  1763.                         SAVEINTS;
  1764.                         HALT;
  1765.                       END;
  1766.     IF P1 = 'M'  THEN BEGIN
  1767.                         KOPFZEILE;
  1768.                         HATPAR := TRUE;
  1769.                         INTMAP;
  1770.                       END;
  1771.     IF P1 = 'X'  THEN BEGIN
  1772.                         KOPFZEILE;
  1773.                         HATPAR := TRUE;
  1774.                         DRIVERDIS;
  1775.                       END;
  1776.   END;
  1777.   IF NOT HATPAR THEN BEGIN
  1778.     KOPFZEILE;
  1779.     MCBLISTE;
  1780.   END;
  1781.  
  1782.  
  1783.   REPEAT;
  1784.     MOUSEORKEY;
  1785.     CH1 := READKEY;
  1786.     IF CH1 = #0 THEN CH2 := READKEY ELSE CH2 := #0;
  1787.  
  1788.     CASE CH1 OF
  1789. {TAB}  #9 : BEGIN
  1790.               INC(WP[WN].X,10);
  1791.               IF WP[WN].X > (WP[WN].W - (LO(WINDMAX) - LO(WINDMIN)))
  1792.                 THEN WP[WN].X := WP[WN].W - (LO(WINDMAX) - LO(WINDMIN)) -1;
  1793.               UPDWIN;
  1794.             END;
  1795. {ESC}  ^[ : IF LENGTH(WS) > 0 THEN BEGIN
  1796.               CLOSEWINDOW(WN);
  1797.             END ELSE BEGIN
  1798.               CH1 := #0;
  1799.               CH2 := #1;
  1800.             END;
  1801.       '+' : IF WN = 7 THEN BEGIN
  1802.               INC(MCBDP);
  1803.               IF MCBDP > MCBAP THEN MCBDP := 1;
  1804.               MEHRINFO;
  1805.             END;
  1806.       '-' : IF WN = 7 THEN BEGIN
  1807.               DEC(MCBDP);
  1808.               IF MCBDP < 1 THEN MCBDP := MCBAP;
  1809.               MEHRINFO;
  1810.             END;
  1811.     END; { CASE CH1 }
  1812.     CASE CH2 OF
  1813. {F1}  #59 : HELP;
  1814. {F2}  #60 : MCBLISTE;
  1815. {F3}  #61 : INTMAP;
  1816. {F4}  #62 : MEMINFO;
  1817. {F5}  #63 : DRIVERDIS;
  1818. {F6}  #64 : CONFIGDIS;
  1819. {F7}  #65 : CLOSEWINDOWS;
  1820. {F8}  #66 : MEHRINFO;
  1821. {F9}  #67 : DUMP;
  1822. {F10} #68 : IF WN = 1 THEN BEGIN
  1823.               CLOSEWINDOW(1);
  1824.               INC(SIZMOD);
  1825.               IF SIZMOD > 4 THEN SIZMOD := 1;
  1826.               MCBLISTE;
  1827.             END;
  1828.  
  1829. {S1}  #84 : IF LENGTH(WS) > 0 THEN CLOSEWINDOW(WN);
  1830. {S2}  #85 : BEGIN END;
  1831. {S3}  #86 : BEGIN END;
  1832. {S4}  #87 : BEGIN END;
  1833. {S5}  #88 : BEGIN
  1834.               RESTOREINTS(FALSE,FALSE);
  1835.               MCBLISTENEU;
  1836.             END;
  1837. {S6}  #89 : BEGIN
  1838.               RESTOREINTS(TRUE,FALSE);
  1839.               MCBLISTENEU;
  1840.             END;
  1841. {S9}  #92 : BEGIN
  1842.               SAVEINTS;
  1843.               MCBLISTENEU;
  1844.             END;
  1845.  
  1846. {A5} #108 : BEGIN
  1847.               RESTOREINTS(FALSE,TRUE);
  1848.               MCBLISTENEU;
  1849.             END;
  1850. {A6} #109 : BEGIN
  1851.               RESTOREINTS(TRUE,TRUE);
  1852.               MCBLISTENEU;
  1853.             END;
  1854.  
  1855. {HO}  #71 : BEGIN
  1856.               IF WP[WN].X = 1 THEN WP[WN].Y := 1 ELSE WP[WN].X := 1;
  1857.               UPDWIN;
  1858.             END;
  1859. {EN}  #79 : BEGIN
  1860.               WP[WN].Y := WP[WN].L - (HI(WINDMAX) - HI(WINDMIN));
  1861.               UPDWIN;
  1862.             END;
  1863. {PU}  #73 : BEGIN
  1864.               DEC(WP[WN].Y,HI(WINDMAX)-HI(WINDMIN)-1);
  1865.               IF WP[WN].Y < 1 THEN WP[WN].Y := 1;
  1866.               UPDWIN;
  1867.             END;
  1868. {PD}  #81 : IF WP[WN].Y < (WP[WN].L - (HI(WINDMAX) - HI(WINDMIN))) THEN BEGIN
  1869.               INC(WP[WN].Y,HI(WINDMAX)-HI(WINDMIN)-1);
  1870.               UPDWIN;
  1871.             END;
  1872. {RI}  #77 : BEGIN
  1873.               DEC(WP[WN].X,2);
  1874.               IF WP[WN].X < 1 THEN WP[WN].X := 1;
  1875.               UPDWIN;
  1876.             END;
  1877. {LE}  #75 : IF WP[WN].X < (WP[WN].W - (LO(WINDMAX) - LO(WINDMIN)) - 1) THEN BEGIN
  1878.               INC(WP[WN].X,2);
  1879.               UPDWIN;
  1880.             END;
  1881. {UP}  #72 : IF WP[WN].Y > 1 THEN BEGIN
  1882.               DEC(WP[WN].Y);
  1883.               UPDWIN;
  1884.             END;
  1885. {DN}  #80 : IF WP[WN].Y < (WP[WN].L - (HI(WINDMAX) - HI(WINDMIN))) THEN BEGIN
  1886.               INC(WP[WN].Y);
  1887.               UPDWIN;
  1888.             END;
  1889.  
  1890. {CRI}#116 : BEGIN
  1891.               IF MOVEWINDOW(1,0) THEN HIDDENCURSOR;
  1892.             END;
  1893. {CLE}#115 : BEGIN
  1894.               IF MOVEWINDOW(-1,0) THEN HIDDENCURSOR;
  1895.             END;
  1896. {CUP}#141 : BEGIN
  1897.               IF MOVEWINDOW(0,-1) THEN HIDDENCURSOR;
  1898.             END;
  1899. {CDN}#145 : BEGIN
  1900.               IF MOVEWINDOW(0,1) THEN HIDDENCURSOR;
  1901.             END;
  1902.  
  1903. {ARI}#157 : BEGIN
  1904.               IF RESIZEWINDOW(1,0,' ')
  1905.                 THEN UPDWIN
  1906.                 ELSE IF MOVEWINDOW(-1,0) THEN
  1907.                   IF RESIZEWINDOW(1,0,' ') THEN UPDWIN;
  1908.             END;
  1909. {ALE}#155 : BEGIN
  1910.               IF RESIZEWINDOW(-1,0,' ') THEN HIDDENCURSOR;
  1911.             END;
  1912. {AUP}#152 : BEGIN
  1913.               IF RESIZEWINDOW(0,-1,' ') THEN HIDDENCURSOR;
  1914.             END;
  1915. {ADN}#160 : BEGIN
  1916.               IF RESIZEWINDOW(0,1,' ')
  1917.                 THEN UPDWIN
  1918.                 ELSE IF MOVEWINDOW(0,-1) THEN
  1919.                   IF RESIZEWINDOW(0,1,' ') THEN UPDWIN;
  1920.             END;
  1921.     END; { CASE CH2 }
  1922.   UNTIL CH2 = #1;
  1923.  
  1924.   AUSDIEMAUS;
  1925. END.
  1926.  
  1927.  
  1928.