home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 007 / menu.bas < prev    next >
Encoding:
BASIC Source File  |  1985-06-03  |  1.8 KB  |  31 lines
  1. 10 DIM PROG$(64)    'MENU PROGRAM - Creates Menus of Basic Files DOS 2.*
  2. 15 'This program is a revision of an earlier DOS 1.* ver
  3. 20 SCREEN 0: KEY OFF:KEY 2,"RUN"+CHR$(34)+"MENU.BAS"+CHR$(13)  'Return to Menu
  4. 30 CLS:WIDTH 80:COLOR 0,0:FILES "*.BAS"   'DISPLAY BASIC FILNAMES invisibly
  5. 40 FOR DR%=2 TO 24      'Row on screen to be Read
  6. 50 FOR DC%=0 TO 65 STEP 18   'File Names are in Four Columns
  7. 60 IF CHR$(SCREEN(DR%,DC%+1))=" " THEN 130   'Stop when no more File names
  8. 70 AR%=AR%+1            'Go to next row in Array
  9. 80 FOR L%=1 TO 8        'Read first 8 characters of File name
  10. 90 PROG$(AR%)=PROG$(AR%)+CHR$(SCREEN(DR%,DC%+L%))    'Add name to Array
  11. 100 NEXT: NEXT: NEXT
  12. 120 WIDTH 80
  13. 130 LOCATE 1,1: COLOR 14,0: PRINT "BASIC Programs on this diskette:"
  14. 140 FOR DC%=1 TO 66 STEP 13     'Display file names in 6 columns
  15. 150 FOR DR%=3 TO 14             'from screen row 3 to 14
  16. 160 I%=I%+1              ' Go to next row in Array
  17. 170 IF PROG$(I%)="" THEN 200  ELSE LOCATE DR%,DC%
  18. 175 COLOR 0,7:PRINT USING "##";I%;:
  19. 176 COLOR 7,0: PRINT " ";PROG$(I%);    'Stop when Array is empty
  20. 180 NEXT DR%
  21. 190 NEXT DC%
  22. 200 LOCATE 18,1: INPUT "ENTER NUMBER OF PROGRAM DESIRED (Press 0 to Exit): ";P
  23. 205 IF P=0 THEN WIDTH 80: KEY 2, "RUN"+CHR$(13): CLS: KEY ON: SYSTEM: END
  24. 210 LOCATE 20,1: COLOR 14,0: PRINT "PRESS (F2) TO RETURN TO THIS MENU WHEN FINISHED";
  25. 211 SOUND 32000,25: SOUND 32000,1
  26. 215 PRINT "-------------------------------------------------------------------------------"
  27. 220 LOCATE 22,1: COLOR 7,0: PRINT "If Pressing (F2) Doesn't Return"
  28. 222 LOCATE 23,1: PRINT "You to This Menu, Press (CTRL/BREAK)"
  29. 224 LOCATE 24,1: PRINT "and Then Press (F2)."
  30. 240 RUN PROG$(P)       'RUN  the Program Selected
  31.