home *** CD-ROM | disk | FTP | other *** search
/ QBasic & Borland Pascal & C / Delphi5.iso / C / BC_502 / START16.PAK / C0W.ASM < prev    next >
Encoding:
Assembly Source File  |  1997-05-06  |  12.9 KB  |  482 lines
  1. ;[]------------------------------------------------------------[]
  2. ;|      C0W.ASM -- Start Up Code For Windows                    |
  3. ;[]------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 8.0
  7. ; 
  8. ;       Copyright (c) 1991, 1997 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11. ; $Revision:   8.2  $
  12.  
  13.         locals
  14.  
  15. .286
  16.  
  17.         __C0__ = 1
  18. include         RULES.ASI
  19.  
  20.         ASSUME CS:_TEXT, DS:DGROUP
  21.  
  22.         public  __acrtused              ;satisfy MS for now
  23. __acrtused      equ     0
  24. IFNDEF __DPMI16__
  25.         public  __WINMAINCALL           ; used internally
  26. ENDIF
  27.         public  __INITAPPCALLED         ; used internally
  28.  
  29. IFNDEF __DPMI16__
  30. extrn           WINMAIN:DIST
  31. ENDIF
  32.  
  33. extrn           INITAPP:far
  34. extrn           INITTASK:far
  35. extrn           FATALEXIT:far
  36. extrn           WAITEVENT:far
  37. extrn           LOCKSEGMENT:far
  38. extrn           UNLOCKSEGMENT:far
  39. extrn           GETWINFLAGS:far
  40. IFDEF __LARGE__
  41. extrn           MESSAGEBOX:far
  42. ENDIF
  43. IFDEF __DPMI16__
  44.   extrn         _main:DIST
  45.   extrn         _OkToInitWindowsRTL:DIST
  46.   extrn         __abort:DIST
  47. ENDIF
  48. extrn           _exit:DIST
  49. extrn           __exit:DIST
  50. extrn           __exitbuf:DIST
  51. extrn           __exitfopen:DIST
  52. extrn           __exitopen:DIST
  53. extrn           __setupio:near                  ;required!
  54. extrn           __ExceptInit:DIST
  55.  
  56.         public __DestructorCount        ;Offset to global destructor count
  57. __DestructorCount EQU  10H
  58.         public __Exception_list         ;Offset to global exception list
  59. __Exception_list  EQU  14H
  60. NULL            segment
  61.         db      16 dup (0)              ;Windows
  62.         db       4 dup (0)              ;destructor count
  63.         db       2 dup (0)              ;exception list
  64.         db       4 dup (0)              ;exception vptr
  65.         db       6 dup (0)              ;reserved
  66.         db       2 dup (0)              ;VBX control jump vector
  67.                         ;MUST be at SS:20h
  68.         db       2 dup (0)              ;reserved
  69.         ends
  70.  
  71. _CVTSEG         segment
  72.         public __RealCvtVector
  73. __RealCvtVector label word
  74.         ends
  75.  
  76. _SCNSEG         segment
  77.         public __ScanTodVector
  78. __ScanTodVector label word
  79.         ends
  80.  
  81. _FPSEG          segment
  82.         public __FPVector
  83. __FPVector      dd      0
  84.         ends
  85.  
  86. _DATA           segment
  87.         public _errno
  88. _errno          dw      0
  89.         public __protected
  90. __protected     dw      0
  91.         public __8086
  92. __8086          dw      0
  93.         public __8087
  94. __8087          dw      0
  95.         public __psp
  96. __psp           dw      0
  97.         public __hInstance
  98. __hInstance     dw      0
  99.         public __hPrev
  100. __hPrev         dw      0
  101.         public __pszCmdline
  102. __pszCmdline    dw      0
  103.         public __cmdShow
  104. __cmdShow       dw      0
  105.         public __version
  106. __version       label word
  107.         public __osversion
  108. __osversion     label word
  109.         public __osmajor
  110. __osmajor       db      0
  111.         public __osminor
  112. __osminor       db      0
  113.         public __osmode         ;Used for OS/2 protected mode by MS,
  114. __osmode        db      0               ;  currently set to 0 under Windows
  115.         public __WinAllocFlag   ;Used by malloc to get additional flags
  116. __WinAllocFlag  dw      0               ;  to pass to GlobalAlloc (for DLL use)
  117.         public __LockWIN87EM    ;Used do lock down WIN87EM to avoid
  118. __LockWIN87EM   dw      1               ;  DLL unload ordering problem
  119.         public  __abend
  120. __abend         dw      0               ;Signals abnormal end, don't run destructors etc.
  121.  
  122. IFDEF __DPMI16__
  123.   extrn         __C0environ:dword
  124.   extrn         __C0argv:dword
  125.   extrn         __C0argc:word
  126. ENDIF
  127.  
  128. CopyRight       db      'Borland C++ - Copyright 1995 Borland Intl.',0
  129.  
  130. IFDEF __LARGE__
  131. CGFailMessage    db    'CodeGuard cannot be run with multiple processes',0
  132. CGMessageTitle    db    'CodeGuard Message',0
  133. CGFail        dw    0
  134. ENDIF
  135.  
  136. IFDEF __DPMI16__
  137. DPMI16Error_s   db      'This DPMI16 application was linked incorrectly and'
  138.         db      ' will fail.',10,13,'$'
  139. ENDIF
  140.         ends
  141.  
  142. _TEXT           segment
  143.  
  144. Main            proc near
  145. IFDEF __LARGE__
  146.         jmp    @@Start
  147.  
  148.         db    'CGINITCB'    ; signature
  149.         dw    offset CGFail    ; offset in DGROUP of status word
  150. ENDIF
  151. @@Start:
  152.  
  153. ;Windows initialization.  Sets up registers and stack.
  154.  
  155. IFDEF   __DPMI16__
  156.         mov     ax, seg DGROUP
  157.         mov     ds, ax
  158. ENDIF
  159.         push    bx cx es
  160.         xor     ax,ax
  161.         push    ax
  162.         call    __ExceptInit
  163.         pop     ax
  164.         pop     es cx bx
  165.  
  166.         ;INITTASK returns:
  167.         ;  'Failure:
  168.         ;    AX = zero if it failed
  169.         ;  Success:
  170.         ;    AX = 1
  171.         ;    CX = stack limit
  172.         ;    DX = cmdShow parameter to CreateWindow
  173.         ;    ES:BX = -> DOS format command line (ES = PSP address)
  174.         ;    SI = hPrevinstance
  175.         ;    DI = hinstance
  176.         call    INITTASK
  177.         or      ax,ax
  178.         jnz     @@OK
  179.         jmp     @@Fail
  180. @@OK:           mov     word ptr ss:[__Exception_list], -1
  181.         mov     __psp,es
  182.         mov     word ptr __pszCmdline,bx
  183.         mov     __hPrev,si
  184.         mov     __hInstance,di
  185.         mov     __cmdShow,dx
  186.  
  187. IF LDATA EQ false
  188.         mov     ax,-1
  189.         push    ax
  190.         call    LOCKSEGMENT
  191. ENDIF
  192.  
  193. ;Clear _BSS, uninitialized data area
  194.  
  195. IFNDEF  __HUGE__
  196.         xor     ax, ax
  197.         push    ds
  198.         pop     es
  199.         mov     di,offset DGROUP:BeginBSS
  200.         mov     cx,offset DGROUP:EndBSS
  201.         sub     cx,di
  202.         cld
  203.         rep
  204.         stosb
  205. ENDIF
  206.  
  207. ;Init the Windows App
  208.  
  209.         xor     ax,ax
  210.         push    ax
  211.         call    WAITEVENT
  212.         push    __hInstance
  213.         call    INITAPP
  214. __INITAPPCALLED:
  215.  
  216. IFDEF __LARGE__
  217. ;Check whether CodeGuard detected multiple clients
  218.         cmp    CGFail,0
  219.         je    @@TestInit
  220. ;If so then display message and fail initializaion
  221.         pusha
  222.         call    MESSAGEBOX pascal, 0, ds offset CGFailMessage, ds offset CGMessageTitle, 1010h ; MB_ICONSTOP | MB_SYSTEMMODAL
  223.         popa
  224.         xor    ax,ax
  225. ENDIF
  226.  
  227. ;Test whether INITAPP suceeded
  228. @@TestInit:    or      ax,ax
  229.         jnz     @@InitOK
  230.         jmp     @@Fail
  231. @@InitOK:
  232.  
  233. ;Determine DOS version
  234.  
  235.         mov     ah, 30h
  236.         int     21h
  237.         mov     __version, ax   ; save minor and major revision
  238.  
  239. ;Determine whether we are in protected mode
  240.  
  241.         call    GETWINFLAGS
  242.         test    ax,1            ; WF_PMODE = 1
  243.         jz      @@realmode      ; Note:  GETWINFLAGS returns a long,
  244.                     ; so if WF_PMODE changed it could be
  245.                     ; in the high word.
  246.         mov     __protected, 8  ; Eight is for convenience.
  247. @@realmode:
  248.  
  249. ;Test for 8086/8087 presence
  250.  
  251.         test    ax,0400h        ; WF_8087 = 0x0400
  252.         jz      @@no8087
  253.         mov     __8087, 1
  254. @@no8087:
  255.         and     ax,08h+04h+02h  ; WF_CPU486|WF_CPU386|WF_CPU286
  256.         shr     ax,1            ; Convert to 4 or 2 or 1 or 0
  257.         test    ax,0004h        ; Have 4, 486 done
  258.         jnz     @@NoAdjust
  259.         or      ax,ax           ; Have 0, 8086 done
  260.         jz      @@NoAdjust
  261.         inc     ax              ; Have 2 or 1, need 3 or 2
  262. @@NoAdjust:
  263.         mov     __8086,ax       ; Set CPU Type
  264.  
  265.  
  266. IFDEF  __DPMI16__
  267. ;
  268. ; Here we attempt to prevent an early death caused by linking
  269. ; the libs in the wrong order
  270. ;
  271.         call    _OkToInitWindowsRTL
  272.         or      ax, ax
  273.         jnz     DPMI16Error
  274. ENDIF
  275.  
  276. ;Call our initialization functions, including C++ static constructors.
  277.  
  278.         mov     ax,ds
  279.         mov     es,ax
  280.         mov     si,offset DGROUP:InitStart      ;si = start of table
  281.         mov     di,offset DGROUP:InitEnd        ;di = end of table
  282.         call    Initialize
  283.  
  284. IFDEF __DPMI16__
  285. ;Set up and call _main for DPMI16 application
  286.  
  287.         push    word ptr [__C0environ+2]
  288.         push    word ptr [__C0environ]
  289.         push    word ptr [__C0argv+2]
  290.         push    word ptr [__C0argv]
  291.         push    [__C0argc]
  292.         call    _main
  293. ELSE
  294. ;Set up and call WinMain for Windows application
  295.         push    __hInstance
  296.         push    __hPrev
  297.         push    __psp
  298.         push    word ptr __pszCmdline
  299.         push    __cmdShow
  300. __WINMAINCALL:  call    WINMAIN
  301. ENDIF
  302.         push    ax      ; Push return value
  303.  
  304.         cmp     __abend, 0
  305.         jne     @@abnormalexit
  306.         call    _exit   ; Normal exit
  307. @@abnormalexit: call    __exit  ; Abnormal exit, don't call destructors etc.
  308.  
  309. IFDEF  __DPMI16__
  310. DPMI16Error:
  311.         mov     ah, 9
  312.         mov     dx, offset DPMI16Error_s
  313.         int     21h
  314.         call    __abort
  315. ENDIF
  316. ;---------------------------------------------------------------------------
  317. ;       _cleanup()      call all #pragma exit cleanup routines.
  318. ;       _checknull()    check for null pointer zapping copyright message
  319. ;       _terminate(int) exit program with error code
  320. ;       _restorezero()  restore interrupt vectors
  321. ;
  322. ;       These functions are called by exit(), _exit(), _cexit(),
  323. ;       and _c_exit().
  324. ;---------------------------------------------------------------------------
  325.  
  326. ;       Call cleanup routines
  327.  
  328. __cleanup       PROC    DIST
  329.         PUBLIC  __cleanup
  330.  
  331.         mov     ax,ds
  332.         mov     es,ax
  333.         push    si
  334.         push    di
  335.         mov     si,offset DGROUP:ExitStart
  336.         mov     di,offset DGROUP:ExitEnd
  337.         call    Cleanup
  338.         pop     di
  339.         pop     si
  340.         ret
  341. __cleanup       ENDP
  342.  
  343. ;       Check for null pointers before exit.  NO-OP on Windows.
  344.  
  345. __checknull     PROC    DIST
  346.         PUBLIC  __checknull
  347.         ret
  348. __checknull     ENDP
  349.  
  350. ;       Restore grabbed interrupt vectors.  NO-OP on Windows.
  351.  
  352. __restorezero     PROC    DIST
  353.         PUBLIC  __restorezero
  354.         ret
  355. __restorezero     ENDP
  356.  
  357. ;       Exit to DOS
  358.  
  359. __terminate     PROC    DIST
  360.         PUBLIC  __terminate
  361.  
  362. IF LDATA EQ false
  363.         mov     ax,-1
  364.         push    ax
  365.         call    UNLOCKSEGMENT
  366. ENDIF
  367.         mov     bp,sp
  368.         mov     al,[bp+cPtrSize]
  369.         mov     ah,4ch                  ;exit
  370.         int     21h
  371. __terminate     ENDP
  372.  
  373. @@Fail:         mov     al,0ffh
  374.         push    ax
  375.         call    _exit
  376.  
  377.         mov     ah,4ch                  ;exit
  378.         int     21h
  379.         endp
  380.  
  381. ;       Return default data segment in AX
  382.  
  383. __GetDGROUP     PROC    FAR
  384.         PUBLIC  __GetDGROUP
  385.         mov     ax, ss
  386.         ret
  387.         endp
  388.  
  389. ;------------------------------------------------------------------
  390. ;  Loop through a startup/exit (SE) table,
  391. ;  calling functions in order of priority.
  392. ;  ES:SI is assumed to point to the beginning of the SE table
  393. ;  ES:DI is assumed to point to the end of the SE table
  394. ;  First 64 priorities are reserved by Borland
  395. ;------------------------------------------------------------------
  396. PNEAR           EQU     0
  397. PFAR            EQU     1
  398. NOTUSED         EQU     0ffh
  399.  
  400. SE              STRUC
  401. calltype        db      ?                       ; 0=near,1=far,ff=not used
  402. priority        db      ?                       ; 0=highest,ff=lowest
  403. addrlow         dw      ?
  404. addrhigh        dw      ?
  405. SE              ENDS
  406.  
  407. Initialize      proc near
  408. @@Start:        mov     ax,100h                 ;start with lowest priority
  409.         mov     dx,di                   ;set sentinel to end of table
  410.         mov     bx,si                   ;bx = start of table
  411.  
  412. @@TopOfTable:   cmp     bx,di                   ;and the end of the table?
  413.         je      @@EndOfTable            ;yes, exit the loop
  414.         cmp     es:[bx.calltype],NOTUSED;check the call type
  415.         je      @@Next
  416.         mov     cl, es:[bx.priority]    ;move priority to CX
  417.         xor     ch, ch
  418.         cmp     cx,ax                   ;check the priority
  419.         jae     @@Next                  ;too high?  skip
  420.         mov     ax,cx                   ;keep priority
  421.         mov     dx,bx                   ;keep index in dx
  422. @@Next:         add     bx,SIZE SE              ;bx = next item in table
  423.         jmp     @@TopOfTable
  424.  
  425. @@EndOfTable:   cmp     dx,di                   ;did we exhaust the table?
  426.         je      @@Done                  ;yes, quit
  427.         mov     bx,dx                   ;bx = highest priority item
  428.         cmp     es:[bx.calltype],PNEAR  ;is it near or far?
  429.         mov     es:[bx.calltype],NOTUSED;wipe the call type
  430.         push    es                      ;save es
  431.         je      @@NearCall
  432.  
  433. @@FarCall:      call    DWORD PTR es:[bx.addrlow]
  434.         pop     es                      ;restore es
  435.         jmp     short @@Start
  436.  
  437. @@NearCall:     call    WORD PTR es:[bx.addrlow]
  438.         pop     es                      ;restore es
  439.         jmp     short @@Start
  440.  
  441. @@Done:         ret
  442.         endp
  443.  
  444. Cleanup         proc near
  445. @@Start:        mov     ah,0                    ;start with highest priority
  446.         mov     dx,di                   ;set sentinel to end of table
  447.         mov     bx,si                   ;bx = start of table
  448.  
  449. @@TopOfTable:   cmp     bx,di                   ;and the end of the table?
  450.         je      @@EndOfTable            ;yes, exit the loop
  451.         cmp     es:[bx.calltype],NOTUSED;check the call type
  452.         je      @@Next
  453.         cmp     es:[bx.priority],ah     ;check the priority
  454.         jb      @@Next                  ;too low?  skip
  455.         mov     ah,es:[bx.priority]     ;keep priority
  456.         mov     dx,bx                   ;keep index in dx
  457. @@Next:         add     bx,SIZE SE              ;bx = next item in table
  458.         jmp     @@TopOfTable
  459.  
  460. @@EndOfTable:   cmp     dx,di                   ;did we exhaust the table?
  461.         je      @@Done                  ;yes, quit
  462.         mov     bx,dx                   ;bx = highest priority item
  463.         cmp     es:[bx.calltype],PNEAR  ;is it near or far?
  464.         mov     es:[bx.calltype],NOTUSED;wipe the call type
  465.         push    es                      ;save es
  466.         je      @@NearCall
  467.  
  468. @@FarCall:      call    DWORD PTR es:[bx.addrlow]
  469.         pop     es                      ;restore es
  470.         jmp     short @@Start
  471.  
  472. @@NearCall:     call    WORD PTR es:[bx.addrlow]
  473.         pop     es                      ;restore es
  474.         jmp     short @@Start
  475.  
  476. @@Done:         ret
  477.         endp
  478.  
  479.         ends
  480.  
  481.         end Main
  482.