home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / assemblr / library / sampler1 / free.asm < prev    next >
Encoding:
Assembly Source File  |  1985-08-28  |  6.1 KB  |  211 lines
  1.         name    free
  2.         page    60,132
  3.         title   'FREE --- Report free space on disk'
  4.  
  5. ; FREE --- a utility to report free space on
  6. ;          the default or selected disk drive.
  7. ; 
  8. ; Requires PC-DOS or MS-DOS 2.0.
  9. ;
  10. ; Used in the form:
  11. ; A> FREE  [unit:] 
  12. ; (item in square brackets is optional)
  13. ;
  14. ; version 1.0   July 4, 1984 
  15. ; Copyright (c) 1984 by Ray Duncan
  16. ; May be freely reproduced for non-commercial use. 
  17.  
  18. cr      equ     0dh             ;ASCII carriage return
  19. lf      equ     0ah             ;ASCII line feed
  20. blank    equ    20h        ;ASCII space code
  21. eom    equ    '$'        ;end of string marker
  22.  
  23.  
  24. ; Here we define a dummy segment containing labels
  25. ; for the default file control block and the command tail buffer,
  26. ; so that the main program can access those locations.
  27. ;
  28. psp    segment para public 'PSP'  
  29.  
  30.     org    05ch
  31. fcb    label    byte        ;default file control block
  32.  
  33.     org    080h
  34. command    label    byte        ;default command buffer
  35.  
  36. psp    ends
  37.  
  38.  
  39. cseg    segment    para public 'CODE'
  40.  
  41.     assume    cs:cseg,ds:psp,es:data,ss:stack
  42.  
  43.  
  44. get_drive proc    near        ;get drive selection, if any,
  45.                 ;otherwise obtain the identity
  46.                 ;of the current disk drive.
  47.                 ;Return drive (1=A, 2=B, etc) in AL.
  48.                 ;
  49.     mov     al,fcb            ;Pick up the drive code, parsed 
  50.                 ;by DOS into the default file
  51.                 ;control block.
  52.     or    al,al        ;Is it the default?
  53.     jnz    get_drive1    ;no, use it
  54.     mov    ah,19h        ;Yes, get the actual current
  55.     int    21h        ;drive from PC-DOS.
  56.     inc     al        ;Increment to match FCB code.
  57. get_drive1:            ;Return drive code in AL.
  58.     ret
  59. get_drive endp
  60.  
  61.  
  62. free     proc    far             ;entry point from PC-DOS
  63.  
  64.         push    ds              ;save DS:0000 for final
  65.         xor     ax,ax           ;return to PC-DOS
  66.         push    ax
  67.         mov     ax,data         ;make our data segment
  68.         mov     es,ax           ;addressable via ES register.
  69.         mov     ah,30h        ;check version of PC-DOS.    
  70.         int     21h
  71.         cmp     al,2
  72.         jae     free1        ;proceed, DOS 2.0 or greater.
  73.         mov     dx,offset msg2  ;DOS 1.x --- print error message
  74.     mov    ax,es        ;and exit. First fix up DS register 
  75.     mov    ds,ax        ;so error message is addressable.
  76.     jmp    free4
  77.  
  78. free1:  call    get_drive     ;get drive selection into DL.
  79.     push    es        ;copy ES to DS for remainder
  80.     pop    ds        ;of the program...
  81.     assume    ds:data        ;and tell assembler about it.
  82.     mov    dl,al        
  83.     add    al,'A'-1    ;form drive letter from drive code,
  84.     mov    outputb,al    ;and put it into the output string. 
  85.     mov    ah,36h        ;now call DOS to get free disk space.
  86.     int    21h
  87.     cmp    ax,-1        ;was drive invalid?
  88.     je    free3        ;yes,go print error message
  89.                 ;drive was ok, so now registers are...
  90.                 ;AX=number of sectors per cluster
  91.                 ;BX=available clusters,
  92.                 ;CX=number of bytes per sector,
  93.                 ;DX=total clusters per drive.
  94.                 ;calculate free space:
  95.     mul    cx        ;sectors per cluster * bytes per sector
  96.                 ;(we assume this won't overflow into DX)
  97.     mul    bx        ;then * available clusters 
  98.  
  99.                 ;DX:AX now contains free space in bytes.
  100.                 ;SI = last byte address for converted string.
  101.     mov    si,offset (outputa+9)
  102.     mov    cx,10        ;CX = 10, radix for conversion
  103.     call    bin_to_asc    ;convert free space value to ASCII,
  104.     mov    dx,offset output
  105.     jmp    free4        ;and print it out.
  106.  
  107. free3:  mov     dx,offset msg1  ;illegal drive, print error
  108.  
  109. free4:    mov    ah,9        ;print the string whose address
  110.     int    21h        ;is in DX.
  111.     ret            ;then return to DOS.
  112.  
  113. free   endp
  114.  
  115.  
  116. ; Convert 32 bit binary value to ASCII string.
  117. ;
  118. ; Call with  DX:AX = signed 32 bit value
  119. ;         CX    = radix
  120. ;            SI    = last byte of area to store resulting string
  121. ;                 (make sure enough room is available to store
  122. ;              the string in the radix you have selected.)
  123. ;
  124. ; Destroys AX, BX, CX, DX, and SI.
  125. ;
  126. bin_to_asc proc    near        ;convert DX:AX to ASCII.
  127.                 ;force storage of at least 1 digit.
  128.     mov    byte ptr [si],'0' 
  129.     or    dx,dx        ;test sign of 32 bit value,
  130.     pushf            ;and save sign on stack.
  131.     jns    bin1        ;jump if it was positive.
  132.     not    dx        ;it was negative, take 2's complement
  133.     not    ax        ;of the value. 
  134.     add    ax,1
  135.     adc    dx,0
  136. bin1:                ;divide the 32 bit value by the radix 
  137.                 ;to extract the next digit for the
  138.                 ;forming string.
  139.     mov    bx,ax        ;is the value zero yet?
  140.     or    bx,dx
  141.     jz    bin3        ;yes, we are done converting.
  142.     call    divide        ;no, divide by radix.
  143.     add    bl,'0'        ;convert the remainder to an ASCII digit.
  144.     cmp    bl,'9'        ;we might be converting to hex ASCII,
  145.     jle    bin2        ;jump if in range 0-9,
  146.     add    bl,'A'-'9'-1    ;correct it if in range A-F.
  147. bin2:    mov    [si],bl        ;store this character into string.
  148.     dec    si        ;back up through string,
  149.     jmp    bin1        ;and do it again.
  150. bin3:                ;restore sign flag,
  151.     popf            ;was original value negative?
  152.     jns    bin4        ;no, jump
  153.                 ;yes,store sign into output string.
  154.     mov    byte ptr [si],'-'
  155. bin4:    ret            ;back to caller.
  156. bin_to_asc endp
  157.  
  158.  
  159. ; General purpose 32 bit by 16 bit unsigned divide.
  160. ; This must be used instead of the plain machine unsigned divide
  161. ; for cases where the quotient may overflow 16 bits (for example,
  162. ; dividing 100,000 by 2).  If called with a zero divisor, this
  163. ; routine returns the dividend unchanged and gives no warning.
  164. ;
  165. ; Call with DX:AX = 32 bit dividend
  166. ;           CX    = divisor
  167. ;
  168. ; Returns   DX:AX = quotient
  169. ;           BX    = remainder
  170. ;        CX    = divisor (unchanged)
  171. ;
  172. divide    proc    near        ; Divide DX:AX by CX
  173.     jcxz    div1        ; exit if divide by zero
  174.     push    ax        ; 0:dividend_upper/divisor
  175.     mov    ax,dx
  176.     xor    dx,dx
  177.     div    cx
  178.     mov    bx,ax        ; BX = quotient1
  179.     pop    ax        ; remainder1:dividend_lower/divisor
  180.     div    cx
  181.     xchg    bx,dx        ; DX:AX = quotient1:quotient2
  182. div1:    ret            ; BX = remainder2
  183. divide    endp
  184.  
  185. cseg    ends
  186.  
  187.  
  188. data    segment para public 'DATA'
  189.  
  190. output        db    cr,lf
  191. outputa        db    10 dup (blank)
  192.         db    ' bytes free on drive '
  193. outputb        db    'x:',cr,lf,eom
  194.  
  195. msg1            db      cr,lf
  196.                 db      'That disk drive does not exist.'
  197.                 db      cr,lf,eom
  198.  
  199. msg2            db      cr,lf
  200.                 db      'Requires DOS version 2 or greater.'
  201.                 db      cr,lf,eom
  202.  
  203. data    ends    
  204.  
  205.  
  206. stack   segment para stack 'STACK'
  207.         db      64 dup (?)
  208. stack   ends
  209.  
  210.         end     free
  211.