Programmer's ROM - The Computer Language Library/programmersrom.iso/ada/piwg/t000003.ada

Text File | 1988-05-03 | 2.9 KB | 106 lines

-- PERFORMANCE MEASUREMENT :  Task entry call and return time measured
--                            Two tasks active, one entry per task
--                            tasks in a package
--                            no select statement

with REMOTE_GLOBAL ; use REMOTE_GLOBAL ;
package TASK_PACK_3 is
  task T1 is
    entry E1 ;
  end T1 ;
  task T2 is
    entry E2 ;
  end T2 ;
end TASK_PACK_3 ;

with TASK_PACK_3 ; use TASK_PACK_3 ;
with REMOTE_GLOBAL ; use REMOTE_GLOBAL ; -- control optimization
with ITERATION ; -- obtain stable measurement
with PIWG_IO ; -- output results

procedure T000003 is  -- main procedure to execute
  CPU_TIME : DURATION ; -- CPU time for one feature execution
  WALL_TIME : DURATION ; -- WALL time for one feature execution
  CHECK_TIMES : constant := 100 ; -- inside loop count and check
  ITERATION_COUNT : INTEGER ; -- set and varied by ITERATION package
  STABLE : BOOLEAN ; -- true when measurement stable
  CASE_COUNT : constant := 2 ;

begin

  ITERATION.START_CONTROL ;  -- dummy to bring in pages on some machines

  delay 0.5 ;  -- wait for stable enviornment on some machines

  ITERATION.INITIALIZE ( ITERATION_COUNT ) ;

  loop  -- until stable measurement, ITERATION_COUNT increases each time

--
-- Control loop
--
    ITERATION.START_CONTROL ;
    for J in 1 .. ITERATION_COUNT loop
      GLOBAL := 0 ;
      for INSIDE_LOOP in 1 .. CHECK_TIMES loop
        GLOBAL := GLOBAL + A_ONE ;
        REMOTE ;
      end loop ;
    end loop ;
    ITERATION.STOP_CONTROL ( GLOBAL , CHECK_TIMES ) ;


--
-- Test loop
--
    ITERATION.START_TEST ;
    for J in 1 .. ITERATION_COUNT loop
      GLOBAL := 0 ;
      for INSIDE_LOOP in 1 .. CHECK_TIMES loop
        T1.E1 ; -- this has control global increment and call inside
        T2.E2 ; -- this has control global increment and call inside
      end loop ;
    end loop ;
    GLOBAL := GLOBAL / CASE_COUNT ;
    ITERATION.STOP_TEST ( GLOBAL , CHECK_TIMES ) ;
    ITERATION.TEST_STABLE ( ITERATION_COUNT , STABLE ) ;
    exit when STABLE ;
  end loop ;
--
  ITERATION.FEATURE_TIMES ( CPU_TIME , WALL_TIME ) ;
  CPU_TIME := DURATION ( CPU_TIME / CASE_COUNT ) ;
  WALL_TIME := DURATION ( WALL_TIME / CASE_COUNT ) ;
--
-- Printout
--
  PIWG_IO.PIWG_OUTPUT ( "T000003" , "Tasking" ,
                        CPU_TIME , WALL_TIME , ITERATION_COUNT ,
     " Task entry call and return time measured" ,
     " Two tasks active, one entry per task, tasks in a package " ,
     " no select statement " ) ;
  abort T1 ;
  abort T2 ;
end T000003 ;

package body TASK_PACK_3 is
  task body T1 is
  begin
    loop
      accept E1 do
        GLOBAL := GLOBAL + A_ONE ;
        REMOTE ;
      end E1 ;
    end loop ;
  end T1 ;

  task body T2 is
  begin
    loop
      accept E2 do
        GLOBAL := GLOBAL + A_ONE ;
        REMOTE ;
      end E2 ;
    end loop ;
  end T2 ;
end TASK_PACK_3 ;