home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / assemblr / mslang / as / driver.asm < prev    next >
Encoding:
Assembly Source File  |  1985-08-28  |  17.6 KB  |  622 lines
  1.         name    driver
  2.         page    55,132
  3.         title   'DRIVER --- installable driver template'
  4.  
  5. ;
  6. ; This is a "template" for a MS-DOS installable device driver.
  7. ; The actual driver subroutines are stubs only and have
  8. ; no effect but to return a non-error "done" status.
  9. ; 
  10. ; Ray Duncan
  11. ; Laboratory Microsystems Inc.
  12. ; April 1985
  13.  
  14. code    segment public 'CODE'
  15.  
  16. driver  proc    far
  17.  
  18.         assume  cs:code,ds:code,es:code
  19.  
  20.         org     0
  21.  
  22.  
  23. Max_Cmd equ     15              ; MS-DOS command code maximum
  24.                                 ; this is 15 for MS-DOS 3.x
  25.                                 ; and 12 for MS-DOS 2.x 
  26.  
  27.  
  28. cr      equ     0dh             ; ASCII carriage return
  29. lf      equ     0ah             ; ASCII line feed
  30. eom     equ     '$'             ; end of message signal
  31.  
  32.  
  33.         page
  34. ;
  35. ; Device Driver Header
  36. ;
  37. Header  dd      -1              ;link to next device,-1= end of list
  38.  
  39.         dw      8000h           ;attribute word
  40.                                 ;bit 15=1 for character devices
  41.  
  42.         dw      Strat           ;device "Strategy" entry point
  43.  
  44.         dw      Intr            ;device "Interrupt" entry point
  45.  
  46.         db      'DRIVER  '      ;char device name, 8 char, or
  47.                                 ;if block device, no. of units
  48.                                 ;in first byte followed by 
  49.                                 ;7 don't care bytes     
  50.  
  51.  
  52.  
  53. ; Interpretation of Attribute word:
  54. ; 
  55. ; Bit           Significance
  56. ;
  57. ; 15            =1 for character drivers
  58. ; 14            =1 if driver can handle IOCTL
  59. ; 13            =1 if block device & non-IBM format
  60. ; 12            0
  61. ; 11            open/close/RM supported (DOS 3.x)
  62. ; 10            0
  63. ;  9            0
  64. ;  8            0
  65. ;  7            0
  66. ;  6            0
  67. ;  5            0
  68. ;  4            0
  69. ;  3            =1 if CLOCK device
  70. ;  2            =1 if NUL device
  71. ;  1            =1 if Standard Output
  72. ;  0            =1 if Standard Input
  73.  
  74.         page
  75. ;
  76. ; local variables for use by driver
  77. ;
  78. RH_Ptr  dd      ?               ; pointer to request header
  79.                                 ; passed to Strat by BDOS
  80.  
  81. Ident   db      cr,lf,lf
  82.         db      'LMI Example Device Driver 1.0'
  83.         db      cr,lf
  84.         db      'Copyright (c) 1985 '
  85.         db      'Laboratory Microsystems Inc.' 
  86.         db      cr,lf,lf,eom
  87. ;
  88. ; MS-DOS Command Codes dispatch table.
  89. ; The "Interrupt" routine uses this table and the 
  90. ; Command Code supplied in the Request Header to 
  91. ; transfer to the appropriate driver subroutine.
  92.  
  93. Dispatch:
  94.         dw      Init            ;  0 = init driver into system
  95.         dw      Media_Chk       ;  1 = media check on blk dev
  96.         dw      Build_Bpb       ;  2 = build BIOS param block
  97.         dw      Ioctl_Inp       ;  3 = I/O ctrl read from dev
  98.         dw      Input           ;  4 = normal destructive read
  99.         dw      Nd_Input        ;  5 = non-destructive read,no wait
  100.         dw      Inp_Stat        ;  6 = return current input status
  101.         dw      Inp_Flush       ;  7 = flush device input buffers
  102.         dw      Output          ;  8 = normal output to device
  103.         dw      Outp_Vfy        ;  9 = output with verify
  104.         dw      Outp_Stat       ; 10 = return current output status
  105.         dw      Outp_Flush      ; 11 = flush output buffers
  106.         dw      Ioctl_Outp      ; 12 = I/O control output
  107.         dw      Dev_Open        ; 13 = device open      (MS-DOS 3.x)
  108.         dw      Dev_Close       ; 14 = device close     (MS-DOS 3.x)
  109.         dw      Rem_Media       ; 15 = removeable media (MS-DOS 3.x)
  110.         page
  111. ; 
  112. ; MS-DOS Request Header structure definition
  113. ;
  114. ; The first 13 bytes of all Request Headers are the same
  115. ; and are referred to as the "Static" part of the Header.
  116. ; The number and meaning of the following bytes varies.
  117. ; In this "Struc" definition we show the Request Header
  118. ; contents for Read and Write calls.
  119. ;
  120. Request struc                   ; request header template structure
  121.         
  122.                                 ; beginning of "Static" portion
  123. Rlength db      ?               ; length of request header
  124. Unit    db      ?               ; unit number for this request
  125. Command db      ?               ; request header's command code
  126. Status  dw      ?               ; driver's return status word
  127. Reserve db      8 dup (?)       ; reserved area
  128.                                 ; end of "Static" portion       
  129.  
  130. Media   db      ?               ; media descriptor byte
  131. Address dd      ?               ; memory address for transfer
  132. Count   dw      ?               ; byte/sector count value
  133. Sector  dw      ?               ; starting sector value
  134.  
  135. Request ends                    ; end of request header template
  136.  
  137. ;
  138. ; Status word is interpreted as follows:
  139. ;
  140. ;  Bit(s)   Significance
  141. ;   15       Error
  142. ;   10-14    Reserved
  143. ;   9        Busy
  144. ;   8        Done
  145. ;   0-7      Error code if bit 15=1
  146.  
  147. ; Predefined BDOS error codes are:
  148. ; 
  149. ;   0       Write protect violation
  150. ;   1       Unknown unit
  151. ;   2       Drive not ready
  152. ;   3       Unknown command
  153. ;   4       CRC error
  154. ;   5       Bad drive request structure length
  155. ;   6       Seek error
  156. ;   7       Unknown media
  157. ;   8       Sector not found
  158. ;   9       Printer out of paper
  159. ;   10      Write fault
  160. ;   11      Read fault
  161. ;   12      General failure     
  162. ;   13-14   Reserved
  163. ;   15      Invalid disk change  (MS-DOS 3.x)
  164.  
  165.         page
  166.  
  167. ; Device Driver "Strategy Routine"
  168.  
  169. ; Each time a request is made for this device, the BDOS
  170. ; first calls "Strategy routine",  then immediately calls
  171. ; the "Interrupt routine".  
  172.  
  173. ; The Strategy routine is passed the address of the
  174. ; Request Header in ES:BX, which it saves in a local
  175. ; variable and then returns to the BDOS.
  176.  
  177. Strat   proc    far     
  178.                                 ; save address of Request Header
  179.         mov     word ptr cs:[RH_Ptr],bx
  180.         mov     word ptr cs:[RH_Ptr+2],es
  181.  
  182.         ret                     ; back to BDOS
  183.  
  184. Strat   endp
  185.  
  186.         page
  187.  
  188.  
  189. ; Device Driver "Interrupt Routine"
  190.  
  191. ; This entry point is called by the BDOS immediately after 
  192. ; the call to the "Strategy Routine", which saved the long
  193. ; address of the Request Header in the local variable "RH_Ptr".
  194.  
  195. ; The "Interrupt Routine" uses the Command Code passed in
  196. ; the Request Header to transfer to the appropriate device
  197. ; handling routine.  Each command code routine is responsible
  198. ; for any necessary return information into the Request Header,
  199. ; then transfers to Error or Exit to set the Return Status code.
  200.  
  201. Intr    proc  far
  202.  
  203.         push    ax              ; save general registers 
  204.         push    bx
  205.         push    cx
  206.         push    dx
  207.         push    ds
  208.         push    es
  209.         push    di
  210.         push    si
  211.         push    bp
  212.  
  213.         push    cs              ; make local data addressable
  214.         pop     ds
  215.  
  216.         les     di,[RH_Ptr]     ; ES:DI = Request Header
  217.  
  218.                                 ; get BX = Command Code
  219.         mov     bl,es:[di.Command]
  220.         xor     bh,bh
  221.         cmp     bx,Max_Cmd      ; make sure its legal
  222.         jg      Unk_Command     ; too big, exit with error code
  223.         shl     bx,1            ; form index to Dispatch table
  224.                                 ; and branch to driver routine
  225.         jmp     word ptr [bx+Dispatch]
  226.  
  227.         page
  228.  
  229.  
  230. ; General collection of exit points for the driver routines.
  231.  
  232.  
  233. Unk_Command:                    ; Come here if Command Code too big.
  234.         mov     al,3            ; Sets "Unknown Command" error 
  235.                                 ; code and "Done" bit.
  236.  
  237. Error:                          ; Transfer here with AL = error code.
  238.         mov     ah,81h          ; Sets "Error" and "Done" bits.
  239.         jmp     Exit
  240.  
  241. Done:   mov     ah,1            ; Come here if I/O complete and
  242.                                 ; no error, sets "Done" bit only.
  243.  
  244.  
  245. Exit:                           ; General purpose exit point.
  246.                                 ; Transfer here with AX = 
  247.                                 ; Return Status word to be
  248.                                 ; placed into Request Header.
  249.  
  250.         lds     bx,cs:[RH_Ptr]          ; set status
  251.         mov     ds:[bx.Status],ax
  252.  
  253.         pop     bp              ;restore general registers
  254.         pop     si
  255.         pop     di
  256.         pop     es
  257.         pop     ds
  258.         pop     dx
  259.         pop     cx
  260.         pop     bx
  261.         pop     ax
  262.         ret                     ; back to BDOS
  263.  
  264.         page
  265.  
  266.  
  267. ; Function 1  Media Check
  268.  
  269. ; Block devices only.  Should be a NOP for character devices.
  270. ;
  271. ; This routine is called first by BDOS for a block device transfer,
  272. ; passing current media descriptor byte at Request Header + 
  273. ;
  274. ; Media Check routine sets status word and in addition passes back 
  275. ; return byte at Request Header + 14  as follows:
  276.  
  277. ;    -1  Media has been changed
  278. ;     0  Don't know if media changed
  279. ;     1  Media has not been changed
  280. ;
  281. ; If driver can return 1 or -1, performance is improved because
  282. ; MS-DOS does not need to reread the FAT for each directory access.
  283.  
  284.  
  285. Media_Chk:
  286.  
  287.         jmp     Done
  288.  
  289.         page
  290.  
  291. ;
  292. ; Function 2  Build BIOS Parameter Block
  293. ; 
  294. ; Block devices only.  Should be a NOP for character devices.
  295. ;
  296. ; This routine is called by MS-DOS when Media-Changed code is
  297. ; returned by Media Check routine, or if Not Sure code is returned
  298. ; and there are no dirty buffers.
  299. ; 
  300. ; Build BPB call receives pointer to one-sector buffer in Address
  301. ; Field of Request Header (offset 14).  If "Non-IBM-Format" bit 
  302. ; in attribute word is zero, the buffer contains the first sector
  303. ; of the FAT including the media identification byte and should not 
  304. ; be altered by the driver.   If the "Non-IBM-Format" bit is set, 
  305. ; the buffer may be used as scratch space.
  306. ;
  307. ; The Build BPB routine sets status and returns a DWORD pointer to 
  308. ; the new Bios Parameter Block at Request Header + 18.
  309. ;
  310.  
  311. Build_Bpb:
  312.  
  313.         jmp     Done
  314.  
  315.         page
  316.  
  317. ;
  318. ; Function 3  I/O Control Read 
  319. ; 
  320. ; Only called if IOCTL bit set in Device Header Attribute word.
  321. ;
  322. ; Called with:
  323. ;
  324. ; Request Header + 13  BYTE   Media descriptor byte from DPB
  325. ; Request Header + 14  DWORD  Transfer address
  326. ; Request Header + 18  WORD   byte/sector count
  327. ; Request Header + 20  WORD   starting sector no. (block dev.)
  328. ;
  329. ; Returns the Return Status word set appropriately, and
  330. ; Request Header + 18  WORD   actual bytes or sectors transferred
  331. ; 
  332. ; No error check is performed on IOCTL I/O calls.
  333.  
  334. Ioctl_Inp:
  335.  
  336.         jmp     Done
  337.  
  338.         page
  339.  
  340. ;
  341. ; Function 4  Read from Device
  342. ;
  343. ; Called with
  344. ;
  345. ; Request Header + 13  BYTE   Media descriptor byte from DPB
  346. ; Request Header + 14  DWORD  Transfer address
  347. ; Request Header + 18  WORD   byte/sector count
  348. ; Request Header + 20  WORD   starting sector no. (block dev.)
  349. ;
  350. ; Returns the Return Status word set appropriately, and
  351. ; Request Header + 18  WORD   actual bytes or sectors transferred
  352.  
  353. Input: 
  354.  
  355.         jmp     Done
  356.  
  357.         page
  358.  
  359. ;
  360. ; Function 5  Non-destructive Read from Device
  361. ; 
  362. ; Character devices only.
  363. ;
  364. ; If Input Status request returns Busy bit=0 (characters 
  365. ; waiting), ; the next character that would be read is returned 
  366. ; at Request Header + 13.  This character is not removed from
  367. ; the Input Buffer.  This basically provides the capability to 
  368. ; "look-ahead" by one character.
  369.  
  370. Nd_Input:
  371.  
  372.         jmp     Done
  373.  
  374.         page
  375.  
  376. ;
  377. ; Function 6  Input Status
  378. ; 
  379. ; Character devices only.
  380. ;
  381. ; Sets the Returned Status word:
  382. ; Done bit = 1
  383. ; Busy bit = 1 read request would go to physical device
  384. ;          = 0 characters already in device buffer, read request
  385. ;              would return quickly.
  386. ;
  387. ; MS-DOS assumes all character devices have type-ahead buffer.
  388. ; If device does not have type-ahead buffer, should always
  389. ; return Busy bit=0 so MS-DOS will not hang.
  390.  
  391. Inp_Stat:
  392.  
  393.         jmp     Done
  394.  
  395.         page
  396.  
  397. ;
  398. ; Function 7  Flush Input Buffers
  399. ; 
  400. ; Character devices only.
  401. ;
  402. ; Terminate all pending requests, i.e. the Input buffer is
  403. ; emptied.
  404.  
  405. Inp_Flush:
  406.  
  407.         jmp     Done
  408.  
  409.         page
  410.  
  411. ;
  412. ; Function 8  Write to Device
  413. ; 
  414. ; Called with
  415. ;
  416. ; Request Header + 13  BYTE   Media descriptor byte from DPB
  417. ; Request Header + 14  DWORD  Transfer address
  418. ; Request Header + 18  WORD   byte/sector count
  419. ; Request Header + 20  WORD   starting sector no. (block dev.)
  420. ;
  421. ; Returns the Return Status word set appropriately, and
  422. ; Request Header + 18  WORD   actual bytes or sectors transferred
  423.  
  424. Output: 
  425.  
  426.         jmp     Done
  427.  
  428.         page
  429.  
  430. ;
  431. ; Function 9  Write with Verify to Device
  432. ; 
  433. ; Called with
  434. ;
  435. ; Request Header + 13  BYTE   Media descriptor byte from DPB
  436. ; Request Header + 14  DWORD  Transfer address
  437. ; Request Header + 18  WORD   byte/sector count
  438. ; Request Header + 20  WORD   starting sector no. (block dev.)
  439. ;
  440. ; Returns the Return Status word set appropriately, and
  441. ; Request Header + 18  WORD   actual bytes or sectors transferred
  442.  
  443. Outp_Vfy: 
  444.  
  445.         jmp     Done
  446.  
  447.         page
  448.  
  449. ;
  450. ; Function 10  Output Status
  451. ;
  452. ; Character devices only.
  453. ;
  454. ; Sets the Returned Status word:
  455. ; Done bit = 1
  456. ; Busy bit = 1 write request would wait for completion of
  457. ;              current request
  458. ;          = 0 device idle, write request would start immediately.
  459. ;
  460.  
  461. Outp_Stat:
  462.  
  463.         jmp     Done
  464.  
  465.         page
  466.  
  467. ;
  468. ; Function 11  Flush Output Buffers
  469. ; 
  470. ; Character devices only.
  471. ;
  472. ; Terminate pending requests.  The output buffer, if any,
  473. ; is emptied.
  474.  
  475. Outp_Flush:
  476.  
  477.         jmp     Done
  478.  
  479.         page
  480.  
  481. ;
  482. ; Function 12  I/O Control Write 
  483. ; 
  484. ; Only called if IOCTL bit in Device Header Attribute word is set.
  485. ;
  486. ; Called with
  487. ;
  488. ; Request Header + 13  BYTE   Media descriptor byte from DPB
  489. ; Request Header + 14  DWORD  Transfer address
  490. ; Request Header + 18  WORD   byte/sector count
  491. ; Request Header + 20  WORD   starting sector no. (block dev.)
  492. ;
  493. ; Returns the Return Status word set appropriately, and
  494. ; Request Header + 18  WORD   actual bytes or sectors transferred
  495. ;
  496. ; No error check is performed on IOCTL calls.
  497.  
  498. Ioctl_Outp:
  499.  
  500.         jmp     Done
  501.  
  502.         page
  503.  
  504. ;
  505. ; Function 13  Device Open
  506. ;
  507. ; MS-DOS version 3.0 and above only.
  508. ; Only called if OPEN/CLOSE/RM bit set in Attribute word.
  509. ; May be used to manage local buffering.  Reference count
  510. ; is incremented keeping track of number of open files on
  511. ; the device.  On character devices can be used to send
  512. ; device initialization string, which can be set by IOCTL 
  513. ; Write.  Note that CON AUX and PRN devices are always open.
  514. ;
  515. ; Returns the Return Status word set to "Done".
  516. ;
  517. Dev_Open:
  518.  
  519.         jmp     Done
  520.  
  521.         page
  522.  
  523. ;
  524. ; Function 14  Device Close
  525. ;
  526. ; MS-DOS version 3.0 and above only.
  527. ; Only called if OPEN/CLOSE/RM bit set in Attribute word.
  528. ; May be used to manage local buffering.  Reference count
  529. ; is decremented keeping track of number of open files on
  530. ; the device; when count reaches zero all files have been closed 
  531. ; and the driver should flush buffers as user may change disks.
  532. ; On character devices can be used to send device post-I/O
  533. ; string such as a form feed, which can be set by IOCTL 
  534. ; Write.  Note that CON AUX and PRN devices are never closed.
  535. ;
  536. ; Returns the Return Status word set to "Done".
  537. ;
  538. Dev_Close:
  539.  
  540.         jmp     Done
  541.  
  542.         page
  543.  
  544. ;
  545. ; Function 15  Removeable Media
  546. ;
  547. ; MS-DOS version 3.0 and above only.
  548. ; Only called if OPEN/CLOSE/RM bit set in Attribute word
  549. ;    and device type is block.
  550. ;
  551. ; Returns the Return Status word set to "Done" and 
  552. ; Busy bit = 1 if media is non-removable.  
  553. ;          = 0 if media is removable.
  554. ;
  555. Rem_Media:
  556.  
  557.         jmp     Done
  558.  
  559.  
  560.         page
  561.  
  562. ; This Initialization code for the driver is called only
  563. ; once when the driver is loaded.  It is responsible for
  564. ; initializing the hardware, setting up any necessary 
  565. ; interrupt vectors, and it must return the address
  566. ; of the first free memory after the driver to the BDOS.
  567. ; If it is a block device driver, Init must also return the 
  568. ; address of the Bios Parameter Block pointer array; if all 
  569. ; units are the same, all pointers can point to the same BPB.
  570. ; Only MS-DOS services 01-0CH and 30H can be called by the 
  571. ; Initialization function. 
  572. ;
  573. ; In this example, Init returns its own address to the DOS as 
  574. ; the start of free memory after the driver, so that the memory 
  575. ; occupied by INIT will be reclaimed after it is finished 
  576. ; with its work.  
  577. ;
  578. ; Called with:
  579. ;
  580. ; Request Header + 18  DWORD pointer to the character after the "="
  581. ;                            on the CONFIG.SYS line that loaded 
  582. ;                            driver; this information is read only.
  583. ;                  22  BYTE  drive letter for first unit of a 
  584. ;                            block driver (0=A 1=B etc)
  585. ;                            (MS-DOS 3.x only)   
  586. ;
  587. ; Returns:
  588. ; 
  589. ; Request Header + 13  BYTE  Number of units (block devices only)
  590. ;                + 14  DWORD address of first free memory above driver
  591. ;                + 18  DWORD BPB pointer array (block devices only)     
  592. ;
  593.  
  594. Init:                           ; Function 0
  595.                                 ; initialize device driver
  596.  
  597.         push    es              ; push Request Header addr
  598.         push    di
  599.  
  600.         mov     ah,9            ; print sign-on message
  601.         mov     dx,offset Ident
  602.         int     21h
  603.  
  604.         pop     di              ; restore Request Header addr
  605.         pop     es
  606.  
  607.                                 ; set first usable memory addr.
  608.         mov     word ptr es:[di.Address],offset Init
  609.         mov     word ptr es:[di.Address+2],cs
  610.  
  611.         jmp     Done
  612.  
  613.  
  614. Intr    endp
  615.  
  616.  
  617. Driver  endp
  618.  
  619. code    ends
  620.         
  621.         end     
  622.