home *** CD-ROM | disk | FTP | other *** search
/ Set of Apple II Hard Drive Images / hard.hdv / HARD / MIDI2 / PERFORMANCE (.txt) < prev    next >
Encoding:
Applesoft BASIC Source Code  |  1991-01-24  |  1.4 KB  |  57 lines  |  [FC] Applesoft BASIC Program (0x0801)
  1. 1  REM   ENTER PREFIX OF THIS PROGRAM FILE IN LINE 5
  2. 5 RT$ = "/HARD/MIDI2/"
  3. 10  TEXT : HOME 
  4. 20  PRINT "1) RECORD A MIDI PERFORMANCE"
  5. 30  PRINT "2) LOAD A MIDI PERFORMANCE"
  6. 40  PRINT "3) PLAY THE SEQUENCE IN MEMORY"
  7. 50  PRINT "4) SAVE THE SEQUENCE IN MEMORY"
  8. 55  PRINT "0) EXIT"
  9. 60  PRINT : PRINT 
  10. 100  INPUT "ENTER CHOICE: ";C
  11. 110  PRINT : PRINT 
  12. 1000  IF C < >1  THEN 2000
  13. 1010  PRINT  CHR$(4)"BLOAD"RT$"SEQUENCER,A$6000"
  14. 1020  HGR2 : HGR : VTAB 24
  15. 1030  PRINT "PRESS ANY KEY WHEN DONE PLAYING."
  16. 1050  CALL 24576
  17. 1060 EN =  PEEK(251) + PEEK(252) *256
  18. 1070 LN = EN -8192
  19. 1900 LD = 1
  20. 1999  GOTO 9000
  21. 2000  IF C < >2  THEN 3000
  22. 2005  PRINT 
  23. 2007  PRINT "NOTE: DO NOT USE THE .D OR .T ": PRINT "EXTENSIONS WHEN ENTERING FILE NAMES"
  24. 2009  PRINT 
  25. 2010  PRINT "PRESS RETURN FOR CATALOG"
  26. 2020  PRINT "TYPE / TO CHANGE PREFIX"
  27. 2030  PRINT 
  28. 2040  INPUT "FILENAME:";F$
  29. 2050  IF F$ = ""  THEN  PRINT  CHR$(4)"CAT": GOTO 2005
  30. 2055  IF F$ = "/"  THEN  INPUT "PREFIX:";P$: PRINT  CHR$(4)"PREFIX "P$: GOTO 2005
  31. 2060 F$ =  LEFT$(F$,13)
  32. 2070 F1$ = F$ +".D":F2$ = F$ +".T"
  33. 2075  HGR2 : HGR : TEXT 
  34. 2080  PRINT  CHR$(4)"BLOAD "F1$",A$2000"
  35. 2090  PRINT  CHR$(4)"BLOAD "F2$",A$4000"
  36. 2900 LD = 1
  37. 2910 LN = 0
  38. 2999  GOTO 9000
  39. 3000  IF C < >3  THEN 4000
  40. 3005  IF LD = 0  THEN  PRINT "OPTION NOT VALID AT THIS TIME": INPUT "PRESS RETURN:";R$: GOTO 9000
  41. 3010  PRINT  CHR$(4)"BLOAD"RT$"SEQ.PLAYER,A$6000"
  42. 3020  INPUT "SPEED (16-128  56=AVG):";SP
  43. 3030  IF SP <16  OR SP >128  THEN 3020
  44. 3040  POKE 4,SP
  45. 3050  PRINT : PRINT "ANY KEY STOPS PLAYBACK"
  46. 3060  CALL 24576
  47. 3999  GOTO 9000
  48. 4000  IF C < >4  THEN 5000
  49. 4010  IF LN = 0  THEN  PRINT "OPTION NOT VALID AT THIS TIME": INPUT "PRESS RETURN:";R$: GOTO 9000
  50. 4020  PRINT "SAVE FILE": PRINT 
  51. 4025  PRINT "NOTE: THE FILE WILL BE SAVED IN 2 PARTS": PRINT "WITH THE EXTENSIONS .D AND .T": PRINT 
  52. 4030  INPUT "ENTER PATHNAME:";PT$
  53. 4050  PRINT  CHR$(4)"BSAVE"PT$".D,A$2000,L"LN
  54. 4060  PRINT  CHR$(4)"BSAVE"PT$".T,A$4000,L"LN
  55. 5000  IF C < >0  THEN 9000
  56. 5010  END 
  57. 9000  GOTO 10