home *** CD-ROM | disk | FTP | other *** search
/ QBasic & Borland Pascal & C / Delphi5.iso / Runimage / Delphi50 / Source / Rtl / Sys / READREC.ASM < prev    next >
Encoding:
Assembly Source File  |  1999-08-11  |  1.3 KB  |  81 lines
  1.  
  2. ; *******************************************************
  3. ; *                            *
  4. ; *     Delphi Runtime Library                          *
  5. ; *                            *
  6. ; *    Copyright (c) 1996,98 Inprise Corporation    *
  7. ; *                            *
  8. ; *******************************************************
  9.  
  10.     INCLUDE    SE.ASM
  11.     INCLUDE    FILEIO.ASM
  12.  
  13.     .386
  14.     .MODEL    FLAT
  15.  
  16.     EXTRN    ReadFile:NEAR, GetLastError:NEAR, SetInOutRes:NEAR
  17.  
  18.     PUBLIC    _ReadRec
  19.  
  20.     .CODE
  21.  
  22. ;    PROCEDURE _ReadRec( f: File; buffer: Pointer );
  23.  
  24. _ReadRec PROC
  25.  
  26. ; ->    EAX    Pointer to file variable
  27. ;    EDX    Pointer to buffer
  28.  
  29.     PUSH    EBX
  30.  
  31.     MOV    EBX,EAX
  32.  
  33.     MOV    ECX,[EBX].Mode        ; File must be open
  34.     SUB    ECX,fmInput
  35.     JE    @@skip
  36.     SUB    ECX,fmInOut-fmInput
  37.     JNE    @@fileNotOpen
  38. @@skip:
  39.  
  40. ;    ReadFile(f.Handle, buffer, f.RecSize, @result, Nil);
  41.  
  42.     PUSH    0            ; space for OS result
  43.     MOV    EAX,ESP
  44.  
  45.     PUSH    0            ; pass lpOverlapped
  46.     PUSH    EAX            ; pass @result
  47.  
  48.     PUSH    [EBX].RecSize        ; pass nNumberOfBytesToRead
  49.  
  50.     PUSH    EDX            ; pass lpBuffer
  51.     PUSH    [EBX].Handle        ; pass hFile
  52.     CALL    ReadFile
  53.     POP    EDX            ; pop result
  54.     DEC    EAX            ; check EAX = TRUE
  55.     JNZ    @@error
  56.  
  57.     CMP    EDX,[EBX].RecSize    ; result = f.RecSize ?
  58.     JNE     @@readError
  59. @@exit:
  60.     POP    EBX
  61.  
  62.     RET
  63.  
  64. @@error:
  65.     CALL    GetLastError
  66. @@errExit:
  67.     CALL    SetInOutRes
  68.     JMP    @@exit
  69.  
  70. @@fileNotOpen:
  71.     MOV    EAX,103
  72.     JMP    @@errExit
  73.  
  74. @@readError:
  75.     MOV    EAX,100
  76.     JMP    @@errExit
  77.  
  78. _ReadRec ENDP
  79.  
  80.     END
  81.