home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / basic / library / gwbasic / friendly / 21.bas next >
Encoding:
BASIC Source File  |  1994-05-25  |  12.9 KB  |  259 lines
  1. 10 '6/15/83
  2. 20 WIDTH 80:SCREEN 0,0,0:KEY OFF:LOCATE ,,0:CLEAR:ON KEY(10) GOSUB 2400:DEFSTR Z:DIM DK(52),CDSU(52),LIN$(5,13):XX=1:YY=1:GOSUB 2070:GOSUB 2470
  3. 30 GOSUB 2010:M$="$$#,###.##":CSH=2000
  4. 40 IF CSH<=0 AND PS<>1 THEN 2560
  5. 50 IF CSH>10000 THEN 2580
  6. 60 GOSUB 2190:GOSUB 2550:GOSUB 2420:TS=0:HOLD=0:GOSUB 2120
  7. 70 LOCATE 24,1:PRINT SPC(66);:LOCATE 24,20
  8. 80 LOCATE 23,1:PRINT SPC(62)
  9. 90 IF PS THEN PS=0:LOCATE 23,33:PRINT"The Bet Stands";:COLOR 15,0:LOCATE 6,69:PRINT USING M$;BT*100:COLOR 3,0:GOTO 110
  10. 100 GOSUB 980
  11. 110 CD=CD+1:IF CD>40 THEN GOSUB 2010:GOTO 110
  12. 120 A=1:B=1:CP(1)=DK(CD):HOLD=CD:CD=0:GOSUB 2040:CD=HOLD:A=8:B=1:CD=CD+1:PYR(1)=DK(CD):GOSUB 2040:A=1:B=12:CD=CD+1:CP(2)=DK(CD):GOSUB 2040
  13. 130 A=8:B=12:CD=CD+1:PYR(2)=DK(CD):GOSUB 2040
  14. 140 IF PYR(1)>9 THEN PYR(1)=10
  15. 150 IF CP(1)>9 THEN CP(1)=10
  16. 160 IF CP(2)>9 THEN CP(2)=10
  17. 170 IF CP(1)=10 AND CP(2)=1 THEN BJK1=1:GOTO 640
  18. 180 IF CP(2)=10 AND CP(1)=1 THEN BJK1=1:GOTO 640
  19. 190 IF PYR(2)>9 THEN PYR(2)=10
  20. 200 IF PYR(1)<>PYR(2) OR SPF1 THEN 230
  21. 210 COLOR 31,0:LOCATE 24,22:PRINT"Do You Wish To Split Your Hand? <Y/N>     ";:COLOR 3,0:GOSUB 1810:IF NO THEN 230
  22. 220 GOSUB 1360:IF NSP THEN 230 ELSE 130
  23. 230 NSP=0:GOSUB 1940:IF PS THEN 640
  24. 240 IF BJK1 THEN 640
  25. 250 IF BJK2 THEN 640
  26. 260 GOSUB 1240
  27. 270 LOCATE 24,1:PRINT SPC(62);:COLOR 15,0
  28. 280 LOCATE 24,19:PRINT"     Hit, Stand Or Double Down? <H/S/D>        ";
  29. 290 COLOR 3,0:GOSUB 1870:IF HIT THEN 430
  30. 300 IF STD THEN 480
  31. 310 IF CSH-BT*100>=0 THEN CSH=CSH-BT*100:BT=BT*2:GOSUB 2550:GOTO 350
  32. 320 LOCATE 24,1:PRINT SPC(62);:LOCATE 24,20:COLOR 15,0
  33. 330 PRINT"You Don't Have Enough Money To Double Down";
  34. 340 FOR D=1 TO 4000:NEXT:GOTO 390
  35. 350 A=8:TS=1:B=12+TS*11:CD=CD+1:LOCATE 6,69:COLOR 15,0:PRINT USING M$;BT*100:COLOR 3,0:PYR(TS+2)=DK(CD)
  36. 360 GOSUB 2040:GOSUB 1240
  37. 370 IF PYRBTD THEN 640
  38. 380 GOTO 480
  39. 390 LOCATE 24,1:PRINT SPC(79);:COLOR 15,0
  40. 400 LOCATE 24,20:PRINT"You Have"PYRHD"Showing.  Hit Or Stand? <H/S>";
  41. 410 GOSUB 1870:IF HIT THEN 430
  42. 420 IF STD THEN 480 ELSE 410
  43. 430 TS=TS+1:CD=CD+1:B=12+TS*11:PYR(TS+2)=DK(CD)
  44. 440 GOSUB 2040:GOSUB 1240
  45. 450 IF PYRHD=21 THEN 480
  46. 460 IF PYRBTD THEN 640
  47. 470 GOTO 390
  48. 480 TS=0
  49. 490 A=1:SWAP CD,HOLD:B=1:GOSUB 2040:SWAP HOLD,CD
  50. 500 CPHD=0
  51. 510 FOR C=1 TO TS+2
  52. 520 IF CP(C)>9 THEN CP(C)=10
  53. 530 CPHD=CPHD+CP(C)
  54. 540 NEXT
  55. 550 FOR C=1 TO TS+2
  56. 560 IF CP(C)<>1 THEN 590
  57. 570 IF CPHD+10=21 THEN CPHD=CPHD+10:GOTO 640
  58. 580 IF CPHD+10<21 THEN CPHD=CPHD+10
  59. 590 NEXT
  60. 600 IF CPHD>16 THEN 650
  61. 610 FOR QQ=1 TO 1500:NEXT
  62. 620 TS=TS+1:CD=CD+1:CP(TS+2)=DK(CD):A=1:B=12+TS*11
  63. 630 GOSUB 2040:GOTO 500
  64. 640 A=1:SWAP CD,HOLD:B=1:GOSUB 2040:SWAP HOLD,CD
  65. 650 IF PS THEN 730
  66. 660 IF BJK1 THEN 760
  67. 670 IF BJK2 THEN 780
  68. 680 IF PYRBTD THEN 810
  69. 690 IF CPHD>21 THEN 830
  70. 700 IF CPHD=PYRHD THEN 730
  71. 710 IF CPHD>PYRHD THEN 860
  72. 720 GOTO 880
  73. 730 PS=1
  74. 740 LOCATE 23,1:PRINT SPC(66);:LOCATE 23,31
  75. 750 PRINT"Push To Next Hand!";::GOTO 910
  76. 760 LOCATE 23,1:PRINT SPC(66);:LOCATE 23,25
  77. 770 PRINT"Dealer Has Blackjack!  You Lose.";:GOTO 910
  78. 780 LOCATE 23,1:PRINT SPC(66);:LOCATE 23,22
  79. 790 PRINT"You Have Blackjack! Dealer Pays Double.";
  80. 800 CSH=CSH+BT*300:GOSUB 2550:GOTO 910
  81. 810 LOCATE 23,1:PRINT SPC(66);:LOCATE 23,29
  82. 820 PRINT"You Busted! Dealer Wins.";:GOTO 910
  83. 830 LOCATE 23,1:PRINT SPC(66);:LOCATE 23,30
  84. 840 PRINT"Dealer Busted! You Win.";
  85. 850 CSH=CSH+BT*200:GOSUB 2550:GOTO 910
  86. 860 LOCATE 23,1:PRINT SPC(66);:LOCATE 23,21
  87. 870 PRINT"Dealer Has"CPHD". You Have"PYRHD". Dealer Wins";:GOTO 910
  88. 880 LOCATE 23,1:PRINT SPC(66);:LOCATE 23,23
  89. 890 PRINT"Dealer Has"CPHD". You Have"PYRHD". You Win.";
  90. 900 CSH=CSH+BT*200:GOSUB 2550
  91. 910 LOCATE 24,1:PRINT SPC(66);
  92. 920 COLOR 15,0:LOCATE 24,27:PRINT" Strike Any Key To Continue ";
  93. 930 IF INKEY$="" THEN 930 ELSE LOCATE 6,69:COLOR 15,0:PRINT USING M$;0:LOCATE 7,68:PRINT SPC(11):LOCATE 8,69:PRINT SPC(11):LOCATE 24,1:PRINT SPC(62);:COLOR 3,0
  94. 940 SPF1=0:IF SPF AND PYRBTD THEN SPF=0:PYRHD=PYRHD2:PYRBTD=0:GOTO 500
  95. 950 SPF1=0:IF SPF THEN SPF=0:PYRHD=PYRHD2:GOTO 690
  96. 960 LOCATE 6,69:COLOR 15,0:PRINT USING M$;0:LOCATE 24,1:PRINT SPC(62);:COLOR 3,0
  97. 970 GOTO 40
  98. 980 LOCATE 23,1:PRINT SPC(66);:LOCATE 24,1:PRINT SPC(66);
  99. 990 COLOR 15,0:LOCATE 23,22:PRINT"Place Your Bet Please. How Many Chips,";
  100. 1000 LOCATE 24,22:PRINT"From 1 to"CSH/100"?  Then Strike Enter Key.  ";:COLOR 3,0:
  101. 1010 Z="":ZH=""
  102. 1020 DEF SEG:POKE 106,0:IF INKEY$<>"" THEN 1020
  103. 1030 DEF SEG=&H40:POKE &H17,(PEEK(&H17) OR 96)
  104. 1040 Z=INKEY$:IF Z="" THEN 1040
  105. 1050 IF Z<>CHR$(8) AND RIGHT$(Z,1)<>CHR$(75) THEN 1080
  106. 1060 IF ZH="" THEN 1040
  107. 1070 PRINT CHR$(29)" "CHR$(29);:ZH=LEFT$(ZH,LEN(ZH)-1):GOTO 1040
  108. 1080 IF Z=CHR$(13) THEN 1120
  109. 1090 IF Z<"0" OR Z>"9" THEN 1040
  110. 1100 IF LEN(ZH)>3 THEN 1040
  111. 1110 ZH=ZH+Z:PRINT Z;:GOTO 1040
  112. 1120 BT=VAL(ZH)
  113. 1130 COLOR 15,0:LOCATE 5,69:PRINT"The Bet Is"
  114. 1140 LOCATE 6,69:PRINT USING M$;BT*100:COLOR 3,0
  115. 1150 LOCATE 23,1:PRINT SPC(66);
  116. 1160 IF BT<1 THEN 1210
  117. 1170 IF BT<=CSH/100 THEN CSH=CSH-BT*100:GOSUB 2550:GOTO 2120
  118. 1180 LOCATE 23,1:PRINT SPC(66);:LOCATE 24,1:PRINT SPC(66);:LOCATE 24,20
  119. 1190 PRINT"You Don't Have That Many Chips. Please Try Again.";
  120. 1200 FOR D=1 TO 3000:NEXT:LOCATE 24,1:PRINT SPC(79);:GOTO 980
  121. 1210 LOCATE 23,1:PRINT SPC(66);:LOCATE 24,1:PRINT SPC(66);:LOCATE 24,20
  122. 1220 PRINT"Please Bet An Amount Greater Than Zero.";
  123. 1230 GOTO 1200
  124. 1240 PYRHD=0:PYRBTD=0
  125. 1250 FOR C=1 TO TS+2
  126. 1260 IF PYR(C)>9 THEN PYR(C)=10
  127. 1270 PYRHD=PYRHD+PYR(C)
  128. 1280 NEXT
  129. 1290 IF PYRHD>21 THEN PYRBTD=1:RETURN
  130. 1300 FOR C=1 TO TS+2
  131. 1310 IF PYR(C)<>1 THEN 1340
  132. 1320 IF PYRHD+10=21 THEN PYRHD=21:RETURN
  133. 1330 IF PYRHD+10<21 THEN PYRHD=PYRHD+10
  134. 1340 NEXT
  135. 1350 RETURN
  136. 1360 IF CSH-BT*100>=0 THEN 1400
  137. 1370 LOCATE 24,1:PRINT SPC(79);:LOCATE 24,20
  138. 1380 PRINT"You Don't Have Enough Money To Split Your Hand.";
  139. 1390 NSP=1:FOR F=1 TO 3000:NEXT:LOCATE 24,1:PRINT SPC(79);:RETURN
  140. 1400 SPF1=1:SWAP PYR(1),HOLD(1):PYR(1)=PYR(2)
  141. 1410 COLOR 15,0:LOCATE 7,68:PRINT"Bottom Hand":LOCATE 8,69:PRINT USING M$;BT*100:COLOR 3,0
  142. 1420 FOR D=8 TO 15:LOCATE D,12:PRINT SPC(11);:NEXT
  143. 1430 CSH=CSH-BT*100:GOSUB 2550
  144. 1440 A=15:B=1:GOSUB 2040
  145. 1450 CD=CD+1:B=12:PYR(2)=DK(CD):GOSUB 2040
  146. 1460 GOSUB 1940:IF BJK2 THEN 1690
  147. 1470 GOSUB 1240:TS=0
  148. 1480 LOCATE 24,1:PRINT SPC(79);:COLOR 15,0
  149. 1490 LOCATE 24,23:PRINT"Hit,Stand, Or Double Down? <H/S/D>";
  150. 1500 GOSUB 1870:IF HIT THEN 1610
  151. 1510 IF STD THEN 1680
  152. 1520 IF CSH-BT*100>=0 THEN 1560
  153. 1530 LOCATE 24,1:PRINT SPC(79);:LOCATE 24,20
  154. 1540 PRINT"You Don't Have Enough Money To Double Down";
  155. 1550 FOR F=1 TO 3000:NEXT:GOTO 1650
  156. 1560 CSH=CSH-BT*100:BT2=BT*2:LOCATE 8,69:COLOR 15,0:PRINT USING M$;BT2*100:COLOR 3,0:GOSUB 2550
  157. 1570 A=15:TS=1:B=12+TS*11:CD=CD+1:PYR(TS+2)=DK(CD)
  158. 1580 GOSUB 2040:GOSUB 1240
  159. 1590 IF PYRBTD THEN 1720
  160. 1600 GOTO 1740
  161. 1610 TS=TS+1:CD=CD+1:B=12+TS*11:PYR(TS+2)=DK(CD)
  162. 1620 GOSUB 2040:GOSUB 1240
  163. 1630 IF PYRHD=21 THEN 1740
  164. 1640 IF PYRBTD THEN 1720
  165. 1650 LOCATE 24,1:PRINT SPC(79);:COLOR 15,0
  166. 1660 LOCATE 24,20:PRINT"You Have"PYRHD"Showing. Hit Or Stand? <H/S>";
  167. 1670 GOSUB 1870:IF HIT THEN 1610
  168. 1680 IF STD THEN 1740 ELSE 1670
  169. 1690 LOCATE 23,1:PRINT SPC(66);:LOCATE 23,20
  170. 1700 PRINT"You Have Blackjack! Dealer Pays Double.";
  171. 1710 CSH=CSH+BT*300:GOSUB 2550:GOTO 1750
  172. 1720 LOCATE 23,1:PRINT SPC(66);:LOCATE 23,20
  173. 1730 PRINT"You Busted! Dealer Wins.";:GOTO 1750
  174. 1740 SPF=1
  175. 1750 SWAP PYR(1),HOLD(1):TS=0
  176. 1760 PYRHD2=PYRHD
  177. 1770 LOCATE 24,1:PRINT SPC(79);
  178. 1780 COLOR 15,0:LOCATE 24,27:PRINT" Strike Any Key To Continue ";:COLOR 3,0
  179. 1790 LOCATE 23,1:PRINT SPC(66)
  180. 1800 IF INKEY$="" THEN 1800 ELSE LOCATE 24,1:PRINT SPC(62);:RETURN
  181. 1810 DEF SEG:POKE 106,0
  182. 1820 IF INKEY$<>"" THEN 1820
  183. 1830 Z=INKEY$
  184. 1840 IF Z="Y" OR Z="y" THEN YES=1:NO=0:RETURN
  185. 1850 IF Z="N" OR Z="n" THEN YES=0:NO=1:RETURN
  186. 1860 GOTO 1830
  187. 1870 DEF SEG:POKE 106,0:IF INKEY$<>"" THEN 1870
  188. 1880 HIT=0:STD=0
  189. 1890 Z=INKEY$
  190. 1900 IF Z="H" OR Z="h" THEN HIT=1:RETURN
  191. 1910 IF Z="S" OR Z="s" THEN STD=1:RETURN
  192. 1920 IF Z="D" OR Z="d" THEN RETURN
  193. 1930 GOTO 1880
  194. 1940 BJK1=0:BJK2=0:PS=0
  195. 1950 IF CP(1)=1 AND CP(2)>9 THEN BJK1=1
  196. 1960 IF CP(1)>9 AND CP(2)=1 THEN BJK1=1
  197. 1970 IF PYR(1)=1 AND PYR(2)>9 THEN BJK2=1
  198. 1980 IF PYR(1)>9 AND PYR(2)=1 THEN BJK2=1
  199. 1990 IF BJK1 AND BJK2 THEN PS=1
  200. 2000 RETURN
  201. 2010 LOCATE 2,28:PRINT"One Moment Please While":LOCATE 3,30:PRINT"I Shuffle The Deck":ERASE DK:DIM DK(52):FOR A=1 TO 13:RANDOMIZE VAL(RIGHT$(TIME$,2))*RND*RND:FOR C=1 TO 4
  202. 2020 B=FIX(RND*52)+1:ABC=RND*RND*RND*RND*RND*(ABC+2):IF DK(B)<>0 THEN 2020
  203. 2030 DK(B)=A:CDSU(B)=C:NEXT C,A:LOCATE 2,1:PRINT SPC(66):LOCATE 3,1:PRINT SPC(66):CD=0:RETURN
  204. 2040 COLOR 3,0:LOCATE A,B:PRINT"╔═════════╗";:LOCATE A+1,B:PRINT"║         ║";:LOCATE A+2,B:PRINT"║         ║";:LOCATE A+3,B:PRINT"║         ║";:LOCATE A+4,B:PRINT"║         ║";:LOCATE A+5,B:PRINT"║         ║";:LOCATE A+6,B:PRINT"╚═════════╝";:COLOR 6
  205. 2050 SOUND 25000,.01:SOUND 37,0:LOCATE A+1,B+1:PRINT LIN$(1,DK(CD));:LOCATE A+2,B+1:PRINT LIN$(2,DK(CD));:IF DK(CD)<>1 THEN LOCATE A+3,B+1:PRINT LIN$(3,DK(CD)); ELSE LOCATE A+3,B+5:PRINT SU$(CDSU(CD));
  206. 2060 LOCATE A+4,B+1:PRINT LIN$(4,DK(CD));:LOCATE A+5,B+1:PRINT LIN$(5,DK(CD));:LOCATE A+2,B+1:PRINT SU$(CDSU(CD));:LOCATE A+4,B+9:PRINT SU$(CDSU(CD));:COLOR 3,0:RETURN
  207. 2070 FOR A=0 TO 13:FOR B=1 TO 5:READ LIN$(B,A):NEXT:NEXT:FOR A=1 TO 4:READ SU$(A):NEXT:HOLD=0:RETURN
  208. 2080 DATA "XXXXXXXXX","XXXXXXXXX","XXXXXXXXX","XXXXXXXXX","XXXXXXXXX","A        ","         ","         ","         ","        A","2   ▄    ","         ","         ","         ","    ▄   2","3   ▄    ","         ","    ▄    ","         ","    ▄   3"
  209. 2090 DATA "4 ▄   ▄  ","         ","         ","         ","  ▄   ▄ 4","5 ▄   ▄  ","         ","    ▄    ","         ","  ▄   ▄ 5","6 ▄   ▄  ","         ","  ▄   ▄  ","         ","  ▄   ▄ 6","7 ▄   ▄  ","    ▄    ","  ▄   ▄  ","         ","  ▄   ▄ 7"
  210. 2100 DATA "8 ▄   ▄  ","    ▄    ","  ▄   ▄  ","    ▄    ","  ▄   ▄ 8","9 ▄   ▄  ","  ▄   ▄  ","    ▄    ","  ▄   ▄  ","  ▄   ▄ 9","10▄   ▄  ","  ▄ ▀ ▄  ","         ","  ▄   ▄  ","  ▄ ▀ ▄10","J        ","         ","         ","         ","        J"
  211. 2110 DATA "Q        ","         ","         ","         ","        Q","K        ","         ","         ","         ","        K","","","",""
  212. 2120 COLOR 10:H=CSH/100:H1=0
  213. 2130 IF H>10 THEN H1=H1+1:H=H-10:GOTO 2130
  214. 2140 FOR F=13 TO 23:LOCATE F,68:PRINT SPC(11):NEXT
  215. 2150 FOR F=23 TO 24-H STEP-1:LOCATE F,68:PRINT STRING$(3,223);:NEXT
  216. 2160 COLOR 12:IF H1>10 THEN HH=10 ELSE HH=H1
  217. 2170 FOR F=23 TO 24-HH STEP-1:LOCATE F,74:PRINT STRING$(5,223);:NEXT
  218. 2180 COLOR 3,0:RETURN
  219. 2190 FOR D=1 TO 22:LOCATE D,1:PRINT STRING$(66,32):NEXT:RETURN
  220. 2200 G1=BT:G2=0
  221. 2210 IF G1>9 THEN G2=G2+1:G1=G1-10:GOTO 2210
  222. 2220 F2=14+P*25
  223. 2230 F=0
  224. 2240 IF F=G2 THEN 2310
  225. 2250 FOR F1=18 TO 16 STEP-1
  226. 2260 IF F=G2 THEN 2310 ELSE F=F+1
  227. 2270 LOCATE F1,5+F2:PRINT STRING$(5,223);
  228. 2280 NEXT F1
  229. 2290 F2=F2+6
  230. 2300 GOTO 2240
  231. 2310 F2=F2+6
  232. 2320 F=0
  233. 2330 IF F=G1 THEN RETURN
  234. 2340 FOR F1=18 TO 16 STEP-1
  235. 2350 IF F=G1 THEN 2380 ELSE F=F+1
  236. 2360 LOCATE F1,5+F2:PRINT STRING$(3,223);
  237. 2370 NEXT F1
  238. 2380 F2=F2+4
  239. 2390 GOTO 2330
  240. 2400 KEY(10) OFF:XX=CSRLIN:YY=POS(0):LOCATE 25,1:PRINT SPC(79);:COLOR 15,0:LOCATE 25,22:PRINT"Do You Wish To Leave This Game? <Y/N>";:COLOR 3,0
  241. 2410 GOSUB 1810:IF YES THEN 2440
  242. 2420 LOCATE 25,1:PRINT SPC(60);
  243. 2430 LOCATE 25,24:COLOR 0,7:PRINT" Strike <F10> To Leave This Game ";:COLOR 3,0:LOCATE 25,67:PRINT" 100's 1000's";:LOCATE XX,YY,0:Z="":KEY(10) ON:RETURN
  244. 2440 CLEAR:ON ERROR GOTO 2450:RUN"MENU2"
  245. 2450 CLEAR:ON ERROR GOTO 2460:RUN"MENU1"
  246. 2460 RUN"MENU3"
  247. 2470 CLS:COLOR 6,0:LOCATE 1,1:PRINT STRING$(80,219):FOR A=2 TO 22:LOCATE A,1:PRINT"█":LOCATE A,80:PRINT"█":NEXT:LOCATE 23,1:PRINT STRING$(80,219);:LOCATE 3,19:COLOR 11,0:PRINT"F R I E N D L Y W A R E   B L A C K J A C K
  248. 2480 COLOR 15,0:LOCATE 8,23:PRINT"Would You Like Instructions? <Y/N>":GOSUB 1810:IF YES THEN ELSE CLS:RETURN
  249. 2490 COLOR 7,0:LOCATE 6,20:PRINT"In the game of Blackjack, a standard deck":LOCATE 7,20:PRINT"of cards is used.   The computer (dealer)":LOCATE 8,20:PRINT"will deal  two  cards face up to you  and
  250. 2500 LOCATE 9,20:PRINT"two cards to himself, one face up and the":LOCATE 10,20:PRINT"other face down.":LOCATE 11,20:PRINT"The object is to come as close to twenty-":LOCATE 12,20:PRINT"one  (21)  as possible without  `busting'
  251. 2510 LOCATE 13,20:PRINT"by going over twenty-one. Aces can count":LOCATE 14,20:PRINT"as one or eleven,face cards are ten, and":LOCATE 15,20:PRINT"all other cards are face value.  You may":LOCATE 16,20:PRINT"take a HIT (another card to better  your
  252. 2520 LOCATE 17,20:PRINT"hand), STAND  (play the cards you have),":LOCATE 18,20:PRINT"or DOUBLE DOWN (double your bet and take":LOCATE 19,20:PRINT"one card immediately after the deal).All":LOCATE 20,20:PRINT"ties are pushes.
  253. 2530 LOCATE 25,27:COLOR 15,0:PRINT"Strike Any Key To Continue";
  254. 2540 Z=INKEY$:IF Z="" THEN 2540 ELSE CLS:RETURN
  255. 2550 COLOR 15,0:LOCATE 2,71:PRINT"You Have";:COLOR 15,0:LOCATE 3,69:PRINT USING "$$#,###.##";CSH:COLOR 3,0:RETURN
  256. 2560 CLS:LOCATE 5,23:PRINT"You Have Lost  All  Of  Your Money!"
  257. 2570 LOCATE 7,23:PRINT"Would You Like To Play Again? <Y/N>";:GOSUB 1810:IF NO THEN 2440 ELSE 30
  258. 2580 CLS:LOCATE 5,29:COLOR 31,0:PRINT"You Broke The Bank !!!":COLOR 3,0: FOR F=1 TO 20:SOUND 500,1:SOUND 200,1:SOUND 150,1:NEXT:GOTO 2570
  259.