home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / overhead.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1984-04-24  |  2.3 KB  |  90 lines
  1. 10  '   PROGRAM TO CREATE MASTERS FOR OVERHEAD TRANSPARENCIES
  2. 15  '   TITLES CENTERED, CHOICE OF CENTERED OR LEFT JUSTIFIED STRINGS
  3. 20  '   (For use with an Epson Printer with GrafTrax+)
  4. 30  '
  5. 40  '   Written by Read Gilgen for Q&D Purposes (c)1983
  6. 50  '   Copy freely and modify to your heart's content
  7. 60  '
  8. 100  KEY OFF:CLS
  9. 110  DIM LIN$(25)
  10. 120  '
  11. 125  LOCATE 25,1:PRINT "Commas & leading or trailing spaces need quote marks."
  12. 126  LOCATE 1,1
  13. 200  ' GO GET TITLE STRINGS
  14. 210  '
  15. 220  GOSUB 1520
  16. 230  '
  17. 300  ' GET LINE STRINGS
  18. 310  '
  19. 320  FOR WORKING=1 TO 20
  20. 330    PRINT "LINE";WORKING;":  ";LIN$(WORKING)
  21. 340    INPUT LIN$(WORKING)
  22. 350    LINLEN=LEN(LIN$(WORKING)):IF LINLEN>MAXLEN THEN MAXLEN=LINLEN
  23. 360    IF LIN$(WORKING)="" THEN GOTO 400
  24. 370  NEXT
  25. 380  '
  26. 400  ' DISPLAY TO SCREEN BEFORE PRINTING
  27. 410  '
  28. 420  CLS
  29. 430  PRINT TIT$:PRINT
  30. 440  PRINT SUBTIT1$
  31. 450  PRINT SUBTIT2$
  32. 460  PRINT:PRINT
  33. 470  FOR DISPLAY=1 TO WORKING
  34. 480   PRINT LIN$(DISPLAY)
  35. 490  NEXT
  36. 500  PRINT:PRINT "OK?  (Y/N)": ANS$=INPUT$(1):PRINT
  37. 510  IF ANS$<>"y" AND ANS$<>"Y" THEN GOTO 600 ELSE GOTO 700
  38. 520  '
  39. 600  'CORRECTIONS
  40. 610  '
  41. 620  PRINT "CORRECT TITLES (T) OR LINES (L)";:INPUT ANS$
  42. 630  IF ANS$="T" OR ANS$="t" THEN GOSUB 1520:GOTO 400
  43. 640  INPUT "WHICH LINE#";ANS$
  44. 650  ANS=VAL(ANS$):IF ANS=0 THEN GOTO 640
  45. 660  PRINT "LINE WAS:     ";LIN$(ANS)
  46. 670  INPUT "NEW LINE IS:";LIN$(ANS)
  47. 680  GOTO 400
  48. 690  '
  49. 700  'PRINT TO PRINTER
  50. 710  '
  51. 720  PRINT:INPUT "LEFT JUSTIFIED LINES (L) OR CENTERED (C): ";JL$
  52. 730  IF JL$="C" OR JL$="c" THEN JL=0 ELSE JL=-1
  53. 740  CLS:PRINT "MAKE SURE PRINTER IS READY AND SET AT TOP"
  54. 750  PRINT "(Press any key to continue . . .":ANS$=INPUT$(1)
  55. 760  LPRINT CHR$(27);"@";CHR$(27)"E"
  56. 770  TM=(66-(12+(WORKING*2)))/2
  57. 780  FOR TOP=1 TO TM
  58. 790    LPRINT
  59. 800  NEXT
  60. 810  CNTR=(40-(LEN(TIT$)))/2
  61. 820  LPRINT CHR$(14);CHR$(27);"-";CHR$(1);SPACE$(CNTR)+TIT$
  62. 830  LPRINT CHR$(27);"-";CHR$(0)
  63. 840  LPRINT
  64. 850  IF SUBTIT1$>"" THEN CNTR=(40-(LEN(SUBTIT1$)))/2:LPRINT CHR$(14);SPACE$(CNTR);SUBTIT1$
  65. 860  IF SUBTIT2$>"" THEN CNTR=(40-(LEN(SUBTIT2$)))/2:LPRINT CHR$(14);SPACE$(CNTR);SUBTIT2$
  66. 870  LPRINT:LPRINT:LPRINT:LPRINT
  67. 880  FOR PRINTOUT=1 TO WORKING
  68. 890    IF JL THEN CNTR=(40-MAXLEN)/2 ELSE CNTR=(40-LEN(LIN$(PRINTOUT)))/2
  69. 900    LPRINT CHR$(14);SPACE$(CNTR);LIN$(PRINTOUT)
  70. 910    LPRINT
  71. 920  NEXT
  72. 930  LPRINT CHR$(12);
  73. 940  '
  74. 1000  ' DO IT AGAIN?
  75. 1010  '
  76. 1020  CLS:PRINT"PRINT THIS AGAIN? (Y/N)":ANS$=INPUT$(1)
  77. 1030  IF ANS$<>"y" AND ANS$<>"Y" THEN END
  78. 1040  PRINT "MAKE CORRECTIONS?  (Y/N)":ANS$=INPUT$(1)
  79. 1050  IF ANS$<>"y" AND ANS$<>"Y" THEN 700 ELSE 400
  80. 1060  '
  81. 1500  ' GET THE TITLE STRINGS
  82. 1510  '
  83. 1520  PRINT "TITLE (WILL BE CENTERED & UNDERLINED):"
  84. 1530  INPUT TIT$
  85. 1540  PRINT "SUBTITLE (CENTERED.  <CR> IF NONE):"
  86. 1550  INPUT SUBTIT1$
  87. 1560  PRINT "2ND SUBTITLE (<CR> IF NONE):"
  88. 1570  INPUT SUBTIT2$
  89. 1580  RETURN
  90.