home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / INFO / CLIPPER / NFSRC.ZIP / ISPRINT.ASM < prev    next >
Encoding:
Assembly Source File  |  1991-08-16  |  8.3 KB  |  216 lines
  1. ; File......: ISPRINT.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   15 Aug 1991 23:07:56  $
  4. ; Revision..: $Revision:   1.2  $
  5. ; Log file..: $Logfile:   E:/nanfor/src/isprint.asv  $
  6. ; 
  7. ; This function is an original work by Ted Means and is placed in the
  8. ; public domain.  I got the idea from Norm Mongeau, but the code is
  9. ; all mine.
  10. ;
  11. ; Modification history:
  12. ; ---------------------
  13. ;
  14. ; $Log:   E:/nanfor/src/isprint.asv  $
  15. ;  
  16. ;     Rev 1.2   15 Aug 1991 23:07:56   GLENN
  17. ;  Forest Belt proofread/edited/cleaned up doc
  18. ;  
  19. ;     Rev 1.1   14 Jun 1991 19:54:38   GLENN
  20. ;  Minor edit to file header
  21. ;  
  22. ;     Rev 1.0   01 Apr 1991 01:03:26   GLENN
  23. ;  Nanforum Toolkit
  24. ;  
  25. ;
  26.  
  27.  
  28. ;  $DOC$
  29. ;  $FUNCNAME$
  30. ;     FT_ISPRINT()
  31. ;  $CATEGORY$
  32. ;     DOS/BIOS
  33. ;  $ONELINER$
  34. ;     Check printer status
  35. ;  $SYNTAX$
  36. ;     FT_ISPRINT( [ <cDevice> ] ) -> lResult
  37. ;  $ARGUMENTS$
  38. ;     <cDevice> is optional and is the device to test (LPT2, COM1, etc.).
  39. ;     If omitted, the function will default to the PRN device.
  40. ;  $RETURNS$
  41. ;     .T.  if device is ready for output.
  42. ;     .F.  if one of the following conditions occurs:
  43. ;          1)  The device is not ready.
  44. ;          2)  The device does not exist.
  45. ;          3)  DOS couldn't open the device for some reason
  46. ;              (such as no file handles available).
  47. ;  $DESCRIPTION$
  48. ;     The Clipper IsPrinter() function is somewhat limited because it only
  49. ;     works with LPT1.  Furthermore, it talks directly to the hardware, so
  50. ;     if you have redirected LPT1 via the DOS MODE command, the IsPrinter()
  51. ;     function will return erroneous results.
  52. ;
  53. ;     This function offers a better alternative.  Instead of talking to the
  54. ;     hardware, it issues a DOS call that checks to see if the device is
  55. ;     ready or not.  That gives DOS an opportunity to deal with any
  56. ;     redirections, and since you pass the device name as a parameter, you
  57. ;     can test any device, not just LPT1 (note that the function defaults
  58. ;     to PRN if you fail to pass a valid parameter).
  59. ;
  60. ;     The function also temporarily traps the DOS critical error handler so
  61. ;     you don't get any nasty error messages if the device isn't ready.  It
  62. ;     restores the old critical error handler before exiting.
  63. ;
  64. ;     Note that although this function is mainly designed for testing
  65. ;     printers, you can also check to see if a drive is ready.  Since DOS
  66. ;     thinks the NUL device exists on every drive, you can pass a drive
  67. ;     letter followed by NUL as a parameter.  If DOS is able to open the
  68. ;     NUL device, then the drive is ready, otherwise the door is open or
  69. ;     something else is wrong.
  70. ;
  71. ;     The source code is written to adhere to Turbo Assembler's IDEAL mode.
  72. ;     To use another assembler, you will need to rearrange the PROC and
  73. ;     SEGMENT directives, and also the ENDP and ENDS directives (a very
  74. ;     minor task).
  75. ;  $EXAMPLES$
  76. ;     IF ! FT_ISPRINT()
  77. ;        Qout( "PRN is not ready!" )
  78. ;     ENDIF
  79. ;
  80. ;     IF ! FT_ISPRINT( "COM2" )
  81. ;        Qout( "Check the device on COM2.  Something is wrong." )
  82. ;     ENDIF
  83. ;
  84. ;     IF ! FT_ISPRINT( "A:\NUL" )
  85. ;        Qout( "Oops, better check drive A!" )
  86. ;     ENDIF
  87. ;  $END$
  88. ;
  89.  
  90.  
  91.          IDEAL
  92.  
  93. Public   FT_ISPRINT
  94.  
  95. Old24Vec EQU       DWord Ptr BP - 4
  96. Old24Ofs EQU       Word Ptr BP - 4
  97. Old24Seg EQU       Word Ptr BP - 2
  98. Handle   EQU       Word Ptr BP - 6
  99. OpenFlag EQU       Byte Ptr BP - 8
  100.  
  101. Extrn    __ParInfo:Far
  102. Extrn    __ParC:Far
  103. Extrn    __RetL:Far
  104.  
  105. Segment  _NanFor   Word      Public    "CODE"
  106.          Assume    CS:_NanFor
  107.  
  108. IsReady  DB        ?
  109.  
  110. Proc     FT_ISPRINT          Far
  111.  
  112.          Push      BP                        ; Save BP
  113.          Mov       BP,SP                     ; Set up stack reference
  114.          Sub       SP,8                      ; Allocate room for locals
  115.          Mov       [Handle],4                ; Default to PRN
  116.          Mov       [OpenFlag],0              ; Initialize flag
  117.  
  118.          Xor       AX,AX                     ; Request param count
  119.          Push      AX                        ; Put request on stack
  120.          Call      __ParInfo                 ; Count params
  121.          Or        AX,AX                     ; Zero params?
  122.          JZ        PrtTest                   ; Yes, so use default
  123.  
  124. ParType: Mov       AX,1                      ; Specify first param
  125.          Push      AX                        ; Put param # on stack
  126.          Call      __ParInfo                 ; Get type
  127.          Test      AX,1                      ; Character?
  128.          JZ        PrtTest                   ; No, so use default
  129.  
  130. GetParam:Mov       AX,1                      ; Specify first param
  131.          Push      AX                        ; Put param # on stack
  132.          Call      __ParC                    ; Retrieve parameter
  133.  
  134.          Push      DS                        ; Save DS
  135.          Mov       DS,DX                     ; Get segment of device name
  136.          Mov       DX,AX                     ; Get offset of device name
  137.          Mov       AX,3D01h                  ; DOS service--open file or device
  138.          Int       21h                       ; Call DOS
  139.          Pop       DS                        ; Restore DS
  140.          JNC       DHandle                   ; No error, so device was opened
  141.          Xor       AX,AX                     ; Set return value to false
  142.          Jmp       Short RetVal              ; We're outta here
  143.  
  144. DHandle: Mov       [Handle],AX               ; Supply device's handle
  145.          Inc       [OpenFlag]                ; Set flag so close can occur
  146.          
  147. PrtTest: Call      Near _FTHook24            ; Install local INT 24h handler
  148.          Mov       [_NanFor:IsReady],1       ; Assume printer ready
  149.          Mov       AX,4407h                  ; DOS service--get output status
  150.          Mov       BX,[Handle]               ; Choose standard print device
  151.          Int       21h                       ; Call DOS
  152.          And       AL,[_NanFor:IsReady]      ; Combine error reports
  153.          CBW                                 ; Clear high byte
  154.          Call      Near _FTUnHook24          ; Restore old INT 24h vector
  155.  
  156. RetVal:  Push      AX                        ; Put return value on stack
  157.          Call      __RetL                    ; Return status to Clipper app
  158.  
  159.          Cmp       [OpenFlag],1              ; Need to close device?
  160.          JNE       Exit                      ; No, so go ahead and exit
  161.          Mov       AH,3Eh                    ; DOS service--close handle
  162.          Mov       BX,[Handle]               ; Supply file handle
  163.          Int       21h                       ; Call DOS
  164.  
  165. Exit:    Mov       SP,BP                     ; Realign stack
  166.          Pop       BP                        ; Restore BP
  167.          Ret                                 ; Far return to Clipper app
  168. Endp     FT_ISPRINT
  169.  
  170.  
  171.  
  172. Proc     _FTHook24 Near
  173.  
  174.          Push      DS                        ; Save DS
  175.  
  176.          Mov       AX,3524h                  ; DOS service--get INT 24h vector
  177.          Int       21h                       ; Call DOS
  178.          Mov       [Old24Ofs],BX             ; Save offset
  179.          Mov       [Old24Seg],ES             ; Save segment value
  180.  
  181.          Push      CS
  182.          Pop       DS                        ; Set DS to local segment
  183.          Mov       DX,Offset _NanFor:Int_24  ; Offset of local handler
  184.          Mov       AX,2524h                  ; DOS service--set INT 24h vector
  185.          Int       21h                       ; Call DOS  
  186.  
  187.          Pop       DS
  188.          Ret                                 ; Near return
  189. Endp     _FTHook24
  190.  
  191.  
  192.  
  193. Proc     _FTUnHook24         Near
  194.  
  195.          Push      DS                        ; Save DS
  196.          Push      AX                        ; Save AX
  197.          Mov       AX,2524h                  ; DOS service--set INT 24h vector
  198.          LDS       DX,[Old24Vec]             ; Get address of original handler
  199.          Int       21h                       ; Call DOS
  200.          Pop       AX
  201.          Pop       DS
  202.          Ret                                 ; Near return
  203. Endp     _FTUnHook24
  204.  
  205.  
  206.  
  207. Proc     Int_24    Far
  208.  
  209.          Mov       [_NanFor:IsReady],0       ; Indicate not ready
  210.          Xor       AX,AX                     ; Tell DOS to ignore error
  211.          IRet
  212. Endp     Int_24
  213. Ends     _NanFor
  214. End
  215. 
  216.