home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / basic / library / zbasic / pia / address.bas next >
Encoding:
BASIC Source File  |  1987-10-30  |  2.0 KB  |  49 lines
  1. 100 DEFINT A,G,I,K,M,N,P,S,T,U,W: DEFDBL B,C,D,L,O
  2. 101 DEFSNG E,F,H,J,Q,R,V,X,Y,Z
  3. 105 REM $INCLUDE: 'COMMON.BAS'
  4. 110 REM $INCLUDE: 'GETSTRN.BAS'
  5. 1000 REM Retrieve current address
  6. 1005 OPEN "I",1,"ADDRESS.DAT"
  7. 1010 FOR K1=1 TO 4: INPUT #1,T$(K1): NEXT K1: CLOSE #1
  8. 1015 REM Print address correction menu
  9. 1020 CLS: GOSUB 2000: PRINT "   ";: GOSUB 9870
  10. 1025 PRINT STRING$(20," ");"Set social security office address";
  11. 1030 PRINT STRING$(21," "): GOSUB 2000
  12. 1035 PRINT: PRINT: PRINT "   Current address is:"
  13. 1040 FOR K1=1 TO 4: PRINT "   (";K1;") ";
  14. 1045 PRINT T$(K1): NEXT K1: PRINT
  15. 1050 GOSUB 9860: PRINT "   Enter line number to change, or 0 if";
  16. 1055 PRINT " okay > ";: K8=VAL(FNGETSTRN$(1)): GOSUB 9850
  17. 1060 IF K8<0 OR K8>4 THEN BEEP: GOTO 1050
  18. 1065 IF K8=0 THEN 1200
  19. 1070 GOSUB 9860: PRINT "   Enter new line";K8;"(RETURN if none)"
  20. 1075 PRINT "   > ";: T$(K8)=FNGETSTRN$(34): GOSUB 9850
  21. 1080 GOTO 1015
  22. 1200 REM Save new address
  23. 1205 OPEN "O",1,"ADDRESS.DAT"
  24. 1210 FOR K1=1 TO 4: PRINT #1,CHR$(34);T$(K1);CHR$(34): NEXT K1: CLOSE #1
  25. 1400 REM Print exit menu
  26. 1405 CLS: GOSUB 2000: PRINT "   ";: GOSUB 9870
  27. 1410 PRINT STRING$(29," ");"Program selection";STRING$(29," ")
  28. 1415 GOSUB 2000: PRINT: PRINT
  29. 1420 GOSUB 9860: PRINT "   Enter desired program:"
  30. 1425 PRINT "     0 to calculate a PIA"
  31. 1427 PRINT "     1 to review or change configuration"
  32. 1430 PRINT "     2 to review or update historical amounts"
  33. 1435 PRINT "   > ";: K8=VAL(FNGETSTRN$(1))
  34. 1440 IF K8<0 OR K8>2 THEN BEEP: GOTO 1420
  35. 1445 CLS: GOSUB 9850: ON K8+1 GOTO 1600,1460,1450
  36. 1450 PRINT "   Loading data-update program; please wait..."
  37. 1455 CHAIN "OLDAWBI"
  38. 1460 PRINT "   Loading configuration program; please wait..."
  39. 1465 CHAIN "CONFIG"
  40. 1600 PRINT "   Loading PIA data-input program; please wait..."
  41. 1605 CHAIN "PIAIN"
  42. 2000 REM Subroutine to draw 75 hyphens
  43. 2005 GOSUB 9860: PRINT "   ";STRING$(75,"-"): RETURN
  44. 9800 REM 1-line subroutines
  45. 9813 REM For Macintosh, $INCLUDE "COLOR.MAC"
  46. 9814 REM $INCLUDE: 'COLOR.BAS'
  47. 9900 GOSUB 9860: CLS: END
  48. 9999 REM ADDRESS.BAS - 10/30/87 - 03:45 PM
  49.