home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / INFO / CLIPPER / NFSRC.ZIP / ACCTQTR.PRG < prev    next >
Encoding:
Text File  |  1991-08-16  |  4.5 KB  |  128 lines
  1. /*
  2.  * File......: ACCTQTR.PRG
  3.  * Author....: Jo W. French dba Practical Computing
  4.  * CIS ID....: 74731,1751
  5.  * Date......: $Date:   15 Aug 1991 23:02:36  $
  6.  * Revision..: $Revision:   1.2  $
  7.  * Log file..: $Logfile:   E:/nanfor/src/acctqtr.prv  $
  8.  * 
  9.  * The functions contained herein are the original work of Jo W. French
  10.  * and are placed in the public domain.
  11.  *
  12.  * Modification history:
  13.  * ---------------------
  14.  *
  15.  * $Log:   E:/nanfor/src/acctqtr.prv  $
  16.  * 
  17.  *    Rev 1.2   15 Aug 1991 23:02:36   GLENN
  18.  * Forest Belt proofread/edited/cleaned up doc
  19.  * 
  20.  *    Rev 1.1   14 Jun 1991 19:50:44   GLENN
  21.  * Minor edit to file header
  22.  * 
  23.  *    Rev 1.0   01 Apr 1991 01:00:26   GLENN
  24.  * Nanforum Toolkit
  25.  *
  26.  */
  27.  
  28. /*  $DOC$
  29.  *  $FUNCNAME$
  30.  *     FT_ACCTQTR()
  31.  *  $CATEGORY$
  32.  *     Date/Time
  33.  *  $ONELINER$
  34.  *     Return accounting quarter data
  35.  *  $SYNTAX$
  36.  *     FT_ACCTQTR( [ <dGivenDate> ], [ <nQtrNum> ] ) -> aDateinfo
  37.  *  $ARGUMENTS$
  38.  *     <dGivenDate> is any valid date in any date format.  Defaults
  39.  *     to current system date if not supplied.
  40.  *
  41.  *     <nQtrNum> is a number from 1 to 4 signifying a quarter.
  42.  *     Defaults to current quarter if not supplied.
  43.  *  $RETURNS$
  44.  *     A three element array containing the following data:
  45.  *
  46.  *        aDateInfo[1] - The year and qtr. as a character string "YYYYQQ"
  47.  *        aDateInfo[2] - The beginning date of the accounting quarter
  48.  *        aDateInfo[3] - The ending date of the accounting quarter
  49.  *  $DESCRIPTION$
  50.  *     FT_ACCTQTR() creates an array containing data about the
  51.  *     accounting quarter containing the given date.
  52.  *
  53.  *     An accounting period has the following characteristics:
  54.  *
  55.  *     If the first week of the period contains 4 or more 'work'
  56.  *     days, it is included in the period; otherwise, the first
  57.  *     week was included in the prior period.
  58.  *
  59.  *     If the last week of the period contains 4 or more 'work'
  60.  *     days it is included in the period; otherwise, the last week
  61.  *     is included in the next period.  This results in 13 week
  62.  *     'quarters' and 4 or 5 week 'months'.  Every 5 or 6 years, a
  63.  *     'quarter' will contain 14 weeks and the year will contain 53
  64.  *     weeks.
  65.  *  $EXAMPLES$
  66.  *     // get info about accounting month containing 9/15/90
  67.  *     aDateInfo := FT_ACCTQTR( CTOD("09/15/90") )
  68.  *     ? aDateInfo[1]   //  199003       (3rd quarter)
  69.  *     ? aDateInfo[2]   //  07/01/90     beginning of quarter 3
  70.  *     ? aDateInfo[3]   //  09/29/90     end of quarter 3
  71.  *
  72.  *     // get info about accounting qtr. 2 in year containing 9/15/90
  73.  *     aDateInfo := FT_ACCTQTR( CTOD("09/15/90"), 2 )
  74.  *     ? aDateInfo[1]   //  199002
  75.  *     ? aDateInfo[2]   //  04/01/89   beginning of quarter 2
  76.  *     ? aDateInfo[3]   //  06/30/90   end of quarter 2
  77.  *  $SEEALSO$
  78.  *     FT_DATECNFG() FT_ACCTWEEK() FT_ACCTMONTH() FT_ACCTYEAR()
  79.  *  $END$
  80. */
  81.  
  82. FUNCTION FT_ACCTQTR(dGivenDate,nQtrNum)
  83. LOCAL nYTemp, nQTemp, lIsQtr
  84. LOCAL aRetVal
  85.  
  86. IF dGivenDate == NIL .OR. !VALTYPE(dGivenDate) $ 'ND'
  87.   dGivenDate := DATE()
  88. ELSEIF VALTYPE(dGivenDate) == 'N'
  89.   nQtrNum := dGivenDate
  90.   dGivenDate := DATE()
  91. ENDIF
  92. lIsQtr := IF(nQtrNum == NIL .OR. VALTYPE(nQtrNum) != 'N', .F., .T.)
  93. nQtrNum := IF(lIsQtr, IF(nQtrNum > 0 .AND. nQtrNum < 5, ;
  94.                          nQtrNum, 4), NIL)
  95. aRetVal := FT_QTR(dGivenDate)
  96. nYTemp := VAL(SUBSTR(aRetVal[1],1,4))
  97. nQTemp := VAL(SUBSTR(aRetVal[1],5,2))
  98. aRetVal[2] := FT_ACCTADJ(aRetVal[2])
  99. aRetVal[3] := FT_ACCTADJ(aRetVal[3], .T. )
  100.  
  101. IF dGivenDate >= aRetVal[2] .AND. dGivenDate <= aRetVal[3]
  102.   * All Ok
  103. ELSEIF dGivenDate < aRetVal[2]
  104.   dGivenDate := FT_MADD(dGivenDate, -1)
  105.   aRetVal := FT_QTR(dGivenDate)
  106.   nYTemp := IF(nQTemp - 1 > 0, nQTemp, nYTemp - 1)
  107.   nQTemp := IF(nQTemp - 1 > 0, nQTemp -1, 4)
  108.   aRetVal[2] := FT_ACCTADJ(aRetVal[2])
  109.   aRetVal[3] := FT_ACCTADJ(aRetVal[3], .T. )
  110. ELSE
  111.   dGivenDate := FT_MADD(dGivenDate,1)
  112.   aRetVal := FT_QTR(dGivenDate)
  113.   nYTemp := IF(nQTemp + 1 < 5, nYTemp, nYTemp + 1)
  114.   nQTemp := IF(nQTemp + 1 < 5, nQTemp +1, 1)
  115.   aRetVal[2] := FT_ACCTADJ(aRetVal[2])
  116.   aRetVal[3] := FT_ACCTADJ(aRetVal[3], .T. )
  117. ENDIF
  118. IF lIsQtr
  119.   aRetVal := FT_QTR(dGivenDate, nQtrNum)
  120.   nYTemp  := VAL(SUBSTR(aRetVal[1],1,4))
  121.   nQTemp  := VAL(SUBSTR(aRetVal[1],5,2))
  122.   aRetVal[2] := FT_ACCTADJ(aRetVal[2])
  123.   aRetVal[3] := FT_ACCTADJ(aRetVal[3], .T. )
  124. ENDIF
  125. aRetVal[1] := STR(nYTemp,4) + PADL(LTRIM(STR(nQTemp,2)), 2, '0')
  126. RETURN aRetVal
  127.  
  128.