home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / PASCAL / TUR6_101.ZIP / V5.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-06-07  |  5.1 KB  |  83 lines
  1. ;--------------------------------------------------------------------
  2. ; Author       : Kevin Dahl                                         :
  3. ; Last Revised : June 7, 1986                                       :
  4. ;                                                                   :
  5. ; FILENAME - V5.ENH                                                 :
  6. ;                                                                   :
  7. ; FILLCOLATTRIB                                                     :
  8. ;        This routine displays a column of attribute bytes.         :
  9. ; ENTRY                                                             :
  10. ;        [bp+6]  = Color to be displayed in the column              :
  11. ;        [bp+8]  = Number of rows to be used for displaying the     :
  12. ;                  attribute in the column specified                :
  13. ;        [bp+10] = Row the column of the attribute is to start in   :
  14. ;        [bp+12] = Column the attribute byte is to be displayed in  :
  15. ;                                                                   :
  16. ; EXIT                                                              :
  17. ;        Nothing is returned                                        :
  18. ;--------------------------------------------------------------------
  19. fillcolattrib proc      near
  20.               push      ds
  21.               push      bp                       ; save stack
  22.               mov       bp,sp
  23.               mov       ah,0fh                   ; get current video mode
  24.               int       10h                      ; using BIOS services
  25.               xor       dx,dx
  26.               mov       dl,ah                    ; save number columns per line
  27.               cmp       al,7                     ; check for monochrome monitor
  28.               je        v16
  29.               cmp       al,3                     ; check if text modes
  30.               ja        v20                      ; graphics mode - no write
  31.               mov       cx,7                     ; set for 40 col text modes
  32.               cmp       dl,80                    ; check for num of cols
  33.               jb        v15                      ; 40 cols if jmp
  34.               inc       cx                       ; if get here then 80 cols
  35. v15:
  36.               xor       ax,ax                    ; zero out ax
  37.               mov       al,bh                    ; active display page for CGA
  38.               shl       ax,cl                    ; calc address for display page
  39.               mov       cx,0B800h                ; address for CGA
  40.               add       ax,cx                    ; calc starting address
  41.               jmp       v17
  42. v16:
  43.               mov       ax,0B000h                ; monochrome monitor address
  44. v17:
  45.               mov       es,ax                    ; video address into es
  46.               mov       ax,[bp+10]               ; row coordinate
  47.               mov       bx,[bp+12]               ; col coordinate
  48.               push      dx                       ; save number cols per line
  49.               dec       ax                       ; (row - 1)
  50.               mul       dx                       ; (row - 1) * number of columns
  51.               add       ax,bx                    ; (row - 1) * # cols + col offset
  52.               dec       ax                       ; (row - 1) * # cols + col offset - 1
  53.               shl       ax,1                     ; ((row-1)* #cols + col offset - 1)*2
  54.               mov       di,ax                    ; offset in display scrn for attribute
  55.               inc       di                       ; set for attribute byte
  56.               pop       bx                       ; # cols per screen
  57.               shl       bx,1                     ; cols on display
  58.               mov       cx,[bp+8]                ; number of rows to use
  59.               cmp       cx,1
  60.               jb        v20                      ; no characters to display
  61.               mov       ah,[bp+6]                ; attribute byte into ah
  62.               mov       dx,03DAh                 ; status port
  63.               cld                                ; clear direction flag
  64.               cli                                ; clear interrupts
  65. v18:
  66.               in        al,dx                    ; get status
  67.               test      al,1                     ; is it low?
  68.               jnz       v18                      ; wait until it is
  69. v19:
  70.               in        al,dx                    ; get status
  71.               test      al,1                     ; is it high?
  72.               jz        v19                      ; wait until it is
  73.               mov       es:byte ptr[di],ah       ; display attribute byte
  74.               add       di,bx                    ; next row address
  75.               loop      v18                      ; repeat until column is filled
  76.               sti                                ; turn interrupts back on
  77. v20:
  78.               mov       sp,bp                    ; restore stack
  79.               pop       bp                       ; restore base pointer
  80.               pop       ds                       ; restore data segment
  81.               ret       8                        ; remove parameters and return
  82. fillcolattrib endp
  83.