home *** CD-ROM | disk | FTP | other *** search
/ Skunkware 98 / Skunkware 98.iso / osr5 / sco / scripts / toroff < prev    next >
Encoding:
AWK Script  |  1997-08-26  |  28.0 KB  |  761 lines
  1. #!/usr/local/bin/gawk -f
  2. # @(#) toroff.gawk 1.1 96/06/18
  3. # 1989  john h. dubois iii (john@armory.com)
  4. # 92/05/21 converted to a #!awk script
  5. # 94/10/07 Added all options.
  6. # 96/06/18 Deal with files that do not start or end neatly.
  7.  
  8. BEGIN { 
  9.     Name = "toroff"
  10.     Usage = "Usage: " Name " [-h] [-l<margin>] [filename ...]"
  11.     ARGC = Opts(Name,Usage,"hl:",0)
  12.     if ("h" in Options) {
  13.     print \
  14. Name ": convert formatted text to roff source.\n"\
  15. Usage "\n"\
  16. Name " converts text with normal paragraphs (left justified, with the first\n"\
  17. "line indented at least three spaces and all others less than three spaces)\n"\
  18. "to troff/nroff -ms source, preserving the paragraphs by preceding each\n"\
  19. "with '.PP'.\n"\
  20. "Sentences are put on individual lines, split over multiple lines if they\n"\
  21. "will not fit on one line.  The maximum length a line is allowed to reach\n"\
  22. "is 79 characters.  Sentences are delimited by words ending in '.', '?',\n"\
  23. "and '!', or the same followed by a close parentheses.  Note that this is\n"\
  24. "not a perfect algorithm.\n"\
  25. "Options:\n"\
  26. "-h: Print this help.\n"\
  27. "-l<margin>: Output -ms code to indent the output by <margin> ens."
  28.     exit 0
  29.     }
  30.     if ("l" in Options)
  31.     print ".nr PO " Options["l"] "n"
  32.     LineLen = 0
  33. }
  34.  
  35. # Do for the first line of a paragraph
  36. NR == 1 || $0 ~ /^   / { 
  37.     if (LineLen == 0) 
  38.     print ".PP"
  39.     else { 
  40.     print "\n.PP"
  41.     LineLen = 0 
  42.     }
  43. }
  44.  
  45. # Do for all lines
  46. { 
  47.     for (f = 1; f <= NF; f++) { 
  48.     WordLen = length($f)
  49.     if (LineLen == 0) {
  50.         LineLen = WordLen
  51.         printf "%s",$f
  52.     }
  53.     else {
  54.         LineLen += 1 + WordLen
  55.         if (LineLen <= 79)
  56.         printf " %s",$f
  57.         else {
  58.         LineLen = WordLen
  59.         printf "\n%s",$f
  60.         }
  61.     }
  62.     lchar = substr($f,WordLen,1)
  63.     if (lchar == ")")
  64.         lchar = substr($f,WordLen - 1,1)
  65.     if (lchar == "." || lchar == "?" || lchar == "!") {
  66.         print ""
  67.         LineLen = 0
  68.     }
  69.     }
  70. }
  71.  
  72. END {
  73.     if (LineLen > 0)
  74.     print ""
  75. }
  76.  
  77. ### Start of ProcArgs library
  78. # @(#) ProcArgs 1.11 96/12/08
  79. # 92/02/29 john h. dubois iii (john@armory.com)
  80. # 93/07/18 Added "#" arg type
  81. # 93/09/26 Do not count -h against MinArgs
  82. # 94/01/01 Stop scanning at first non-option arg.  Added ">" option type.
  83. #          Removed meaning of "+" or "-" by itself.
  84. # 94/03/08 Added & option and *()< option types.
  85. # 94/04/02 Added NoRCopt to Opts()
  86. # 94/06/11 Mark numeric variables as such.
  87. # 94/07/08 Opts(): Do not require any args if h option is given.
  88. # 95/01/22 Record options given more than once.  Record option num in argv.
  89. # 95/06/08 Added ExclusiveOptions().
  90. # 96/01/20 Let rcfiles be a colon-separated list of filenames.
  91. #          Expand $VARNAME at the start of its filenames.
  92. #          Let varname=0 and -option- turn off an option.
  93. # 96/05/05 Changed meaning of 7th arg to Opts; now can specify exactly how many
  94. #          of the vars should be searched for in the environment.
  95. #          Check for duplicate rcfiles.
  96. # 96/05/13 Return more specific error values.  Note: ProcArgs() and InitOpts()
  97. #          now return various negatives values on error, not just -1, and
  98. #          Opts() may set Err to various positive values, not just 1.
  99. #          Added AllowUnrecOpt.
  100. # 96/05/23 Check type given for & option
  101. # 96/06/15 Re-port to awk
  102. # 96/10/01 Moved file-reading code into ReadConfFile(), so that it can be
  103. #          used by other functions.
  104. # 96/10/15 Added OptChars
  105. # 96/11/01 Added exOpts arg to Opts()
  106. # 96/11/16 Added ; type
  107. # 96/12/08 Added Opt2Set() & Opt2Sets()
  108. # 96/12/27 Added CmdLineOpt()
  109.  
  110. # optlist is a string which contains all of the possible command line options.
  111. # A character followed by certain characters indicates that the option takes
  112. # an argument, with type as follows:
  113. # :    String argument
  114. # ;    Non-empty string argument
  115. # *    Floating point argument
  116. # (    Non-negative floating point argument
  117. # )    Positive floating point argument
  118. # #    Integer argument
  119. # <    Non-negative integer argument
  120. # >    Positive integer argument
  121. # The only difference the type of argument makes is in the runtime argument
  122. # error checking that is done.
  123.  
  124. # The & option is a special case used to get numeric options without the
  125. # user having to give an option character.  It is shorthand for [-+.0-9].
  126. # If & is included in optlist and an option string that begins with one of
  127. # these characters is seen, the value given to "&" will include the first
  128. # char of the option.  & must be followed by a type character other than ":"
  129. # or ";".
  130. # Note that if e.g. &> is given, an option of -.5 will produce an error.
  131.  
  132. # Strings in argv[] which begin with "-" or "+" are taken to be
  133. # strings of options, except that a string which consists solely of "-"
  134. # or "+" is taken to be a non-option string; like other non-option strings,
  135. # it stops the scanning of argv and is left in argv[].
  136. # An argument of "--" or "++" also stops the scanning of argv[] but is removed.
  137. # If an option takes an argument, the argument may either immediately
  138. # follow it or be given separately.
  139. # "-" and "+" options are treated the same.  "+" is allowed because most awks
  140. # take any -options to be arguments to themselves.  gawk 2.15 was enhanced to
  141. # stop scanning when it encounters an unrecognized option, though until 2.15.5
  142. # this feature had a flaw that caused problems in some cases.  See the OptChars
  143. # parameter to explicitly set the option-specifier characters.
  144.  
  145. # If an option that does not take an argument is given,
  146. # an index with its name is created in Options and its value is set to the
  147. # number of times it occurs in argv[].
  148.  
  149. # If an option that does take an argument is given, an index with its name is
  150. # created in Options and its value is set to the value of the argument given
  151. # for it, and Options[option-name,"count"] is (initially) set to the 1.
  152. # If an option that takes an argument is given more than once,
  153. # Options[option-name,"count"] is incremented, and the value is assigned to
  154. # the index (option-name,instance) where instance is 2 for the second occurance
  155. # of the option, etc.
  156. # In other words, the first time an option with a value is encountered, the
  157. # value is assigned to an index consisting only of its name; for any further
  158. # occurances of the option, the value index has an extra (count) dimension.
  159.  
  160. # The sequence number for each option found in argv[] is stored in
  161. # Options[option-name,"num",instance], where instance is 1 for the first
  162. # occurance of the option, etc.  The sequence number starts at 1 and is
  163. # incremented for each option, both those that have a value and those that
  164. # do not.  Options set from a config file have a value of 0 assigned to this.
  165.  
  166. # Options and their arguments are deleted from argv.
  167. # Note that this means that there may be gaps left in the indices of argv[].
  168. # If compress is nonzero, argv[] is packed by moving its elements so that
  169. # they have contiguous integer indices starting with 0.
  170. # Option processing will stop with the first unrecognized option, just as
  171. # though -- was given except that unlike -- the unrecognized option will not be
  172. # removed from ARGV[].  Normally, an error value is returned in this case.
  173. # If AllowUnrecOpt is true, it is not an error for an unrecognized option to
  174. # be found, so the number of remaining arguments is returned instead.
  175. # If OptChars is not a null string, it is the set of characters that indicate
  176. # that an argument is an option string if the string begins with one of the
  177. # characters.  A string consisting solely of two of the same option-indicator
  178. # characters stops the scanning of argv[].  The default is "-+".
  179. # argv[0] is not examined.
  180. # The number of arguments left in argc is returned.
  181. # If an error occurs, the global string OptErr is set to an error message
  182. # and a negative value is returned.
  183. # Current error values:
  184. # -1: option that required an argument did not get it.
  185. # -2: argument of incorrect type supplied for an option.
  186. # -3: unrecognized (invalid) option.
  187. function ProcArgs(argc,argv,OptList,Options,compress,AllowUnrecOpt,OptChars,
  188. ArgNum,ArgsLeft,Arg,ArgLen,ArgInd,Option,Pos,NumOpt,Value,HadValue,specGiven,
  189. NeedNextOpt,GotValue,OptionNum,Escape,dest,src,count,c,OptTerm,OptCharSet)
  190. {
  191. # ArgNum is the index of the argument being processed.
  192. # ArgsLeft is the number of arguments left in argv.
  193. # Arg is the argument being processed.
  194. # ArgLen is the length of the argument being processed.
  195. # ArgInd is the position of the character in Arg being processed.
  196. # Option is the character in Arg being processed.
  197. # Pos is the position in OptList of the option being processed.
  198. # NumOpt is true if a numeric option may be given.
  199.     ArgsLeft = argc
  200.     NumOpt = index(OptList,"&")
  201.     OptionNum = 0
  202.     if (OptChars == "")
  203.     OptChars = "-+"
  204.     while (OptChars != "") {
  205.     c = substr(OptChars,1,1)
  206.     OptChars = substr(OptChars,2)
  207.     OptCharSet[c]
  208.     OptTerm[c c]
  209.     }
  210.     for (ArgNum = 1; ArgNum < argc; ArgNum++) {
  211.     Arg = argv[ArgNum]
  212.     if (length(Arg) < 2 || !((specGiven = substr(Arg,1,1)) in OptCharSet))
  213.         break    # Not an option; quit
  214.     if (Arg in OptTerm) {
  215.         delete argv[ArgNum]
  216.         ArgsLeft--
  217.         break
  218.     }
  219.     ArgLen = length(Arg)
  220.     for (ArgInd = 2; ArgInd <= ArgLen; ArgInd++) {
  221.         Option = substr(Arg,ArgInd,1)
  222.         if (NumOpt && Option ~ /[-+.0-9]/) {
  223.         # If this option is a numeric option, make its flag be & and
  224.         # its option string flag position be the position of & in
  225.         # the option string.
  226.         Option = "&"
  227.         Pos = NumOpt
  228.         # Prefix Arg with a char so that ArgInd will point to the
  229.         # first char of the numeric option.
  230.         Arg = "&" Arg
  231.         ArgLen++
  232.         }
  233.         # Find position of flag in option string, to get its type (if any).
  234.         # Disallow & as literal flag.
  235.         else if (!(Pos = index(OptList,Option)) || Option == "&") {
  236.         if (AllowUnrecOpt) {
  237.             Escape = 1
  238.             break
  239.         }
  240.         else {
  241.             OptErr = "Invalid option: " specGiven Option
  242.             return -3
  243.         }
  244.         }
  245.  
  246.         # Find what the value of the option will be if it takes one.
  247.         # NeedNextOpt is true if the option specifier is the last char of
  248.         # this arg, which means that if the option requires a value it is
  249.         # the next arg.
  250.         if (NeedNextOpt = (ArgInd >= ArgLen)) { # Value is the next arg
  251.         if (GotValue = ArgNum + 1 < argc)
  252.             Value = argv[ArgNum+1]
  253.         }
  254.         else {    # Value is included with option
  255.         Value = substr(Arg,ArgInd + 1)
  256.         GotValue = 1
  257.         }
  258.  
  259.         if (HadValue = AssignVal(Option,Value,Options,
  260.         substr(OptList,Pos + 1,1),GotValue,"",++OptionNum,!NeedNextOpt,
  261.         specGiven)) {
  262.         if (HadValue < 0)    # error occured
  263.             return HadValue
  264.         if (HadValue == 2)
  265.             ArgInd++    # Account for the single-char value we used.
  266.         else {
  267.             if (NeedNextOpt) {    # option took next arg as value
  268.             delete argv[++ArgNum]
  269.             ArgsLeft--
  270.             }
  271.             break    # This option has been used up
  272.         }
  273.         }
  274.     }
  275.     if (Escape)
  276.         break
  277.     # Do not delete arg until after processing of it, so that if it is not
  278.     # recognized it can be left in ARGV[].
  279.     delete argv[ArgNum]
  280.     ArgsLeft--
  281.     }
  282.     if (compress != 0) {
  283.     dest = 1
  284.     src = argc - ArgsLeft + 1
  285.     for (count = ArgsLeft - 1; count; count--) {
  286.         ARGV[dest] = ARGV[src]
  287.         dest++
  288.         src++
  289.     }
  290.     }
  291.     return ArgsLeft
  292. }
  293.  
  294. # Assignment to values in Options[] occurs only in this function.
  295. # Option: Option specifier character.
  296. # Value: Value to be assigned to option, if it takes a value.
  297. # Options[]: Options array to return values in.
  298. # ArgType: Argument type specifier character.
  299. # GotValue: Whether any value is available to be assigned to this option.
  300. # Name: Name of option being processed.
  301. # OptionNum: Number of this option (starting with 1) if set in argv[],
  302. #     or 0 if it was given in a config file or in the environment.
  303. # SingleOpt: true if the value (if any) that is available for this option was
  304. #     given as part of the same command line arg as the option.  Used only for
  305. #     options from the command line.
  306. # specGiven is the option specifier character use, if any (e.g. - or +),
  307. # for use in error messages.
  308. # Global variables: OptErr
  309. # Return value: negative value on error, 0 if option did not require an
  310. # argument, 1 if it did & used the whole arg, 2 if it required just one char of
  311. # the arg.
  312. # Current error values:
  313. # -1: Option that required an argument did not get it.
  314. # -2: Value of incorrect type supplied for option.
  315. # -3: Bad type given for option &
  316. function AssignVal(Option,Value,Options,ArgType,GotValue,Name,OptionNum,
  317. SingleOpt,specGiven,  UsedValue,Err,NumTypes) {
  318.     # If option takes a value...    [
  319.     NumTypes = "*()#<>]"
  320.     if (Option == "&" && ArgType !~ "[" NumTypes) {    # ]
  321.     OptErr = "Bad type given for & option"
  322.     return -3
  323.     }
  324.  
  325.     if (UsedValue = (ArgType ~ "[:;" NumTypes)) {    # ]
  326.     if (!GotValue) {
  327.         if (Name != "")
  328.         OptErr = "Variable requires a value -- " Name
  329.         else
  330.         OptErr = "option requires an argument -- " Option
  331.         return -1
  332.     }
  333.     if ((Err = CheckType(ArgType,Value,Option,Name,specGiven)) != "") {
  334.         OptErr = Err
  335.         return -2
  336.     }
  337.     # Mark this as a numeric variable; will be propogated to Options[] val.
  338.     if (ArgType != ":" && ArgType != ";")
  339.         Value += 0
  340.     if ((Instance = ++Options[Option,"count"]) > 1)
  341.         Options[Option,Instance] = Value
  342.     else
  343.         Options[Option] = Value
  344.     }
  345.     # If this is an environ or rcfile assignment & it was given a value...
  346.     else if (!OptionNum && Value != "") {
  347.     UsedValue = 1
  348.     # If the value is "0" or "-" and this is the first instance of it,
  349.     # do not set Options[Option]; this allows an assignment in an rcfile to
  350.     # turn off an option (for the simple "Option in Options" test) in such
  351.     # a way that it cannot be turned on in a later file.
  352.     if (!(Option in Options) && (Value == "0" || Value == "-"))
  353.         Instance = 1
  354.     else
  355.         Instance = ++Options[Option]
  356.     # Save the value even though this is a flag
  357.     Options[Option,Instance] = Value
  358.     }
  359.     # If this is a command line flag and has a - following it in the same arg,
  360.     # it is being turned off.
  361.     else if (OptionNum && SingleOpt && substr(Value,1,1) == "-") {
  362.     UsedValue = 2
  363.     if (Option in Options)
  364.         Instance = ++Options[Option]
  365.     else
  366.         Instance = 1
  367.     Options[Option,Instance]
  368.     }
  369.     # If this is a flag assignment without a value, increment the count for the
  370.     # flag unless it was turned off.  The indicator for a flag being turned off
  371.     # is that the flag index has not been set in Options[] but it has an
  372.     # instance count.
  373.     else if (Option in Options || !((Option,1) in Options))
  374.     # Increment number of times this flag seen; will inc null value to 1
  375.     Instance = ++Options[Option]
  376.     Options[Option,"num",Instance] = OptionNum
  377.     return UsedValue
  378. }
  379.  
  380. # Option is the option letter
  381. # Value is the value being assigned
  382. # Name is the var name of the option, if any
  383. # ArgType is one of:
  384. # :    String argument
  385. # ;    Non-null string argument
  386. # *    Floating point argument
  387. # (    Non-negative floating point argument
  388. # )    Positive floating point argument
  389. # #    Integer argument
  390. # <    Non-negative integer argument
  391. # >    Positive integer argument
  392. # specGiven is the option specifier character use, if any (e.g. - or +),
  393. # for use in error messages.
  394. # Returns null on success, err string on error
  395. function CheckType(ArgType,Value,Option,Name,specGiven,  Err,ErrStr) {
  396.     if (ArgType == ":")
  397.     return ""
  398.     if (ArgType == ";") {
  399.     if (Value == "")
  400.         Err = "must be a non-empty string"
  401.     }
  402.     # A number begins with optional + or -, and is followed by a string of
  403.     # digits or a decimal with digits before it, after it, or both
  404.     else if (Value !~ /^[-+]?([0-9]+|[0-9]*\.[0-9]+|[0-9]+\.)$/)
  405.     Err = "must be a number"
  406.     else if (ArgType ~ "[#<>]" && Value ~ /\./)
  407.     Err = "may not include a fraction"
  408.     else if (ArgType ~ "[()<>]" && Value < 0)
  409.     Err = "may not be negative"
  410.     # (
  411.     else if (ArgType ~ "[)>]" && Value == 0)
  412.     Err = "must be a positive number"
  413.     if (Err != "") {
  414.     ErrStr = "Bad value \"" Value "\".  Value assigned to "
  415.     if (Name != "")
  416.         return ErrStr "variable " substr(Name,1,1) " " Err
  417.     else {
  418.         if (Option == "&")
  419.         Option = Value
  420.         return ErrStr "option " specGiven substr(Option,1,1) " " Err
  421.     }
  422.     }
  423.     else
  424.     return ""
  425. }
  426.  
  427. # Note: only the above functions are needed by ProcArgs.
  428. # The rest of these functions call ProcArgs() and also do other
  429. # option-processing stuff.
  430.  
  431. # Opts: Process command line arguments.
  432. # Opts processes command line arguments using ProcArgs()
  433. # and checks for errors.  If an error occurs, a message is printed
  434. # and the program is exited.
  435. #
  436. # Input variables:
  437. # Name is the name of the program, for error messages.
  438. # Usage is a usage message, for error messages.
  439. # OptList the option description string, as used by ProcArgs().
  440. # MinArgs is the minimum number of non-option arguments that this
  441. # program should have, non including ARGV[0] and +h.
  442. # If the program does not require any non-option arguments,
  443. # MinArgs should be omitted or given as 0.
  444. # rcFiles, if given, is a colon-seprated list of filenames to read for
  445. # variable initialization.  If a filename begins with ~/, the ~ is replaced
  446. # by the value of the environment variable HOME.  If a filename begins with
  447. # $, the part from the character after the $ up until (but not including)
  448. # the first character not in [a-zA-Z0-9_] will be searched for in the
  449. # environment; if found its value will be substituted, if not the filename will
  450. # be discarded.
  451. # rcfiles are read in the order given.
  452. # Values given in them will not override values given on the command line,
  453. # and values given in later files will not override those set in earlier
  454. # files, because AssignVal() will store each with a different instance index.
  455. # The first instance of each variable, either on the command line or in an
  456. # rcfile, will be stored with no instance index, and this is the value
  457. # normally used by programs that call this function.
  458. # VarNames is a comma-separated list of variable names to map to options,
  459. # in the same order as the options are given in OptList.
  460. # If EnvSearch is given and nonzero, the first EnvSearch variables will also be
  461. # searched for in the environment.  If set to -1, all values will be searched
  462. # for in the environment.  Values given in the environment will override
  463. # those given in the rcfiles but not those given on the command line.
  464. # NoRCopt, if given, is an additional letter option that if given on the
  465. # command line prevents the rcfiles from being read.
  466. # See ProcArgs() for a description of AllowUnRecOpt and optChars, and
  467. # ExclusiveOptions() for a description of exOpts.
  468. # Special options:
  469. # If x is made an option and is given, some debugging info is output.
  470. # h is assumed to be the help option.
  471.  
  472. # Global variables:
  473. # The command line arguments are taken from ARGV[].
  474. # The arguments that are option specifiers and values are removed from
  475. # ARGV[], leaving only ARGV[0] and the non-option arguments.
  476. # The number of elements in ARGV[] should be in ARGC.
  477. # After processing, ARGC is set to the number of elements left in ARGV[].
  478. # The option values are put in Options[].
  479. # On error, Err is set to a positive integer value so it can be checked for in
  480. # an END block.
  481. # Return value: The number of elements left in ARGV is returned.
  482. # Must keep OptErr global since it may be set by InitOpts().
  483. function Opts(Name,Usage,OptList,MinArgs,rcFiles,VarNames,EnvSearch,NoRCopt,
  484. AllowUnrecOpt,optChars,exOpts,  ArgsLeft,e) {
  485.     if (MinArgs == "")
  486.     MinArgs = 0
  487.     ArgsLeft = ProcArgs(ARGC,ARGV,OptList NoRCopt,Options,1,AllowUnrecOpt,
  488.     optChars)
  489.     if (ArgsLeft < (MinArgs+1) && !("h" in Options)) {
  490.     if (ArgsLeft >= 0) {
  491.         OptErr = "Not enough arguments"
  492.         Err = 4
  493.     }
  494.     else
  495.         Err = -ArgsLeft
  496.     printf "%s: %s.\nUse -h for help.\n%s\n",
  497.     Name,OptErr,Usage > "/dev/stderr"
  498.     exit 1
  499.     }
  500.     if (rcFiles != "" && (NoRCopt == "" || !(NoRCopt in Options)) &&
  501.     (e = InitOpts(rcFiles,Options,OptList,VarNames,EnvSearch)) < 0)
  502.     {
  503.     print Name ": " OptErr ".\nUse -h for help." > "/dev/stderr"
  504.     Err = -e
  505.     exit 1
  506.     }
  507.     if ((exOpts != "") && ((OptErr = ExclusiveOptions(exOpts,Options)) != ""))
  508.     {
  509.     printf "%s: Error: %s\n",Name,OptErr > "/dev/stderr"
  510.     Err = 1
  511.     exit 1
  512.     }
  513.     return ArgsLeft
  514. }
  515.  
  516. # ReadConfFile(): Read a file containing var/value assignments, in the form
  517. # <variable-name><assignment-char><value>.
  518. # Whitespace (spaces and tabs) around a variable (leading whitespace on the
  519. # line and whitespace between the variable name and the assignment character) 
  520. # is stripped.  Lines that do not contain an assignment operator or which
  521. # contain a null variable name are ignored, other than possibly being noted in
  522. # the return value.  If more than one assignment is made to a variable, the
  523. # first assignment is used.
  524. # Input variables:
  525. # File is the file to read.
  526. # Comment is the line-comment character.  If it is found as the first non-
  527. #     whitespace character on a line, the line is ignored.
  528. # Assign is the assignment string.  The first instance of Assign on a line
  529. #     separates the variable name from its value.
  530. # If StripWhite is true, whitespace around the value (whitespace between the
  531. #     assignment char and trailing whitespace on the line) is stripped.
  532. # VarPat is a pattern that variable names must match.  
  533. #     Example: "^[a-zA-Z][a-zA-Z0-9]+$"
  534. # If FlagsOK is true, variables are allowed to be "set" by being put alone on
  535. #     a line; no assignment operator is needed.  These variables are set in
  536. #     the output array with a null value.  Lines containing nothing but
  537. #     whitespace are still ignored.
  538. # Output variables:
  539. # Values[] contains the assignments, with the indexes being the variable names
  540. #     and the values being the assigned values.
  541. # Lines[] contains the line number that each variable occured on.  A flag set
  542. #     is record by giving it an index in Lines[] but not in Values[].
  543. # Return value:
  544. # If any errors occur, a string consisting of descriptions of the errors
  545. # separated by newlines is returned.  In no case will the string start with a
  546. # numeric value.  If no errors occur,  the number of lines read is returned.
  547. function ReadConfigFile(Values,Lines,File,Comment,Assign,StripWhite,VarPat,
  548. FlagsOK,
  549. Line,Status,Errs,AssignLen,LineNum,Var,Val) {
  550.     if (Comment != "")
  551.     Comment = "^" Comment
  552.     AssignLen = length(Assign)
  553.     if (VarPat == "")
  554.     VarPat = "."    # null varname not allowed
  555.     while ((Status = (getline Line < File)) == 1) {
  556.     LineNum++
  557.     sub("^[ \t]+","",Line)
  558.     if (Line == "")        # blank line
  559.         continue
  560.     if (Comment != "" && Line ~ Comment)
  561.         continue
  562.     if (Pos = index(Line,Assign)) {
  563.         Var = substr(Line,1,Pos-1)
  564.         Val = substr(Line,Pos+AssignLen)
  565.         if (StripWhite) {
  566.         sub("^[ \t]+","",Val)
  567.         sub("[ \t]+$","",Val)
  568.         }
  569.     }
  570.     else {
  571.         Var = Line    # If no value, var is entire line
  572.         Val = ""
  573.     }
  574.     if (!FlagsOK && Val == "") {
  575.         Errs = Errs \
  576.         sprintf("\nBad assignment on line %d of file %s: %s",
  577.         LineNum,File,Line)
  578.         continue
  579.     }
  580.     sub("[ \t]+$","",Var)
  581.     if (Var !~ VarPat) {
  582.         Errs = Errs sprintf("\nBad variable name on line %d of file %s: %s",
  583.         LineNum,File,Var)
  584.         continue
  585.     }
  586.     if (!(Var in Lines)) {
  587.         Lines[Var] = LineNum
  588.         if (Pos)
  589.         Values[Var] = Val
  590.     }
  591.     }
  592.     if (Status)
  593.     Errs = Errs "\nCould not read file " File
  594.     close(File)
  595.     return Errs == "" ? LineNum : substr(Errs,2)    # Skip first newline
  596. }
  597.  
  598. # Variables:
  599. # Data is stored in Options[].
  600. # rcFiles, OptList, VarNames, and EnvSearch are as as described for Opts().
  601. # Global vars:
  602. # Sets OptErr.  Uses ENVIRON[].
  603. # If anything is read from any of the rcfiles, sets READ_RCFILE to 1.
  604. function InitOpts(rcFiles,Options,OptList,VarNames,EnvSearch,
  605. Line,Var,Pos,Vars,Map,CharOpt,NumVars,TypesInd,Types,Type,Ret,i,rcFile,
  606. fNames,numrcFiles,filesRead,Err,Values,retStr) {
  607.     split("",filesRead,"")    # make awk know this is an array
  608.     NumVars = split(VarNames,Vars,",")
  609.     TypesInd = Ret = 0
  610.     if (EnvSearch == -1)
  611.     EnvSearch = NumVars
  612.     for (i = 1; i <= NumVars; i++) {
  613.     Var = Vars[i]
  614.     CharOpt = substr(OptList,++TypesInd,1)
  615.     if (CharOpt ~ "^[:;*()#<>&]$")
  616.         CharOpt = substr(OptList,++TypesInd,1)
  617.     Map[Var] = CharOpt
  618.     Types[Var] = Type = substr(OptList,TypesInd+1,1)
  619.     # Do not overwrite entries from environment
  620.     if (i <= EnvSearch && Var in ENVIRON &&
  621.     (Err = AssignVal(CharOpt,ENVIRON[Var],Options,Type,1,Var,0)) < 0)
  622.         return Err
  623.     }
  624.  
  625.     numrcFiles = split(rcFiles,fNames,":")
  626.     for (i = 1; i <= numrcFiles; i++) {
  627.     rcFile = fNames[i]
  628.     if (rcFile ~ "^~/")
  629.         rcFile = ENVIRON["HOME"] substr(rcFile,2)
  630.     else if (rcFile ~ /^\$/) {
  631.         rcFile = substr(rcFile,2)
  632.         match(rcFile,"^[a-zA-Z0-9_]*")
  633.         envvar = substr(rcFile,1,RLENGTH)
  634.         if (envvar in ENVIRON)
  635.         rcFile = ENVIRON[envvar] substr(rcFile,RLENGTH+1)
  636.         else
  637.         continue
  638.     }
  639.     if (rcFile in filesRead)
  640.         continue
  641.     # rcfiles are liable to be given more than once, e.g. UHOME and HOME
  642.     # may be the same
  643.     filesRead[rcFile]
  644.     if ("x" in Options)
  645.         printf "Reading configuration file %s\n",rcFile > "/dev/stderr"
  646.     retStr = ReadConfigFile(Values,Lines,rcFile,"#","=",0,"",1)
  647.     if (retStr > 0)
  648.         READ_RCFILE = 1
  649.     else if (ret != "") {
  650.         OptErr = retStr
  651.         Ret = -1
  652.     }
  653.     for (Var in Lines)
  654.         if (Var in Map) {
  655.         if ((Err = AssignVal(Map[Var],
  656.         Var in Values ? Values[Var] : "",Options,Types[Var],
  657.         Var in Values,Var,0)) < 0)
  658.             return Err
  659.         }
  660.         else {
  661.         OptErr = sprintf(\
  662.         "Unknown var \"%s\" assigned to on line %d\nof file %s",Var,
  663.         Lines[Var],rcFile)
  664.         Ret = -1
  665.         }
  666.     }
  667.  
  668.     if ("x" in Options)
  669.     for (Var in Map)
  670.         if (Map[Var] in Options)
  671.         printf "(%s) %s=%s\n",Map[Var],Var,Options[Map[Var]] > \
  672.         "/dev/stderr"
  673.         else
  674.         printf "(%s) %s not set\n",Map[Var],Var > "/dev/stderr"
  675.     return Ret
  676. }
  677.  
  678. # OptSets is a semicolon-separated list of sets of option sets.
  679. # Within a list of option sets, the option sets are separated by commas.  For
  680. # each set of sets, if any option in one of the sets is in Options[] AND any
  681. # option in one of the other sets is in Options[], an error string is returned.
  682. # If no conflicts are found, nothing is returned.
  683. # Example: if OptSets = "ab,def,g;i,j", an error will be returned due to
  684. # the exclusions presented by the first set of sets (ab,def,g) if:
  685. # (a or b is in Options[]) AND (d, e, or f is in Options[]) OR
  686. # (a or b is in Options[]) AND (g is in Options) OR
  687. # (d, e, or f is in Options[]) AND (g is in Options)
  688. # An error will be returned due to the exclusions presented by the second set
  689. # of sets (i,j) if: (i is in Options[]) AND (j is in Options[]).
  690. # todo: make options given on command line unset options given in config file
  691. # todo: that they conflict with.
  692. function ExclusiveOptions(OptSets,Options,
  693. Sets,SetSet,NumSets,Pos1,Pos2,Len,s1,s2,c1,c2,ErrStr,L1,L2,SetSets,NumSetSets,
  694. SetNum,OSetNum) {
  695.     NumSetSets = split(OptSets,SetSets,";")
  696.     # For each set of sets...
  697.     for (SetSet = 1; SetSet <= NumSetSets; SetSet++) {
  698.     # NumSets is the number of sets in this set of sets.
  699.     NumSets = split(SetSets[SetSet],Sets,",")
  700.     # For each set in a set of sets except the last...
  701.     for (SetNum = 1; SetNum < NumSets; SetNum++) {
  702.         s1 = Sets[SetNum]
  703.         L1 = length(s1)
  704.         for (Pos1 = 1; Pos1 <= L1; Pos1++)
  705.         # If any of the options in this set was given, check whether
  706.         # any of the options in the other sets was given.  Only check
  707.         # later sets since earlier sets will have already been checked
  708.         # against this set.
  709.         if ((c1 = substr(s1,Pos1,1)) in Options)
  710.             for (OSetNum = SetNum+1; OSetNum <= NumSets; OSetNum++) {
  711.             s2 = Sets[OSetNum]
  712.             L2 = length(s2)
  713.             for (Pos2 = 1; Pos2 <= L2; Pos2++)
  714.                 if ((c2 = substr(s2,Pos2,1)) in Options)
  715.                 ErrStr = ErrStr "\n"\
  716.                 sprintf("Cannot give both %s and %s options.",
  717.                 c1,c2)
  718.             }
  719.     }
  720.     }
  721.     if (ErrStr != "")
  722.     return substr(ErrStr,2)
  723.     return ""
  724. }
  725.  
  726. # The value of each instance of option Opt that occurs in Options[] is made an
  727. # index of Set[].
  728. # The return value is the number of instances of Opt in Options.
  729. function Opt2Set(Options,Opt,Set,  count) {
  730.     if (!(Opt in Options))
  731.     return 0
  732.     Set[Options[Opt]]
  733.     count = Options[Opt,"count"]
  734.     for (; count > 1; count--)
  735.     Set[Options[Opt,count]]
  736.     return count
  737. }
  738.  
  739. # The value of each instance of option Opt that occurs in Options[] that
  740. # begins with "!" is made an index of nSet[] (with the ! stripped from it).
  741. # Other values are made indexes of Set[].
  742. # The return value is the number of instances of Opt in Options.
  743. function Opt2Sets(Options,Opt,Set,nSet,  count,aSet,ret) {
  744.     ret = Opt2Set(Options,Opt,aSet)
  745.     for (value in aSet)
  746.     if (substr(value,1,1) == "!")
  747.         nSet[substr(value,2)]
  748.     else
  749.         Set[value]
  750.     return ret
  751. }
  752.  
  753. # Returns true if option Opt was given on the command line.
  754. function CmdLineOpt(Options,Opt,  i) {
  755.     for (i = 1; (Opt,"num",i) in Options; i++)
  756.     if (Options[Opt,"num",i] != 0)
  757.         return 1
  758.     return 0
  759. }
  760. ### End of ProcArgs library
  761.