home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / INFO / CLIPPER / NFSRC.ZIP / ADAPTER.ASM < prev    next >
Encoding:
Assembly Source File  |  1991-08-16  |  3.3 KB  |  113 lines
  1. ; File......: ADAPTER.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   15 Aug 1991 23:07:18  $
  4. ; Revision..: $Revision:   1.2  $
  5. ; Log file..: $Logfile:   E:/nanfor/src/adapter.asv  $
  6. ; 
  7. ; This is an original work by Ted Means and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   E:/nanfor/src/adapter.asv  $
  14. ;  
  15. ;     Rev 1.2   15 Aug 1991 23:07:18   GLENN
  16. ;  Forest Belt proofread/edited/cleaned up doc
  17. ;  
  18. ;     Rev 1.1   14 Jun 1991 19:54:18   GLENN
  19. ;  Minor edit to file header
  20. ;  
  21. ;     Rev 1.0   01 Apr 1991 01:03:08   GLENN
  22. ;  Nanforum Toolkit
  23. ;  
  24. ;
  25.  
  26.  
  27.  
  28. ;  $DOC$
  29. ;  $FUNCNAME$
  30. ;     FT_ADAPTER()
  31. ;  $CATEGORY$
  32. ;     Video
  33. ;  $ONELINER$
  34. ;     Report the type of video adapter installed
  35. ;  $SYNTAX$
  36. ;     FT_ADAPTER() -> nResult
  37. ;  $ARGUMENTS$
  38. ;     None
  39. ;  $RETURNS$
  40. ;     Integer representing type of video adapter
  41. ;
  42. ;        0 - monochrome
  43. ;        1 - CGA
  44. ;        2 - EGA
  45. ;        3 - VGA
  46. ;  $DESCRIPTION$
  47. ;     This function is valuable if you use a graphics library and need to
  48. ;     know what type of graphics adapter is installed.
  49. ;
  50. ;     The source code is written to adhere to Turbo Assembler's IDEAL mode.
  51. ;     To use another assembler, you will need to rearrange the PROC and
  52. ;     SEGMENT directives, and also the ENDP and ENDS directives (a very
  53. ;     minor task).
  54. ;  $EXAMPLES$
  55. ;     iVideo := FT_ADAPTER()
  56. ;
  57. ;     DO CASE
  58. ;        CASE iVideo == 0
  59. ;           QOUT( "You have a monochrome adapter." )
  60. ;        CASE iVideo == 1
  61. ;           QOUT( "You have a CGA adapter." )
  62. ;        CASE iVideo == 2
  63. ;           QOUT( "You have an EGA adapter." )
  64. ;        CASE iVideo == 3
  65. ;           QOUT( "You have a VGA adapter." )
  66. ;     ENDCASE
  67. ;  $SEEALSO$
  68. ;     FT_SETMODE()
  69. ;  $END$
  70. ;
  71.  
  72.          IDEAL
  73.  
  74. Public   FT_ADAPTER
  75.  
  76. Extrn    __RetNI:Far
  77.  
  78. Segment  _NanFor   Word      "CODE"
  79.          Assume    CS:_NanFor
  80.  
  81. Proc     FT_ADAPTER          Far
  82.  
  83.          Xor       BX,BX                     ; Clear BX
  84.          Mov       ES,BX                     ; Set ES to low memory
  85.          Cmp       [Word Ptr ES:463h],3B4h   ; See if mono
  86.          JE        Done                      ; If so, we're done
  87.  
  88. IsVGA:   Mov       AX,1A00h                  ; VGA-only BIOS call
  89.          Int       10h                       ; Call video BIOS
  90.          Cmp       AL,1Ah                    ; See if call supported
  91.          JNE       IsEGA                     ; If not, try EGA
  92.          Mov       BX,3                      ; Indicate VGA
  93.          JMP       Short Done                ; Return to application
  94.  
  95. IsEGA:   Mov       AH,12h                    ; EGA-only BIOS call
  96.          Mov       BL,10h                    ; Set BL to test value
  97.          Int       10h                       ; Call video BIOS
  98.          Cmp       BL,10h                    ; Did BL change?
  99.          JE        IsCGA                     ; No, so it's a CGA
  100.          Mov       BX,2                      ; Indicate EGA
  101.          Jmp       Short Done                ; Return to application
  102.  
  103. IsCGA:   Mov       BX,1                      ; Indicate CGA
  104.  
  105. Done:    Push      BX                        ; Save adapter type on stack
  106.          Call      __RetNI                   ; Return it
  107.          Add       SP,2                      ; Realign stack
  108.          Ret
  109. Endp     FT_ADAPTER
  110. Ends     _NanFor
  111. End
  112. 
  113.