home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / lisp / interpre / xlispplu / xlisp2tc / _turboc_ / xlisp.eg < prev    next >
Encoding:
Internet Message Format  |  1991-04-14  |  7.8 KB
  1. From sce!mitel!uunet!mailrus!cs.utexas.edu!tut.cis.ohio-state.edu!ucbvax!hplabs!hpfcso!hpfcbig!tim Fri Feb 16 07:17:21 EST 1990
  2. Article: 73 of comp.lang.lisp.x
  3. Path: cognos!sce!mitel!uunet!mailrus!cs.utexas.edu!tut.cis.ohio-state.edu!ucbvax!hplabs!hpfcso!hpfcbig!tim
  4. From: tim@hpfcbig.SDE.HP.COM (Tim Mikkelsen)
  5. Newsgroups: comp.lang.lisp.x
  6. Subject: Re: intro to XLISP objects
  7. Message-ID: <1170006@hpfcbig.SDE.HP.COM>
  8. Date: 12 Feb 90 16:24:20 GMT
  9. References: <1170004@hpfcbig.SDE.HP.COM>
  10. Organization: HP SESD, Fort Collins, CO
  11. Lines: 228
  12.  
  13.  
  14. A MORE REALISTIC EXAMPLE 
  15. ______________________________________________________________________________
  16.  
  17.  
  18. The following is an example, using the idea of tools again.  It contains
  19. a hierarchy of tool  classes.  The top of the class  hierarchy is TOOLS.
  20. HAND-TOOLS and SHOP-TOOLS are sub-classes of TOOLS.  The example creates
  21. instances of these  sub-classes.  It is possible to extend this  example
  22. in various ways.  One obvious  extension would be to create a third tier
  23. of classes  under  HAND-TOOLS  that could  contain  classes like drills,
  24. screwdrivers, pliers and so on.
  25.  
  26.  
  27.  
  28.  
  29. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  30. ;
  31. ;    File name:    tools.lsp
  32. ;    Author:        Tim Mikkelsen
  33. ;    Description:    Object-oriented example program
  34. ;    Language:    XLISP 2.0
  35. ;
  36. ;    Date Created:    10-Jan-1988
  37. ;    Date Updated:    2-Apr-1989
  38. ;    
  39. ;    (c) Copyright 1988, by Tim Mikkelsen, all rights reserved.
  40. ;        Permission is granted for unrestricted non-commercial use.
  41. ;
  42. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  43.  
  44. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  45. ;
  46. ;    Define the superclasses and classes
  47. ;
  48. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  49.  
  50. ;
  51. ; make TOOLS superclass
  52. ;    with a different :ISNEW method
  53. ;    added methods are :BORROW and :RETURN
  54. ;    class variables are    NUMBER        contains # of tool instances
  55. ;                ACTIVE-LIST    contains list of current objects
  56. ;    instance variables are     POWER         list - (AC BATTERY HAND)
  57. ;                MOVEABLE     CAN-CARRY or CAN-ROLL or FIXED
  58. ;                OPERATIONS    list
  59. ;                MATERIAL     list - (WOOD METAL PLASTIC ...)
  60. ;                PIECES         list
  61. ;                LOCATION    HOME or person's name
  62. ;
  63.  
  64. (setq tools (send class :new '(power 
  65.                    moveable 
  66.                    operations 
  67.                    material 
  68.                    pieces 
  69.                    location) 
  70.                  '(number active-list)))
  71. (send tools :answer :isnew '() 
  72.                    '((if (null number) (setq number 1)
  73.                                  (setq number (1+ number)))
  74.                  (setq active-list (cons self active-list))
  75.                  (setq location 'home)))
  76. (send tools :answer :borrow '(by-who)
  77.                     '((if (eq location 'home) (setq location by-who)
  78.                                      (print "you can't"))))
  79. (send tools :answer :return '()
  80.                     '((if (eq location 'home) (print "got it already")
  81.                                      (setq location 'home))))
  82.  
  83. ;
  84. ; make HAND-TOOLS class
  85. ;    with a different :ISNEW method
  86. ;    new instance variable    WEIGHT        <number> of pounds
  87. ;    the rest is inherited from TOOLS 
  88. ; 
  89.  
  90. (setq hand-tools (send class :new '(weight) '() tools))
  91. (send hand-tools :answer :isnew '(pow op mat parts w-in)
  92.                     '((setq power pow)
  93.                       (setq moveable 'can-carry)
  94.                       (setq operations op)
  95.                       (setq material mat)
  96.                           (setq pieces parts)
  97.                       (setq weight w-in)
  98.                       (send-super :isnew)))
  99.  
  100. ;
  101. ; make SHOP-TOOLS class
  102. ;    with a different :ISNEW method
  103. ;    no new instance variables
  104. ;    the rest is inherited from TOOLS 
  105. ; 
  106.  
  107. (setq shop-tools (send class :new '() '() tools))
  108. (send shop-tools :answer :isnew '(pow mov op mat parts)
  109.                     '((setq power pow)
  110.                      (setq moveable mov)
  111.                      (setq operations op)
  112.                      (setq material mat)
  113.                      (setq pieces parts)
  114.                      (send-super :isnew)))
  115.  
  116. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  117. ;
  118. ;    Create instances of various tool classes 
  119. ;
  120. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  121.  
  122. (setq hand-drill (send hand-tools :new         ; make an instance - HAND-DRILL
  123.                  '(ac) 
  124.                  '(drill polish grind screw)
  125.                  '(wood metal plastic)
  126.                  '(drill drill-bits screw-bits buffer)
  127.                  '2.5))
  128.  
  129. (setq table-saw (send shop-tools :new         ; make an instance - TABLE-SAW
  130.                  '(ac)
  131.                  'fixed
  132.                  '(rip cross-cut)
  133.                  '(wood plastic)
  134.                  '(saw blades fence)))
  135.  
  136.  
  137. (setq radial-arm (send shop-tools :new         ; make an instance = RADIAL-ARM
  138.                  '(ac)
  139.                  'can-roll
  140.                  '(rip cross-cut)
  141.                  '(wood plastic)
  142.                  '(saw blades dust-bag)))
  143.  
  144.  
  145. The following  session shows how to use the tool  definitions  from this
  146. better  example.  The example starts at the OS shell and brings up xlisp
  147. running the file 'tools.lsp'.
  148.  
  149.      ________________________________________________________________
  150.     |
  151.     |    cmd? xlisp tools
  152.     |    ; loading "init.lsp"
  153.     |    ; loading "tools.lsp"
  154.     |    > (send hand-drill :borrow 'fred)
  155.     |    FRED
  156.     |
  157.     |    > (send table-saw :return)
  158.     |    "got it already"
  159.     |    "got it already"
  160.     |
  161.     |    > (send hand-drill :borrow 'joe)
  162.     |    "you can't"
  163.     |    "you can't"
  164.     |
  165.     |    > (send hand-drill :return)
  166.     |    HOME
  167.     |________________________________________________________________
  168.  
  169.  
  170. So, Fred was able to borrow the HAND-DRILL.  When an attempt was made to
  171. return the  TABLE-SAW,  it was  already  at home.  A second  attempt  to
  172. borrow the HAND-DRILL  indicated that "you can't" because it was already
  173. lent out.  Lastly, the HAND-DRILL was returned successfully.  (Note that
  174. the "got it  already"  and "you  can't"  strings  show up  twice  in the
  175. display because the methods both print and return the string.)
  176.  
  177. The following session shows the structure of the TOOLS object:
  178.  
  179.      ________________________________________________________________
  180.     |
  181.     |    > (send tools :show)
  182.     |    Object is #<Object: #276fc>, Class is #<Object: #23fe2>
  183.     |      MESSAGES = ((:RETURN . #<Closure-:RETURN: #2dbd0>) 
  184.     |                (:BORROW . #<Closure-:BORROW: #2ddba>) 
  185.     |              (:ISNEW . #<Closure-:ISNEW: #274a4>))
  186.     |      IVARS = (POWER MOVEABLE OPERATIONS MATERIAL PIECES LOCATION)
  187.     |      CVARS = (NUMBER ACTIVE-LIST)
  188.     |      CVALS = #(3 (#<Object: #2cadc> 
  189.     |                 #<Object: #2cda2> 
  190.     |           #<Object: #2d0e0>))
  191.     |      SUPERCLASS = #<Object: #23fd8>
  192.     |      IVARCNT = 6
  193.     |      IVARTOTAL = 6
  194.     |    #<Object: #276fc>
  195.     |________________________________________________________________
  196.  
  197.  
  198. The two TOOLS sub-classes HAND-TOOLS and SHOP-TOOLS structure looks like:
  199.  
  200.      ________________________________________________________________
  201.     |
  202.     |    > (send hand-tools :show)
  203.     |    Object is #<Object: #2dab8>, Class is #<Object: #23fe2>
  204.     |      MESSAGES = ((:ISNEW . #<Closure-:ISNEW: #2d7a2>))
  205.     |      IVARS = (WEIGHT)
  206.     |      CVARS = NIL
  207.     |      CVALS = NIL
  208.     |      SUPERCLASS = #<Object: #276fc>
  209.     |      IVARCNT = 1
  210.     |      IVARTOTAL = 7
  211.     |    #<Object: #2dab8>
  212.     |
  213.     |    > (send shop-tools :show)
  214.     |    Object is #<Object: #2d680>, Class is #<Object: #23fe2>
  215.     |      MESSAGES = ((:ISNEW . #<Closure-:ISNEW: #2d450>))
  216.     |      IVARS = NIL
  217.     |      CVARS = NIL
  218.     |      CVALS = NIL
  219.     |      SUPERCLASS = #<Object: #276fc>
  220.     |      IVARCNT = 0
  221.     |      IVARTOTAL = 6
  222.     |    #<Object: #2d680>
  223.     |________________________________________________________________
  224.  
  225.  
  226. The class HAND-TOOLS has an instance HAND-DRILL which looks like:
  227.  
  228.      ________________________________________________________________
  229.     |
  230.     |    > (send hand-drill :show)
  231.     |    Object is #<Object: #2d0e0>, Class is #<Object: #2dab8>
  232.     |      WEIGHT = 2.5
  233.     |      POWER = (AC)
  234.     |      MOVEABLE = CAN-CARRY
  235.     |      OPERATIONS = (DRILL POLISH GRIND SCREW)
  236.     |      MATERIAL = (WOOD METAL PLASTIC)
  237.     |      PIECES = (DRILL DRILL-BITS SCREW-BITS BUFFER)
  238.     |      LOCATION = HOME
  239.     |    #<Object: #2d0e0>
  240.     |________________________________________________________________
  241.  
  242.  
  243.