home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / assemblr / mslang / as / break.asm < prev    next >
Encoding:
Assembly Source File  |  1985-08-28  |  5.7 KB  |  172 lines
  1.         title   Control-Break handler for Lattice C programs
  2.         name    break
  3.         include dos.mac
  4.  
  5. ;
  6. ; Control-Break Interrupt Handler for Lattice C programs 
  7. ; running on IBM PCs (and ROM BIOS compatibles)
  8. ; 
  9. ; Ray Duncan, May 1985
  10. ;
  11. ; This module allows C programs running on the IBM PC
  12. ; to retain control when the user enters a Control-Break
  13. ; or Control-C.  This is accomplished by taking over the
  14. ; Int 23H (MS-DOS Control-Break) and Int 1BH (IBM PC 
  15. ; ROM BIOS Keyboard Driver Control-Break) interrupt 
  16. ; vectors.  The interrupt handler sets an internal
  17. ; flag (which must be declared STATIC INT) to TRUE within
  18. ; the C program; the C program can poll or ignore this 
  19. ; flag as it wishes.
  20. ; 
  21. ; The module follows the Lattice C parameter passing
  22. ; conventions, and also relies on the Lattice file DOS.MAC
  23. ; for the definition of certain constants and macros.
  24. ;
  25. ; The Int 23H Control-Break handler is a function of MS-DOS
  26. ; and is present on all MS-DOS machines, however, the Int 1BH
  27. ; handler is a function of the IBM PC ROM BIOS and will not
  28. ; necessarily be present on other machines. 
  29. ; 
  30.         if      lprog
  31. args    equ     6               ;offset of arguments, Large models
  32.         else
  33. args    equ     4               ;offset of arguments, Small models
  34.         endif
  35.  
  36. cr      equ     0dh             ;ASCII carriage return
  37. lf      equ     0ah             ;ASCII line feed
  38.  
  39.         pseg
  40.  
  41.         public  capture,release ;function names for C
  42.  
  43.  
  44. ;
  45. ; The function CAPTURE is called by the C program to
  46. ; take over the MS-DOS and keyboard driver Control-
  47. ; Break interrupts (1BH and 23H).  It is passed the
  48. ; address of a flag within the C program which is set
  49. ; to TRUE whenever a Control-Break or Control-C
  50. ; is detected.  The function is used in the form:
  51. ; 
  52. ;               static int flag;
  53. ;               capture(&flag)
  54. ;
  55.  
  56. capture proc    near            ;take over Control-Break 
  57.  
  58.         push    bp              ;interrupt vectors
  59.         mov     bp,sp
  60.         push    ds
  61.  
  62.         mov     ax,word ptr [bp+args]
  63.         mov     cs:flag,ax      ;save address of integer
  64.         mov     cs:flag+2,ds    ;flag variable in C program
  65.  
  66.                                 ;pick up original vector contents
  67.         mov     ax,3523h        ;for interrupt 23H (MS-DOS
  68.         int     21h             ;Control-Break handler)
  69.         mov     cs:int23,bx
  70.         mov     cs:int23+2,es
  71.  
  72.         mov     ax,351bh        ;and interrupt 1BH 
  73.         int     21h             ;(IBM PC ROM BIOS keyboard driver
  74.         mov     cs:int1b,bx     ;Control-Break interrupt handler)
  75.         mov     cs:int1b+2,es
  76.  
  77.         push    cs              ;set address of new handler     
  78.         pop     ds
  79.         mov     dx,offset ctrlbrk
  80.         mov     ax,02523H       ;for interrupt 23H
  81.         int     21h
  82.         mov     ax,0251bH       ;and interrupt 1BH
  83.         int     21h
  84.  
  85.         pop     ds              ;restore registers and
  86.         pop     bp              ;return to C program
  87.         ret
  88.  
  89. capture endp
  90.  
  91.  
  92. ;
  93. ; The function RELEASE is called by the C program to
  94. ; return the MS-DOS and keyboard driver Control-Break
  95. ; interrupt vectors to their original state.  Int 23h is
  96. ; also automatically restored by MS-DOS upon the termination
  97. ; of a process, however, calling RELEASE allows the C
  98. ; program to restore the default action of a Control-C
  99. ; without terminating.  The function is used in the form:
  100. ;
  101. ;               release()
  102. ;
  103.  
  104. release proc    near            ;restore Control-Break interrupt
  105.                                 ;vectors to their original state        
  106.         push    bp
  107.         mov     bp,sp
  108.         push    ds
  109.  
  110.         mov     dx,cs:int1b     ;set interrupt 1BH
  111.         mov     ds,cs:int1b+2   ;(MS-DOS Control-Break 
  112.         mov     ax,251bh        ;interrupt handler)     
  113.         int     21h
  114.  
  115.         mov     dx,cs:int23     ;set interrupt 23H
  116.         mov     ds,cs:int23+2   ;(IBM PC ROM BIOS keyboard driver 
  117.         mov     ax,2523h        ;Control-Break interrupt handler)
  118.         int     21h
  119.  
  120.         pop     ds              ;restore registers and
  121.         pop     bp              ;return to C program
  122.         ret
  123.  
  124. release endp
  125.  
  126.  
  127. ;
  128. ; This is the actual interrupt handler which is called by
  129. ; the ROM BIOS keyboard driver or by MS-DOS when a Control-C
  130. ; or Control-Break is detected.  Since the interrupt handler
  131. ; may be called asynchronously by the keyboard driver, it
  132. ; is severely restricted in what it may do without crashing
  133. ; the system (e.g. no calls on DOS allowed).  In this
  134. ; version, it simply sets a flag within the C program to
  135. ; TRUE to indicate that a Control-C or Control-Break has
  136. ; been detected; the address of this flag was passed
  137. ; by the C program during the call to the CAPTURE function.
  138. ;
  139.  
  140. ctrlbrk proc    far             ;Control-Break interrupt handler
  141.  
  142.         push    bx              ;save affected registers
  143.         push    ds
  144.  
  145.         mov     bx,cs:flag      ;set flag within C program
  146.         mov     ds,cs:flag+2    ;to "True"
  147.         mov     word ptr ds:[bx],-1
  148.         
  149.         pop     ds              ;restore registers and exit
  150.         pop     bx
  151.  
  152.         iret
  153.  
  154. ctrlbrk endp
  155.  
  156.  
  157. flag    dw      0,0             ;long address of C program's
  158.                                 ;Control-Break detected flag
  159.  
  160. int23   dw      0,0             ;original contents of MS-DOS
  161.                                 ;Control-Break Interrupt 23H
  162.                                 ;vector
  163.         
  164. int1b   dw      0,0             ;original contents of ROM BIOS
  165.                                 ;keyboard driver Control-Break
  166.                                 ;Interrupt 1BH vector
  167.  
  168.  
  169.         endps
  170.  
  171.         end
  172.