home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / CLIPPER / MISC / ENTRY.ZIP / DESIGN.BAS < prev    next >
Encoding:
BASIC Source File  |  1988-04-07  |  2.1 KB  |  63 lines
  1. 10 ON ERROR GOTO 320
  2. 20 CLS : KEY OFF : INPUT "FORMAT FILE ";F$ : OPEN F$ FOR INPUT AS 1 : CLS
  3. 30 IF EOF(1) THEN CLOSE : GOTO 90
  4. 40 INPUT #1,R,C,P$,T,S
  5. 50 IF T<3 THEN LOCATE R,C : PRINT P$;" ";
  6. 60 IF T=1 THEN PRINT STRING$(S,"^");
  7. 70 IF T=2 THEN PRINT STRING$(S,"~");
  8. 80 GOTO 30
  9. 90 C=1 : R=1 : OPEN F$ FOR OUTPUT AS 1
  10. 100 LOCATE 25,1 : PRINT F$; : LOCATE 25,30 : PRINT "~ = ALPHANUMERIC DATA           ^ = NUMERIC DATA";
  11. 110 '
  12. 120 LOCATE 25,20 : PRINT R;C;
  13. 130 LOCATE R,C,1 : K$=INKEY$ : IF K$="" THEN 130
  14. 140 IF K$=CHR$(0)+CHR$(72) THEN GOSUB 240 : GOTO 120
  15. 150 IF K$=CHR$(0)+CHR$(75) THEN GOSUB 260 : GOTO 120
  16. 160 IF K$=CHR$(0)+CHR$(77) THEN GOSUB 280 : GOTO 120
  17. 170 IF K$=CHR$(0)+CHR$(115) THEN C=1 : GOTO 120
  18. 180 IF K$=CHR$(0)+CHR$(116) THEN C=80 : GOTO 120
  19. 190 IF K$=CHR$(0)+CHR$(80) THEN GOSUB 300 : GOTO 120
  20. 200 IF K$=CHR$(27) THEN 340
  21. 210 IF K$<CHR$(32) OR K$>CHR$(126) THEN 120
  22. 220 PRINT K$; : IF C=80 THEN GOTO 120 ELSE C=C+1 : GOTO 120
  23. 230 '
  24. 240 IF R=1 THEN RETURN ELSE R=R-1 : RETURN
  25. 250 '
  26. 260 IF C=1 THEN RETURN ELSE C=C-1 : RETURN
  27. 270 '
  28. 280 IF C=80 THEN RETURN ELSE C=C+1 : RETURN
  29. 290 '
  30. 300 IF R=24 THEN RETURN ELSE R=R+1 : RETURN
  31. 310 '
  32. 320 IF ERR=53 THEN CLS : RESUME 90 ELSE CLOSE : CLS : PRINT "ERROR ";ERR;" AT ";ERL : KEY ON : END
  33. 330 '
  34. 340 F=0 : C=0 : R=0 : P$="" : T=0 : S=0 : L$=""
  35. 350 FOR R1=1 TO 24
  36. 360 FOR C1=1 TO 80
  37. 370 K$=CHR$(SCREEN(R1,C1))
  38. 380 IF K$="^" THEN GOSUB 490 : GOTO 450
  39. 390 IF K$="~" THEN GOSUB 540 : GOTO 450
  40. 400 IF F=0 AND K$=" " THEN L$=K$ : GOTO 450
  41. 410 IF F=0 AND K$<>" " THEN L$=K$ : P$=P$+K$ : C=C1 : R=R1 : F=1 : GOTO 450 
  42. 420 IF F=1 AND K$=" " AND L$=K$ THEN GOSUB 590 : GOTO 450
  43. 430 IF F=2 AND K$=" " THEN GOSUB 590 : GOTO 450
  44. 440 P$=P$+K$ : L$=K$
  45. 450 NEXT C1
  46. 460 NEXT R1
  47. 470 CLOSE : CHAIN "MENU.BAS"
  48. 480 '
  49. 490 T=1 : S=S+1
  50. 500 IF F=0 THEN R=R1 : C=C1-1 : F=2 : RETURN
  51. 510 IF F=1 THEN F=2
  52. 520 RETURN
  53. 530 '
  54. 540 T=2 : S=S+1
  55. 550 IF F=0 THEN R=R1 : C=C1-1 : F=2 : RETURN
  56. 560 IF F=1 THEN F=2
  57. 570 RETURN
  58. 580 '
  59. 590 IF P$<>"" THEN P$=LEFT$(P$,LEN(P$)-1)
  60. 600 PRINT #1,R;",";C;",";P$;",";T;",";S
  61. 610 F=0 : C=0 : R=0 : P$="" : T=0 : S=0 : L$=" "
  62. 620 RETURN
  63.