home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / INFO / CLIPPER / NFSRC.ZIP / AINT86.ASM < prev    next >
Encoding:
Assembly Source File  |  1991-08-16  |  4.3 KB  |  121 lines
  1. ; File......: AINT86.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   15 Aug 1991 23:07:24  $
  4. ; Revision..: $Revision:   1.1  $
  5. ; Log file..: $Logfile:   E:/nanfor/src/aint86.asv  $
  6. ; 
  7. ; This is an original work by Ted Means and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   E:/nanfor/src/aint86.asv  $
  14. ;  
  15. ;     Rev 1.1   15 Aug 1991 23:07:24   GLENN
  16. ;  Forest Belt proofread/edited/cleaned up doc
  17. ;  
  18. ;     Rev 1.0   27 May 1991 13:21:48   GLENN
  19. ;  Initial revision.
  20. ;
  21.  
  22.  
  23. ; This file is a part of the ft_int86() package.  For complete
  24. ; documentation, read cint86.c, available elsewhere in the 
  25. ; Nanforum Toolkit.
  26. ;
  27. ; This module should be compiled with TASM.
  28.  
  29.  
  30. Public   __ftint86
  31.  
  32. Segment  _NanFor   Word      Public    "CODE"
  33.          Assume    CS:_NanFor
  34.  
  35. Proc     __ftint86 Far
  36.  
  37.          Pop       CX                        ; Remove return address from
  38.          Pop       DX                        ; stack
  39.  
  40.          Pop       [CS:RegOfs]               ; Get pointer to register
  41.          Pop       [CS:RegSeg]               ; structure from stack
  42.  
  43.          Pop       AX                        ; Get desired interrupt
  44.  
  45.          Push      DX                        ; Put return address back onto
  46.          Push      CX                        ; stack to prevent underflow
  47.  
  48.          Push      DS                        ; Save modified registers
  49.          Push      SI
  50.          Push      DI
  51.          Push      BP
  52.  
  53.          Mov       AH,35h                    ; DOS service -- get vector
  54.          Int       21h                       ; Call DOS
  55.          Mov       [CS:HndSeg],ES            ; Store address of desired
  56.          Mov       [CS:HndOfs],BX            ; interrupt handler
  57.  
  58.          LDS       BX,[CS:RegPtr]            ; Load pointer to register values
  59.          Push      [Word Ptr BX + 16]        ; Put ES value on stack
  60.          Push      [Word Ptr BX + 14]        ; Put DS value on stack
  61.          Push      [Word Ptr BX + 12]        ; Put BP value on stack
  62.          Push      [Word Ptr BX + 10]        ; Put DI value on stack
  63.          Push      [Word Ptr BX + 8]         ; Put SI value on stack
  64.          Push      [Word Ptr BX + 6]         ; Put DX value on stack
  65.          Push      [Word Ptr BX + 4]         ; Put CX value on stack
  66.          Push      [Word Ptr BX + 2]         ; Put BX value on stack
  67.          Mov       AX,[Word Ptr BX + 0]      ; Get AX value
  68.          Pop       BX                        ; Get BX value
  69.          Pop       CX                        ; Get CX value
  70.          Pop       DX                        ; Get DX value
  71.          Pop       SI                        ; Get SI value
  72.          Pop       DI                        ; Get DI value
  73.          Pop       BP                        ; Get BP value
  74.          Pop       DS                        ; Get DS value
  75.          Pop       ES                        ; Get ES value
  76.  
  77.          PushF                               ; Simulate INT instruction by
  78.          CLI                                 ; using PushF and CLI
  79.          Call      [CS:Handler]              ; Call the interrupt handler
  80.  
  81.          Push      AX                        ; Save all registers to preserve
  82.          Push      BX                        ; the state of the CPU after
  83.          Push      CX                        ; the interrupt executed
  84.          Push      DX
  85.          Push      SI
  86.          Push      DI
  87.          Push      BP
  88.          Push      DS
  89.          Push      ES
  90.          PushF
  91.  
  92.          LDS       BX,[CS:RegPtr]            ; Load pointer to register values
  93.          Pop       [Word Ptr BX + 18]        ; Get saved registers and load
  94.          Pop       [Word Ptr BX + 16]        ; into data structure
  95.          Pop       [Word Ptr BX + 14]
  96.          Pop       [Word Ptr BX + 12]
  97.          Pop       [Word Ptr BX + 10]
  98.          Pop       [Word Ptr BX + 8]
  99.          Pop       [Word Ptr BX + 6]
  100.          Pop       [Word Ptr BX + 4]
  101.          Pop       [Word Ptr BX + 2]
  102.          Pop       [Word Ptr BX + 0]
  103.  
  104.          Pop       BP                        ; Restore registers
  105.          Pop       DI
  106.          Pop       SI
  107.          Pop       DS
  108.          Ret
  109. Endp     __ftint86
  110.  
  111. Label    Handler   DWord
  112. HndOfs   DW        ?
  113. HndSeg   DW        ?
  114.  
  115. Label    RegPtr    DWord
  116. RegOfs   DW        ?
  117. RegSeg   DW        ?
  118.  
  119. Ends     _NanFor
  120. End
  121.