home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / PROGRAMS / UTILS / DOS_HELP / ADVMSDOS.ZIP / FREE.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-06-19  |  6.1 KB  |  217 lines
  1.         name    free
  2.         page    60,132
  3.         title   'FREE --- Report free space on disk'
  4.  
  5. ; FREE --- a utility to report free space on
  6. ;          the default or selected disk drive.
  7. ;
  8. ; version 1.0   July 4, 1984 
  9. ; Copyright (c) 1984 by Ray Duncan
  10. ; 
  11. ; Requires PC-DOS or MS-DOS 2.0.
  12. ;
  13. ; Used in the form:
  14. ;
  15. ;     A> FREE  [unit:] 
  16. ;
  17. ; (item in square brackets is optional)
  18. ;
  19. ; To assemble, link, and convert this program into 
  20. ; an EXE file, follow these steps:
  21. ;
  22. ;    C>MASM FREE;
  23. ;     C>LINK FREE;
  24. ;
  25.  
  26. cr      equ     0dh             ;ASCII carriage return
  27. lf      equ     0ah             ;ASCII line feed
  28. blank    equ    20h        ;ASCII space code
  29. eom    equ    '$'        ;end of string marker
  30.  
  31.  
  32. ; Here we define a dummy segment containing labels
  33. ; for the default file control block and the command tail buffer,
  34. ; so that the main program can access those locations.
  35. ;
  36. psp    segment para public 'PSP'  
  37.  
  38.     org    05ch
  39. fcb    label    byte        ;default file control block
  40.  
  41.     org    080h
  42. command    label    byte        ;default command buffer
  43.  
  44. psp    ends
  45.  
  46.  
  47. cseg    segment    para public 'CODE'
  48.  
  49.     assume    cs:cseg,ds:psp,es:data,ss:stack
  50.  
  51.  
  52. get_drive proc    near        ;get drive selection, if any,
  53.                 ;otherwise obtain the identity
  54.                 ;of the current disk drive.
  55.                 ;Return drive (1=A, 2=B, etc) in AL.
  56.                 ;
  57.     mov     al,fcb            ;Pick up the drive code, parsed 
  58.                 ;by DOS into the default file
  59.                 ;control block.
  60.     or    al,al        ;Is it the default?
  61.     jnz    get_drive1    ;no, use it
  62.     mov    ah,19h        ;Yes, get the actual current
  63.     int    21h        ;drive from PC-DOS.
  64.     inc     al        ;Increment to match FCB code.
  65. get_drive1:            ;Return drive code in AL.
  66.     ret
  67. get_drive endp
  68.  
  69.  
  70. free     proc    far             ;entry point from PC-DOS
  71.  
  72.         mov     ax,data         ;make our data segment
  73.         mov     es,ax           ;addressable via ES register.
  74.         mov     ah,30h        ;check version of PC-DOS.    
  75.         int     21h
  76.         cmp     al,2
  77.         jae     free1        ;proceed, DOS 2.0 or greater.
  78.         mov     dx,offset msg2  ;DOS 1.x --- print error message
  79.     mov    ax,es        ;and exit. First fix up DS register 
  80.     mov    ds,ax        ;so error message is addressable.
  81.     jmp    free4
  82.  
  83. free1:  call    get_drive     ;get drive selection into DL.
  84.     push    es        ;copy ES to DS for remainder
  85.     pop    ds        ;of the program...
  86.     assume    ds:data        ;and tell assembler about it.
  87.     mov    dl,al        
  88.     add    al,'A'-1    ;form drive letter from drive code,
  89.     mov    outputb,al    ;and put it into the output string. 
  90.     mov    ah,36h        ;now call DOS to get free disk space.
  91.     int    21h
  92.     cmp    ax,-1        ;was drive invalid?
  93.     je    free3        ;yes,go print error message
  94.                 ;drive was ok, so now registers are...
  95.                 ;AX=number of sectors per cluster
  96.                 ;BX=available clusters,
  97.                 ;CX=number of bytes per sector,
  98.                 ;DX=total clusters per drive.
  99.                 ;calculate free space:
  100.     mul    cx        ;sectors per cluster * bytes per sector
  101.                 ;(we assume this won't overflow into DX)
  102.     mul    bx        ;then * available clusters 
  103.  
  104.                 ;DX:AX now contains free space in bytes.
  105.                 ;SI = last byte address for converted string.
  106.     mov    si,offset (outputa+9)
  107.     mov    cx,10        ;CX = 10, radix for conversion
  108.     call    bin_to_asc    ;convert free space value to ASCII,
  109.     mov    dx,offset output
  110.     jmp    free4        ;and print it out.
  111.  
  112. free3:  mov     dx,offset msg1  ;illegal drive, print error
  113.  
  114. free4:    mov    ah,9        ;print the string whose address
  115.     int    21h        ;is in DX.
  116.     mov     ax,4c00h        ;then return to DOS 
  117.     int    21h
  118.  
  119. free   endp
  120.  
  121.  
  122. ; Convert 32 bit binary value to ASCII string.
  123. ;
  124. ; Call with  DX:AX = signed 32 bit value
  125. ;         CX    = radix
  126. ;            SI    = last byte of area to store resulting string
  127. ;                 (make sure enough room is available to store
  128. ;              the string in the radix you have selected.)
  129. ;
  130. ; Destroys AX, BX, CX, DX, and SI.
  131. ;
  132. bin_to_asc proc    near        ;convert DX:AX to ASCII.
  133.                 ;force storage of at least 1 digit.
  134.     mov    byte ptr [si],'0' 
  135.     or    dx,dx        ;test sign of 32 bit value,
  136.     pushf            ;and save sign on stack.
  137.     jns    bin1        ;jump if it was positive.
  138.     not    dx        ;it was negative, take 2's complement
  139.     not    ax        ;of the value. 
  140.     add    ax,1
  141.     adc    dx,0
  142. bin1:                ;divide the 32 bit value by the radix 
  143.                 ;to extract the next digit for the
  144.                 ;forming string.
  145.     mov    bx,ax        ;is the value zero yet?
  146.     or    bx,dx
  147.     jz    bin3        ;yes, we are done converting.
  148.     call    divide        ;no, divide by radix.
  149.     add    bl,'0'        ;convert the remainder to an ASCII digit.
  150.     cmp    bl,'9'        ;we might be converting to hex ASCII,
  151.     jle    bin2        ;jump if in range 0-9,
  152.     add    bl,'A'-'9'-1    ;correct it if in range A-F.
  153. bin2:    mov    [si],bl        ;store this character into string.
  154.     dec    si        ;back up through string,
  155.     jmp    bin1        ;and do it again.
  156. bin3:                ;restore sign flag,
  157.     popf            ;was original value negative?
  158.     jns    bin4        ;no, jump
  159.                 ;yes,store sign into output string.
  160.     mov    byte ptr [si],'-'
  161. bin4:    ret            ;back to caller.
  162. bin_to_asc endp
  163.  
  164.  
  165. ; General purpose 32 bit by 16 bit unsigned divide.
  166. ; This must be used instead of the plain machine unsigned divide
  167. ; for cases where the quotient may overflow 16 bits (for example,
  168. ; dividing 100,000 by 2).  If called with a zero divisor, this
  169. ; routine returns the dividend unchanged and gives no warning.
  170. ;
  171. ; Call with DX:AX = 32 bit dividend
  172. ;           CX    = divisor
  173. ;
  174. ; Returns   DX:AX = quotient
  175. ;           BX    = remainder
  176. ;        CX    = divisor (unchanged)
  177. ;
  178. divide    proc    near        ; Divide DX:AX by CX
  179.     jcxz    div1        ; exit if divide by zero
  180.     push    ax        ; 0:dividend_upper/divisor
  181.     mov    ax,dx
  182.     xor    dx,dx
  183.     div    cx
  184.     mov    bx,ax        ; BX = quotient1
  185.     pop    ax        ; remainder1:dividend_lower/divisor
  186.     div    cx
  187.     xchg    bx,dx        ; DX:AX = quotient1:quotient2
  188. div1:    ret            ; BX = remainder2
  189. divide    endp
  190.  
  191. cseg    ends
  192.  
  193.  
  194. data    segment para public 'DATA'
  195.  
  196. output        db    cr,lf
  197. outputa        db    10 dup (blank)
  198.         db    ' bytes free on drive '
  199. outputb        db    'x:',cr,lf,eom
  200.  
  201. msg1            db      cr,lf
  202.                 db      'That disk drive does not exist.'
  203.                 db      cr,lf,eom
  204.  
  205. msg2            db      cr,lf
  206.                 db      'Requires DOS version 2 or greater.'
  207.                 db      cr,lf,eom
  208.  
  209. data    ends    
  210.  
  211.  
  212. stack   segment para stack 'STACK'
  213.         db      64 dup (?)
  214. stack   ends
  215.  
  216.         end     free
  217.