home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / INFO / CLIPPER / NFSRC.ZIP / HANDCNT.ASM < prev    next >
Encoding:
Assembly Source File  |  1991-08-16  |  6.2 KB  |  175 lines
  1. ; File......: HANDCNT.ASM
  2. ; Author....: Bob Clarke
  3. ; CIS ID....: 72621,3563
  4. ; Date......: $Date:   15 Aug 1991 23:06:52  $
  5. ; Revision..: $Revision:   1.2  $
  6. ; Log file..: $Logfile:   E:/nanfor/src/handcnt.asv  $
  7. ; 
  8. ; This is an original work by Bob Clarke and is placed in the
  9. ; public domain.
  10. ;
  11. ; Modification history:
  12. ; ---------------------
  13. ;
  14. ; $Log:   E:/nanfor/src/handcnt.asv  $
  15. ;  
  16. ;     Rev 1.2   15 Aug 1991 23:06:52   GLENN
  17. ;  Forest Belt proofread/edited/cleaned up doc
  18. ;  
  19. ;     Rev 1.1   14 Jun 1991 19:54:36   GLENN
  20. ;  Minor edit to file header
  21. ;  
  22. ;     Rev 1.0   07 Jun 1991 21:58:52   GLENN
  23. ;  Initial revision.
  24. ;
  25.  
  26. ; $DOC$
  27. ; $FUNCNAME$
  28. ;    FT_HANDCNT()
  29. ; $CATEGORY$
  30. ;    DOS/BIOS
  31. ; $ONELINER$
  32. ;    Count number of available DOS (not network) file handles
  33. ; $SYNTAX$
  34. ;    FT_HANDCNT() -> nHandles
  35. ; $ARGUMENTS$
  36. ;    None
  37. ; $RETURNS$
  38. ;    numeric, long integer
  39. ; $DESCRIPTION$
  40. ;    FT_HANDCNT() finds the internal DOS Device Control Blocks used for 
  41. ;    storing file information and counts the number of DCB entries.  The
  42. ;    DCB is set up by reading the FILES= line in CONFIG.SYS, and there
  43. ;    is one DCB entry for each file handle.
  44. ;
  45. ;    NOTE: For Novell networks, the number of network file handles is
  46. ;          controlled by SHELL.CFG.  To date, I know where this information
  47. ;          is stored after SHELL.CFG has been read, but have not come up
  48. ;          with a reliable way to retrieve the information.  There is no
  49. ;          public variable associated with the storage location, and the
  50. ;          location can change from version to version of NETx.EXE.
  51. ;          Novell Tech Support's response, though friendly, was "Nope, we 
  52. ;          don't know of a way for you to do it, either.  Good luck."
  53. ; $EXAMPLES$
  54. ;    nHandles := FT_HANDCNT()
  55. ;    ? "This PC has " + LTRIM( STR( nHandles ) ) + " set by CONFIG.SYS."
  56. ; $SEEALSO$
  57. ;
  58. ; $INCLUDE$
  59. ;
  60. ; $END$
  61. ;
  62. ;
  63.  
  64. Public   FT_HANDCNT
  65. Extrn    __RETNL:Far
  66.  
  67. _NanFor  Segment  Word Public 'CODE'
  68.          Assume CS:_Nanfor
  69.  
  70. FT_HANDCNT    Proc Far
  71.  
  72.          push bp
  73.          push es
  74.          push ds
  75.          push si
  76.          push di
  77.          mov  ah,52h                   ;Get Configuration Variable Table
  78.          push es
  79.          push ds
  80.          int  21h
  81.  
  82. ; ES:BX now contains pointer to CVT (Configuration Variable Table)
  83.  
  84.  
  85. ;
  86. ;CVT structure for DOS 3.x:
  87. ;
  88. ;    (The ampersand indicates the address in ES:BX)
  89. ;
  90. ;offset byte        field length        description
  91. ;-----------        ------------        ------------
  92. ;
  93. ;    -08h           double word         current buffer in BUFFERS= chain
  94. ;    -04h           word                offset within current buffer
  95. ;    -02h           word                segment of first memory control block
  96. ;&    00h           double word         pointer to first Drive Parameter Block
  97. ;     04h           double word         Pointer to first DCB (system file table
  98. ;                                       Device Control Block)
  99. ;     08h           double word         pointer to CLOCK$ device driver
  100. ;     0Ch           double word         pointer to CON device driver
  101. ;     10h           word                maximum bytes per sector on any block
  102. ;                                       device
  103. ;     12h           double word         pointer to start of disk buffer chain
  104. ;     16h           double word         pointer to Logical Drive Table
  105. ;     1Ah           double word         pointer to start of DOS's FCB chain
  106. ;     1Eh           word                number of FCBs to keep when swapping
  107. ;     20h           byte                number of block devices
  108. ;     21h           byte                number of logical drives, set by value
  109. ;                                       of LASTDRIVE in CONFIG.SYS (defaults
  110. ;                                       to 5 if not specified)
  111. ;     22h                               Beginning of NUL device driver;
  112. ;                                       first device in the device-driver
  113. ;                                       chain
  114. ;
  115. ; For DOS 4.x, the only change in the CVT was the item at offset 12h.  It is 
  116. ; now a double word pointer to EMS link record that leads to the DOS buffer
  117. ; chain.  All other items and addresses are the same as for DOS 3.x.
  118. ;
  119. ; The number of DCBs in a system is established by the FILES= line in
  120. ; CONFIG.SYS.  The default number is 8 if no FILES= line is found.
  121. ; DCBs are grouped in "links" and each link is preceded by a 3-word header.
  122. ;
  123. ;Structure of device control block header:
  124. ;
  125. ;offset byte        field length        description
  126. ;-----------        ------------        ------------
  127. ;    00h            double word         Far pointer to next link header,
  128. ;                                       or xxxx:FFFFh to indicate that this
  129. ;                                       is final link in chain.
  130. ;    04h            word                number of blocks in this link
  131. ;
  132. ;
  133. ; For more detailed information, see "DOS Programmer's Reference: 2nd Edition"
  134. ; by Que Corporation, pages 807-818.
  135. ;
  136.  
  137.  
  138.          add  bx,4                     ;move to address of first DCB
  139.          mov  si,word ptr es:[bx]      ;get offset of DCB
  140.          mov  ds,word ptr es:[bx+2]    ;get segment of DCB
  141.  
  142. ; DS:SI now contains a pointer to header of first DCB
  143.  
  144.          xor  ax,ax                    ;use as a count holder
  145.          xor  dx,dx                    ;use as a count holder
  146. hand1:   add  ax,word ptr [si+4]       ;adjust running total
  147.          adc  dx,0
  148.          mov  cx,word ptr [si]         ;offset of next link header
  149.          mov  bx,word ptr [si+2]       ;segment of next link header
  150.          mov  si,cx
  151.          mov  ds,bx
  152.          cmp  cx,0ffffh                ;possible end of list?
  153.          jne  hand1                    ;if not, keep looking
  154.          pop  ds
  155.          pop  es
  156.  
  157. ; sum of dcbs from all links is now in DX:AX
  158.  
  159.          pop  di                  ;restore registers before returning value
  160.          pop  si
  161.          pop  ds
  162.          pop  es
  163.          pop  bp
  164.          push dx
  165.          push ax
  166.          call __retnl
  167.          add  sp,4
  168.          ret
  169.  
  170. FT_HANDCNT    Endp
  171. _NanFor       Ends
  172.               End
  173.  
  174. 
  175.