home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / INFO / CLIPPER / NFSRC.ZIP / SAVEATT.ASM < prev    next >
Encoding:
Assembly Source File  |  1991-08-16  |  7.7 KB  |  184 lines
  1. ; File......: SAVEATT.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   15 Aug 1991 23:07:58  $
  4. ; Revision..: $Revision:   1.1  $
  5. ; Log file..: $Logfile:   E:/nanfor/src/saveatt.asv  $
  6. ; 
  7. ; This is an original work by Ted Means and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   E:/nanfor/src/saveatt.asv  $
  14. ;  
  15. ;     Rev 1.1   15 Aug 1991 23:07:58   GLENN
  16. ;  Forest Belt proofread/edited/cleaned up doc
  17. ;  
  18. ;     Rev 1.0   12 Jun 1991 01:30:20   GLENN
  19. ;  Initial revision.
  20. ;
  21.  
  22.  
  23. ;  $DOC$
  24. ;  $FUNCNAME$
  25. ;     FT_SAVEATT()
  26. ;  $CATEGORY$
  27. ;     Video
  28. ;  $ONELINER$
  29. ;     Save the attribute bytes of a specified screen region.
  30. ;  $SYNTAX$
  31. ;     FT_SAVEATT( <nTop>, <nLeft>, <nBottom>, <nRight>  ) -> cAttributes
  32. ;  $ARGUMENTS$
  33. ;     <nTop>, <nLeft>, <nBottom>, and <nRight> define the screen region.
  34. ;  $RETURNS$
  35. ;     A character string containing the screen attribute bytes for the
  36. ;     specified region.  If the memory to store the return value could
  37. ;     not be allocated, the function returns NIL.
  38. ;  $DESCRIPTION$
  39. ;     This function is similar to Clipper's SaveScreen(), except that it only
  40. ;     saves the attribute bytes.  This is useful if you want to change the
  41. ;     screen color without affecting the text.
  42. ;
  43. ;     *** INTERNALS ALERT ***
  44. ;
  45. ;     This function calls the Clipper internal __gtMaxCol to obtain the
  46. ;     maximum column value for the current video mode.  If you're too gutless
  47. ;     to use internals, then this function isn't for you.
  48. ;  $EXAMPLES$
  49. ;     // Save attributes of row 4
  50. ;     cBuffer := FT_SAVEATT( 4, 0, 4, maxcol())
  51. ;
  52. ;     // Save attributes from middle of screen
  53. ;     cBuffer := FT_SAVEATT(10,20,14,59)
  54. ;  $SEEALSO$
  55. ;     FT_RESTATT()
  56. ;  $END$
  57. ;
  58.  
  59.         IDEAL
  60.  
  61. Public   FT_SAVEATT
  62.  
  63. Extrn    __ParNI:Far
  64. Extrn    __gtMaxCol:Far                      ; INTERNAL!!  INTERNAL!!
  65. Extrn    __XAlloc:Far
  66. Extrn    __XFree:Far
  67. Extrn    __RetCLen:Far
  68.  
  69. Upper    EQU       Word Ptr BP - 2
  70. Left     EQU       Word Ptr BP - 4
  71. Lower    EQU       Word Ptr BP - 6
  72. Right    EQU       Word Ptr BP - 8
  73. BufSize  EQU       Word Ptr BP - 10
  74. BufSeg   EQU       Word Ptr BP - 12
  75. BufOfs   EQU       Word Ptr BP - 14
  76. BufPtr   EQU       DWord Ptr BP - 14
  77. MaxCol   EQU       Word Ptr BP - 16
  78.  
  79. Segment  _NanFor   Word      "CODE"
  80.          Assume    CS:_NanFor
  81.  
  82. Proc     FT_SAVEATT          Far
  83.  
  84.          Push      BP                        ; Save BP
  85.          Mov       BP,SP                     ; Set up stack reference
  86.          Sub       SP,16                     ; Allocate space for locals
  87.  
  88.          Call      __gtMaxCol                ; Get current value of maxcol()
  89.          Inc       AX                        ; Set to number of columns
  90.          Mov       [MaxCol],AX               ; Store it in local
  91.  
  92.          Mov       AX,1                      ; Specify param #1
  93.          Push      AX                        ; Put on stack
  94.          Call      __ParNI                   ; Get value
  95.          Mov       [Upper],AX                ; Store in local
  96.  
  97.          Mov       AX,2                      ; Specify param #2
  98.          Push      AX                        ; Put on stack
  99.          Call      __ParNI                   ; Get value
  100.          Mov       [Left],AX                 ; Store in local
  101.  
  102.          Mov       AX,3                      ; Specify param #3
  103.          Push      AX                        ; Put on stack
  104.          Call      __ParNI                   ; Get value
  105.          Mov       [Lower],AX                ; Store in local
  106.          
  107.          Mov       AX,4                      ; Specify param #4
  108.          Push      AX                        ; Put on stack
  109.          Call      __ParNI                   ; Get value
  110.          Mov       [Right],AX                ; Store in local
  111.          Add       SP,8
  112.  
  113.          Mov       AX,[Right]                ; Load right column
  114.          Sub       AX,[Left]                 ; Subtract left
  115.          Inc       AX                        ; Get column count
  116.          Mov       DX,[Lower]                ; Load lower row
  117.          Sub       DX,[Upper]                ; Subtract upper
  118.          Inc       DX                        ; Get row count
  119.          Mul       DX                        ; Calculate buffer size
  120.          Mov       [BufSize],AX              ; Store in local
  121.          Push      AX                        ; Put on stack
  122.          Call      __XAlloc                  ; Allocate buffer
  123.          Add       SP,2                      ; Realign stack
  124.          Mov       [BufSeg],DX               ; Load segment into local
  125.          Mov       [BufOfs],AX               ; Load offset into local
  126.          Or        DX,AX                     ; Check for null pointer
  127.          JZ        Exit                      ; If so, allocation failed
  128.  
  129. SetPtr:  Push      DS                        ; Save appropriate registers and
  130.          Push      SI                        ; make sure direction flag clear
  131.          Push      DI
  132.          CLD
  133.  
  134.          LES       DI,[BufPtr]               ; Load pointer to buffer
  135.          Xor       AX,AX                     ; Clear AX
  136.          Mov       DS,AX                     ; Point DS to low memory
  137.          Mov       AX,0B800h                 ; Initialize video base
  138.          Cmp       [Word Ptr 463h],3B4h      ; Monochrome?
  139.          JNE       SetVid                    ; No, continue
  140.          Mov       AX,0B000h                 ; Set video base to mono
  141.  
  142. SetVid:  Mov       DS,AX                     ; Set video base
  143.          Xor       SI,SI                     ; Start at offset 0
  144.          Mov       CX,[Lower]                ; Get lower row
  145.          Sub       CX,[Upper]                ; Subtract upper row
  146.          Inc       CX                        ; Get number of rows
  147.  
  148. Rows:    Mov       AX,CX                     ; Get row number
  149.          Sub       AX,[Lower]                ; Subtract last row
  150.          Dec       AX                        ; Get negation of row
  151.          Neg       AX                        ; Convert to abs()
  152.          Mul       [MaxCol]                  ; Multiply by column count
  153.          SHL       AX,1                      ; Multiply by two
  154.          Mov       BX,[Left]                 ; Get left column
  155.          SHL       BX,1                      ; Multiply by two
  156.          Inc       BX                        ; Point to attribute byte
  157.          Add       BX,AX                     ; Add rows * columns
  158.          Push      CX                        ; Save row indicator
  159.          Mov       CX,[Right]                ; Load right column
  160.          Sub       CX,[Left]                 ; Subtract left column
  161.          Inc       CX                        ; Get number of columns
  162. Cols:    Mov       AL,[Byte Ptr BX + SI]     ; Load attribute byte
  163.          Stosb                               ; Store in allocated string
  164.          Add       BX,2                      ; Point to next attribute byte
  165.          Loop      Cols                      ; Get next byte
  166.          Pop       CX                        ; Restore row indicator
  167.          Loop      Rows                      ; Do next row
  168.  
  169. Done:    Pop       DI                        ; Restore registers
  170.          Pop       SI
  171.          Pop       DS
  172.          Push      [BufSize]                 ; Put buffer size on stack
  173.          Push      [BufSeg]                  ; Put buffer segment on stack
  174.          Push      [BufOfs]                  ; Put buffer offset on stack
  175.          Call      __RetCLen                 ; Return string to Clipper app
  176.          Call      __XFree                   ; Free memory held by buffer
  177. Exit:    Mov       SP,BP
  178.          Pop       BP
  179.          Ret
  180. Endp     FT_SAVEATT
  181. Ends     _NanFor
  182. End
  183. 
  184.