home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / library / dos / teseract / tesspark.asm < prev    next >
Encoding:
Assembly Source File  |  1988-10-02  |  8.6 KB  |  285 lines
  1.         PAGE 60,132
  2.         TITLE TESSPARK.ASM -- TesSeRact Demo program to park disk drive heads
  3. ;----------------------------------------------------------------------------
  4. SUBTTL  TesSeRact Revision Level 1
  5. ;-----------------------------------------------------------------------------
  6. ;   TesSeRact(tm) -- A Library of Routines for Creating Ram-Resident (TSR)
  7. ;                    programs for the IBM PC and compatible Personal
  8. ;                    Computers.
  9. ;
  10. ;The software, documentation and source code are: 
  11. ; 
  12. ;       Copyright (C) 1986, 1987, 1988 Tesseract Development Team
  13. ;       All Rights Reserved 
  14. ; 
  15. ;       c/o Chip Rabinowitz
  16. ;       Innovative Data Concepts
  17. ;       2084 Woodlawn Avenue
  18. ;       Glenside, PA 19038
  19. ;       1-215-884-3373
  20. ;
  21. ;-----------------------------------------------------------------------------
  22. ;   This product supports the TesSeRact Standard for Ram-Resident Program 
  23. ;   Communication.  For information about TesSeRact, contact the TesSeRact 
  24. ;   Development Team at:
  25. ;       Compuserve:    70731,20
  26. ;       MCIMAIL:       315-5415
  27. ;   This MCIMAIL Account has been provided to the TesSeRact Development
  28. ;   Team by Borland International, Inc.  The TesSeRact Development Team
  29. ;   is in no way associated with Borland International, Inc.
  30. ;-----------------------------------------------------------------------------
  31. ;
  32. ; BASED on code originally provided by Jim Mischel
  33. ;
  34. ; ORIGINAL COPYRIGHT NOTICE:
  35. ;
  36. ;;;; AUTOPARK.ASM - program to automatically park the disk drive heads
  37. ;;;; at specified time intervals.
  38. ;;;;
  39. ;;;; Copyright (c) 1988, Jim Mischel
  40. ;;;;
  41. ;;;;
  42. ;;;; This program has been assembled using MASM 5.0.  Changes may be required for
  43. ;;;; use with earlier versions.
  44. ;;;;
  45. ;;;; To build:
  46. ;;;;    MASM AUTOPARK ;
  47. ;;;;    LINK AUTOPARK ;
  48. ;;;;    EXE2BIN AUTOPARK AUTOPARK.COM
  49.  
  50. ;
  51. ; To assemble this TesSeRact version:
  52. ;
  53. ;       MASM TESSPARK;
  54. ;       LINK TESS_ASM+TESS_BP+TESSPARK+TESS_END,TESSPARK;
  55. ;       EXE2BIN TESSPARK.EXE TESSPARK.COM
  56. ;
  57.  
  58. .model small
  59.  
  60. .code
  61.  
  62. ; wait_count is # of timer ticks to wait between the last disk access
  63. ; and parking the disk.  Each tick is approximately 1/18.2 seconds.
  64. ; 
  65. ; Maximum wait count is 65536 ticks (0), which is darn close to 1 hour.
  66. ;
  67. wait_count      equ     1092            ;1 minute
  68. ;wait_count     equ     192             ;10 seconds (for testing)
  69.  
  70.  
  71. speaker_beep    equ     1               ;sound TESSBEEP if set
  72.  
  73. tick_count      dw      ?
  74.  
  75. ;
  76. ; This routine attempts to park the disk.
  77. ; Returns with carry set if park was unsuccessful.
  78. ;
  79. ; I'm not real clear on all the details here.  I disassembled this from a
  80. ; park program I've been using.  It will park the heads on all hard disks.
  81. ; It's using some undocumented (or not very well documented) features of the
  82. ; AT BIOS.  From looking at the code, I'd say it doesn't work on XT's, but
  83. ; when run, it seems to work fine.
  84. ;
  85. parkit  proc    near
  86.         mov     si,0080h
  87. pk0:    mov     ah,08h
  88.         mov     dx,si                   ;DX is drive ID
  89.         int     13h                     ;get drive parameters
  90.         add     dl,30h
  91.         xor     dh,dh                   ;This is going to tell
  92.         add     dx,4fh                  ;us whether we've got an AT
  93.         mov     di,dx                   ;save drive count
  94.         cmp     di,0080h
  95.         jb      pkdone                  ;< 0080 means it's an XT
  96.         inc     ch                      ;CH is tracks + 1
  97.         jnb     pk1
  98.         add     cl,40h                  ;CL is sectors
  99. pk1:    mov     ax,0c01h                ;seek to cylinder
  100.         mov     dx,si                   ;DX is drive ID
  101.         int     13h                     ;this does the seek
  102.         inc     si                      ;bump drive count
  103.         cmp     si,di
  104.         jbe     pk0                     ;loop until all drives are parked
  105. pkdone:
  106. if speaker_beep
  107. EXTRN TESSBEEP:NEAR
  108.  
  109.         call    TESSBEEP
  110. endif
  111.         ret
  112. parkit  endp
  113.  
  114. ;
  115. ; TesSeRact Entry Points
  116. ;
  117. ;
  118. PUBLIC  TSRUSERPROC, TSRTIMERPROC, TSRBACKCHECK, TSRMAIN, TSRBACKPROC
  119. PUBLIC  TSRCLEANUP
  120.  
  121. ;
  122. ; These are NULL procedures.  We don't service them in this program
  123. ;
  124. ;
  125. TSRUSERPROC:
  126. TSRMAIN:
  127.         ret
  128.  
  129. MyParms dw      0                       ;saved location of INT 13 flag 
  130.                                         ;  from TesSeRact data area
  131.  
  132. do_park db      0                       ;flag set when we want to park
  133.  
  134. TSRBACKCHECK proc near
  135.         assume cs:_TEXT, ds:_TEXT
  136.  
  137.         mov     al,do_park              ;do we want to park the disk?
  138.         xor     ah,ah                   ;if non-zero, yes!
  139.         ret
  140. TSRBACKCHECK endp
  141.  
  142. TSRBACKPROC proc near
  143.         assume cs:_TEXT, ds:_TEXT
  144.  
  145.         call    near ptr parkit         ;attempt to park it
  146.         mov     do_park,0
  147.         mov     bx,[MyParms]
  148.         mov     word ptr [tick_count],wait_count        ;restart wait
  149.         mov     byte ptr [bx],0
  150.  
  151.         ret
  152. TSRBACKPROC endp
  153.  
  154. TSRCLEANUP proc near
  155.         assume cs:_TEXT, ds:_TEXT
  156.  
  157.         or      ax,ax
  158.         jnz     clean_term
  159.  
  160. clean_init:
  161. ;
  162. ;  Please note that the data area returned by this function is also available
  163. ;    as the TESS_GLOBALS public symbol.
  164. ;
  165.         mov     cx,ParkNum
  166.         mov     bx,4h                   ;in data area
  167.         mov     ax,5453h
  168.         int     2fh
  169.  
  170.         add     bx,3h                   ;add in offset we want (Was13)
  171.  
  172.         mov     MyParms,bx              ;since we know segment is our's
  173.                                         ;we don't need to worry about it!
  174.  
  175. clean_term:                             ;nothing needed to terminate!
  176. clean_out:
  177.         ret
  178.  
  179. TSRCLEANUP endp
  180.  
  181.  
  182. TSRTIMERPROC proc near
  183.         assume cs:_TEXT, ds:_TEXT
  184.  
  185.         mov     bx,[MyParms]
  186.         cmp     byte ptr [bx],1
  187.         jne     no_park
  188. no_disk:
  189.         mov     [do_park],0
  190.         dec     word ptr [tick_count]
  191.         jnz     no_park
  192.  
  193.         mov     [do_park],1
  194. clear_it:
  195.         mov     word ptr [tick_count],wait_count        ;restart wait
  196.         mov     byte ptr [bx],0                         ;clear flag
  197. no_park:
  198.         ret
  199.  
  200. TSRTIMERPROC endp
  201.  
  202. ;
  203. ; If AUTOPARK already installed, display error message and exit.
  204. ; If not installed, attempt to park the disks and install the resident
  205. ; portion.
  206. ;
  207. EXTRN TSDOINIT:NEAR
  208. EXTRN TSCHECKRESIDENT:near
  209. EXTRN TSSETSTACK:near
  210.  
  211. ParkNum         dw 0                    ;our ID number
  212. ParkName        db 'TESSPARK',0         ;our Identification string
  213.  
  214. public mystack
  215. public topstack
  216.  
  217. mystack         db 512 dup(0)           ;stack to use
  218.  
  219. topstack        equ this byte
  220.  
  221. PUBLIC TESSINITSTART                    ;required entry point
  222.  
  223. TESSINITSTART:
  224.         assume cs:_TEXT, ds:_TEXT
  225.  
  226.         mov     dx,offset signon
  227.         mov     ah,09
  228.         int     21h                     ;display the signon message
  229.  
  230.         mov     si,offset ParkName
  231.         mov     di,offset ParkNum
  232.         call    TSCHECKRESIDENT
  233.  
  234.         or      ax,ax
  235.         jz      do_install
  236.  
  237.         mov     dx,offset already_installed     ;we must already be installed
  238.         mov     ah,09
  239.         int     21h                     ;display message
  240. term_it:
  241.         mov     ax,4c01h
  242.         int     21h                     ;and exit with error code
  243.  
  244. do_install:
  245.         mov     di,offset topstack
  246.         dec     di
  247.         dec     di
  248.         mov     si,di
  249.         call    TSSETSTACK
  250.  
  251.         call    near ptr parkit         ;attempt to park disk
  252.         jmp     short inst1
  253.  
  254. inst1:
  255.         mov     word ptr cs:[tick_count],wait_count     ;start wait
  256. ;
  257. ; display installed message and exit
  258. ;
  259.         mov     dx,offset installed
  260.         mov     ah,09
  261.         int     21h
  262.  
  263.         mov     dx,offset TESSINITSTART
  264.         mov     bx,1060h                ;no pop graphics, timer proc and
  265.                                         ;    background procs only
  266.         xor     ax,ax                   ;no hotkey!
  267.         dec     ax                      ;no hotkey is -1
  268.  
  269.         call    TSDOINIT
  270.         jmp     term_it                 ;we should never do this!
  271.  
  272. signon  db      13,10,'TESSPARK.COM Version 1.0, Copyright (c) '
  273.         db      '1988, TesSeRact(tm) Development Team',13,10
  274.         db      'All Rights Reserved',13,10,10
  275.         db      'Based on Original Code provided by Jim Mischel:',13,10
  276.         db      '   AUTOPARK 1.0  Copyright (c) 1988, Jim Mischel',13,10,'$'
  277. installed       label   byte
  278.         db      'TESSPARK installed',13,10,'$'
  279. already_installed       label   byte
  280.         db      'TESSPARK already installed',7,13,10,'$'
  281.  
  282. _TEXT ends
  283.  
  284.         END
  285.