home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / PASCAL / BPL70N12.ZIP / ARISOURC.ZIP / LSHR.ASM < prev   
Encoding:
Assembly Source File  |  1993-02-10  |  2.3 KB  |  61 lines
  1.  
  2. ; *******************************************************
  3. ; *                                                     *
  4. ; *     Turbo Pascal Runtime Library Version 7.0        *
  5. ; *     Longint Shift Right                             *
  6. ; *                                                     *
  7. ; *     Copyright (C) 1992,1993 Norbert Juffa           *
  8. ; *                                                     *
  9. ; *******************************************************
  10.  
  11.              TITLE   LSHR
  12.  
  13.  
  14. CODE         SEGMENT BYTE PUBLIC
  15.  
  16.              ASSUME  CS:CODE
  17.  
  18. ; Publics
  19.  
  20.              PUBLIC  LongShr
  21.  
  22. ;-------------------------------------------------------------------------------
  23. ; LongShr performs a logical right shift on its LONGINT argument, that is, the
  24. ; sign for negative numbers is not preserved. It allows a variable shift count
  25. ; to be used, but masks this off so that the count is in the range 0...31.
  26. ; Counts > 31 would not be sensible, since the result would be already zero by
  27. ; the 31st shift.
  28. ;
  29. ; INPUT:     DX:AX     argument
  30. ;            CX        count
  31. ;
  32. ; OUTPUT:    DX:AX     argument SHR count
  33. ;
  34. ; DESTROYS:  AX,BX,CX,DX,Flags
  35. ;-------------------------------------------------------------------------------
  36.  
  37. LongShr      PROC    FAR
  38.              AND     CX, 1FH           ; mask off shift count to 0..31
  39.              CMP     CL, 16            ; 16 shifts or more ?
  40.              JAE     $more_16          ; yes
  41.              MOV     BX, DX            ; duplicate hi-word of number
  42.              SHR     DX, CL            ; shift hi-word of number
  43.              SHR     AX, CL            ; shift lo-word of number
  44.              NEG     CL                ; compute new shift count as
  45.              ADD     CL, 16            ;  16 - old shift count
  46.              SHL     BX, CL            ; get bits shifted out of hi-word
  47.              OR      AX, BX            ; move them into lo-word
  48. $zero_shr:   RET                       ; done
  49. $more_16:    XCHG    AX, DX            ; shift number
  50.              XOR     DX, DX            ;  by 16 bits
  51.              SUB     CL, 16            ; 16 shifts done
  52.              SHR     AX, CL            ; perform remaining shifts
  53.              RET                       ; done
  54. LongShr      ENDP
  55.  
  56.              ALIGN   4
  57.  
  58. CODE         ENDS
  59.  
  60.              END
  61.