home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / INFO / CROSSASM / ASM370.ZIP / PET.ALC < prev    next >
Encoding:
Text File  |  1985-06-15  |  2.4 KB  |  76 lines
  1.          TITLE 'PET - PRINT ELAPSED TIME IN SECONDS SINCE LAST CALL'
  2. *
  3. * AUTHOR.    DON HIGGINS.
  4. * DATE.      04/08/85.
  5. * REMARKS.   PC/370 SUBROUTINE TO PRINT THE FOLLOWING:
  6. *
  7. *             1.  CURRENT DATE AND TIME.
  8. *             2.  ELAPSED TIME IN SECONDS SINCE LAST CALL.
  9. *             3.  NUMBER OF 370 INSTRUCTIONS EXECUTED SINCE LAST CALL.
  10. *             4.  AVERAGE INSTRUCTIONS PER SECOND SINCE LAST CALL.
  11. *
  12. PET      CSECT
  13.          USING *,R15
  14.          STM   R14,R15,RSAVE
  15.          L     R15,=V(DAT)       DISPLAY DATE AND TIME
  16.          BALR  R14,R15
  17.          USING *,R14
  18.          LM    R14,R15,RSAVE
  19.          DROP  R14
  20.          SVC   ICNTSVC
  21.          L     R0,0(R1)
  22.          L     R1,INSCOUNT
  23.          ST    R0,INSCOUNT       SAVE LAST INSTR. COUNT
  24.          CVD   R0,PWORK
  25.          MVC   DCOUNT,MASKCNT
  26.          ED    DCOUNT,PWORK+4
  27.          LA    R2,DCNTMSG
  28.          SVC   WTO               DISPLAY CURRENT INSTRUCTION COUNTER
  29.          SR    R0,R1
  30.          ST    R0,INSDIFF        SAVE TOTAL SINCE LAST CALL
  31.          L     R15,=V(TIMER)
  32.          BALR  R14,R15
  33.          USING *,R14
  34.          LM    R14,R15,RSAVE
  35.          DROP  R14
  36.          L     R1,TSAVE
  37.          ST    R0,TSAVE         SAVE CURRENT TIMER VALUE IN 100TH SEC.
  38.          LTR   R1,R1
  39.          BZR   R14              EXIT NOW IF FIRST CALL
  40.          SR    R0,R1
  41.          ST    R0,SEC100        SAVE ELAPSED TIME IN 100TH SEC
  42.          CVD   R0,PWORK
  43.          MVC   DTIME,MASKSEC
  44.          ED    DTIME,PWORK+4
  45.          L     R1,INSDIFF
  46.          MH    R1,=H'100'       SET R0-R1 = 100 * INSTRUCTIONS IN INTERVAL
  47.          SR    R0,R0
  48.          D     R0,SEC100        SET R1 = INSTRUCTIONS PER SECOND
  49.          CVD   R1,PWORK
  50.          MVC   DIPS,MASKCNT
  51.          ED    DIPS,PWORK+4
  52.          LA    R2,DTIMEMSG
  53.          SVC   WTO
  54.          BR    R14
  55. R15      EQU   15
  56. R14      EQU   14
  57. R2       EQU   2
  58. R1       EQU   1
  59. R0       EQU   0
  60. RSAVE    DC    2F'0'
  61. TSAVE    DC    F'0'
  62. INSCOUNT DC    F'0'
  63. INSDIFF  DC    F'0'
  64. SEC100   DC    F'0'
  65. PWORK    DC    D'0'
  66. MASKSEC  DC    X'402020',C',',X'202120',C'.',X'2020'
  67. MASKCNT  DC    X'4020',C',',X'202020',C',',X'202020'
  68. DCNTMSG  DC    C' INSTRUCTION COUNTER ='
  69. DCOUNT   DC    CL10' Z,ZZZ,ZZZ',C'$'
  70. DTIMEMSG DC    C' ELAPSED TIME ='
  71. DTIME    DC    CL10' ZZ,ZZ9.99',C' SEC    INSTR/SEC = '
  72. DIPS     DC    CL10' Z,ZZZ,ZZZ',C'$'
  73. ICNTSVC  EQU   16
  74. WTO      EQU   209
  75.          END
  76.